configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT()
   4 AC_CONFIG_SRCDIR([byteorder.h])
   5 AC_CONFIG_HEADER(config.h)
   6 AC_PREREQ(2.59)
   7
   8 RSYNC_VERSION=3.1.0dev
   9 AC_SUBST(RSYNC_VERSION)
  10 AC_MSG_NOTICE([Configuring rsync $RSYNC_VERSION])
  11
  12 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$RSYNC_VERSION"], [rsync release version])
  13
  14 LDFLAGS=${LDFLAGS-""}
  15
  16 AC_CANONICAL_HOST
  17
  18 # We must decide this before testing the compiler.
  19
  20 # Please allow this to default to yes, so that your users have more
  21 # chance of getting a useful stack trace if problems occur.
  22
  23 AC_MSG_CHECKING([whether to include debugging symbols])
  24 AC_ARG_ENABLE(debug,
  25         AC_HELP_STRING([--disable-debug],
  26                 [disable debugging symbols and features]))
  27
  28 if test x"$enable_debug" = x"no"; then
  29     AC_MSG_RESULT(no)
  30     ac_cv_prog_cc_g=no
  31 else
  32     AC_MSG_RESULT([yes])
  33     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  34     # leave ac_cv_prog_cc_g alone; AC_PROG_CC will try to include -g if it can
  35 fi
  36
  37 dnl Checks for programs.
  38 AC_PROG_CC
  39 AC_PROG_CPP
  40 AC_PROG_EGREP
  41 AC_PROG_INSTALL
  42 AC_PROG_CC_STDC
  43 AC_SUBST(SHELL)
  44
  45 AC_DEFINE([_GNU_SOURCE], 1,
  46           [Define _GNU_SOURCE so that we get all necessary prototypes])
  47
  48 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  49         AC_MSG_WARN([rsync requires an ANSI C compiler and you do not seem to have one])
  50 fi
  51
  52 AC_ARG_ENABLE(profile,
  53         AC_HELP_STRING([--enable-profile],
  54                 [turn on CPU profiling]))
  55 if test x"$enable_profile" = x"yes"; then
  56         CFLAGS="$CFLAGS -pg"
  57 fi
  58
  59
  60 # Specifically, this turns on panic_action handling.
  61 AC_ARG_ENABLE(maintainer-mode,
  62         AC_HELP_STRING([--enable-maintainer-mode],
  63                 [turn on extra debug features]))
  64 if test x"$enable_maintainer_mode" = x"yes"; then
  65         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
  66 fi
  67
  68
  69 # This is needed for our included version of popt.  Kind of silly, but
  70 # I don't want our version too far out of sync.
  71 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
  72
  73 # If GCC, turn on warnings.
  74 if test x"$GCC" = x"yes"; then
  75         CFLAGS="$CFLAGS -Wall -W"
  76 fi
  77
  78 AC_ARG_WITH(included-popt,
  79         AC_HELP_STRING([--with-included-popt], [use bundled popt library, not from system]))
  80
  81 AC_ARG_WITH(protected-args,
  82         AC_HELP_STRING([--with-protected-args], [make --protected-args option the default]))
  83 if test x"$with_protected_args" = x"yes"; then
  84         AC_DEFINE_UNQUOTED(RSYNC_USE_PROTECTED_ARGS, 1, [Define to 1 if --protected-args should be the default])
  85 fi
  86
  87 AC_ARG_WITH(rsync-path,
  88         AC_HELP_STRING([--with-rsync-path=PATH], [set default --rsync-path to PATH (default: rsync)]),
  89         [ RSYNC_PATH="$with_rsync_path" ],
  90         [ RSYNC_PATH="rsync" ])
  91
  92 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
  93
  94 AC_ARG_WITH(rsyncd-conf,
  95         AC_HELP_STRING([--with-rsyncd-conf=PATH], [set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
  96         [ if test ! -z "$with_rsyncd_conf" ; then
  97                 case $with_rsyncd_conf in
  98                         yes|no)
  99                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 100                                 ;;
 101                         /*)
 102                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
 103                                 ;;
 104                         *)
 105                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 106                                 ;;
 107                 esac
 108         else
 109                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 110         fi ],
 111         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 112
 113 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 114
 115 AC_ARG_WITH(rsh,
 116         AC_HELP_STRING([--with-rsh=CMD], [set remote shell command to CMD (default: ssh)]))
 117
 118 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 119 if test x$HAVE_REMSH = x1; then
 120         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 121 fi
 122
 123 if test x"$with_rsh" != x; then
 124         RSYNC_RSH="$with_rsh"
 125 else
 126         RSYNC_RSH="ssh"
 127 fi
 128 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 129
 130 AC_CHECK_PROG(HAVE_YODL2MAN, yodl2man, 1, 0)
 131 if test x$HAVE_YODL2MAN = x1; then
 132     MAKE_MAN=man
 133 else
 134     MAKE_MAN=man-copy
 135 fi
 136
 137 # Some programs on solaris are only found in /usr/xpg4/bin (or work better than others versions).
 138 AC_PATH_PROG(SHELL_PATH, sh, /bin/sh, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 139 AC_PATH_PROG(FAKEROOT_PATH, fakeroot, /usr/bin/fakeroot, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 140
 141 AC_ARG_WITH(nobody-group,
 142     AC_HELP_STRING([--with-nobody-group=GROUP],
 143                    [set the default unprivileged group (default nobody or nogroup)]),
 144     [ NOBODY_GROUP="$with_nobody_group" ])
 145
 146 if test x"$with_nobody_group" = x; then
 147     AC_MSG_CHECKING([the group for user "nobody"])
 148     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 149         NOBODY_GROUP=nobody
 150     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 151         NOBODY_GROUP=nogroup
 152     else
 153         NOBODY_GROUP=nobody # test for others?
 154     fi
 155     AC_MSG_RESULT($NOBODY_GROUP)
 156 fi
 157
 158 AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody])
 159 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 160
 161 # arrgh. libc in some old debian version screwed up the largefile
 162 # stuff, getting byte range locking wrong
 163 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 164 AC_TRY_RUN([
 165 #define _FILE_OFFSET_BITS 64
 166 #include <stdio.h>
 167 #include <fcntl.h>
 168 #include <sys/types.h>
 169 #include <sys/wait.h>
 170
 171 int main(void)
 172 {
 173         struct flock lock;
 174         int status;
 175         char tpl[32] = "/tmp/locktest.XXXXXX";
 176         int fd = mkstemp(tpl);
 177         if (fd < 0) {
 178                 strcpy(tpl, "conftest.dat");
 179                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 180         }
 181
 182         lock.l_type = F_WRLCK;
 183         lock.l_whence = SEEK_SET;
 184         lock.l_start = 0;
 185         lock.l_len = 1;
 186         lock.l_pid = 0;
 187         fcntl(fd,F_SETLK,&lock);
 188         if (fork() == 0) {
 189                 lock.l_start = 1;
 190                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 191         }
 192         wait(&status);
 193         unlink(tpl);
 194         exit(WEXITSTATUS(status));
 195 }
 196 ],
 197 rsync_cv_HAVE_BROKEN_LARGEFILE=yes,rsync_cv_HAVE_BROKEN_LARGEFILE=no,rsync_cv_HAVE_BROKEN_LARGEFILE=cross)])
 198 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 199    AC_SYS_LARGEFILE
 200 fi
 201
 202 ipv6type=unknown
 203 ipv6lib=none
 204 ipv6trylibc=yes
 205
 206 AC_ARG_ENABLE(ipv6,
 207         AC_HELP_STRING([--disable-ipv6],
 208                 [do not even try to use IPv6]))
 209 if test x"$enable_ipv6" != x"no"; then
 210         AC_MSG_CHECKING([ipv6 stack type])
 211         for i in inria kame linux-glibc linux-inet6 solaris toshiba v6d zeta cygwin; do
 212                 case $i in
 213                 inria)
 214                         # http://www.kame.net/
 215                         AC_EGREP_CPP(yes, [
 216 #include <netinet/in.h>
 217 #ifdef IPV6_INRIA_VERSION
 218 yes
 219 #endif],
 220                                 [ipv6type=$i;
 221                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 222                                 ])
 223                         ;;
 224                 kame)
 225                         # http://www.kame.net/
 226                         AC_EGREP_CPP(yes, [
 227 #include <netinet/in.h>
 228 #ifdef __KAME__
 229 yes
 230 #endif],
 231                                 [ipv6type=$i;
 232                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 233                         ;;
 234                 linux-glibc)
 235                         # http://www.v6.linux.or.jp/
 236                         AC_EGREP_CPP(yes, [
 237 #include <features.h>
 238 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 239 yes
 240 #endif],
 241                                 [ipv6type=$i;
 242 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 243                         ;;
 244                 linux-inet6)
 245                         # http://www.v6.linux.or.jp/
 246                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 247                                 ipv6type=$i
 248                                 ipv6lib=inet6
 249                                 ipv6libdir=/usr/inet6/lib
 250                                 ipv6trylibc=yes;
 251                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 252                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 253                         fi
 254                         ;;
 255                 solaris)
 256                         # http://www.sun.com
 257                         AC_EGREP_CPP(yes, [
 258 #include <netinet/ip6.h>
 259 #ifdef __sun
 260 yes
 261 #endif],
 262                                 [ipv6type=$i;
 263                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 264                         ;;
 265                 toshiba)
 266                         AC_EGREP_CPP(yes, [
 267 #include <sys/param.h>
 268 #ifdef _TOSHIBA_INET6
 269 yes
 270 #endif],
 271                                 [ipv6type=$i;
 272                                 ipv6lib=inet6;
 273                                 ipv6libdir=/usr/local/v6/lib;
 274                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 275                         ;;
 276                 v6d)
 277                         AC_EGREP_CPP(yes, [
 278 #include </usr/local/v6/include/sys/v6config.h>
 279 #ifdef __V6D__
 280 yes
 281 #endif],
 282                                 [ipv6type=$i;
 283                                 ipv6lib=v6;
 284                                 ipv6libdir=/usr/local/v6/lib;
 285                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 286                         ;;
 287                 zeta)
 288                         AC_EGREP_CPP(yes, [
 289 #include <sys/param.h>
 290 #ifdef _ZETA_MINAMI_INET6
 291 yes
 292 #endif],
 293                                 [ipv6type=$i;
 294                                 ipv6lib=inet6;
 295                                 ipv6libdir=/usr/local/v6/lib;
 296                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 297                         ;;
 298                 cygwin)
 299                         AC_EGREP_CPP(yes, [
 300 #include <netinet/in.h>
 301 #ifdef _CYGWIN_IN6_H
 302 yes
 303 #endif],
 304                                 [ipv6type=$i;
 305                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 306                         ;;
 307                 esac
 308                 if test "$ipv6type" != "unknown"; then
 309                         break
 310                 fi
 311         done
 312         AC_MSG_RESULT($ipv6type)
 313
 314         AC_SEARCH_LIBS(getaddrinfo, inet6)
 315 fi
 316
 317 dnl Do you want to disable use of locale functions
 318 AC_ARG_ENABLE([locale],
 319         AC_HELP_STRING([--disable-locale],
 320                 [disable locale features]))
 321 AH_TEMPLATE([CONFIG_LOCALE],
 322 [Undefine if you do not want locale features.  By default this is defined.])
 323 if test x"$enable_locale" != x"no"; then
 324         AC_DEFINE(CONFIG_LOCALE)
 325 fi
 326
 327 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 328 case $host_os in
 329         *cygwin* ) AC_MSG_RESULT(yes)
 330                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 331                             [Define to 1 if sockets need to be shutdown])
 332                    ;;
 333                * ) AC_MSG_RESULT(no);;
 334 esac
 335
 336 AC_C_BIGENDIAN
 337 AC_HEADER_DIRENT
 338 AC_HEADER_TIME
 339 AC_HEADER_SYS_WAIT
 340 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
 341     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
 342     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
 343     sys/un.h sys/attr.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
 344     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h \
 345     sys/acl.h acl/libacl.h attr/xattr.h sys/xattr.h sys/extattr.h \
 346     popt.h popt/popt.h linux/falloc.h netinet/in_systm.h netinet/ip.h)
 347 AC_HEADER_MAJOR
 348
 349 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
 350 AC_TRY_RUN([
 351 #include <sys/types.h>
 352 #ifdef MAJOR_IN_MKDEV
 353 #include <sys/mkdev.h>
 354 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
 355 #  define makedev mkdev
 356 # endif
 357 #elif defined MAJOR_IN_SYSMACROS
 358 #include <sys/sysmacros.h>
 359 #endif
 360
 361 int main(void)
 362 {
 363         dev_t dev = makedev(0, 5, 7);
 364         if (major(dev) != 5 || minor(dev) != 7)
 365                 exit(1);
 366         return 0;
 367 }
 368 ],
 369 rsync_cv_MAKEDEV_TAKES_3_ARGS=yes,rsync_cv_MAKEDEV_TAKES_3_ARGS=no,rsync_cv_MAKEDEV_TAKES_3_ARGS=no)])
 370 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
 371    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
 372 fi
 373
 374 AC_CHECK_SIZEOF(int)
 375 AC_CHECK_SIZEOF(long)
 376 AC_CHECK_SIZEOF(long long)
 377 AC_CHECK_SIZEOF(short)
 378 AC_CHECK_SIZEOF(int16_t)
 379 AC_CHECK_SIZEOF(uint16_t)
 380 AC_CHECK_SIZEOF(int32_t)
 381 AC_CHECK_SIZEOF(uint32_t)
 382 AC_CHECK_SIZEOF(int64_t)
 383 AC_CHECK_SIZEOF(off_t)
 384 AC_CHECK_SIZEOF(off64_t)
 385 AC_CHECK_SIZEOF(time_t)
 386
 387 AC_C_INLINE
 388 AC_C_LONG_DOUBLE
 389
 390 AC_TYPE_SIGNAL
 391 AC_TYPE_UID_T
 392 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
 393 AC_TYPE_GETGROUPS
 394 AC_CHECK_MEMBERS([struct stat.st_rdev,
 395                   struct stat.st_mtimensec,
 396                   struct stat.st_mtim.tv_nsec],,,[
 397 #ifdef HAVE_SYS_TYPES_H
 398 #include <sys/types.h>
 399 #endif
 400 #ifdef HAVE_SYS_STAT_H
 401 #include <sys/stat.h>
 402 #endif
 403 #ifdef HAVE_UNISTD_H
 404 #include <unistd.h>
 405 #endif])
 406
 407 TYPE_SOCKLEN_T
 408
 409 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 410     AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
 411         rsync_cv_errno=yes,rsync_cv_have_errno_decl=no)])
 412 if test x"$rsync_cv_errno" = x"yes"; then
 413    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 414 fi
 415
 416 # The following test taken from the cvs sources
 417 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 418 # These need checks to be before checks for any other functions that
 419 #    might be in the same libraries.
 420 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 421 # libsocket.so which has a bad implementation of gethostbyname (it
 422 # only looks in /etc/hosts), so we only look for -lsocket if we need
 423 # it.
 424 AC_CHECK_FUNCS(connect)
 425 if test x"$ac_cv_func_connect" = x"no"; then
 426     case "$LIBS" in
 427     *-lnsl*) ;;
 428     *) AC_CHECK_LIB(nsl_s, printf) ;;
 429     esac
 430     case "$LIBS" in
 431     *-lnsl*) ;;
 432     *) AC_CHECK_LIB(nsl, printf) ;;
 433     esac
 434     case "$LIBS" in
 435     *-lsocket*) ;;
 436     *) AC_CHECK_LIB(socket, connect) ;;
 437     esac
 438     case "$LIBS" in
 439     *-linet*) ;;
 440     *) AC_CHECK_LIB(inet, connect) ;;
 441     esac
 442     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 443     dnl has been cached.
 444     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 445        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 446         # ac_cv_func_connect=yes
 447         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 448         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 449     fi
 450 fi
 451
 452 AC_SEARCH_LIBS(inet_ntop, resolv)
 453
 454 # For OS X, Solaris, HP-UX, etc.: figure out if -liconv is needed.  We'll
 455 # accept either iconv_open or libiconv_open, since some include files map
 456 # the former to the latter.
 457 AC_SEARCH_LIBS(iconv_open, iconv)
 458 AC_SEARCH_LIBS(libiconv_open, iconv)
 459
 460 AC_MSG_CHECKING([for iconv declaration])
 461 AC_CACHE_VAL(am_cv_proto_iconv, [
 462     AC_TRY_COMPILE([
 463 #include <stdlib.h>
 464 #include <iconv.h>
 465 extern
 466 #ifdef __cplusplus
 467 "C"
 468 #endif
 469 #if defined(__STDC__) || defined(__cplusplus)
 470 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 471 #else
 472 size_t iconv();
 473 #endif
 474 ], [], am_cv_proto_iconv_arg1="", am_cv_proto_iconv_arg1="const")
 475       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 476     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed -e 's/( /(/'`
 477 AC_MSG_RESULT([$]{ac_t:-
 478          }[$]am_cv_proto_iconv)
 479 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 480                    [Define as const if the declaration of iconv() needs const.])
 481
 482 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 483
 484 AC_CHECK_FUNCS(inet_ntop, , [AC_LIBOBJ(lib/inet_ntop)])
 485 AC_CHECK_FUNCS(inet_pton, , [AC_LIBOBJ(lib/inet_pton)])
 486
 487 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
 488 AC_HAVE_TYPE([struct sockaddr_storage], [#include <sys/types.h>
 489 #include <sys/socket.h>])
 490
 491 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 492 #   builtin getaddrinfo if one of the defines don't exist
 493 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 494                rsync_cv_HAVE_GETADDR_DEFINES,[
 495                         AC_EGREP_CPP(yes, [
 496                         #include <sys/types.h>
 497                         #include <sys/socket.h>
 498                         #include <netdb.h>
 499                         #ifdef AI_PASSIVE
 500                         yes
 501                         #endif],
 502                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 503                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 504 if test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" -a x"$ac_cv_type_struct_addrinfo" = x"yes"; then
 505         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 506         # something else so we must include <netdb.h> to get the
 507         # redefinition.
 508         AC_CHECK_FUNCS(getaddrinfo, ,
 509                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 510                 AC_TRY_LINK([#include <sys/types.h>
 511                 #include <sys/socket.h>
 512                 #include <netdb.h>],[getaddrinfo(NULL, NULL, NULL, NULL);],
 513                         [AC_MSG_RESULT([yes])
 514                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 515                                 [Define to 1 if you have the "getaddrinfo" function and required types.])],
 516                         [AC_MSG_RESULT([no])
 517                         AC_LIBOBJ(lib/getaddrinfo)])])
 518 else
 519         AC_LIBOBJ(lib/getaddrinfo)
 520 fi
 521
 522 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 523                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 524                 [],
 525                 [
 526 #include <sys/types.h>
 527 #include <sys/socket.h>
 528 ])
 529
 530 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 531                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 532                 [],
 533                 [
 534 #include <sys/types.h>
 535 #include <sys/socket.h>
 536 #include <netinet/in.h>
 537 ])
 538
 539 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 540                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 541                 [],
 542                 [
 543 #include <sys/types.h>
 544 #include <sys/socket.h>
 545 #include <netinet/in.h>
 546 ])
 547
 548 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 549                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 550                 [],
 551                 [
 552 #include <sys/types.h>
 553 #include <sys/socket.h>
 554 #include <netinet/in.h>
 555 ])
 556
 557 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
 558 #if HAVE_SYS_TYPES_H
 559 # include <sys/types.h>
 560 #endif
 561 #if HAVE_SYS_STAT_H
 562 # include <sys/stat.h>
 563 #endif
 564 #if STDC_HEADERS
 565 # include <stdlib.h>
 566 # include <stddef.h>
 567 #else
 568 # if HAVE_STDLIB_H
 569 #  include <stdlib.h>
 570 # endif
 571 #endif
 572 ])
 573
 574 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 575 #
 576 AC_CHECK_FUNCS(strcasecmp)
 577 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 578     AC_CHECK_LIB(resolv, strcasecmp)
 579 fi
 580
 581 AC_CHECK_FUNCS(aclsort)
 582 if test x"$ac_cv_func_aclsort" = x"no"; then
 583     AC_CHECK_LIB(sec, aclsort)
 584 fi
 585
 586 dnl At the moment we don't test for a broken memcmp(), because all we
 587 dnl need to do is test for equality, not comparison, and it seems that
 588 dnl every platform has a memcmp that can do at least that.
 589 dnl AC_FUNC_MEMCMP
 590
 591 AC_FUNC_UTIME_NULL
 592 AC_FUNC_ALLOCA
 593 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup chown chmod lchmod mknod mkfifo \
 594     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 595     memmove lchown vsnprintf snprintf vasprintf asprintf setsid strpbrk \
 596     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
 597     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 598     seteuid strerror putenv iconv_open locale_charset nl_langinfo getxattr \
 599     extattr_get_link sigaction sigprocmask setattrlist getgrouplist \
 600     initgroups utimensat posix_fallocate attropen)
 601
 602 dnl cygwin iconv.h defines iconv_open as libiconv_open
 603 if test x"$ac_cv_func_iconv_open" != x"yes"; then
 604     AC_CHECK_FUNC(libiconv_open, [ac_cv_func_iconv_open=yes; AC_DEFINE(HAVE_ICONV_OPEN, 1)])
 605 fi
 606
 607 dnl Preallocation stuff (also fallocate, posix_fallocate function tests above):
 608
 609 AC_CACHE_CHECK([for useable fallocate],rsync_cv_have_fallocate,[
 610 AC_TRY_LINK([#include <fcntl.h>
 611 #include <sys/types.h>],
 612 [fallocate(0, 0, 0, 0);],
 613 rsync_cv_have_fallocate=yes,rsync_cv_have_fallocate=no)])
 614 if test x"$rsync_cv_have_fallocate" = x"yes"; then
 615     AC_DEFINE(HAVE_FALLOCATE, 1, [Define to 1 if you have the fallocate function and it compiles and links without error])
 616 fi
 617
 618 AC_CACHE_CHECK([for SYS_fallocate],rsync_cv_have_sys_fallocate,[
 619 AC_TRY_COMPILE([#include <sys/syscall.h>
 620 #include <sys/types.h>],
 621 [syscall(SYS_fallocate, 0, 0, (loff_t)0, (loff_t)0);],
 622 rsync_cv_have_sys_fallocate=yes,rsync_cv_have_sys_fallocate=no)])
 623 if test x"$rsync_cv_have_sys_fallocate" = x"yes"; then
 624     AC_DEFINE(HAVE_SYS_FALLOCATE, 1, [Define to 1 if you have the SYS_fallocate syscall number])
 625 fi
 626
 627 if test x"$ac_cv_func_posix_fallocate" = x"yes"; then
 628     AC_MSG_CHECKING([whether posix_fallocate is efficient])
 629     case $host_os in
 630     *cygwin*)
 631         AC_MSG_RESULT(yes)
 632         AC_DEFINE(HAVE_EFFICIENT_POSIX_FALLOCATE, 1,
 633                   [Define if posix_fallocate is efficient (Cygwin)])
 634         ;;
 635     *)
 636         AC_MSG_RESULT(no)
 637         ;;
 638     esac
 639 fi
 640
 641 dnl End of preallocation stuff
 642
 643 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 644 if test $ac_cv_func_getpgrp = yes; then
 645     AC_FUNC_GETPGRP
 646 fi
 647
 648 AC_ARG_ENABLE(iconv-open,
 649     AC_HELP_STRING([--disable-iconv-open],
 650             [disable all use of iconv_open() function]),
 651     [], [enable_iconv_open=$ac_cv_func_iconv_open])
 652
 653 if test x"$enable_iconv_open" != x"no"; then
 654     AC_DEFINE(USE_ICONV_OPEN, 1, [Define to 1 if you want rsync to make use of iconv_open()])
 655 fi
 656
 657 AC_ARG_ENABLE(iconv,
 658     AC_HELP_STRING([--disable-iconv],
 659             [disable rsync's --iconv option]),
 660     [], [enable_iconv=$enable_iconv_open])
 661 AH_TEMPLATE([ICONV_OPTION],
 662 [Define if you want the --iconv option.  Specifing a value will set the
 663 default iconv setting (a NULL means no --iconv processing by default).])
 664 if test x"$enable_iconv" != x"no"; then
 665         if test x"$enable_iconv" = x"yes"; then
 666                 AC_DEFINE(ICONV_OPTION, NULL)
 667         else
 668                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
 669         fi
 670         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
 671 fi
 672
 673 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
 674   AC_TRY_RUN([
 675 #if HAVE_UNISTD_H
 676 # include <unistd.h>
 677 #endif
 678 #include <stdlib.h>
 679 #include <errno.h>
 680     main() {
 681         char const *dangling_symlink = "conftest.dangle";
 682         unlink(dangling_symlink);
 683         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 684         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) exit(1);
 685         exit(0);
 686     }],
 687   rsync_cv_chown_modifies_symlink=yes,rsync_cv_chown_modifies_symlink=no,rsync_cv_chown_modifies_symlink=no)])
 688 if test $rsync_cv_chown_modifies_symlink = yes; then
 689   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 690 fi
 691
 692 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
 693   AC_TRY_RUN([
 694 #if HAVE_UNISTD_H
 695 # include <unistd.h>
 696 #endif
 697 #include <stdlib.h>
 698 #include <errno.h>
 699 #define FILENAME "conftest.dangle"
 700     main() {
 701         unlink(FILENAME);
 702         if (symlink("conftest.no-such", FILENAME) < 0) abort();
 703         if (link(FILENAME, FILENAME "2") < 0) exit(1);
 704         exit(0);
 705     }],
 706   rsync_cv_can_hardlink_symlink=yes,rsync_cv_can_hardlink_symlink=no,rsync_cv_can_hardlink_symlink=no)])
 707 if test $rsync_cv_can_hardlink_symlink = yes; then
 708   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
 709 fi
 710
 711 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
 712   AC_TRY_RUN([
 713 #if HAVE_UNISTD_H
 714 # include <unistd.h>
 715 #endif
 716 #include <stdlib.h>
 717 #include <errno.h>
 718 #define FILENAME "conftest.fifi"
 719     main() {
 720         unlink(FILENAME);
 721         if (mkfifo(FILENAME, 0777) < 0) abort();
 722         if (link(FILENAME, FILENAME "2") < 0) exit(1);
 723         exit(0);
 724     }],
 725   rsync_cv_can_hardlink_special=yes,rsync_cv_can_hardlink_special=no,rsync_cv_can_hardlink_special=no)])
 726 if test $rsync_cv_can_hardlink_special = yes; then
 727     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
 728 fi
 729
 730 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 731 AC_TRY_RUN([
 732 #include <sys/types.h>
 733 #include <sys/socket.h>
 734
 735 main() {
 736        int fd[2];
 737 #ifdef __CYGWIN__
 738        exit(1);
 739 #else
 740        exit((socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1);
 741 #endif
 742 }],
 743 rsync_cv_HAVE_SOCKETPAIR=yes,rsync_cv_HAVE_SOCKETPAIR=no,rsync_cv_HAVE_SOCKETPAIR=cross)])
 744 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 745     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
 746 fi
 747
 748 if test x"$with_included_popt" != x"yes"; then
 749     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 750 fi
 751 if test x"$ac_cv_header_popt_popt_h" = x"yes"; then
 752     # If the system has /usr/include/popt/popt.h, we enable the
 753     # included popt because an attempt to "#include <popt/popt.h>"
 754     # would use our included header file anyway (due to -I.), and
 755     # might conflict with the system popt.
 756     with_included_popt=yes
 757 elif test x"$ac_cv_header_popt_h" != x"yes"; then
 758     with_included_popt=yes
 759 fi
 760
 761 AC_MSG_CHECKING([whether to use included libpopt])
 762 if test x"$with_included_popt" = x"yes"; then
 763     AC_MSG_RESULT($srcdir/popt)
 764     BUILD_POPT='$(popt_OBJS)'
 765     CFLAGS="$CFLAGS -I$srcdir/popt"
 766     if test x"$ALLOCA" != x
 767     then
 768         # this can be removed when/if we add an included alloca.c;
 769         #  see autoconf documentation on AC_FUNC_ALLOCA
 770         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
 771     fi
 772 else
 773     AC_MSG_RESULT(no)
 774 fi
 775
 776 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
 777 AC_TRY_COMPILE([],[signed char *s = ""],
 778 rsync_cv_SIGNED_CHAR_OK=yes,rsync_cv_SIGNED_CHAR_OK=no)])
 779 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
 780     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
 781 fi
 782
 783 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
 784 AC_TRY_RUN([#include <sys/types.h>
 785 #include <dirent.h>
 786 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 787 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 788 di->d_name[0] == 0) exit(0); exit(1);} ],
 789 rsync_cv_HAVE_BROKEN_READDIR=yes,rsync_cv_HAVE_BROKEN_READDIR=no,rsync_cv_HAVE_BROKEN_READDIR=cross)])
 790 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 791     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
 792 fi
 793
 794 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
 795 AC_TRY_COMPILE([#include <sys/types.h>
 796 #include <utime.h>],
 797 [struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));],
 798 rsync_cv_HAVE_STRUCT_UTIMBUF=yes,rsync_cv_HAVE_STRUCT_UTIMBUF=no)])
 799 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
 800     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
 801 fi
 802
 803 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
 804 AC_TRY_COMPILE([#include <sys/time.h>
 805 #include <unistd.h>],
 806 [struct timeval tv; exit(gettimeofday(&tv, NULL));],
 807 rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes,rsync_cv_HAVE_GETTIMEOFDAY_TZ=no)])
 808 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
 809     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
 810 fi
 811
 812 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
 813 AC_TRY_RUN([
 814 #include <sys/types.h>
 815 #include <stdarg.h>
 816 void foo(const char *format, ...) {
 817        va_list ap;
 818        int len;
 819        char buf[5];
 820
 821        va_start(ap, format);
 822        len = vsnprintf(0, 0, format, ap);
 823        va_end(ap);
 824        if (len != 5) exit(1);
 825
 826        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 827
 828        exit(0);
 829 }
 830 main() { foo("hello"); }
 831 ],
 832 rsync_cv_HAVE_C99_VSNPRINTF=yes,rsync_cv_HAVE_C99_VSNPRINTF=no,rsync_cv_HAVE_C99_VSNPRINTF=cross)])
 833 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 834     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
 835 fi
 836
 837
 838 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
 839 AC_TRY_RUN([#include <stdlib.h>
 840 #include <sys/types.h>
 841 #include <sys/stat.h>
 842 #include <unistd.h>
 843 main() {
 844   struct stat st;
 845   char tpl[20]="/tmp/test.XXXXXX";
 846   int fd = mkstemp(tpl);
 847   if (fd == -1) exit(1);
 848   unlink(tpl);
 849   if (fstat(fd, &st) != 0) exit(1);
 850   if ((st.st_mode & 0777) != 0600) exit(1);
 851   exit(0);
 852 }],
 853 rsync_cv_HAVE_SECURE_MKSTEMP=yes,
 854 rsync_cv_HAVE_SECURE_MKSTEMP=no,
 855 rsync_cv_HAVE_SECURE_MKSTEMP=cross)])
 856 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
 857     case $host_os in
 858     hpux*)
 859         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
 860         dnl so we noisily skip using it.  See HP change request JAGaf34426
 861         dnl for details. (sbonds)
 862         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
 863         ;;
 864     *)
 865         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
 866         ;;
 867     esac
 868 fi
 869
 870
 871 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
 872 AC_TRY_RUN([
 873 #include <stdio.h>
 874 #include <sys/stat.h>
 875 #include <errno.h>
 876 main() { int rc, ec; char *fn = "fifo-test";
 877 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
 878 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
 879 return 0;}],
 880            rsync_cv_MKNOD_CREATES_FIFOS=yes,rsync_cv_MKNOD_CREATES_FIFOS=no,rsync_cv_MKNOD_CREATES_FIFOS=cross)])
 881 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
 882     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
 883 fi
 884
 885 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
 886 AC_TRY_RUN([
 887 #include <stdio.h>
 888 #include <sys/stat.h>
 889 #include <errno.h>
 890 main() { int rc, ec; char *fn = "sock-test";
 891 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
 892 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
 893 return 0;}],
 894            rsync_cv_MKNOD_CREATES_SOCKETS=yes,rsync_cv_MKNOD_CREATES_SOCKETS=no,rsync_cv_MKNOD_CREATES_SOCKETS=cross)])
 895 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
 896     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
 897 fi
 898
 899 #
 900 # The following test was mostly taken from the tcl/tk plus patches
 901 #
 902 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
 903 rm -rf conftest*
 904 cat > conftest.$ac_ext <<EOF
 905 int main() { return 0; }
 906 EOF
 907 ${CC-cc} -c -o conftest..o conftest.$ac_ext
 908 if test -f conftest..o; then
 909     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
 910 else
 911     rsync_cv_DASHC_WORKS_WITH_DASHO=no
 912 fi
 913 rm -rf conftest*
 914 ])
 915 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
 916     OBJ_SAVE="#"
 917     OBJ_RESTORE="#"
 918     CC_SHOBJ_FLAG='-o $@'
 919 else
 920     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
 921     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
 922     CC_SHOBJ_FLAG=""
 923 fi
 924
 925 AC_SUBST(OBJ_SAVE)
 926 AC_SUBST(OBJ_RESTORE)
 927 AC_SUBST(CC_SHOBJ_FLAG)
 928 AC_SUBST(BUILD_POPT)
 929 AC_SUBST(MAKE_MAN)
 930
 931 AC_CHECK_FUNCS(_acl __acl _facl __facl)
 932 #################################################
 933 # check for ACL support
 934
 935 AC_MSG_CHECKING([whether to support ACLs])
 936 AC_ARG_ENABLE(acl-support,
 937         AC_HELP_STRING([--disable-acl-support],
 938                        [disable ACL support]))
 939
 940 if test x"$enable_acl_support" = x"no"; then
 941     AC_MSG_RESULT(no)
 942 else
 943     case "$host_os" in
 944     *sysv5*)
 945         AC_MSG_RESULT(Using UnixWare ACLs)
 946         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
 947         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
 948         ;;
 949     solaris*|*cygwin*)
 950         AC_MSG_RESULT(Using solaris ACLs)
 951         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
 952         AC_DEFINE(SUPPORT_ACLS, 1)
 953         ;;
 954     *hpux*)
 955         AC_MSG_RESULT(Using HPUX ACLs)
 956         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
 957         AC_DEFINE(SUPPORT_ACLS, 1)
 958         ;;
 959     *irix*)
 960         AC_MSG_RESULT(Using IRIX ACLs)
 961         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
 962         AC_DEFINE(SUPPORT_ACLS, 1)
 963         ;;
 964     *aix*)
 965         AC_MSG_RESULT(Using AIX ACLs)
 966         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
 967         AC_DEFINE(SUPPORT_ACLS, 1)
 968         ;;
 969     *osf*)
 970         AC_MSG_RESULT(Using Tru64 ACLs)
 971         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
 972         AC_DEFINE(SUPPORT_ACLS, 1)
 973         LIBS="$LIBS -lpacl"
 974         ;;
 975     darwin*)
 976         AC_MSG_RESULT(Using OS X ACLs)
 977         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
 978         AC_DEFINE(SUPPORT_ACLS, 1)
 979         ;;
 980     *)
 981         AC_MSG_RESULT(running tests:)
 982         AC_CHECK_LIB(acl,acl_get_file)
 983             AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
 984             AC_TRY_LINK([#include <sys/types.h>
 985 #include <sys/acl.h>],
 986 [ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);],
 987 samba_cv_HAVE_POSIX_ACLS=yes,samba_cv_HAVE_POSIX_ACLS=no)])
 988         AC_MSG_CHECKING(ACL test results)
 989         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
 990             AC_MSG_RESULT(Using posix ACLs)
 991             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
 992             AC_DEFINE(SUPPORT_ACLS, 1)
 993             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
 994                 AC_TRY_LINK([#include <sys/types.h>
 995 #include <sys/acl.h>],
 996 [ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);],
 997 samba_cv_HAVE_ACL_GET_PERM_NP=yes,samba_cv_HAVE_ACL_GET_PERM_NP=no)])
 998             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
 999                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
1000             fi
1001         else
1002             if test x"$enable_acl_support" = x"yes"; then
1003                 AC_MSG_ERROR(Failed to find ACL support)
1004             else
1005                 AC_MSG_RESULT(No ACL support found)
1006             fi
1007         fi
1008         ;;
1009     esac
1010 fi
1011
1012 #################################################
1013 # check for extended attribute support
1014 AC_MSG_CHECKING(whether to support extended attributes)
1015 AC_ARG_ENABLE(xattr-support,
1016     AC_HELP_STRING([--disable-xattr-support],
1017             [disable extended attributes]),
1018     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link$ac_cv_func_attropen" in
1019         *yes*) enable_xattr_support=maybe ;;
1020         *) enable_xattr_support=no ;;
1021         esac])
1022 AH_TEMPLATE([SUPPORT_XATTRS],
1023 [Define to 1 to add support for extended attributes])
1024 if test x"$enable_xattr_support" = x"no"; then
1025     AC_MSG_RESULT(no)
1026 else
1027     case "$host_os" in
1028     *linux*)
1029         AC_MSG_RESULT(Using Linux xattrs)
1030         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs])
1031         AC_DEFINE(SUPPORT_XATTRS, 1)
1032         AC_DEFINE(NO_SYMLINK_USER_XATTRS, 1, [True if symlinks do not support user xattrs])
1033         ;;
1034     darwin*)
1035         AC_MSG_RESULT(Using OS X xattrs)
1036         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
1037         AC_DEFINE(SUPPORT_XATTRS, 1)
1038         AC_DEFINE(NO_DEVICE_XATTRS, 1, [True if device files do not support xattrs])
1039         AC_DEFINE(NO_SPECIAL_XATTRS, 1, [True if special files do not support xattrs])
1040         ;;
1041     freebsd*)
1042         AC_MSG_RESULT(Using FreeBSD extattrs)
1043         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
1044         AC_DEFINE(SUPPORT_XATTRS, 1)
1045         ;;
1046     solaris*)
1047         AC_MSG_RESULT(Using Solaris xattrs)
1048         AC_DEFINE(HAVE_SOLARIS_XATTRS, 1, [True if you have Solaris xattrs])
1049         AC_DEFINE(SUPPORT_XATTRS, 1)
1050         AC_DEFINE(NO_SYMLINK_XATTRS, 1, [True if symlinks do not support xattrs])
1051         ;;
1052     *)
1053         if test x"$enable_xattr_support" = x"yes"; then
1054             AC_MSG_ERROR(Failed to find extended attribute support)
1055         else
1056             AC_MSG_RESULT(No extended attribute support found)
1057         fi
1058         ;;
1059     esac
1060 fi
1061
1062 if test x"$enable_acl_support" = x"no" -o x"$enable_xattr_support" = x"no" -o x"$enable_iconv" = x"no"; then
1063     AC_MSG_CHECKING([whether $CC supports -Wno-unused-parameter])
1064     OLD_CFLAGS="$CFLAGS"
1065     CFLAGS="$CFLAGS -Wno-unused-parameter"
1066     AC_TRY_LINK([#include <stdio.h>], [printf("hello\n");], [rsync_warn_flag=yes], [rsync_warn_flag=no])
1067     AC_MSG_RESULT([$rsync_warn_flag])
1068     if test x"$rsync_warn_flag" = x"no"; then
1069         CFLAGS="$OLD_CFLAGS"
1070     fi
1071 fi
1072
1073 case "$CC" in
1074 ' checker'*|checker*)
1075     AC_DEFINE(FORCE_FD_ZERO_MEMSET, 1, [Used to make "checker" understand that FD_ZERO() clears memory.])
1076     ;;
1077 esac
1078
1079 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
1080 AC_OUTPUT
1081
1082 AC_MSG_RESULT()
1083 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
1084 AC_MSG_RESULT()