configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Revision$)
   3 AC_PREREQ(2.62)
   4 test -z "$CFLAGS" && CFLAGS="-g"
   5 AC_INIT([Heimdal],[7.99.1],[https://github.com/heimdal/heimdal/issues])
   6 AC_CONFIG_SRCDIR([kuser/kinit.c])
   7 AC_CONFIG_HEADERS(include/config.h)
   8 AC_CONFIG_MACRO_DIR([cf])
   9
  10 AM_INIT_AUTOMAKE([foreign 1.11])
  11 AM_MAINTAINER_MODE
  12
  13 LT_PREREQ([2.2])
  14 LT_INIT([shared static win32-dll])
  15
  16
  17 dnl Checks for programs.
  18 AC_PROG_CC
  19 AM_PROG_CC_C_O
  20 AC_PROG_CPP
  21
  22 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  23
  24 AC_PREFIX_DEFAULT(/usr/heimdal)
  25
  26 test "$sysconfdir" = '${prefix}/etc' && sysconfdir='/etc'
  27 test "$localstatedir" = '${prefix}/var' && localstatedir='/var/heimdal'
  28
  29 AC_CANONICAL_HOST
  30 CANONICAL_HOST=$host
  31 AC_SUBST(CANONICAL_HOST)
  32
  33 rk_SYS_LARGEFILE
  34
  35 rk_AIX
  36 rk_IRIX
  37 rk_SUNOS
  38
  39 dnl
  40 dnl this is needed to run the configure tests against glibc
  41 dnl
  42 AC_DEFINE([_GNU_SOURCE], 1,
  43         [Define to enable extensions on glibc-based systems such as Linux.])
  44
  45 AC_OBJEXT
  46 AC_EXEEXT
  47
  48 dnl
  49 dnl this is needed when der-protos.h or der-private.h has to be generated
  50 dnl
  51 if ! test -f "$srcdir/lib/asn1/der-protos.h" ||
  52    ! test -f "$srcdir/lib/asn1/der-private.h"; then
  53     AC_KRB_PROG_PERL
  54     AC_KRB_PERL_MOD(Getopt::Std)
  55     AC_KRB_PERL_MOD(File::Compare)
  56     AC_KRB_PERL_MOD(JSON)
  57 fi
  58
  59 dnl AC_KRB_PROG_YACC
  60 AC_PROG_YACC
  61 AM_PROG_LEX
  62 dnl AC_PROG_RANLIB
  63 AC_PROG_AWK
  64 AC_KRB_PROG_LN_S
  65
  66 AC_MIPS_ABI
  67 CC="$CC $abi"
  68 libdir="$libdir$abilibdirext"
  69
  70 AC_C___ATTRIBUTE__
  71
  72 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = "yes")
  73 rk_VERSIONSCRIPT
  74
  75 dnl
  76 dnl Helper bits for cross compiling
  77 dnl
  78
  79
  80
  81 AM_CONDITIONAL(CROSS_COMPILE, test "${cross_compiling}" = yes)
  82
  83 AC_ARG_WITH(cross-tools,
  84         AS_HELP_STRING([--with-cross-tools=dir], [use cross tools in dir]),
  85         [if test "$withval" = "yes"; then
  86                 AC_MSG_ERROR([Need path to cross tools])
  87         fi
  88         with_cross_tools="${with_cross_tools}/"
  89         ])
  90
  91 if test "${cross_compiling}" != yes ; then
  92
  93    ASN1_COMPILE="\$(top_builddir)/lib/asn1/asn1_compile\$(EXEEXT)"
  94    SLC="\$(top_builddir)/lib/sl/slc"
  95
  96    ASN1_COMPILE_DEP="\$(ASN1_COMPILE)"
  97    SLC_DEP="\$(SLC)"
  98 else
  99    ASN1_COMPILE="${with_cross_tools}asn1_compile"
 100    SLC="${with_cross_tools}slc"
 101
 102    ASN1_COMPILE_DEP=
 103    SLC_DEP=
 104
 105    ac_cv_prog_COMPILE_ET=${with_cross_tools}compile_et
 106
 107 fi
 108
 109 AC_SUBST([ASN1_COMPILE])
 110 AC_SUBST([ASN1_COMPILE_DEP])
 111 AC_SUBST([SLC])
 112 AC_SUBST([SLC_DEP])
 113
 114 dnl ---
 115
 116 AC_DEFINE(HEIM_WEAK_CRYPTO, 1, [Define if you want support for weak crypto])
 117
 118 rk_TEST_PACKAGE(openldap,
 119 [#include <lber.h>
 120 #include <ldap.h>],
 121 [-lldap -llber],,,OPENLDAP)
 122
 123 AC_ARG_ENABLE(hdb-openldap-module,
 124         AS_HELP_STRING([--enable-hdb-openldap-module],
 125                 [if you want support to build openldap hdb as shared object]))
 126 if test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes; then
 127     AC_DEFINE(OPENLDAP_MODULE, 1, [Define if you want support for hdb ldap module])
 128 fi
 129 AM_CONDITIONAL(OPENLDAP_MODULE, test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes)
 130
 131 dnl
 132 dnl Optional modules, pk-init, digest, kx509
 133 dnl
 134
 135 AC_ARG_ENABLE(pk-init,
 136         AS_HELP_STRING([--disable-pk-init],
 137                 [if you want disable to PK-INIT support]))
 138 if test "$enable_pk_init" != no ;then
 139         AC_DEFINE([PKINIT], 1, [Define to enable PKINIT.])
 140 fi
 141 AM_CONDITIONAL(PKINIT, test "$enable_pk_init" != no)
 142
 143 AC_ARG_ENABLE(digest,
 144         AS_HELP_STRING([--disable-digest],
 145                 [if you want disable to DIGEST support]))
 146 if test "$enable_digest" != no ;then
 147         AC_DEFINE([DIGEST], 1, [Define to enable DIGEST.])
 148 fi
 149
 150 AC_ARG_ENABLE(kx509,
 151         AS_HELP_STRING([--disable-kx509],
 152                 [if you want disable to kx509 support]))
 153 if test "$enable_kx509" != no ;then
 154         AC_DEFINE([KX509], 1, [Define to enable kx509.])
 155 fi
 156
 157 dnl Need to test if pkg-config exists
 158 PKG_PROG_PKG_CONFIG
 159
 160 dnl libcap-ng
 161 AC_ARG_WITH([capng],
 162   AC_HELP_STRING([--with-capng], [use libcap-ng to drop KDC privileges @<:@default=check@:>@]),
 163   [],
 164   [with_capng=check])
 165 if test "$with_capng" != "no"; then
 166   PKG_CHECK_MODULES([CAPNG], [libcap-ng >= 0.4.0],
 167                     [with_capng=yes],[with_capng=no])
 168 fi
 169 if test "$with_capng" = "yes"; then
 170   AC_DEFINE_UNQUOTED([HAVE_CAPNG], 1, [whether capng is available for privilege reduction])
 171 fi
 172 AM_CONDITIONAL([HAVE_CAPNG], [test "$with_capng" != "no"])
 173 AC_SUBST([CAPNG_CFLAGS])
 174 AC_SUBST([CAPNG_LIBS])
 175
 176 dnl Check for sqlite
 177 rk_TEST_PACKAGE(sqlite3,
 178 [#include <sqlite3.h>
 179 #ifndef SQLITE_OPEN_CREATE
 180 #error "old version"
 181 #endif],
 182 [-lsqlite3],,,SQLITE3)
 183
 184 if test "X$with_sqlite3" != Xyes ; then
 185    INCLUDE_sqlite3="-I\$(top_srcdir)/lib/sqlite"
 186    LIB_sqlite3="\$(top_builddir)/lib/sqlite/libheimsqlite.la"
 187 fi
 188 AM_CONDITIONAL(SQLITE3,  test "X$with_sqlite3" = Xyes)
 189
 190 AC_DEFINE(HAVE_SQLITE3, 1, [Define if you want support for sqlite in Heimdal.])
 191
 192 AC_ARG_ENABLE(sqlite-cache,
 193         AS_HELP_STRING([--disable-sqlite-cache],[if you want support for cache in sqlite]))
 194 if test "$enable_sqlite_cache" != no; then
 195     AC_DEFINE(HAVE_SCC, 1, [Define if you want support for cache in sqlite.])
 196 fi
 197 AM_CONDITIONAL(have_scc, test "$enable_sqlite_cache" != no)
 198
 199
 200 dnl check for libintl
 201 rk_TEST_PACKAGE(libintl,
 202 [#include <libintl.h>],
 203 [-lintl],,,LIBINTL)
 204
 205 dnl path where the hdb directory is stored
 206 AC_ARG_WITH([hdbdir],
 207         [AS_HELP_STRING([--with-hdbdir],[Default location for KDC database @<:@default=/var/heimdal@:>@])],
 208         [],
 209         [with_hdbdir=/var/heimdal])
 210 DIR_hdbdir="$with_hdbdir"
 211 AC_SUBST([DIR_hdbdir])
 212
 213
 214 AM_CONDITIONAL(KRB5, true)
 215 AM_CONDITIONAL(do_roken_rename, true)
 216
 217 AC_DEFINE(SUPPORT_INETD, 1, [Enable use of inetd style startup.])dnl
 218
 219
 220 AC_DEFINE(KRB5, 1, [Enable Kerberos 5 support in applications.])dnl
 221 AC_SUBST(LIB_kdb)dnl
 222
 223 KRB_CRYPTO
 224
 225 KRB_PTHREADS
 226
 227 AC_ARG_ENABLE(dce,
 228         AS_HELP_STRING([--enable-dce],[if you want support for DCE/DFS PAG's]))
 229 if test "$enable_dce" = yes; then
 230     AC_DEFINE(DCE, 1, [Define if you want support for DCE/DFS PAG's.])
 231 fi
 232 AM_CONDITIONAL(DCE, test "$enable_dce" = yes)
 233
 234 ## XXX quite horrible:
 235 if test -f /etc/ibmcxx.cfg; then
 236         dpagaix_ldadd=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/libraries/{;s/^[[^=]]*=\(.*\)/\1/;s/,/ /gp;}'`
 237         dpagaix_cflags=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/options/{;s/^[[^=]]*=\(.*\)/\1/;s/-q[^,]*//;s/,/ /gp;}'`
 238         dpagaix_ldflags=
 239 else
 240         dpagaix_cflags="-D_THREAD_SAFE -D_AIX_PTHREADS_D7 -D_AIX32_THREADS=1 -D_AES_SOURCE -D_AIX41 -I/usr/include/dce"
 241         dpagaix_ldadd="-L/usr/lib/threads -ldcelibc_r -ldcepthreads -lpthreads_compat lpthreads -lc_r"
 242         dpagaix_ldflags="-Wl,-bI:dfspag.exp"
 243 fi
 244 AC_SUBST(dpagaix_cflags)
 245 AC_SUBST(dpagaix_ldadd)
 246 AC_SUBST(dpagaix_ldflags)
 247
 248 AC_ARG_ENABLE([afs-support],
 249         AS_HELP_STRING([--disable-afs-support],[if you don't want support for AFS]))
 250 if test "$enable_afs_support" = no; then
 251         AC_DEFINE(NO_AFS, 1, [Define if you don't wan't support for AFS.])
 252         NO_AFS="1"
 253 fi
 254 AC_SUBST(NO_AFS)dnl
 255 AM_CONDITIONAL(NO_AFS, test "$enable_afs_support" = no)
 256
 257 rk_DB
 258
 259 dnl AC_ROKEN(10,[/usr/heimdal /usr/athena],[lib/roken],[$(top_builddir)/lib/roken/libroken.la],[-I$(top_builddir)/lib/roken -I$(top_srcdir)/lib/roken])
 260
 261 rk_ROKEN(lib/roken)
 262 LIBADD_roken="$LIB_roken"
 263 AC_SUBST(LIBADD_roken)dnl
 264 LIB_roken="\$(top_builddir)/lib/vers/libvers.la $LIB_roken"
 265
 266 rk_OTP
 267
 268 rk_LIBDISPATCH
 269
 270 AC_CHECK_OSFC2
 271
 272 AC_ARG_ENABLE(mmap,
 273         AS_HELP_STRING([--disable-mmap],[disable use of mmap]))
 274 if test "$enable_mmap" = "no"; then
 275         AC_DEFINE(NO_MMAP, 1, [Define if you don't want to use mmap.])
 276 fi
 277
 278 AC_ARG_ENABLE(afs-string-to-key,
 279         AS_HELP_STRING([--disable-afs-string-to-key],
 280         [disable use of weak AFS string-to-key functions]),
 281         [], [enable_afs_string_to_key=yes])
 282
 283 if test "$enable_afs_string_to_key" = "yes"; then
 284         AC_DEFINE(ENABLE_AFS_STRING_TO_KEY, 1, [Define if want to use the weak AFS string to key functions.])
 285         ENABLE_AFS_STRING_TO_KEY=1
 286 fi
 287 AC_SUBST(ENABLE_AFS_STRING_TO_KEY)dnl
 288
 289
 290 rk_CHECK_MAN
 291
 292 rk_TEST_PACKAGE(readline,
 293 [#include <stdio.h>
 294 #if defined(HAVE_READLINE_READLINE_H)
 295 #include <readline/readline.h>
 296 #elif defined(HAVE_READLINE_H)
 297 #include <readline.h>
 298 #endif
 299 ],-lreadline,,, READLINE,, [readline.h readline/readline.h])
 300
 301 rk_TEST_PACKAGE(libedit,
 302 [#include <stdio.h>
 303 #if defined(HAVE_READLINE_READLINE_H)
 304 #include <readline/readline.h>
 305 #elif defined(HAVE_READLINE_H)
 306 #include <readline.h>
 307 #elif defined(HAVE_EDITLINE_READLINE_H)
 308 #include <editline/readline.h>
 309 #endif
 310 ],-ledit,,, READLINE,, [readline.h readline/readline.h editline/readline.h])
 311
 312 AC_CONFIG_SUBDIRS([lib/libedit])
 313
 314 KRB_C_BIGENDIAN
 315 AC_C_INLINE
 316
 317 dnl AM_C_PROTOTYPES
 318
 319 dnl Checks for typedefs, structures, and compiler characteristics.
 320 AC_C_CONST
 321 AC_TYPE_OFF_T
 322 AC_CHECK_TYPE_EXTRA(mode_t, unsigned short, [])
 323 AC_CHECK_TYPE_EXTRA(sig_atomic_t, int, [#include <signal.h>])
 324 AC_HAVE_TYPE([long long])
 325 AC_HEADER_TIME
 326 AC_STRUCT_TM
 327
 328 dnl Checks for header files.
 329 AC_HEADER_STDC
 330
 331 AC_CHECK_HEADERS([\
 332         CommonCrypto/CommonDigest.h             \
 333         CommonCrypto/CommonCryptor.h            \
 334         arpa/telnet.h                           \
 335         bind/bitypes.h                          \
 336         bsdsetjmp.h                             \
 337         curses.h                                \
 338         dlfcn.h                                 \
 339         execinfo.h                              \
 340         fnmatch.h                               \
 341         inttypes.h                              \
 342         io.h                                    \
 343         libutil.h                               \
 344         limits.h                                \
 345         maillock.h                              \
 346         netgroup.h                              \
 347         netinet/in6_machtypes.h                 \
 348         pthread.h                               \
 349         pty.h                                   \
 350         sac.h                                   \
 351         sgtty.h                                 \
 352         siad.h                                  \
 353         signal.h                                \
 354         strings.h                               \
 355         stropts.h                               \
 356         sys/bitypes.h                           \
 357         sys/category.h                          \
 358         sys/file.h                              \
 359         sys/filio.h                             \
 360         sys/ioccom.h                            \
 361         sys/mman.h                              \
 362         sys/param.h                             \
 363         sys/pty.h                               \
 364         sys/ptyio.h                             \
 365         sys/select.h                            \
 366         sys/socket.h                            \
 367         sys/str_tty.h                           \
 368         sys/stream.h                            \
 369         sys/stropts.h                           \
 370         sys/syscall.h                           \
 371         sys/termio.h                            \
 372         sys/timeb.h                             \
 373         sys/times.h                             \
 374         sys/types.h                             \
 375         sys/un.h                                \
 376         locale.h                                \
 377         termcap.h                               \
 378         termio.h                                \
 379         termios.h                               \
 380         time.h                                  \
 381         tmpdir.h                                \
 382         udb.h                                   \
 383         util.h                                  \
 384 ])
 385
 386 dnl On Solaris 8 there's a compilation warning for term.h because
 387 dnl it doesn't define `bool'.
 388 AC_CHECK_HEADERS(term.h, , , -)
 389
 390 dnl aix have asl.h (A/IX screen library) that we don't want
 391 AC_CHECK_HEADERS(asl.h, , , [
 392 #include <asl.h>
 393 #ifndef ASL_STRING_EMERG
 394 #error ASL_STRING_EMERG missing
 395 #endif])
 396
 397 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
 398 #if HAVE_SYS_SOCKET_H
 399 #include <sys/socket.h>
 400 #endif])
 401
 402 AC_CHECK_HEADERS(sys/ptyvar.h, , , [AC_INCLUDES_DEFAULT
 403 #if HAVE_SYS_TTY_H
 404 #include <sys/tty.h>
 405 #endif])
 406
 407 AC_CHECK_HEADERS(sys/strtty.h, , , [AC_INCLUDES_DEFAULT
 408 #if HAVE_TERMIOS_H
 409 #include <termios.h>
 410 #endif
 411 #if HAVE_SYS_STREAM_H
 412 #include <sys/stream.h>
 413 #endif])
 414
 415 AC_CHECK_HEADERS(sys/ucred.h, , , [AC_INCLUDES_DEFAULT
 416 #if HAVE_SYS_TYPES_H
 417 #include <sys/types.h>
 418 #endif
 419 #if HAVE_SYS_PARAM_H
 420 #include <sys/param.h>
 421 #endif])
 422
 423 AC_CHECK_HEADERS(security/pam_modules.h, , , [AC_INCLUDES_DEFAULT
 424 #include <security/pam_appl.h>
 425 ])
 426
 427 dnl export symbols
 428 rk_WIN32_EXPORT(BUILD_KRB5_LIB, KRB5_LIB)
 429 rk_WIN32_EXPORT(BUILD_ROKEN_LIB, ROKEN_LIB)
 430 rk_WIN32_EXPORT(BUILD_GSSAPI_LIB, GSSAPI_LIB)
 431
 432 dnl Checks for libraries.
 433
 434 AC_FIND_FUNC_NO_LIBS(logwtmp, util,[
 435 #ifdef HAVE_UTIL_H
 436 #include <util.h>
 437 #endif
 438 ],[0,0,0])
 439 AC_FIND_FUNC_NO_LIBS(logout, util,[
 440 #ifdef HAVE_UTIL_H
 441 #include <util.h>
 442 #endif
 443 ],[0])
 444 AC_FIND_FUNC_NO_LIBS(openpty, util,[
 445 #ifdef HAVE_UTIL_H
 446 #include <util.h>
 447 #endif
 448 ],[0,0,0,0,0])
 449
 450 AC_FIND_FUNC_NO_LIBS(tgetent, termcap ncurses curses,[
 451 #ifdef HAVE_TERMCAP_H
 452 #include <termcap.h>
 453 #endif
 454 #ifdef HAVE_CURSES_H
 455 #include <curses.h>
 456 #endif
 457 ],[0,0])
 458
 459 dnl Checks for library functions.
 460
 461 AC_CHECK_FUNCS([                                \
 462         _getpty                                 \
 463         _scrsize                                \
 464         arc4random                              \
 465         backtrace                               \
 466         fcntl                                   \
 467         fork                                    \
 468         getpeereid                              \
 469         getpeerucred                            \
 470         grantpt                                 \
 471         kill                                    \
 472         mktime                                  \
 473         ptsname                                 \
 474         rand                                    \
 475         revoke                                  \
 476         select                                  \
 477         setitimer                               \
 478         setpcred                                \
 479         setpgid                                 \
 480         setproctitle                            \
 481         setregid                                \
 482         setresgid                               \
 483         setresuid                               \
 484         setreuid                                \
 485         setsid                                  \
 486         setutent                                \
 487         sigaction                               \
 488         strstr                                  \
 489         ttyname                                 \
 490         ttyslot                                 \
 491         umask                                   \
 492         unlockpt                                \
 493         vhangup                                 \
 494         waitpid                                 \
 495         yp_get_default_domain                   \
 496 ])
 497
 498 AC_MSG_CHECKING([checking for __sync_add_and_fetch])
 499 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>]],
 500         [[unsigned int foo, bar; bar = __sync_add_and_fetch(&foo, 1);]])],
 501         [ac_rk_have___sync_add_and_fetch=yes], [ac_rk_have___sync_add_and_fetch=no])
 502 if test "$ac_rk_have___sync_add_and_fetch" = "yes" ; then
 503         AC_DEFINE_UNQUOTED(HAVE___SYNC_ADD_AND_FETCH, 1, [have __sync_add_and_fetch])
 504 fi
 505 AC_MSG_RESULT($ac_rk_have___sync_add_and_fetch)
 506
 507 AC_FUNC_MMAP
 508
 509 KRB_CAPABILITIES
 510 rk_DLADDR
 511
 512 AC_CHECK_GETPWNAM_R_POSIX
 513
 514 dnl detect doors on solaris
 515 if test "$enable_pthread_support" != no; then
 516    saved_LIBS="$LIBS"
 517    LIBS="$LIBS $PTHREADS_LIBS"
 518    AC_FIND_FUNC_NO_LIBS(door_create, door)
 519    LIBS="$saved_LIBS"
 520 fi
 521
 522 AC_ARG_ENABLE(kcm,
 523         AS_HELP_STRING([--enable-kcm],[enable Kerberos Credentials Manager]),
 524 ,[enable_kcm=yes])
 525
 526 if test "$enable_kcm" = yes ; then
 527    if test  "$ac_cv_header_sys_un_h" != yes -a "$ac_cv_funclib_door_create" != yes ; then
 528         enable_kcm=no
 529    fi
 530 fi
 531 if test "$enable_kcm" = yes; then
 532        AC_DEFINE(HAVE_KCM, 1,
 533                [Define if you want to use the Kerberos Credentials Manager.])
 534 fi
 535 AM_CONDITIONAL(KCM, test "$enable_kcm" = yes)
 536
 537
 538
 539 dnl Cray stuff
 540 AC_CHECK_FUNCS(getudbnam setlim)
 541
 542 dnl AC_KRB_FUNC_GETCWD_BROKEN
 543
 544 AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t,
 545         u_int8_t, u_int16_t, u_int32_t, u_int64_t,
 546         uint8_t, uint16_t, uint32_t, uint64_t],,,[
 547 #ifdef HAVE_INTTYPES_H
 548 #include <inttypes.h>
 549 #endif
 550 #ifdef HAVE_SYS_TYPES_H
 551 #include <sys/types.h>
 552 #endif
 553 #ifdef HAVE_SYS_BITYPES_H
 554 #include <sys/bitypes.h>
 555 #endif
 556 #ifdef HAVE_BIND_BITYPES_H
 557 #include <bind/bitypes.h>
 558 #endif
 559 #ifdef HAVE_NETINET_IN6_MACHTYPES_H
 560 #include <netinet/in6_machtypes.h>
 561 #endif
 562 ])
 563
 564 rk_FRAMEWORK_SECURITY
 565
 566 KRB_READLINE
 567
 568 rk_TELNET
 569
 570 dnl Some operating systems already have com_err and compile_et
 571 CHECK_COMPILE_ET
 572
 573 rk_AUTH_MODULES([sia afskauthlib])
 574
 575 rk_DESTDIRS
 576
 577 rk_WFLAGS([-Wall -Wmissing-prototypes -Wpointer-arith -Wbad-function-cast -Wmissing-declarations -Wnested-externs])
 578
 579
 580 AH_BOTTOM([#ifdef __APPLE__
 581 #include <AvailabilityMacros.h>
 582 #endif])
 583
 584 AH_BOTTOM([#ifdef ROKEN_RENAME
 585 #include "roken_rename.h"
 586 #endif])
 587
 588 AC_ARG_ENABLE(heimdal-documentation,
 589         AS_HELP_STRING([--disable-heimdal-documentation],
 590                 [if you want disable to heimdal documentation]))
 591 AM_CONDITIONAL(HEIMDAL_DOCUMENTATION, test "$enable_heimdal_documentation" != no)
 592
 593 AC_CONFIG_FILES(Makefile                \
 594         etc/Makefile                    \
 595         include/Makefile                \
 596         include/gssapi/Makefile         \
 597         include/hcrypto/Makefile        \
 598         include/kadm5/Makefile          \
 599         lib/Makefile                    \
 600         lib/base/Makefile                       \
 601         lib/asn1/Makefile               \
 602         lib/com_err/Makefile            \
 603         lib/hcrypto/Makefile            \
 604         lib/hx509/Makefile              \
 605         lib/gssapi/Makefile             \
 606         lib/ntlm/Makefile               \
 607         lib/hdb/Makefile                \
 608         lib/ipc/Makefile                \
 609         lib/kadm5/Makefile              \
 610         lib/kafs/Makefile               \
 611         lib/kdfs/Makefile               \
 612         lib/krb5/Makefile               \
 613         lib/otp/Makefile                \
 614         lib/roken/Makefile              \
 615         lib/sl/Makefile                 \
 616         lib/sqlite/Makefile             \
 617         lib/vers/Makefile               \
 618         lib/wind/Makefile               \
 619         po/Makefile                     \
 620         kuser/Makefile                  \
 621         kpasswd/Makefile                \
 622         kadmin/Makefile                 \
 623         admin/Makefile                  \
 624         kcm/Makefile                    \
 625         kdc/Makefile                    \
 626         appl/Makefile                   \
 627         appl/afsutil/Makefile           \
 628         appl/dbutils/Makefile           \
 629         appl/gssmask/Makefile           \
 630         appl/otp/Makefile               \
 631         appl/su/Makefile                \
 632         appl/test/Makefile              \
 633         appl/kf/Makefile                \
 634         appl/dceutils/Makefile          \
 635         tests/Makefile                  \
 636         tests/bin/Makefile              \
 637         tests/can/Makefile              \
 638         tests/db/Makefile               \
 639         tests/kdc/Makefile              \
 640         tests/ldap/Makefile             \
 641         tests/gss/Makefile              \
 642         tests/java/Makefile             \
 643         tests/plugin/Makefile           \
 644         packages/Makefile               \
 645         packages/mac/Makefile           \
 646         doc/Makefile                    \
 647         tools/Makefile                  \
 648 )
 649
 650 AC_OUTPUT
 651
 652 dnl
 653 dnl This is the release version name-number[beta]
 654 dnl
 655
 656 cat > include/newversion.h.in <<EOF
 657 #ifndef VERSION_HIDDEN
 658 #define VERSION_HIDDEN
 659 #endif
 660 VERSION_HIDDEN const char *heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ ($host) @DATE@ \$";
 661 VERSION_HIDDEN const char *heimdal_version = "AC_PACKAGE_STRING";
 662 EOF
 663
 664 if test -f include/version.h && cmp -s include/newversion.h.in include/version.h.in; then
 665         echo "include/version.h is unchanged"
 666         rm -f include/newversion.h.in
 667 else
 668         echo "creating include/version.h"
 669         User=${USER-${LOGNAME}}
 670         Host=`(hostname || uname -n || echo unknown) 2>/dev/null | sed 1q`
 671         Date=`date`
 672         mv -f include/newversion.h.in include/version.h.in
 673         sed -e "s/@USER@/$User/" -e "s/@HOST@/$Host/" -e "s/@DATE@/$Date/" include/version.h.in > include/version.h
 674 fi