ConfigureChecks.cmake

   1 include(CheckIncludeFile)
   2 include(CheckSymbolExists)
   3 include(CheckFunctionExists)
   4 include(CheckLibraryExists)
   5 include(CheckTypeSize)
   6 include(CheckStructHasMember)
   7 include(CheckPrototypeDefinition)
   8 include(TestBigEndian)
   9
  10 set(PACKAGE ${PROJECT_NAME})
  11 set(VERSION ${PROJECT_VERSION})
  12 set(DATADIR ${DATA_INSTALL_DIR})
  13 set(LIBDIR ${LIB_INSTALL_DIR})
  14 set(PLUGINDIR "${PLUGIN_INSTALL_DIR}-${LIBRARY_SOVERSION}")
  15 set(SYSCONFDIR ${SYSCONF_INSTALL_DIR})
  16
  17 set(BINARYDIR ${CMAKE_BINARY_DIR})
  18 set(SOURCEDIR ${CMAKE_SOURCE_DIR})
  19
  20 function(COMPILER_DUMPVERSION _OUTPUT_VERSION)
  21     # Remove whitespaces from the argument.
  22     # This is needed for CC="ccache gcc" cmake ..
  23     string(REPLACE " " "" _C_COMPILER_ARG "${CMAKE_C_COMPILER_ARG1}")
  24
  25     execute_process(
  26         COMMAND
  27             ${CMAKE_C_COMPILER} ${_C_COMPILER_ARG} -dumpversion
  28         OUTPUT_VARIABLE _COMPILER_VERSION
  29     )
  30
  31     string(REGEX REPLACE "([0-9])\\.([0-9])(\\.[0-9])?" "\\1\\2"
  32            _COMPILER_VERSION "${_COMPILER_VERSION}")
  33
  34     set(${_OUTPUT_VERSION} ${_COMPILER_VERSION} PARENT_SCOPE)
  35 endfunction()
  36
  37 if(CMAKE_COMPILER_IS_GNUCC AND NOT MINGW AND NOT OS2)
  38     compiler_dumpversion(GNUCC_VERSION)
  39     if (NOT GNUCC_VERSION EQUAL 34)
  40         set(CMAKE_REQUIRED_FLAGS "-fvisibility=hidden")
  41         check_c_source_compiles(
  42 "void __attribute__((visibility(\"default\"))) test() {}
  43 int main(void){ return 0; }
  44 " WITH_VISIBILITY_HIDDEN)
  45         unset(CMAKE_REQUIRED_FLAGS)
  46     endif (NOT GNUCC_VERSION EQUAL 34)
  47 endif(CMAKE_COMPILER_IS_GNUCC AND NOT MINGW AND NOT OS2)
  48
  49 # HEADERS
  50 check_include_file(sys/filio.h HAVE_SYS_FILIO_H)
  51 check_include_file(sys/signalfd.h HAVE_SYS_SIGNALFD_H)
  52 check_include_file(sys/eventfd.h HAVE_SYS_EVENTFD_H)
  53 check_include_file(sys/timerfd.h HAVE_SYS_TIMERFD_H)
  54 check_include_file(gnu/lib-names.h HAVE_GNU_LIB_NAMES_H)
  55 check_include_file(rpc/rpc.h HAVE_RPC_RPC_H)
  56
  57 # FUNCTIONS
  58 check_function_exists(strncpy HAVE_STRNCPY)
  59 check_function_exists(vsnprintf HAVE_VSNPRINTF)
  60 check_function_exists(snprintf HAVE_SNPRINTF)
  61 check_function_exists(signalfd HAVE_SIGNALFD)
  62 check_function_exists(eventfd HAVE_EVENTFD)
  63 check_function_exists(timerfd_create HAVE_TIMERFD_CREATE)
  64 check_function_exists(bindresvport HAVE_BINDRESVPORT)
  65 check_function_exists(accept4 HAVE_ACCEPT4)
  66 check_function_exists(open64 HAVE_OPEN64)
  67 check_function_exists(fopen64 HAVE_FOPEN64)
  68
  69 check_function_exists(pledge HAVE_PLEDGE)
  70
  71
  72 if (UNIX)
  73     if (NOT LINUX)
  74         # libsocket (Solaris)
  75         check_library_exists(socket getaddrinfo "" HAVE_LIBSOCKET)
  76         if (HAVE_LIBSOCKET)
  77           set(_REQUIRED_LIBRARIES ${_REQUIRED_LIBRARIES} socket)
  78         endif (HAVE_LIBSOCKET)
  79
  80         # libnsl/inet_pton (Solaris)
  81         check_library_exists(nsl inet_pton "" HAVE_LIBNSL)
  82         if (HAVE_LIBNSL)
  83             set(_REQUIRED_LIBRARIES ${_REQUIRED_LIBRARIES} nsl)
  84         endif (HAVE_LIBNSL)
  85     endif (NOT LINUX)
  86
  87     check_function_exists(getaddrinfo HAVE_GETADDRINFO)
  88 endif (UNIX)
  89
  90 set(SWRAP_REQUIRED_LIBRARIES ${_REQUIRED_LIBRARIES} CACHE INTERNAL "socket_wrapper required system libraries")
  91
  92 # STRUCTS
  93 check_struct_has_member("struct in_pktinfo" ipi_addr "sys/types.h;sys/socket.h;netinet/in.h" HAVE_STRUCT_IN_PKTINFO)
  94 set(CMAKE_REQUIRED_FLAGS -D_GNU_SOURCE)
  95 check_struct_has_member("struct in6_pktinfo" ipi6_addr "sys/types.h;sys/socket.h;netinet/in.h" HAVE_STRUCT_IN6_PKTINFO)
  96 unset(CMAKE_REQUIRED_FLAGS)
  97
  98 # STRUCT MEMBERS
  99 check_struct_has_member("struct sockaddr" sa_len "sys/types.h;sys/socket.h;netinet/in.h" HAVE_STRUCT_SOCKADDR_SA_LEN)
 100 check_struct_has_member("struct msghdr" msg_control "sys/types.h;sys/socket.h" HAVE_STRUCT_MSGHDR_MSG_CONTROL)
 101
 102 # PROTOTYPES
 103 check_prototype_definition(gettimeofday
 104     "int gettimeofday(struct timeval *tv, struct timezone *tz)"
 105     "-1"
 106     "sys/time.h"
 107     HAVE_GETTIMEOFDAY_TZ)
 108
 109 check_prototype_definition(gettimeofday
 110     "int gettimeofday(struct timeval *tv, void *tzp)"
 111     "-1"
 112     "sys/time.h"
 113     HAVE_GETTIMEOFDAY_TZ_VOID)
 114
 115 check_prototype_definition(accept
 116     "int accept(int s, struct sockaddr *addr, Psocklen_t addrlen)"
 117     "-1"
 118     "sys/types.h;sys/socket.h"
 119     HAVE_ACCEPT_PSOCKLEN_T)
 120
 121 check_prototype_definition(ioctl
 122     "int ioctl(int s, int r, ...)"
 123     "-1"
 124     "unistd.h;sys/ioctl.h"
 125     HAVE_IOCTL_INT)
 126
 127 if (HAVE_EVENTFD)
 128     check_prototype_definition(eventfd
 129         "int eventfd(unsigned int count, int flags)"
 130         "-1"
 131         "sys/eventfd.h"
 132         HAVE_EVENTFD_UNSIGNED_INT)
 133 endif (HAVE_EVENTFD)
 134
 135 # IPV6
 136 check_c_source_compiles("
 137     #include <stdlib.h>
 138     #include <sys/socket.h>
 139     #include <netdb.h>
 140     #include <netinet/in.h>
 141     #include <net/if.h>
 142
 143 int main(void) {
 144     struct sockaddr_storage sa_store;
 145     struct addrinfo *ai = NULL;
 146     struct in6_addr in6addr;
 147     int idx = if_nametoindex(\"iface1\");
 148     int s = socket(AF_INET6, SOCK_STREAM, 0);
 149     int ret = getaddrinfo(NULL, NULL, NULL, &ai);
 150     if (ret != 0) {
 151         const char *es = gai_strerror(ret);
 152     }
 153
 154     freeaddrinfo(ai);
 155     {
 156         int val = 1;
 157 #ifdef HAVE_LINUX_IPV6_V6ONLY_26
 158 #define IPV6_V6ONLY 26
 159 #endif
 160         ret = setsockopt(s, IPPROTO_IPV6, IPV6_V6ONLY,
 161                          (const void *)&val, sizeof(val));
 162     }
 163
 164     return 0;
 165 }" HAVE_IPV6)
 166
 167 check_c_source_compiles("
 168 #include <sys/socket.h>
 169
 170 int main(void) {
 171     struct sockaddr_storage s;
 172
 173     return 0;
 174 }" HAVE_SOCKADDR_STORAGE)
 175
 176 ###########################################################
 177 # For detecting attributes we need to treat warnings as
 178 # errors
 179 set(CMAKE_REQUIRED_FLAGS "-Werror")
 180
 181 check_c_source_compiles("
 182 void test_constructor_attribute(void) __attribute__ ((constructor));
 183
 184 void test_constructor_attribute(void)
 185 {
 186     return;
 187 }
 188
 189 int main(void) {
 190     return 0;
 191 }" HAVE_CONSTRUCTOR_ATTRIBUTE)
 192
 193 check_c_source_compiles("
 194 void test_destructor_attribute(void) __attribute__ ((destructor));
 195
 196 void test_destructor_attribute(void)
 197 {
 198     return;
 199 }
 200
 201 int main(void) {
 202     return 0;
 203 }" HAVE_DESTRUCTOR_ATTRIBUTE)
 204
 205 check_c_source_compiles("
 206 #define FALL_THROUGH __attribute__((fallthrough))
 207
 208 int main(void) {
 209     int i = 2;
 210
 211     switch (i) {
 212     case 0:
 213         FALL_THROUGH;
 214     case 1:
 215         break;
 216     default:
 217         break;
 218     }
 219
 220     return 0;
 221 }" HAVE_FALLTHROUGH_ATTRIBUTE)
 222
 223 check_c_source_compiles("
 224 __thread int tls;
 225
 226 int main(void) {
 227     return 0;
 228 }" HAVE_GCC_THREAD_LOCAL_STORAGE)
 229
 230 check_c_source_compiles("
 231 void log_fn(const char *format, ...) __attribute__ ((format (printf, 1, 2)));
 232
 233 int main(void) {
 234     return 0;
 235 }" HAVE_FUNCTION_ATTRIBUTE_FORMAT)
 236
 237 check_c_source_compiles("
 238 void test_address_sanitizer_attribute(void) __attribute__((no_sanitize_address));
 239
 240 void test_address_sanitizer_attribute(void)
 241 {
 242     return;
 243 }
 244
 245 int main(void) {
 246     return 0;
 247 }" HAVE_ADDRESS_SANITIZER_ATTRIBUTE)
 248
 249 # Stop treating wanrings as errors
 250 unset(CMAKE_REQUIRED_FLAGS)
 251 ###########################################################
 252
 253 check_library_exists(dl dlopen "" HAVE_LIBDL)
 254 if (HAVE_LIBDL)
 255     find_library(DLFCN_LIBRARY dl)
 256     set(_REQUIRED_LIBRARIES ${_REQUIRED_LIBRARIES} ${DLFCN_LIBRARY})
 257 endif (HAVE_LIBDL)
 258
 259 if (OSX)
 260     set(HAVE_APPLE 1)
 261 endif (OSX)
 262
 263 # ENDIAN
 264 if (NOT WIN32)
 265     test_big_endian(WORDS_BIGENDIAN)
 266 endif (NOT WIN32)
 267
 268 check_type_size(pid_t SIZEOF_PID_T)
 269
 270 set(SWRAP_REQUIRED_LIBRARIES ${_REQUIRED_LIBRARIES} CACHE INTERNAL "swrap required system libraries")