configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([rsync],[ ],[https://rsync.samba.org/bug-tracking.html])
   4
   5 AC_C_BIGENDIAN
   6 AC_HEADER_DIRENT
   7 AC_HEADER_TIME
   8 AC_HEADER_SYS_WAIT
   9 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
  10     unistd.h utime.h compat.h sys/param.h ctype.h sys/wait.h sys/stat.h \
  11     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h grp.h \
  12     sys/un.h sys/attr.h arpa/inet.h arpa/nameser.h locale.h sys/types.h \
  13     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h mcheck.h \
  14     sys/acl.h acl/libacl.h attr/xattr.h sys/xattr.h sys/extattr.h dl.h \
  15     popt.h popt/popt.h linux/falloc.h netinet/in_systm.h netgroup.h \
  16     zlib.h xxhash.h openssl/md4.h openssl/md5.h zstd.h lz4.h sys/file.h \
  17     bsd/string.h)
  18 AC_CHECK_HEADERS([netinet/ip.h], [], [], [[#include <netinet/in.h>]])
  19 AC_HEADER_MAJOR_FIXED
  20
  21 AC_CONFIG_MACRO_DIR([m4])
  22 AC_CONFIG_SRCDIR([byteorder.h])
  23 AC_CONFIG_HEADER(config.h)
  24 AC_PREREQ([2.69])
  25
  26 PACKAGE_VERSION=`sed -n 's/.*RSYNC_VERSION.*"\(.*\)".*/\1/p' <$srcdir/version.h`
  27
  28 AC_MSG_NOTICE([Configuring rsync $PACKAGE_VERSION])
  29
  30 LDFLAGS=${LDFLAGS-""}
  31
  32 AC_CANONICAL_HOST
  33
  34 dnl define the directory for replacement function since AC_LIBOBJ does not
  35 dnl officially support subdirs and fails with automake
  36 AC_CONFIG_LIBOBJ_DIR([lib])
  37
  38 # We must decide this before testing the compiler.
  39
  40 # Please allow this to default to yes, so that your users have more
  41 # chance of getting a useful stack trace if problems occur.
  42
  43 AC_MSG_CHECKING([whether to include debugging symbols])
  44 AC_ARG_ENABLE(debug,
  45         AS_HELP_STRING([--disable-debug],[disable to omit debugging symbols and features]))
  46
  47 if test x"$enable_debug" = x"no"; then
  48     AC_MSG_RESULT(no)
  49     ac_cv_prog_cc_g=no
  50 else
  51     AC_MSG_RESULT([yes])
  52     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  53     # leave ac_cv_prog_cc_g alone; AC_PROG_CC will try to include -g if it can
  54 fi
  55
  56 dnl Checks for programs.
  57 AC_PROG_CC
  58 AC_PROG_CPP
  59 AC_PROG_CXX
  60 AC_PROG_AWK
  61 AC_PROG_EGREP
  62 AC_PROG_INSTALL
  63 AC_PROG_MKDIR_P
  64 AC_PROG_CC_STDC
  65 AC_SUBST(SHELL)
  66 AC_PATH_PROG([PERL], [perl])
  67 AC_PATH_PROG([PYTHON3], [python3])
  68
  69 AC_DEFINE([_GNU_SOURCE], 1,
  70           [Define _GNU_SOURCE so that we get all necessary prototypes])
  71
  72 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  73         AC_MSG_WARN([rsync requires an ANSI C compiler and you do not seem to have one])
  74 fi
  75
  76 no_lib=''
  77 err_msg=''
  78 nl='
  79 '
  80
  81 AC_ARG_ENABLE(profile,
  82         AS_HELP_STRING([--enable-profile],[enable to turn on CPU profiling]))
  83 if test x"$enable_profile" = x"yes"; then
  84         CFLAGS="$CFLAGS -pg"
  85 fi
  86
  87 AC_MSG_CHECKING([if md2man can create manpages])
  88 if test x"$ac_cv_path_PYTHON3" = x; then
  89     AC_MSG_RESULT(no - python3 not found)
  90     md2man_works=no
  91 else
  92     md2man_out=`"$srcdir/md2man" --test "$srcdir/rsync-ssl.1.md" 2>&1`
  93     if test $? = 0; then
  94         AC_MSG_RESULT(yes)
  95         md2man_works=yes
  96     else
  97         AC_MSG_RESULT(no)
  98         md2man_works=no
  99         echo "$md2man_out"
 100     fi
 101 fi
 102
 103 AC_MSG_CHECKING([if we require man-page building])
 104 AC_ARG_ENABLE([md2man],
 105         AS_HELP_STRING([--disable-md2man],[disable to omit manpage creation]))
 106 if test x"$enable_md2man" != x"no"; then
 107     if test -f "$srcdir/rsync.1"; then
 108         AC_MSG_RESULT(optional)
 109     else
 110         AC_MSG_RESULT(required)
 111         if test x"$md2man_works" = x"no"; then
 112             err_msg="$err_msg$nl- You need python3 and either the cmarkgfm OR commonmark python3 lib in order"
 113             err_msg="$err_msg$nl  to build manpages based on the git source (manpages are included in the"
 114             err_msg="$err_msg$nl  official release tar files)."
 115             no_lib="$no_lib md2man"
 116         fi
 117     fi
 118     MAKE_MAN=man
 119 else
 120     AC_MSG_RESULT(no)
 121 fi
 122
 123 # Specifically, this turns on panic_action handling.
 124 AC_ARG_ENABLE(maintainer-mode,
 125         AS_HELP_STRING([--enable-maintainer-mode],[enable to turn on extra debug features]))
 126 if test x"$enable_maintainer_mode" = x"yes"; then
 127         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
 128 fi
 129
 130 # This is needed for our included version of popt.  Kind of silly, but
 131 # I don't want our version too far out of sync.
 132 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
 133
 134 # If GCC, turn on warnings.
 135 if test x"$GCC" = x"yes"; then
 136         CFLAGS="$CFLAGS -Wall -W"
 137 fi
 138
 139 AC_ARG_WITH(rrsync,
 140         AS_HELP_STRING([--with-rrsync],[also install the rrsync script and its manpage]))
 141 if test x"$with_rrsync" != x"yes"; then
 142     with_rrsync=no
 143 else
 144     MAKE_RRSYNC='rrsync'
 145     MAKE_RRSYNC_1='rrsync.1'
 146     GEN_RRSYNC='rrsync.1 rrsync.1.html'
 147 fi
 148 AC_SUBST(with_rrsync)
 149
 150 AC_ARG_WITH(included-popt,
 151         AS_HELP_STRING([--with-included-popt],[use bundled popt library, not from system]))
 152
 153 AC_ARG_WITH(included-zlib,
 154         AS_HELP_STRING([--with-included-zlib],[use bundled zlib library, not from system]))
 155
 156 AC_ARG_WITH(protected-args,
 157         AS_HELP_STRING([--with-protected-args],[make --protected-args option the default]))
 158 if test x"$with_protected_args" = x"yes"; then
 159         AC_DEFINE_UNQUOTED(RSYNC_USE_PROTECTED_ARGS, 1, [Define to 1 if --protected-args should be the default])
 160 fi
 161
 162 AC_ARG_WITH(rsync-path,
 163         AS_HELP_STRING([--with-rsync-path=PATH],[set default --rsync-path to PATH (default: rsync)]),
 164         [ RSYNC_PATH="$with_rsync_path" ],
 165         [ RSYNC_PATH="rsync" ])
 166
 167 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
 168
 169 AC_ARG_WITH(rsyncd-conf,
 170         AS_HELP_STRING([--with-rsyncd-conf=PATH],[set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
 171         [ if test ! -z "$with_rsyncd_conf" ; then
 172                 case $with_rsyncd_conf in
 173                         yes|no)
 174                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 175                                 ;;
 176                         /*)
 177                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
 178                                 ;;
 179                         *)
 180                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 181                                 ;;
 182                 esac
 183         else
 184                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 185         fi ],
 186         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 187
 188 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 189
 190 AC_ARG_WITH(rsh,
 191         AS_HELP_STRING([--with-rsh=CMD],[set remote shell command to CMD (default: ssh)]))
 192
 193 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 194 if test x$HAVE_REMSH = x1; then
 195         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 196 fi
 197
 198 if test x"$with_rsh" != x; then
 199         RSYNC_RSH="$with_rsh"
 200 else
 201         RSYNC_RSH="ssh"
 202 fi
 203 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 204
 205 # Some programs on solaris are only found in /usr/xpg4/bin (or work better than others versions).
 206 AC_PATH_PROG(SHELL_PATH, sh, /bin/sh, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 207 AC_PATH_PROG(FAKEROOT_PATH, fakeroot, /usr/bin/fakeroot, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 208
 209 AC_ARG_WITH(nobody-user,
 210     AS_HELP_STRING([--with-nobody-user=USER],[set the default unprivileged user (default nobody)]),
 211     [ NOBODY_USER="$with_nobody_user" ],
 212     [ NOBODY_USER="nobody" ])
 213
 214 AC_ARG_WITH(nobody-group,
 215     AS_HELP_STRING([--with-nobody-group=GROUP],[set the default unprivileged group (default nobody or nogroup)]),
 216     [ NOBODY_GROUP="$with_nobody_group" ])
 217
 218 if test x"$with_nobody_group" = x; then
 219     AC_MSG_CHECKING([the group for user "nobody"])
 220     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 221         NOBODY_GROUP=nobody
 222     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 223         NOBODY_GROUP=nogroup
 224     else
 225         NOBODY_GROUP=nobody # test for others?
 226     fi
 227     AC_MSG_RESULT($NOBODY_GROUP)
 228 fi
 229
 230 AC_DEFINE_UNQUOTED(NOBODY_USER, "$NOBODY_USER", [unprivileged user--e.g. nobody])
 231 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 232
 233 # rolling-checksum SIMD optimizations
 234 ROLL_SIMD=
 235
 236 AC_MSG_CHECKING([whether to enable rolling-checksum SIMD optimizations])
 237 AC_ARG_ENABLE(roll-simd,
 238     AS_HELP_STRING([--enable-roll-simd],[enable/disable to control rolling-checksum SIMD optimizations (requires c++)]))
 239
 240 # Clag is crashing with -g -O2, so we'll get rid of -g for now.
 241 CXXFLAGS=`echo "$CXXFLAGS" | sed 's/-g //'`
 242 m4_define(SIMD_X86_64_TEST, [[#include <stdio.h>
 243 #if HAVE_STDLIB_H
 244 #include <stdlib.h>
 245 #endif
 246 #include <immintrin.h>
 247 __attribute__ ((target("default"))) int test_ssse3(int x) { return x; }
 248 __attribute__ ((target("default"))) int test_sse2(int x) { return x; }
 249 __attribute__ ((target("default"))) int test_avx2(int x) { return x; }
 250 __attribute__ ((target("ssse3"))) int test_ssse3(int x) { return x; }
 251 __attribute__ ((target("sse2"))) int test_sse2(int x) { return x; }
 252 __attribute__ ((target("avx2"))) int test_avx2(int x) { return x; }
 253 typedef long long __m128i_u __attribute__((__vector_size__(16), __may_alias__, __aligned__(1)));
 254 typedef long long __m256i_u __attribute__((__vector_size__(32), __may_alias__, __aligned__(1)));
 255 __attribute__ ((target("default"))) void more_testing(char* buf, int len) { }
 256 __attribute__ ((target("ssse3"))) void more_testing(char* buf, int len)
 257 {
 258     int i;
 259     for (i = 0; i < (len-32); i+=32) {
 260         __m128i in8_1, in8_2;
 261         in8_1 = _mm_lddqu_si128((__m128i_u*)&buf[i]);
 262         in8_2 = _mm_lddqu_si128((__m128i_u*)&buf[i + 16]);
 263     }
 264 }
 265 ]])
 266
 267 if test x"$enable_roll_simd" = x""; then
 268     case "$host_os" in
 269         *linux*) ;;
 270         *) enable_roll_simd=no ;;
 271     esac
 272 fi
 273
 274 if test x"$enable_roll_simd" != x"no"; then
 275     # For x86-64 SIMD, g++ >=5 or clang++ >=7 is required
 276     if test x"$host_cpu" = x"x86_64" || test x"$host_cpu" = x"amd64"; then
 277         AC_LANG(C++)
 278         if test x"$host" = x"$build"; then
 279             AC_RUN_IFELSE([AC_LANG_PROGRAM([SIMD_X86_64_TEST],[[if (test_ssse3(42) != 42 || test_sse2(42) != 42 || test_avx2(42) != 42) exit(1);]])],
 280                 [CXX_OK=yes],[CXX_OK=no])
 281         else
 282             AC_COMPILE_IFELSE([AC_LANG_PROGRAM([SIMD_X86_64_TEST])],[CXX_OK=yes],[CXX_OK=no])
 283         fi
 284         AC_LANG(C)
 285         if test x"$CXX_OK" = x"yes"; then
 286             # AC_MSG_RESULT() is called below.
 287             ROLL_SIMD="$host_cpu"
 288         elif test x"$enable_roll_simd" = x"yes"; then
 289             AC_MSG_RESULT(error)
 290             AC_MSG_ERROR(The rolling-checksum SIMD compilation test failed.
 291 Omit --enable-roll-simd to continue without it.)
 292         fi
 293     elif test x"$enable_roll_simd" = x"yes"; then
 294         AC_MSG_RESULT(unavailable)
 295         AC_MSG_ERROR(The rolling-checksum SIMD optimizations are currently x86_64|amd64 only.
 296 Omit --enable-roll-simd to continue without it.)
 297     fi
 298 fi
 299
 300 if test x"$ROLL_SIMD" != x""; then
 301     AC_MSG_RESULT([yes ($ROLL_SIMD)])
 302     AC_DEFINE(USE_ROLL_SIMD, 1, [Define to 1 to enable rolling-checksum SIMD optimizations])
 303     ROLL_SIMD='$(ROLL_SIMD_'"$ROLL_SIMD)"
 304     # We only use c++ for its target attribute dispatching, disable unneeded bulky features
 305     CXXFLAGS="$CXXFLAGS -fno-exceptions -fno-rtti"
 306     # Apple often has "g++" as a symlink for clang. Try to find out the truth.
 307     CXX_VERSION=`$CXX --version 2>/dev/null | head -n 2`
 308     case "$CXX_VERSION" in
 309     *clang*) CXXFLAGS="$CXXFLAGS -fno-slp-vectorize" ;; # avoid a performance hit
 310     esac
 311 else
 312     AC_MSG_RESULT(no)
 313 fi
 314
 315 AC_SUBST(ROLL_SIMD)
 316
 317 AC_MSG_CHECKING([if assembler accepts noexecstack])
 318 OLD_CFLAGS="$CFLAGS"
 319 CFLAGS="$CFLAGS -Wa,--noexecstack"
 320 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ ]], [[return 0;]])],
 321 [ NOEXECSTACK='-Wa,--noexecstack' ; AC_MSG_RESULT(yes) ],
 322 [ NOEXECSTACK='' ; AC_MSG_RESULT(no) ])
 323 CFLAGS="$OLD_CFLAGS"
 324 AC_SUBST(NOEXECSTACK)
 325
 326 # arrgh. libc in some old debian version screwed up the largefile
 327 # stuff, getting byte range locking wrong
 328 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 329 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 330 #define _FILE_OFFSET_BITS 64
 331 $ac_includes_default
 332 #ifdef HAVE_FCNTL_H
 333 # include <fcntl.h>
 334 #elif defined HAVE_SYS_FCNTL_H
 335 # include <sys/fcntl.h>
 336 #endif
 337 #ifdef HAVE_SYS_WAIT_H
 338 #include <sys/wait.h>
 339 #endif
 340
 341 int main(void)
 342 {
 343         struct flock lock;
 344         int status;
 345         char tpl[32] = "/tmp/locktest.XXXXXX";
 346         int fd = mkstemp(tpl);
 347         if (fd < 0) {
 348                 strcpy(tpl, "conftest.dat");
 349                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 350         }
 351
 352         lock.l_type = F_WRLCK;
 353         lock.l_whence = SEEK_SET;
 354         lock.l_start = 0;
 355         lock.l_len = 1;
 356         lock.l_pid = 0;
 357         fcntl(fd,F_SETLK,&lock);
 358         if (fork() == 0) {
 359                 lock.l_start = 1;
 360                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 361         }
 362         wait(&status);
 363         unlink(tpl);
 364         return WEXITSTATUS(status);
 365 }
 366 ]])],[rsync_cv_HAVE_BROKEN_LARGEFILE=yes],[rsync_cv_HAVE_BROKEN_LARGEFILE=no],[rsync_cv_HAVE_BROKEN_LARGEFILE=cross])])
 367 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 368    AC_SYS_LARGEFILE
 369 fi
 370
 371 AC_MSG_CHECKING([whether to enable ipv6])
 372 AC_ARG_ENABLE(ipv6,
 373 AS_HELP_STRING([--disable-ipv6],[disable to omit ipv6 support]),
 374 [ case "$enableval" in
 375   no)
 376         AC_MSG_RESULT(no)
 377         ;;
 378   *)    AC_MSG_RESULT(yes)
 379         AC_DEFINE(INET6, 1, [true if you have IPv6])
 380         ;;
 381   esac ],
 382
 383   AC_TRY_RUN([ /* AF_INET6 availability check */
 384 #include <stdlib.h>
 385 #include <sys/types.h>
 386 #include <sys/socket.h>
 387 main()
 388 {
 389    if (socket(AF_INET6, SOCK_STREAM, 0) < 0)
 390      exit(1);
 391    else
 392      exit(0);
 393 }
 394 ],
 395   AC_MSG_RESULT(yes)
 396   AC_DEFINE(INET6, 1, [true if you have IPv6]),
 397   AC_MSG_RESULT(no),
 398   AC_MSG_RESULT(no)
 399 ))
 400
 401 dnl Do you want to disable use of locale functions
 402 AC_ARG_ENABLE([locale],
 403         AS_HELP_STRING([--disable-locale],[disable to omit locale features]))
 404 AH_TEMPLATE([CONFIG_LOCALE],
 405 [Undefine if you do not want locale features.  By default this is defined.])
 406 if test x"$enable_locale" != x"no"; then
 407         AC_DEFINE(CONFIG_LOCALE)
 408 fi
 409
 410 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 411 case $host_os in
 412         *cygwin* ) AC_MSG_RESULT(yes)
 413                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 414                             [Define to 1 if sockets need to be shutdown])
 415                    ;;
 416                * ) AC_MSG_RESULT(no);;
 417 esac
 418
 419 AC_MSG_CHECKING([whether to enable use of openssl crypto library])
 420 AC_ARG_ENABLE([openssl],
 421         AS_HELP_STRING([--disable-openssl],[disable to omit openssl crypto library]))
 422 AH_TEMPLATE([USE_OPENSSL],
 423 [Undefine if you do not want to use openssl crypto library.  By default this is defined.])
 424 if test x"$enable_openssl" != x"no"; then
 425     if test x"$ac_cv_header_openssl_md4_h" = x"yes" && test x"$ac_cv_header_openssl_md5_h" = x"yes"; then
 426       AC_MSG_RESULT(yes)
 427       AC_SEARCH_LIBS(MD5_Init, crypto,
 428           [AC_DEFINE(USE_OPENSSL)
 429            enable_openssl=yes],
 430           [err_msg="$err_msg$nl- Failed to find MD5_Init function in openssl crypto lib.";
 431            no_lib="$no_lib openssl"])
 432     else
 433         AC_MSG_RESULT(no)
 434         err_msg="$err_msg$nl- Failed to find openssl/md4.h and openssl/md5.h for openssl crypto lib support."
 435         no_lib="$no_lib openssl"
 436     fi
 437     if test x"$enable_md5_asm" != x"yes"; then
 438         enable_md5_asm=no
 439     fi
 440 else
 441     AC_MSG_RESULT(no)
 442 fi
 443
 444 MD5_ASM=
 445
 446 AC_MSG_CHECKING([whether to enable MD5 ASM optimizations])
 447 AC_ARG_ENABLE(md5-asm,
 448     AS_HELP_STRING([--enable-md5-asm],[enable/disable to control MD5 ASM optimizations]))
 449
 450 if test x"$enable_md5_asm" = x""; then
 451     case "$host_os" in
 452         *linux*) ;;
 453         *) enable_md5_asm=no ;;
 454     esac
 455 fi
 456
 457 if test x"$enable_md5_asm" != x"no"; then
 458     if test x"$host_cpu" = x"x86_64" || test x"$host_cpu" = x"amd64"; then
 459         MD5_ASM="$host_cpu"
 460     elif test x"$enable_md5_asm" = x"yes"; then
 461         AC_MSG_RESULT(unavailable)
 462         AC_MSG_ERROR(The ASM optimizations are currently x86_64|amd64 only.
 463 Omit --enable-md5-asm to continue without it.)
 464     fi
 465 fi
 466
 467 if test x"$MD5_ASM" != x""; then
 468     AC_MSG_RESULT([yes ($MD5_ASM)])
 469     AC_DEFINE(USE_MD5_ASM, 1, [Define to 1 to enable MD5 ASM optimizations])
 470     MD5_ASM='$(MD5_ASM_'"$MD5_ASM)"
 471 else
 472     AC_MSG_RESULT(no)
 473 fi
 474
 475 AC_SUBST(MD5_ASM)
 476
 477 ROLL_ASM=
 478
 479 AC_MSG_CHECKING([whether to enable rolling-checksum ASM optimizations])
 480 AC_ARG_ENABLE(roll-asm,
 481     AS_HELP_STRING([--enable-roll-asm],[enable/disable to control rolling-checksum ASM optimizations (requires --enable-roll-simd)]))
 482
 483 if test x"$ROLL_SIMD" = x""; then
 484     enable_roll_asm=no
 485 fi
 486
 487 if test x"$enable_roll_asm" = x"yes"; then
 488     ROLL_ASM="$host_cpu"
 489     AC_MSG_RESULT([yes ($ROLL_ASM)])
 490     AC_DEFINE(USE_ROLL_ASM, 1, [Define to 1 to enable rolling-checksum ASM optimizations (requires --enable-roll-simd)])
 491     ROLL_ASM='$(ROLL_ASM_'"$ROLL_ASM)"
 492 else
 493     AC_MSG_RESULT(no)
 494 fi
 495
 496 AC_SUBST(ROLL_ASM)
 497
 498 AC_MSG_CHECKING([whether to enable xxhash checksum support])
 499 AC_ARG_ENABLE([xxhash],
 500         AS_HELP_STRING([--disable-xxhash],[disable to omit xxhash checksums]))
 501 AH_TEMPLATE([SUPPORT_XXHASH],
 502 [Undefine if you do not want xxhash checksums.  By default this is defined.])
 503 if test x"$enable_xxhash" != x"no"; then
 504     if test x"$ac_cv_header_xxhash_h" = x"yes"; then
 505         AC_MSG_RESULT(yes)
 506         AC_SEARCH_LIBS(XXH64_createState, xxhash,
 507             [AC_DEFINE(SUPPORT_XXHASH)],
 508             [err_msg="$err_msg$nl- Failed to find XXH64_createState function in xxhash lib.";
 509              no_lib="$no_lib xxhash"])
 510     else
 511         AC_MSG_RESULT(no)
 512         err_msg="$err_msg$nl- Failed to find xxhash.h for xxhash checksum support.";
 513         no_lib="$no_lib xxhash"
 514     fi
 515 else
 516     AC_MSG_RESULT(no)
 517 fi
 518
 519 AC_MSG_CHECKING([whether to enable zstd compression])
 520 AC_ARG_ENABLE([zstd],
 521         AC_HELP_STRING([--disable-zstd], [disable to omit zstd compression]))
 522 AH_TEMPLATE([SUPPORT_ZSTD],
 523 [Undefine if you do not want zstd compression.  By default this is defined.])
 524 if test x"$enable_zstd" != x"no"; then
 525     if test x"$ac_cv_header_zstd_h" = x"yes"; then
 526         AC_MSG_RESULT(yes)
 527         AC_SEARCH_LIBS(ZSTD_minCLevel, zstd,
 528             [AC_DEFINE(SUPPORT_ZSTD)],
 529             [err_msg="$err_msg$nl- Failed to find ZSTD_minCLevel function in zstd lib.";
 530              no_lib="$no_lib zstd"])
 531     else
 532         AC_MSG_RESULT(no)
 533         err_msg="$err_msg$nl- Failed to find zstd.h for zstd compression support.";
 534         no_lib="$no_lib zstd"
 535     fi
 536 else
 537     AC_MSG_RESULT(no)
 538 fi
 539
 540 AC_MSG_CHECKING([whether to enable LZ4 compression])
 541 AC_ARG_ENABLE([lz4],
 542         AC_HELP_STRING([--disable-lz4], [disable to omit LZ4 compression]))
 543 AH_TEMPLATE([SUPPORT_LZ4],
 544 [Undefine if you do not want LZ4 compression.  By default this is defined.])
 545 if test x"$enable_lz4" != x"no"; then
 546     if test x"$ac_cv_header_lz4_h" = x"yes"; then
 547         AC_MSG_RESULT(yes)
 548         AC_SEARCH_LIBS(LZ4_compress_default, lz4,
 549             [AC_DEFINE(SUPPORT_LZ4)],
 550             [err_msg="$err_msg$nl- Failed to find LZ4_compress_default function in lz4 lib.";
 551              no_lib="$no_lib lz4"])
 552     else
 553         AC_MSG_RESULT(no)
 554         err_msg="$err_msg$nl- Failed to find lz4.h for lz4 compression support."
 555         no_lib="$no_lib lz4"
 556     fi
 557 else
 558     AC_MSG_RESULT(no)
 559 fi
 560
 561 if test x"$no_lib" != x; then
 562     echo ""
 563     echo "Configure found the following issues:"
 564     echo "$err_msg"
 565     echo ""
 566     echo "See the INSTALL file for hints on how to install the missing libraries and/or"
 567     echo "how to generate (or fetch) manpages:"
 568     echo "    https://github.com/WayneD/rsync/blob/master/INSTALL.md"
 569     echo ""
 570     echo "To disable one or more features, the relevant configure options are:"
 571     for lib in $no_lib; do
 572         echo "    --disable-$lib"
 573     done
 574     echo ""
 575     AC_MSG_ERROR(Aborting configure run)
 576 fi
 577
 578 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
 579 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 580 #ifdef HAVE_SYS_TYPES_H
 581 #include <sys/types.h>
 582 #endif
 583 #ifdef MAJOR_IN_MKDEV
 584 #include <sys/mkdev.h>
 585 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
 586 #  define makedev mkdev
 587 # endif
 588 #elif defined MAJOR_IN_SYSMACROS
 589 #include <sys/sysmacros.h>
 590 #endif
 591
 592 int main(void)
 593 {
 594         dev_t dev = makedev(0, 5, 7);
 595         if (major(dev) != 5 || minor(dev) != 7)
 596                 return 1;
 597         return 0;
 598 }
 599 ]])],[rsync_cv_MAKEDEV_TAKES_3_ARGS=yes],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no])])
 600 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
 601    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
 602 fi
 603
 604 AC_CHECK_SIZEOF(int)
 605 AC_CHECK_SIZEOF(long)
 606 AC_CHECK_SIZEOF(long long)
 607 AC_CHECK_SIZEOF(short)
 608 AC_CHECK_SIZEOF(int16_t)
 609 AC_CHECK_SIZEOF(uint16_t)
 610 AC_CHECK_SIZEOF(int32_t)
 611 AC_CHECK_SIZEOF(uint32_t)
 612 AC_CHECK_SIZEOF(int64_t)
 613 AC_CHECK_SIZEOF(off_t)
 614 AC_CHECK_SIZEOF(off64_t)
 615 AC_CHECK_SIZEOF(time_t)
 616 AC_CHECK_SIZEOF(char*)
 617
 618 AC_C_INLINE
 619
 620 AC_TYPE_LONG_DOUBLE_WIDER
 621 ac_cv_c_long_double=$ac_cv_type_long_double_wider
 622 if test $ac_cv_c_long_double = yes; then
 623   AC_DEFINE([HAVE_LONG_DOUBLE],[1],[Define to 1 if the type `long double' works and has more range or precision than `double'.])
 624 fi
 625
 626 AC_TYPE_UID_T
 627 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
 628 AC_TYPE_GETGROUPS
 629 AC_CHECK_MEMBERS([struct stat.st_rdev,
 630                   struct stat.st_mtimensec,
 631                   struct stat.st_mtimespec.tv_nsec,
 632                   struct stat.st_mtim.tv_nsec],,,[
 633 #ifdef HAVE_SYS_TYPES_H
 634 #include <sys/types.h>
 635 #endif
 636 #ifdef HAVE_SYS_STAT_H
 637 #include <sys/stat.h>
 638 #endif
 639 #ifdef HAVE_UNISTD_H
 640 #include <unistd.h>
 641 #endif])
 642
 643 TYPE_SOCKLEN_T
 644
 645 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 646     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]], [[int i = errno]])],[rsync_cv_errno=yes],[rsync_cv_have_errno_decl=no])])
 647 if test x"$rsync_cv_errno" = x"yes"; then
 648    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 649 fi
 650
 651 # The following test taken from the cvs sources
 652 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 653 # These need checks to be before checks for any other functions that
 654 #    might be in the same libraries.
 655 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 656 # libsocket.so which has a bad implementation of gethostbyname (it
 657 # only looks in /etc/hosts), so we only look for -lsocket if we need
 658 # it.
 659 AC_CHECK_FUNCS(connect)
 660 if test x"$ac_cv_func_connect" = x"no"; then
 661     case "$LIBS" in
 662     *-lnsl*) ;;
 663     *) AC_CHECK_LIB(nsl_s, printf) ;;
 664     esac
 665     case "$LIBS" in
 666     *-lnsl*) ;;
 667     *) AC_CHECK_LIB(nsl, printf) ;;
 668     esac
 669     case "$LIBS" in
 670     *-lsocket*) ;;
 671     *) AC_CHECK_LIB(socket, connect) ;;
 672     esac
 673     case "$LIBS" in
 674     *-linet*) ;;
 675     *) AC_CHECK_LIB(inet, connect) ;;
 676     esac
 677     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 678     dnl has been cached.
 679     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 680        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 681         # ac_cv_func_connect=yes
 682         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 683         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 684     fi
 685 fi
 686
 687 AC_SEARCH_LIBS(inet_ntop, resolv)
 688
 689 # For OS X, Solaris, HP-UX, etc.: figure out if -liconv is needed.  We'll
 690 # accept either iconv_open or libiconv_open, since some include files map
 691 # the former to the latter.
 692 AC_SEARCH_LIBS(iconv_open, iconv)
 693 AC_SEARCH_LIBS(libiconv_open, iconv)
 694
 695 AC_MSG_CHECKING([for iconv declaration])
 696 AC_CACHE_VAL(am_cv_proto_iconv, [
 697     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 698 #if HAVE_STDLIB_H
 699 #include <stdlib.h>
 700 #endif
 701 #include <iconv.h>
 702 extern
 703 #ifdef __cplusplus
 704 "C"
 705 #endif
 706 #if defined(__STDC__) || defined(__cplusplus)
 707 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 708 #else
 709 size_t iconv();
 710 #endif
 711 ]], [[]])],[am_cv_proto_iconv_arg1=""],[am_cv_proto_iconv_arg1="const"])
 712       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 713     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed 's/( /(/'`
 714 AC_MSG_RESULT([$]{ac_t:-
 715          }[$]am_cv_proto_iconv)
 716 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 717                    [Define as const if the declaration of iconv() needs const.])
 718
 719 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 720
 721 AC_REPLACE_FUNCS([inet_ntop inet_pton])
 722
 723 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
 724 AC_HAVE_TYPE([struct sockaddr_storage], [
 725 #ifdef HAVE_SYS_TYPES_H
 726 #include <sys/types.h>
 727 #endif
 728 #ifdef HAVE_SYS_SOCKET_H
 729 #include <sys/socket.h>
 730 #endif])
 731
 732 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 733 #   builtin getaddrinfo if one of the defines don't exist
 734 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 735                rsync_cv_HAVE_GETADDR_DEFINES,[
 736                         AC_EGREP_CPP(yes, [
 737 #ifdef HAVE_SYS_TYPES_H
 738 #include <sys/types.h>
 739 #endif
 740 #ifdef HAVE_SYS_SOCKET_H
 741 #include <sys/socket.h>
 742 #endif
 743 #ifdef HAVE_NETDB_H
 744 #include <netdb.h>
 745 #endif
 746 #ifdef AI_PASSIVE
 747 yes
 748 #endif],
 749                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 750                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 751 AS_IF([test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" && test x"$ac_cv_type_struct_addrinfo" = x"yes"],[
 752         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 753         # something else so we must include <netdb.h> to get the
 754         # redefinition.
 755         AC_CHECK_FUNCS(getaddrinfo, ,
 756                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 757                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 758 #ifdef HAVE_SYS_TYPES_H
 759 #include <sys/types.h>
 760 #endif
 761 #ifdef HAVE_SYS_SOCKET_H
 762 #include <sys/socket.h>
 763 #endif
 764 #include <netdb.h>]], [[getaddrinfo(NULL, NULL, NULL, NULL);]])],[AC_MSG_RESULT([yes])
 765                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 766                                 [Define to 1 if you have the "getaddrinfo" function and required types.])],[AC_MSG_RESULT([no])
 767                         AC_LIBOBJ([getaddrinfo])])])
 768     ],[AC_LIBOBJ([getaddrinfo])])
 769
 770 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 771                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 772                 [],
 773                 [
 774 #ifdef HAVE_SYS_TYPES_H
 775 #include <sys/types.h>
 776 #endif
 777 #ifdef HAVE_SYS_SOCKET_H
 778 #include <sys/socket.h>
 779 #endif
 780 ])
 781
 782 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 783                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 784                 [],
 785                 [
 786 #ifdef HAVE_SYS_TYPES_H
 787 #include <sys/types.h>
 788 #endif
 789 #ifdef HAVE_SYS_SOCKET_H
 790 #include <sys/socket.h>
 791 #endif
 792 #include <netinet/in.h>
 793 ])
 794
 795 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 796                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 797                 [],
 798                 [
 799 #ifdef HAVE_SYS_TYPES_H
 800 #include <sys/types.h>
 801 #endif
 802 #ifdef HAVE_SYS_SOCKET_H
 803 #include <sys/socket.h>
 804 #endif
 805 #include <netinet/in.h>
 806 ])
 807
 808 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 809                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 810                 [],
 811                 [
 812 #ifdef HAVE_SYS_TYPES_H
 813 #include <sys/types.h>
 814 #endif
 815 #ifdef HAVE_SYS_SOCKET_H
 816 #include <sys/socket.h>
 817 #endif
 818 #include <netinet/in.h>
 819 ])
 820
 821 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
 822 #if HAVE_SYS_TYPES_H
 823 # include <sys/types.h>
 824 #endif
 825 #if HAVE_SYS_STAT_H
 826 # include <sys/stat.h>
 827 #endif
 828 #if STDC_HEADERS
 829 # include <stdlib.h>
 830 # include <stddef.h>
 831 #else
 832 # if HAVE_STDLIB_H
 833 #  include <stdlib.h>
 834 # endif
 835 #endif
 836 ])
 837
 838 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 839 #
 840 AC_CHECK_FUNCS(strcasecmp)
 841 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 842     AC_CHECK_LIB(resolv, strcasecmp)
 843 fi
 844
 845 AC_CHECK_FUNCS(aclsort)
 846 if test x"$ac_cv_func_aclsort" = x"no"; then
 847     AC_CHECK_LIB(sec, aclsort)
 848 fi
 849
 850 dnl At the moment we don't test for a broken memcmp(), because all we
 851 dnl need to do is test for equality, not comparison, and it seems that
 852 dnl every platform has a memcmp that can do at least that.
 853 dnl AC_FUNC_MEMCMP
 854
 855 AC_FUNC_UTIME_NULL
 856 AC_FUNC_ALLOCA
 857 AC_CHECK_FUNCS(waitpid wait4 getcwd chown chmod lchmod mknod mkfifo \
 858     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 859     chflags getattrlist mktime innetgr linkat \
 860     memmove lchown vsnprintf snprintf vasprintf asprintf setsid strpbrk \
 861     strlcat strlcpy strtol mallinfo mallinfo2 getgroups setgroups geteuid getegid \
 862     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 863     seteuid strerror putenv iconv_open locale_charset nl_langinfo getxattr \
 864     extattr_get_link sigaction sigprocmask setattrlist getgrouplist \
 865     initgroups utimensat posix_fallocate attropen setvbuf nanosleep usleep \
 866     setenv unsetenv)
 867
 868 dnl cygwin iconv.h defines iconv_open as libiconv_open
 869 if test x"$ac_cv_func_iconv_open" != x"yes"; then
 870     AC_CHECK_FUNC(libiconv_open, [ac_cv_func_iconv_open=yes; AC_DEFINE(HAVE_ICONV_OPEN, 1)])
 871 fi
 872
 873 dnl Preallocation stuff (also fallocate, posix_fallocate function tests above):
 874
 875 AC_CACHE_CHECK([for useable fallocate],rsync_cv_have_fallocate,[
 876 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <fcntl.h>
 877 #ifdef HAVE_SYS_TYPES_H
 878 #include <sys/types.h>
 879 #endif]], [[fallocate(0, 0, 0, 0);]])],[rsync_cv_have_fallocate=yes],[rsync_cv_have_fallocate=no])])
 880 if test x"$rsync_cv_have_fallocate" = x"yes"; then
 881     AC_DEFINE(HAVE_FALLOCATE, 1, [Define to 1 if you have the fallocate function and it compiles and links without error])
 882 fi
 883
 884 AC_MSG_CHECKING([for FALLOC_FL_PUNCH_HOLE])
 885 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 886         #define _GNU_SOURCE 1
 887         #include <linux/falloc.h>
 888         #ifndef FALLOC_FL_PUNCH_HOLE
 889         #error FALLOC_FL_PUNCH_HOLE is missing
 890         #endif
 891     ]])], [
 892         AC_MSG_RESULT([yes])
 893         AC_DEFINE([HAVE_FALLOC_FL_PUNCH_HOLE], [1], [Define if FALLOC_FL_PUNCH_HOLE is available.])
 894     ], [
 895         AC_MSG_RESULT([no])
 896     ]
 897 )
 898
 899 AC_MSG_CHECKING([for FALLOC_FL_ZERO_RANGE])
 900 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 901         #define _GNU_SOURCE 1
 902         #include <linux/falloc.h>
 903         #ifndef FALLOC_FL_ZERO_RANGE
 904         #error FALLOC_FL_ZERO_RANGE is missing
 905         #endif
 906     ]])], [
 907         AC_MSG_RESULT([yes])
 908         AC_DEFINE([HAVE_FALLOC_FL_ZERO_RANGE], [1], [Define if FALLOC_FL_ZERO_RANGE is available.])
 909     ], [
 910         AC_MSG_RESULT([no])
 911     ]
 912 )
 913
 914 AC_CACHE_CHECK([for SYS_fallocate],rsync_cv_have_sys_fallocate,[
 915 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/syscall.h>
 916 #ifdef HAVE_UNISTD_H
 917 #include <unistd.h>
 918 #endif
 919 #ifdef HAVE_SYS_TYPES_H
 920 #include <sys/types.h>
 921 #endif]], [[syscall(SYS_fallocate, 0, 0, (loff_t)0, (loff_t)0);]])],[rsync_cv_have_sys_fallocate=yes],[rsync_cv_have_sys_fallocate=no])])
 922 if test x"$rsync_cv_have_sys_fallocate" = x"yes"; then
 923     AC_DEFINE(HAVE_SYS_FALLOCATE, 1, [Define to 1 if you have the SYS_fallocate syscall number])
 924 fi
 925
 926 if test x"$ac_cv_func_posix_fallocate" = x"yes"; then
 927     AC_MSG_CHECKING([whether posix_fallocate is efficient])
 928     case $host_os in
 929     *cygwin*)
 930         AC_MSG_RESULT(yes)
 931         AC_DEFINE(HAVE_EFFICIENT_POSIX_FALLOCATE, 1,
 932                   [Define if posix_fallocate is efficient (Cygwin)])
 933         ;;
 934     *)
 935         AC_MSG_RESULT(no)
 936         ;;
 937     esac
 938 fi
 939
 940 dnl End of preallocation stuff
 941
 942 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 943 if test $ac_cv_func_getpgrp = yes; then
 944     AC_FUNC_GETPGRP
 945 fi
 946
 947 AC_ARG_ENABLE(iconv-open,
 948     AS_HELP_STRING([--disable-iconv-open],[disable to avoid all use of iconv_open()]),
 949     [], [enable_iconv_open=$ac_cv_func_iconv_open])
 950
 951 if test x"$enable_iconv_open" != x"no"; then
 952     AC_DEFINE(USE_ICONV_OPEN, 1, [Define to 1 if you want rsync to make use of iconv_open()])
 953 fi
 954
 955 AC_ARG_ENABLE(iconv,
 956     AS_HELP_STRING([--disable-iconv],[disable to omit the --iconv option]),
 957     [], [enable_iconv=$enable_iconv_open])
 958 AH_TEMPLATE([ICONV_OPTION],
 959 [Define if you want the --iconv option.  Specifying a value will set the
 960 default iconv setting (a NULL means no --iconv processing by default).])
 961 if test x"$enable_iconv" != x"no"; then
 962         if test x"$enable_iconv" = x"yes"; then
 963                 AC_DEFINE(ICONV_OPTION, NULL)
 964         else
 965                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
 966         fi
 967         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
 968 fi
 969
 970 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
 971   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 972 #if HAVE_UNISTD_H
 973 # include <unistd.h>
 974 #endif
 975 #include <stdlib.h>
 976 #include <errno.h>
 977 int main(void) {
 978         char const *dangling_symlink = "conftest.dangle";
 979         unlink(dangling_symlink);
 980         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 981         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) return 1;
 982         return 0;
 983     }]])],[rsync_cv_chown_modifies_symlink=yes],[rsync_cv_chown_modifies_symlink=no],[rsync_cv_chown_modifies_symlink=no])])
 984 if test $rsync_cv_chown_modifies_symlink = yes; then
 985   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 986 fi
 987
 988 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
 989   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 990 #ifdef HAVE_FCNTL_H
 991 # include <fcntl.h>
 992 #elif defined HAVE_SYS_FCNTL_H
 993 # include <sys/fcntl.h>
 994 #endif
 995 #if HAVE_UNISTD_H
 996 # include <unistd.h>
 997 #endif
 998 #include <stdlib.h>
 999 #include <errno.h>
1000 #define FILENAME "conftest.dangle"
1001 int main(void) {
1002         unlink(FILENAME);
1003         if (symlink("conftest.no-such", FILENAME) < 0) abort();
1004         unlink(FILENAME "2");
1005 #ifdef HAVE_LINKAT
1006         if (linkat(AT_FDCWD, FILENAME, AT_FDCWD, FILENAME "2", 0) < 0) return 1;
1007 #else
1008         if (link(FILENAME, FILENAME "2") < 0) return 1;
1009 #endif
1010         return 0;
1011     }]])],[rsync_cv_can_hardlink_symlink=yes],[rsync_cv_can_hardlink_symlink=no],[rsync_cv_can_hardlink_symlink=no])])
1012 if test $rsync_cv_can_hardlink_symlink = yes; then
1013   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
1014 fi
1015
1016 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
1017   AC_RUN_IFELSE([AC_LANG_SOURCE([[
1018 #if HAVE_UNISTD_H
1019 # include <unistd.h>
1020 #endif
1021 #ifdef HAVE_SYS_STAT_H
1022 #include <sys/stat.h>
1023 #endif
1024 #include <stdlib.h>
1025 #include <errno.h>
1026 #define FILENAME "conftest.fifi"
1027 int main(void) {
1028         unlink(FILENAME);
1029         if (mkfifo(FILENAME, 0777) < 0) abort();
1030         unlink(FILENAME "2");
1031         if (link(FILENAME, FILENAME "2") < 0) return 1;
1032         return 0;
1033     }]])],[rsync_cv_can_hardlink_special=yes],[rsync_cv_can_hardlink_special=no],[rsync_cv_can_hardlink_special=no])])
1034 if test $rsync_cv_can_hardlink_special = yes; then
1035     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
1036 fi
1037
1038 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
1039 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1040 #ifdef HAVE_SYS_TYPES_H
1041 #include <sys/types.h>
1042 #endif
1043 #ifdef HAVE_SYS_SOCKET_H
1044 #include <sys/socket.h>
1045 #endif
1046
1047 int main(void) {
1048        int fd[2];
1049        return (socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1;
1050 }]])],[rsync_cv_HAVE_SOCKETPAIR=yes],[rsync_cv_HAVE_SOCKETPAIR=no],[rsync_cv_HAVE_SOCKETPAIR=cross])])
1051 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
1052     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
1053 fi
1054
1055 AC_REPLACE_FUNCS([getpass])
1056
1057 if test x"$with_included_popt" != x"yes"; then
1058     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
1059 fi
1060 if test x"$ac_cv_header_popt_popt_h" = x"yes"; then
1061     # If the system has /usr/include/popt/popt.h, we enable the
1062     # included popt because an attempt to "#include <popt/popt.h>"
1063     # would use our included header file anyway (due to -I.), and
1064     # might conflict with the system popt.
1065     with_included_popt=yes
1066 elif test x"$ac_cv_header_popt_h" != x"yes"; then
1067     with_included_popt=yes
1068 fi
1069
1070 if test x"$GCC" = x"yes"; then
1071     if test x"$with_included_popt" != x"yes"; then
1072         # Turn pedantic warnings into errors to ensure an array-init overflow is an error.
1073         CFLAGS="$CFLAGS -pedantic-errors"
1074     else
1075         # Our internal popt code cannot be compiled with pedantic warnings as errors, so try to
1076         # turn off pedantic warnings (which will not lose the error for array-init overflow).
1077         # Older gcc versions don't understand -Wno-pedantic, so check if --help=warnings lists
1078         # -Wpedantic and use that as a flag.
1079         case `$CC --help=warnings 2>/dev/null | grep Wpedantic` in
1080             *-Wpedantic*) CFLAGS="$CFLAGS -pedantic-errors -Wno-pedantic" ;;
1081         esac
1082     fi
1083 fi
1084
1085 AC_MSG_CHECKING([whether to use included libpopt])
1086 if test x"$with_included_popt" = x"yes"; then
1087     AC_MSG_RESULT($srcdir/popt)
1088     BUILD_POPT='$(popt_OBJS)'
1089     CFLAGS="-I$srcdir/popt $CFLAGS"
1090     if test x"$ALLOCA" != x
1091     then
1092         # this can be removed when/if we add an included alloca.c;
1093         #  see autoconf documentation on AC_FUNC_ALLOCA
1094         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
1095     fi
1096 else
1097     AC_MSG_RESULT(no)
1098 fi
1099
1100 # We default to using our zlib unless --with-included-zlib=no is given.
1101 if test x"$with_included_zlib" != x"no"; then
1102     with_included_zlib=yes
1103 elif test x"$ac_cv_header_zlib_h" != x"yes"; then
1104     with_included_zlib=yes
1105 fi
1106 if test x"$with_included_zlib" != x"yes"; then
1107     AC_CHECK_LIB(z, deflateParams, , [with_included_zlib=yes])
1108 fi
1109
1110 AC_MSG_CHECKING([whether to use included zlib])
1111 if test x"$with_included_zlib" = x"yes"; then
1112     AC_MSG_RESULT($srcdir/zlib)
1113     BUILD_ZLIB='$(zlib_OBJS)'
1114     CFLAGS="-I$srcdir/zlib $CFLAGS"
1115 else
1116     AC_DEFINE(EXTERNAL_ZLIB, 1, [Define to 1 if using external zlib])
1117     AC_MSG_RESULT(no)
1118 fi
1119
1120 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
1121 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[signed char *s = (signed char *)""]])],[rsync_cv_SIGNED_CHAR_OK=yes],[rsync_cv_SIGNED_CHAR_OK=no])])
1122 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
1123     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
1124 fi
1125
1126 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
1127 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1128 #ifdef HAVE_SYS_TYPES_H
1129 #include <sys/types.h>
1130 #endif
1131 #include <dirent.h>
1132 int main(void) { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
1133 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
1134 di->d_name[0] == 0) return 0; return 1;} ]])],[rsync_cv_HAVE_BROKEN_READDIR=yes],[rsync_cv_HAVE_BROKEN_READDIR=no],[rsync_cv_HAVE_BROKEN_READDIR=cross])])
1135 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
1136     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
1137 fi
1138
1139 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
1140 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1141 #ifdef HAVE_SYS_TYPES_H
1142 #include <sys/types.h>
1143 #endif
1144 #include <utime.h>]], [[struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; return utime("foo.c",&tbuf);]])],[rsync_cv_HAVE_STRUCT_UTIMBUF=yes],[rsync_cv_HAVE_STRUCT_UTIMBUF=no])])
1145 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
1146     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
1147 fi
1148
1149 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
1150 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/time.h>
1151 #ifdef HAVE_UNISTD_H
1152 #include <unistd.h>
1153 #endif]], [[struct timeval tv; return gettimeofday(&tv, NULL);]])],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=no])])
1154 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
1155     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
1156 fi
1157
1158 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
1159 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1160 #ifdef HAVE_SYS_TYPES_H
1161 #include <sys/types.h>
1162 #endif
1163 #include <stdarg.h>
1164 #include <stdio.h>
1165 #if HAVE_STDLIB_H
1166 #include <stdlib.h>
1167 #endif
1168 #include <string.h>
1169 void foo(const char *format, ...) {
1170        va_list ap;
1171        int len;
1172        static char buf[] = "12345678901234567890";
1173
1174        va_start(ap, format);
1175        len = vsnprintf(0, 0, format, ap);
1176        va_end(ap);
1177        if (len != 5) exit(1);
1178
1179        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
1180 }
1181 int main(void) { foo("hello"); return 0; }
1182 ]])],[rsync_cv_HAVE_C99_VSNPRINTF=yes],[rsync_cv_HAVE_C99_VSNPRINTF=no],[rsync_cv_HAVE_C99_VSNPRINTF=cross])])
1183 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
1184     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
1185 fi
1186
1187
1188 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
1189 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1190 #ifdef HAVE_SYS_TYPES_H
1191 #include <sys/types.h>
1192 #endif
1193 #include <sys/stat.h>
1194 #ifdef HAVE_UNISTD_H
1195 #include <unistd.h>
1196 #endif
1197 int main(void) {
1198   struct stat st;
1199   char tpl[20]="/tmp/test.XXXXXX";
1200   int fd = mkstemp(tpl);
1201   if (fd == -1) return 1;
1202   unlink(tpl);
1203   if (fstat(fd, &st) != 0) return 1;
1204   if ((st.st_mode & 0777) != 0600) return 1;
1205   return 0;
1206 }]])],[rsync_cv_HAVE_SECURE_MKSTEMP=yes],[rsync_cv_HAVE_SECURE_MKSTEMP=no],[rsync_cv_HAVE_SECURE_MKSTEMP=cross])])
1207 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
1208     case $host_os in
1209     hpux*)
1210         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
1211         dnl so we noisily skip using it.  See HP change request JAGaf34426
1212         dnl for details. (sbonds)
1213         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
1214         ;;
1215     *)
1216         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
1217         ;;
1218     esac
1219 fi
1220
1221
1222 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
1223 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1224 #include <stdio.h>
1225 #include <sys/stat.h>
1226 #include <errno.h>
1227 #if HAVE_UNISTD_H
1228 # include <unistd.h>
1229 #endif
1230 int main(void) { int rc, ec; char *fn = "fifo-test";
1231 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
1232 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1233 return 0;}]])],[rsync_cv_MKNOD_CREATES_FIFOS=yes],[rsync_cv_MKNOD_CREATES_FIFOS=no],[rsync_cv_MKNOD_CREATES_FIFOS=cross])])
1234 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
1235     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
1236 fi
1237
1238 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
1239 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1240 #include <stdio.h>
1241 #include <sys/stat.h>
1242 #include <errno.h>
1243 #if HAVE_UNISTD_H
1244 # include <unistd.h>
1245 #endif
1246 int main(void) { int rc, ec; char *fn = "sock-test";
1247 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
1248 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1249 return 0;}]])],[rsync_cv_MKNOD_CREATES_SOCKETS=yes],[rsync_cv_MKNOD_CREATES_SOCKETS=no],[rsync_cv_MKNOD_CREATES_SOCKETS=cross])])
1250 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
1251     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
1252 fi
1253
1254 #
1255 # The following test was mostly taken from the tcl/tk plus patches
1256 #
1257 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
1258 rm -rf conftest*
1259 cat > conftest.$ac_ext <<EOF
1260 int main(void) { return 0; }
1261 EOF
1262 ${CC-cc} -c -o conftest..o conftest.$ac_ext
1263 if test -f conftest..o; then
1264     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
1265 else
1266     rsync_cv_DASHC_WORKS_WITH_DASHO=no
1267 fi
1268 rm -rf conftest*
1269 ])
1270 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
1271     OBJ_SAVE="#"
1272     OBJ_RESTORE="#"
1273     CC_SHOBJ_FLAG='-o $@'
1274 else
1275     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
1276     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
1277     CC_SHOBJ_FLAG=""
1278 fi
1279
1280 AC_SUBST(OBJ_SAVE)
1281 AC_SUBST(OBJ_RESTORE)
1282 AC_SUBST(CC_SHOBJ_FLAG)
1283 AC_SUBST(BUILD_POPT)
1284 AC_SUBST(BUILD_ZLIB)
1285 AC_SUBST(MAKE_RRSYNC)
1286 AC_SUBST(MAKE_RRSYNC_1)
1287 AC_SUBST(GEN_RRSYNC)
1288 AC_SUBST(MAKE_MAN)
1289
1290 AC_CHECK_FUNCS(_acl __acl _facl __facl)
1291 #################################################
1292 # check for ACL support
1293
1294 AC_MSG_CHECKING([whether to support ACLs])
1295 AC_ARG_ENABLE(acl-support,
1296         AS_HELP_STRING([--disable-acl-support],[disable to omit ACL support]))
1297
1298 if test x"$enable_acl_support" = x"no"; then
1299     AC_MSG_RESULT(no)
1300 else
1301     case "$host_os" in
1302     *sysv5*)
1303         AC_MSG_RESULT(Using UnixWare ACLs)
1304         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
1305         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
1306         ;;
1307     solaris*)
1308         AC_MSG_RESULT(Using solaris ACLs)
1309         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
1310         AC_DEFINE(SUPPORT_ACLS, 1)
1311         ;;
1312     *irix*)
1313         AC_MSG_RESULT(Using IRIX ACLs)
1314         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
1315         AC_DEFINE(SUPPORT_ACLS, 1)
1316         ;;
1317     *aix*)
1318         AC_MSG_RESULT(Using AIX ACLs)
1319         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
1320         AC_DEFINE(SUPPORT_ACLS, 1)
1321         ;;
1322     *osf*)
1323         AC_MSG_RESULT(Using Tru64 ACLs)
1324         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
1325         AC_DEFINE(SUPPORT_ACLS, 1)
1326         LIBS="$LIBS -lpacl"
1327         ;;
1328     darwin*)
1329         AC_MSG_RESULT(Using OS X ACLs)
1330         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
1331         AC_DEFINE(SUPPORT_ACLS, 1)
1332         ;;
1333     *hpux*|*nsk*)
1334         AC_MSG_RESULT(Using HPUX ACLs)
1335         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
1336         AC_DEFINE(SUPPORT_ACLS, 1)
1337         ;;
1338     *)
1339         AC_MSG_RESULT(running tests:)
1340         AC_CHECK_LIB(acl,acl_get_file)
1341         AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
1342             AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1343 #ifdef HAVE_SYS_TYPES_H
1344 #include <sys/types.h>
1345 #endif
1346 #ifdef HAVE_SYS_ACL_H
1347 #include <sys/acl.h>
1348 #endif]], [[ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);]])],[samba_cv_HAVE_POSIX_ACLS=yes],[samba_cv_HAVE_POSIX_ACLS=no])])
1349         AC_MSG_CHECKING(ACL test results)
1350         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
1351             AC_MSG_RESULT(Using posix ACLs)
1352             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
1353             AC_DEFINE(SUPPORT_ACLS, 1)
1354             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
1355                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1356 #ifdef HAVE_SYS_TYPES_H
1357 #include <sys/types.h>
1358 #endif
1359 #ifdef HAVE_SYS_ACL_H
1360 #include <sys/acl.h>
1361 #endif]], [[ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);]])],[samba_cv_HAVE_ACL_GET_PERM_NP=yes],[samba_cv_HAVE_ACL_GET_PERM_NP=no])])
1362             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
1363                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
1364             fi
1365         else
1366             if test x"$enable_acl_support" = x"yes"; then
1367                 AC_MSG_ERROR(Failed to find ACL support)
1368             else
1369                 AC_MSG_RESULT(No ACL support found)
1370             fi
1371         fi
1372         ;;
1373     esac
1374 fi
1375
1376 #################################################
1377 # check for extended attribute support
1378 AC_MSG_CHECKING(whether to support extended attributes)
1379 AC_ARG_ENABLE(xattr-support,
1380     AS_HELP_STRING([--disable-xattr-support],[disable to omit extended attributes]),
1381     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link$ac_cv_func_attropen" in
1382         *yes*) enable_xattr_support=maybe ;;
1383         *) enable_xattr_support=no ;;
1384         esac])
1385 AH_TEMPLATE([SUPPORT_XATTRS],
1386 [Define to 1 to add support for extended attributes])
1387 if test x"$enable_xattr_support" = x"no"; then
1388     AC_MSG_RESULT(no)
1389 else
1390     case "$host_os" in
1391     *linux*|*netbsd*|*cygwin*)
1392         AC_MSG_RESULT(Using Linux xattrs)
1393         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs (or equivalent)])
1394         AC_DEFINE(SUPPORT_XATTRS, 1)
1395         AC_DEFINE(NO_SYMLINK_USER_XATTRS, 1, [True if symlinks do not support user xattrs])
1396         AC_CHECK_LIB(attr,getxattr)
1397         ;;
1398     darwin*)
1399         AC_MSG_RESULT(Using OS X xattrs)
1400         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
1401         AC_DEFINE(SUPPORT_XATTRS, 1)
1402         AC_DEFINE(NO_DEVICE_XATTRS, 1, [True if device files do not support xattrs])
1403         AC_DEFINE(NO_SPECIAL_XATTRS, 1, [True if special files do not support xattrs])
1404         ;;
1405     freebsd*)
1406         AC_MSG_RESULT(Using FreeBSD extattrs)
1407         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
1408         AC_DEFINE(SUPPORT_XATTRS, 1)
1409         ;;
1410     solaris*)
1411         AC_MSG_RESULT(Using Solaris xattrs)
1412         AC_DEFINE(HAVE_SOLARIS_XATTRS, 1, [True if you have Solaris xattrs])
1413         AC_DEFINE(SUPPORT_XATTRS, 1)
1414         AC_DEFINE(NO_SYMLINK_XATTRS, 1, [True if symlinks do not support xattrs])
1415         ;;
1416     *)
1417         if test x"$enable_xattr_support" = x"yes"; then
1418             AC_MSG_ERROR(Failed to find extended attribute support)
1419         else
1420             AC_MSG_RESULT(No extended attribute support found)
1421         fi
1422         ;;
1423     esac
1424 fi
1425
1426 if test x"$enable_acl_support" = x"no" || test x"$enable_xattr_support" = x"no" || test x"$enable_iconv" = x"no"; then
1427     AC_MSG_CHECKING([whether $CC supports -Wno-unused-parameter])
1428     OLD_CFLAGS="$CFLAGS"
1429     CFLAGS="$CFLAGS -Wno-unused-parameter"
1430     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]], [[printf("hello\n");]])],[rsync_warn_flag=yes],[rsync_warn_flag=no])
1431     AC_MSG_RESULT([$rsync_warn_flag])
1432     if test x"$rsync_warn_flag" = x"no"; then
1433         CFLAGS="$OLD_CFLAGS"
1434     fi
1435 fi
1436
1437 case "$CC" in
1438 ' checker'*|checker*)
1439     AC_DEFINE(FORCE_FD_ZERO_MEMSET, 1, [Used to make "checker" understand that FD_ZERO() clears memory.])
1440     ;;
1441 esac
1442
1443 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
1444 AC_OUTPUT
1445
1446 AC_MSG_RESULT()
1447 AC_MSG_RESULT([    rsync $PACKAGE_VERSION configuration successful])
1448 AC_MSG_RESULT()