configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Revision$)
   3 AC_PREREQ(2.62)
   4 test -z "$CFLAGS" && CFLAGS="-g"
   5 AC_INIT([Heimdal],[7.99.1],[https://github.com/heimdal/heimdal/issues])
   6 AC_CONFIG_SRCDIR([kuser/kinit.c])
   7 AC_CONFIG_HEADERS(include/config.h)
   8 AC_CONFIG_MACRO_DIR([cf])
   9
  10 AM_INIT_AUTOMAKE([foreign 1.11])
  11 AM_MAINTAINER_MODE
  12
  13 LT_PREREQ([2.2])
  14 LT_INIT([shared static win32-dll])
  15
  16
  17 dnl Checks for programs.
  18 AC_PROG_CC
  19 AM_PROG_CC_C_O
  20 AC_PROG_CPP
  21
  22 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  23
  24 AC_PREFIX_DEFAULT(/usr/heimdal)
  25
  26 test "$sysconfdir" = '${prefix}/etc' && sysconfdir='/etc'
  27 test "$localstatedir" = '${prefix}/var' && localstatedir='/var/heimdal'
  28
  29 AC_CANONICAL_HOST
  30 CANONICAL_HOST=$host
  31 AC_SUBST(CANONICAL_HOST)
  32
  33 rk_SYS_LARGEFILE
  34
  35 rk_AIX
  36 rk_IRIX
  37 rk_SUNOS
  38
  39 dnl
  40 dnl this is needed to run the configure tests against glibc
  41 dnl
  42 AC_DEFINE([_GNU_SOURCE], 1,
  43         [Define to enable extensions on glibc-based systems such as Linux.])
  44
  45 AC_OBJEXT
  46 AC_EXEEXT
  47
  48 dnl
  49 dnl this is needed when der-protos.h or der-private.h has to be generated
  50 dnl
  51 if ! test -f "$srcdir/lib/asn1/der-protos.h" ||
  52    ! test -f "$srcdir/lib/asn1/der-private.h"; then
  53     AC_KRB_PROG_PERL
  54     AC_KRB_PERL_MOD(Getopt::Std)
  55     AC_KRB_PERL_MOD(File::Compare)
  56     AC_KRB_PERL_MOD(JSON)
  57 fi
  58
  59 dnl AC_KRB_PROG_YACC
  60 AC_PROG_YACC
  61 AM_PROG_LEX
  62 AS_IF([$LEX --nounput -V > /dev/null 2>&1 && test $? -eq 0],
  63       [AC_SUBST([FLEXNOUNPUTARGS], ["--nounput"])],
  64       [AC_SUBST([FLEXNOUNPUTARGS], [""])])
  65 dnl AC_PROG_RANLIB
  66 AC_PROG_AWK
  67 AC_KRB_PROG_LN_S
  68
  69 AC_MIPS_ABI
  70 CC="$CC $abi"
  71 libdir="$libdir$abilibdirext"
  72
  73 AC_C___ATTRIBUTE__
  74
  75 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = "yes")
  76 rk_VERSIONSCRIPT
  77
  78 dnl Code coverage
  79 AC_ARG_ENABLE([gcov],
  80         AC_HELP_STRING([--enable-gcov], [enable gcov code coverage tool]))
  81 AM_CONDITIONAL([ENABLE_GCOV], [test "x$enable_gcov" = xyes])
  82
  83
  84 dnl
  85 dnl Helper bits for cross compiling
  86 dnl
  87
  88
  89
  90 AM_CONDITIONAL(CROSS_COMPILE, test "${cross_compiling}" = yes)
  91
  92 AC_ARG_WITH(cross-tools,
  93         AS_HELP_STRING([--with-cross-tools=dir], [use cross tools in dir]),
  94         [if test "$withval" = "yes"; then
  95                 AC_MSG_ERROR([Need path to cross tools])
  96         fi
  97         with_cross_tools="${with_cross_tools}/"
  98         ])
  99
 100 if test "${cross_compiling}" != yes ; then
 101
 102    ASN1_COMPILE="\$(top_builddir)/lib/asn1/asn1_compile\$(EXEEXT)"
 103    SLC="\$(top_builddir)/lib/sl/slc"
 104
 105    ASN1_COMPILE_DEP="\$(ASN1_COMPILE)"
 106    SLC_DEP="\$(SLC)"
 107 else
 108    ASN1_COMPILE="${with_cross_tools}asn1_compile"
 109    SLC="${with_cross_tools}slc"
 110
 111    ASN1_COMPILE_DEP=
 112    SLC_DEP=
 113
 114    ac_cv_prog_COMPILE_ET=${with_cross_tools}compile_et
 115
 116 fi
 117
 118 AC_SUBST([ASN1_COMPILE])
 119 AC_SUBST([ASN1_COMPILE_DEP])
 120 AC_SUBST([SLC])
 121 AC_SUBST([SLC_DEP])
 122
 123 dnl ---
 124
 125 AC_DEFINE(HEIM_WEAK_CRYPTO, 1, [Define if you want support for weak crypto])
 126
 127 rk_TEST_PACKAGE(openldap,
 128 [#include <lber.h>
 129 #include <ldap.h>],
 130 [-lldap -llber],,,OPENLDAP)
 131
 132 AC_ARG_ENABLE(hdb-openldap-module,
 133         AS_HELP_STRING([--enable-hdb-openldap-module],
 134                 [if you want support to build openldap hdb as shared object]))
 135 if test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes; then
 136     AC_DEFINE(OPENLDAP_MODULE, 1, [Define if you want support for hdb ldap module])
 137 fi
 138 AM_CONDITIONAL(OPENLDAP_MODULE, test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes)
 139
 140 dnl
 141 dnl Optional modules, pk-init, digest, kx509
 142 dnl
 143
 144 AC_ARG_ENABLE(pk-init,
 145         AS_HELP_STRING([--disable-pk-init],
 146                 [if you want disable to PK-INIT support]))
 147 if test "$enable_pk_init" != no ;then
 148         AC_DEFINE([PKINIT], 1, [Define to enable PKINIT.])
 149 fi
 150 AM_CONDITIONAL(PKINIT, test "$enable_pk_init" != no)
 151
 152 AC_ARG_ENABLE(digest,
 153         AS_HELP_STRING([--disable-digest],
 154                 [if you want disable to DIGEST support]))
 155 if test "$enable_digest" != no ;then
 156         AC_DEFINE([DIGEST], 1, [Define to enable DIGEST.])
 157 fi
 158
 159 AC_ARG_ENABLE(kx509,
 160         AS_HELP_STRING([--disable-kx509],
 161                 [if you want disable to kx509 support]))
 162 if test "$enable_kx509" != no ;then
 163         AC_DEFINE([KX509], 1, [Define to enable kx509.])
 164 fi
 165
 166 dnl Need to test if pkg-config exists
 167 PKG_PROG_PKG_CONFIG
 168
 169 dnl libcap-ng
 170 AC_ARG_WITH([capng],
 171   AC_HELP_STRING([--with-capng], [use libcap-ng to drop KDC privileges @<:@default=check@:>@]),
 172   [],
 173   [with_capng=check])
 174 if test "$with_capng" != "no"; then
 175   PKG_CHECK_MODULES([CAPNG], [libcap-ng >= 0.4.0],
 176                     [with_capng=yes],[with_capng=no])
 177 fi
 178 if test "$with_capng" = "yes"; then
 179   AC_DEFINE_UNQUOTED([HAVE_CAPNG], 1, [whether capng is available for privilege reduction])
 180 fi
 181 AM_CONDITIONAL([HAVE_CAPNG], [test "$with_capng" != "no"])
 182 AC_SUBST([CAPNG_CFLAGS])
 183 AC_SUBST([CAPNG_LIBS])
 184
 185 dnl Check for sqlite
 186 rk_TEST_PACKAGE(sqlite3,
 187 [#include <sqlite3.h>
 188 #ifndef SQLITE_OPEN_CREATE
 189 #error "old version"
 190 #endif],
 191 [-lsqlite3],,,SQLITE3)
 192
 193 if test "X$with_sqlite3" != Xyes ; then
 194    INCLUDE_sqlite3="-I\$(top_srcdir)/lib/sqlite"
 195    LIB_sqlite3="\$(top_builddir)/lib/sqlite/libheimsqlite.la"
 196 fi
 197 AM_CONDITIONAL(SQLITE3,  test "X$with_sqlite3" = Xyes)
 198
 199 AC_DEFINE(HAVE_SQLITE3, 1, [Define if you want support for sqlite in Heimdal.])
 200
 201 AC_ARG_ENABLE(sqlite-cache,
 202         AS_HELP_STRING([--disable-sqlite-cache],[if you want support for cache in sqlite]))
 203 if test "$enable_sqlite_cache" != no; then
 204     AC_DEFINE(HAVE_SCC, 1, [Define if you want support for cache in sqlite.])
 205 fi
 206 AM_CONDITIONAL(have_scc, test "$enable_sqlite_cache" != no)
 207
 208
 209 dnl check for libintl
 210 rk_TEST_PACKAGE(libintl,
 211 [#include <libintl.h>],
 212 [-lintl],,,LIBINTL)
 213
 214 dnl path where the hdb directory is stored
 215 AC_ARG_WITH([hdbdir],
 216         [AS_HELP_STRING([--with-hdbdir],[Default location for KDC database @<:@default=/var/heimdal@:>@])],
 217         [],
 218         [with_hdbdir=/var/heimdal])
 219 DIR_hdbdir="$with_hdbdir"
 220 AC_SUBST([DIR_hdbdir])
 221
 222
 223 AM_CONDITIONAL(KRB5, true)
 224 AM_CONDITIONAL(do_roken_rename, true)
 225
 226 AC_DEFINE(SUPPORT_INETD, 1, [Enable use of inetd style startup.])dnl
 227
 228
 229 AC_DEFINE(KRB5, 1, [Enable Kerberos 5 support in applications.])dnl
 230 AC_SUBST(LIB_kdb)dnl
 231
 232 KRB_CRYPTO
 233
 234 KRB_PTHREADS
 235
 236 AC_ARG_ENABLE(dce,
 237         AS_HELP_STRING([--enable-dce],[if you want support for DCE/DFS PAG's]))
 238 if test "$enable_dce" = yes; then
 239     AC_DEFINE(DCE, 1, [Define if you want support for DCE/DFS PAG's.])
 240 fi
 241 AM_CONDITIONAL(DCE, test "$enable_dce" = yes)
 242
 243 ## XXX quite horrible:
 244 if test -f /etc/ibmcxx.cfg; then
 245         dpagaix_ldadd=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/libraries/{;s/^[[^=]]*=\(.*\)/\1/;s/,/ /gp;}'`
 246         dpagaix_cflags=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/options/{;s/^[[^=]]*=\(.*\)/\1/;s/-q[^,]*//;s/,/ /gp;}'`
 247         dpagaix_ldflags=
 248 else
 249         dpagaix_cflags="-D_THREAD_SAFE -D_AIX_PTHREADS_D7 -D_AIX32_THREADS=1 -D_AES_SOURCE -D_AIX41 -I/usr/include/dce"
 250         dpagaix_ldadd="-L/usr/lib/threads -ldcelibc_r -ldcepthreads -lpthreads_compat lpthreads -lc_r"
 251         dpagaix_ldflags="-Wl,-bI:dfspag.exp"
 252 fi
 253 AC_SUBST(dpagaix_cflags)
 254 AC_SUBST(dpagaix_ldadd)
 255 AC_SUBST(dpagaix_ldflags)
 256
 257 AC_ARG_ENABLE([afs-support],
 258         AS_HELP_STRING([--disable-afs-support],[if you don't want support for AFS]))
 259 if test "$enable_afs_support" = no; then
 260         AC_DEFINE(NO_AFS, 1, [Define if you don't wan't support for AFS.])
 261         NO_AFS="1"
 262 fi
 263 AC_SUBST(NO_AFS)dnl
 264 AM_CONDITIONAL(NO_AFS, test "$enable_afs_support" = no)
 265
 266 rk_DB
 267
 268 dnl AC_ROKEN(10,[/usr/heimdal /usr/athena],[lib/roken],[$(top_builddir)/lib/roken/libroken.la],[-I$(top_builddir)/lib/roken -I$(top_srcdir)/lib/roken])
 269
 270 rk_ROKEN(lib/roken)
 271 LIBADD_roken="$LIB_roken"
 272 AC_SUBST(LIBADD_roken)dnl
 273 LIB_roken="\$(top_builddir)/lib/vers/libvers.la $LIB_roken"
 274
 275 rk_OTP
 276
 277 rk_LIBDISPATCH
 278
 279 AC_CHECK_OSFC2
 280
 281 AC_ARG_ENABLE(mmap,
 282         AS_HELP_STRING([--disable-mmap],[disable use of mmap]))
 283 if test "$enable_mmap" = "no"; then
 284         AC_DEFINE(NO_MMAP, 1, [Define if you don't want to use mmap.])
 285 fi
 286
 287 AC_ARG_ENABLE(afs-string-to-key,
 288         AS_HELP_STRING([--disable-afs-string-to-key],
 289         [disable use of weak AFS string-to-key functions]),
 290         [], [enable_afs_string_to_key=yes])
 291
 292 if test "$enable_afs_string_to_key" = "yes"; then
 293         AC_DEFINE(ENABLE_AFS_STRING_TO_KEY, 1, [Define if want to use the weak AFS string to key functions.])
 294         ENABLE_AFS_STRING_TO_KEY=1
 295 fi
 296 AC_SUBST(ENABLE_AFS_STRING_TO_KEY)dnl
 297
 298
 299 rk_CHECK_MAN
 300
 301 rk_TEST_PACKAGE(readline,
 302 [#include <stdio.h>
 303 #if defined(HAVE_READLINE_READLINE_H)
 304 #include <readline/readline.h>
 305 #elif defined(HAVE_READLINE_H)
 306 #include <readline.h>
 307 #endif
 308 ],-lreadline,,, READLINE,, [readline.h readline/readline.h])
 309
 310 rk_TEST_PACKAGE(libedit,
 311 [#include <stdio.h>
 312 #if defined(HAVE_READLINE_READLINE_H)
 313 #include <readline/readline.h>
 314 #elif defined(HAVE_READLINE_H)
 315 #include <readline.h>
 316 #elif defined(HAVE_EDITLINE_READLINE_H)
 317 #include <editline/readline.h>
 318 #endif
 319 ],-ledit,,, READLINE,, [readline.h readline/readline.h editline/readline.h])
 320
 321 AC_CONFIG_SUBDIRS([lib/libedit])
 322
 323 KRB_C_BIGENDIAN
 324 AC_C_INLINE
 325
 326 dnl AM_C_PROTOTYPES
 327
 328 dnl Checks for typedefs, structures, and compiler characteristics.
 329 AC_C_CONST
 330 AC_TYPE_OFF_T
 331 AC_CHECK_TYPE_EXTRA(mode_t, unsigned short, [])
 332 AC_CHECK_TYPE_EXTRA(sig_atomic_t, int, [#include <signal.h>])
 333 AC_HAVE_TYPE([long long])
 334 AC_HEADER_TIME
 335 AC_STRUCT_TM
 336
 337 dnl Checks for header files.
 338 AC_HEADER_STDC
 339
 340 AC_CHECK_HEADERS([\
 341         CommonCrypto/CommonDigest.h             \
 342         CommonCrypto/CommonCryptor.h            \
 343         arpa/telnet.h                           \
 344         bind/bitypes.h                          \
 345         bsdsetjmp.h                             \
 346         curses.h                                \
 347         dlfcn.h                                 \
 348         execinfo.h                              \
 349         fnmatch.h                               \
 350         inttypes.h                              \
 351         io.h                                    \
 352         keyutils.h                              \
 353         libutil.h                               \
 354         limits.h                                \
 355         maillock.h                              \
 356         netgroup.h                              \
 357         netinet/in6_machtypes.h                 \
 358         pthread.h                               \
 359         pty.h                                   \
 360         sac.h                                   \
 361         sgtty.h                                 \
 362         siad.h                                  \
 363         signal.h                                \
 364         strings.h                               \
 365         stropts.h                               \
 366         sys/bitypes.h                           \
 367         sys/category.h                          \
 368         sys/file.h                              \
 369         sys/filio.h                             \
 370         sys/ioccom.h                            \
 371         sys/mman.h                              \
 372         sys/param.h                             \
 373         sys/pty.h                               \
 374         sys/ptyio.h                             \
 375         sys/select.h                            \
 376         sys/socket.h                            \
 377         sys/str_tty.h                           \
 378         sys/stream.h                            \
 379         sys/stropts.h                           \
 380         sys/syscall.h                           \
 381         sys/termio.h                            \
 382         sys/timeb.h                             \
 383         sys/times.h                             \
 384         sys/types.h                             \
 385         sys/un.h                                \
 386         locale.h                                \
 387         termcap.h                               \
 388         termio.h                                \
 389         termios.h                               \
 390         time.h                                  \
 391         tmpdir.h                                \
 392         udb.h                                   \
 393         util.h                                  \
 394 ])
 395
 396 dnl On Solaris 8 there's a compilation warning for term.h because
 397 dnl it doesn't define `bool'.
 398 AC_CHECK_HEADERS(term.h, , , -)
 399
 400 dnl aix have asl.h (A/IX screen library) that we don't want
 401 AC_CHECK_HEADERS(asl.h, , , [
 402 #include <asl.h>
 403 #ifndef ASL_STRING_EMERG
 404 #error ASL_STRING_EMERG missing
 405 #endif])
 406
 407 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
 408 #if HAVE_SYS_SOCKET_H
 409 #include <sys/socket.h>
 410 #endif])
 411
 412 AC_CHECK_HEADERS(sys/ptyvar.h, , , [AC_INCLUDES_DEFAULT
 413 #if HAVE_SYS_TTY_H
 414 #include <sys/tty.h>
 415 #endif])
 416
 417 AC_CHECK_HEADERS(sys/strtty.h, , , [AC_INCLUDES_DEFAULT
 418 #if HAVE_TERMIOS_H
 419 #include <termios.h>
 420 #endif
 421 #if HAVE_SYS_STREAM_H
 422 #include <sys/stream.h>
 423 #endif])
 424
 425 AC_CHECK_HEADERS(sys/ucred.h, , , [AC_INCLUDES_DEFAULT
 426 #if HAVE_SYS_TYPES_H
 427 #include <sys/types.h>
 428 #endif
 429 #if HAVE_SYS_PARAM_H
 430 #include <sys/param.h>
 431 #endif])
 432
 433 AC_CHECK_HEADERS(security/pam_modules.h, , , [AC_INCLUDES_DEFAULT
 434 #include <security/pam_appl.h>
 435 ])
 436
 437 dnl export symbols
 438 rk_WIN32_EXPORT(BUILD_KRB5_LIB, KRB5_LIB)
 439 rk_WIN32_EXPORT(BUILD_ROKEN_LIB, ROKEN_LIB)
 440 rk_WIN32_EXPORT(BUILD_GSSAPI_LIB, GSSAPI_LIB)
 441
 442 dnl Checks for libraries.
 443
 444 AC_FIND_FUNC_NO_LIBS(logwtmp, util,[
 445 #ifdef HAVE_UTIL_H
 446 #include <util.h>
 447 #endif
 448 ],[0,0,0])
 449 AC_FIND_FUNC_NO_LIBS(logout, util,[
 450 #ifdef HAVE_UTIL_H
 451 #include <util.h>
 452 #endif
 453 ],[0])
 454 AC_FIND_FUNC_NO_LIBS(openpty, util,[
 455 #ifdef HAVE_UTIL_H
 456 #include <util.h>
 457 #endif
 458 ],[0,0,0,0,0])
 459
 460 AC_FIND_FUNC_NO_LIBS(tgetent, termcap ncurses curses tinfo,[
 461 #ifdef HAVE_TERMCAP_H
 462 #include <termcap.h>
 463 #endif
 464 #ifdef HAVE_CURSES_H
 465 #include <curses.h>
 466 #endif
 467 ],[0,0])
 468
 469 dnl Checks for library functions.
 470
 471 AC_CHECK_FUNCS([                                \
 472         _getpty                                 \
 473         _scrsize                                \
 474         arc4random                              \
 475         backtrace                               \
 476         fcntl                                   \
 477         fork                                    \
 478         fseeko                                  \
 479         ftello                                  \
 480         getpeereid                              \
 481         getpeerucred                            \
 482         getresgid                               \
 483         getresuid                               \
 484         grantpt                                 \
 485         kill                                    \
 486         mktime                                  \
 487         ptsname                                 \
 488         rand                                    \
 489         revoke                                  \
 490         select                                  \
 491         setitimer                               \
 492         setpcred                                \
 493         setpgid                                 \
 494         setproctitle                            \
 495         setregid                                \
 496         setresgid                               \
 497         setresuid                               \
 498         setreuid                                \
 499         setsid                                  \
 500         setutent                                \
 501         sigaction                               \
 502         strstr                                  \
 503         ttyname                                 \
 504         ttyslot                                 \
 505         umask                                   \
 506         unlockpt                                \
 507         vhangup                                 \
 508         waitpid                                 \
 509         yp_get_default_domain                   \
 510 ])
 511
 512 AC_MSG_CHECKING([checking for __sync_add_and_fetch])
 513 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>]],
 514         [[unsigned int foo, bar; bar = __sync_add_and_fetch(&foo, 1);]])],
 515         [ac_rk_have___sync_add_and_fetch=yes], [ac_rk_have___sync_add_and_fetch=no])
 516 if test "$ac_rk_have___sync_add_and_fetch" = "yes" ; then
 517         AC_DEFINE_UNQUOTED(HAVE___SYNC_ADD_AND_FETCH, 1, [have __sync_add_and_fetch])
 518 fi
 519 AC_MSG_RESULT($ac_rk_have___sync_add_and_fetch)
 520
 521 AC_FUNC_MMAP
 522
 523 KRB_CAPABILITIES
 524 rk_DLADDR
 525
 526 AC_CHECK_GETPWNAM_R_POSIX
 527
 528 dnl detect doors on solaris
 529 if test "$enable_pthread_support" != no; then
 530    saved_LIBS="$LIBS"
 531    LIBS="$LIBS $PTHREADS_LIBS"
 532    AC_FIND_FUNC_NO_LIBS(door_create, door)
 533    LIBS="$saved_LIBS"
 534 fi
 535
 536 AC_ARG_ENABLE(kcm,
 537         AS_HELP_STRING([--enable-kcm],[enable Kerberos Credentials Manager]),
 538 ,[enable_kcm=yes])
 539
 540 if test "$enable_kcm" = yes ; then
 541    if test  "$ac_cv_header_sys_un_h" != yes -a "$ac_cv_funclib_door_create" != yes ; then
 542         enable_kcm=no
 543    fi
 544 fi
 545 if test "$enable_kcm" = yes; then
 546        AC_DEFINE(HAVE_KCM, 1,
 547                [Define if you want to use the Kerberos Credentials Manager.])
 548 fi
 549 AM_CONDITIONAL(KCM, test "$enable_kcm" = yes)
 550
 551 dnl detect keyring on Linux
 552 if test "$ac_cv_header_keyutils_h" = yes; then
 553     AC_CHECK_SIZEOF([key_serial_t],,[
 554         #ifdef HAVE_INTTYPES_H
 555         #include <inttypes.h>
 556         #endif
 557         #ifdef HAVE_SYS_TYPES_H
 558         #include <sys/types.h>
 559         #endif
 560         #include <keyutils.h>
 561     ])
 562 fi
 563
 564 AC_FIND_FUNC_NO_LIBS(add_key, keyutils)
 565 if test -n "$LIB_add_key"; then
 566     saved_LIBS="$LIBS"
 567     LIBS="$LIBS $LIB_add_key"
 568     AC_CHECK_FUNCS(keyctl_get_persistent)
 569     LIBS="$saved_LIBS"
 570 fi
 571
 572 AC_CHECK_SIZEOF([time_t])
 573
 574 dnl Cray stuff
 575 AC_CHECK_FUNCS(getudbnam setlim)
 576
 577 dnl AC_KRB_FUNC_GETCWD_BROKEN
 578
 579 AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t,
 580         u_int8_t, u_int16_t, u_int32_t, u_int64_t,
 581         uint8_t, uint16_t, uint32_t, uint64_t],,,[
 582 #ifdef HAVE_INTTYPES_H
 583 #include <inttypes.h>
 584 #endif
 585 #ifdef HAVE_SYS_TYPES_H
 586 #include <sys/types.h>
 587 #endif
 588 #ifdef HAVE_SYS_BITYPES_H
 589 #include <sys/bitypes.h>
 590 #endif
 591 #ifdef HAVE_BIND_BITYPES_H
 592 #include <bind/bitypes.h>
 593 #endif
 594 #ifdef HAVE_NETINET_IN6_MACHTYPES_H
 595 #include <netinet/in6_machtypes.h>
 596 #endif
 597 ])
 598
 599 rk_FRAMEWORK_SECURITY
 600 rk_FRAMEWORK_COREFOUNDATION
 601
 602 KRB_READLINE
 603
 604 rk_TELNET
 605
 606 dnl Some operating systems already have com_err and compile_et
 607 CHECK_COMPILE_ET
 608
 609 rk_AUTH_MODULES([sia afskauthlib])
 610
 611 rk_DESTDIRS
 612
 613 rk_WFLAGS([-Wall -Wmissing-prototypes -Wpointer-arith -Wbad-function-cast -Wmissing-declarations -Wnested-externs])
 614
 615
 616 AH_BOTTOM([#ifdef __APPLE__
 617 #include <AvailabilityMacros.h>
 618 #endif])
 619
 620 AH_BOTTOM([#ifdef ROKEN_RENAME
 621 #include "roken_rename.h"
 622 #endif])
 623
 624 AC_ARG_ENABLE(heimdal-documentation,
 625         AS_HELP_STRING([--disable-heimdal-documentation],
 626                 [if you want disable to heimdal documentation]))
 627 AM_CONDITIONAL(HEIMDAL_DOCUMENTATION, test "$enable_heimdal_documentation" != no)
 628
 629 AC_CONFIG_FILES(Makefile                \
 630         etc/Makefile                    \
 631         include/Makefile                \
 632         include/gssapi/Makefile         \
 633         include/hcrypto/Makefile        \
 634         include/kadm5/Makefile          \
 635         lib/Makefile                    \
 636         lib/base/Makefile                       \
 637         lib/asn1/Makefile               \
 638         lib/com_err/Makefile            \
 639         lib/hcrypto/Makefile            \
 640         lib/hx509/Makefile              \
 641         lib/gssapi/Makefile             \
 642         lib/ntlm/Makefile               \
 643         lib/hdb/Makefile                \
 644         lib/ipc/Makefile                \
 645         lib/kadm5/Makefile              \
 646         lib/kafs/Makefile               \
 647         lib/kdfs/Makefile               \
 648         lib/krb5/Makefile               \
 649         lib/otp/Makefile                \
 650         lib/roken/Makefile              \
 651         lib/sl/Makefile                 \
 652         lib/sqlite/Makefile             \
 653         lib/vers/Makefile               \
 654         lib/wind/Makefile               \
 655         po/Makefile                     \
 656         kuser/Makefile                  \
 657         kpasswd/Makefile                \
 658         kadmin/Makefile                 \
 659         admin/Makefile                  \
 660         kcm/Makefile                    \
 661         kdc/Makefile                    \
 662         appl/Makefile                   \
 663         appl/afsutil/Makefile           \
 664         appl/dbutils/Makefile           \
 665         appl/gssmask/Makefile           \
 666         appl/otp/Makefile               \
 667         appl/test/Makefile              \
 668         appl/kf/Makefile                \
 669         appl/dceutils/Makefile          \
 670         tests/Makefile                  \
 671         tests/bin/Makefile              \
 672         tests/can/Makefile              \
 673         tests/db/Makefile               \
 674         tests/kdc/Makefile              \
 675         tests/ldap/Makefile             \
 676         tests/gss/Makefile              \
 677         tests/java/Makefile             \
 678         tests/plugin/Makefile           \
 679         packages/Makefile               \
 680         packages/mac/Makefile           \
 681         doc/Makefile                    \
 682         tools/Makefile                  \
 683 )
 684
 685 AC_OUTPUT
 686
 687 dnl
 688 dnl This is the release version name-number[beta]
 689 dnl
 690
 691 if test -d "$srcdir/.git"; then
 692     cat > include/newversion.h.in <<EOF
 693 #ifndef VERSION_HIDDEN
 694 #define VERSION_HIDDEN
 695 #endif
 696 VERSION_HIDDEN const char *heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ @BRANCH@ @TAG@ ($host) @COMMIT@ @DATE@ \$";
 697 VERSION_HIDDEN const char *heimdal_version = "AC_PACKAGE_STRING";
 698 EOF
 699 else
 700     cat > include/newversion.h.in <<EOF
 701 #ifndef VERSION_HIDDEN
 702 #define VERSION_HIDDEN
 703 #endif
 704 VERSION_HIDDEN const char *heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ ($host) @DATE@ \$";
 705 VERSION_HIDDEN const char *heimdal_version = "AC_PACKAGE_STRING";
 706 EOF
 707 fi
 708
 709 if test -f include/version.h && cmp -s include/newversion.h.in include/version.h.in; then
 710         echo "include/version.h is unchanged"
 711         rm -f include/newversion.h.in
 712 else
 713         echo "creating include/version.h"
 714         if test -n "$SOURCE_DATE_EPOCH"; then
 715             Date=`
 716                   # BSD, OS X
 717                   date -u -r "$SOURCE_DATE_EPOCH" "+%Y-%m-%dT%H:%M:%SZ" 2>/dev/null ||
 718                   # Linux
 719                   date -u -d "@${SOURCE_DATE_EPOCH}" 2>/dev/null ||
 720                   # Illumos -- sorry, no -r/-d here
 721                   date -u ||
 722                   date`
 723         else
 724             Date=`date -u "+%Y-%m-%dT%H:%M:%SZ"`
 725         fi
 726         if test -n "$SOURCE_HOST"; then
 727             Host=$SOURCE_HOST
 728         else
 729             Host=`uname -n`
 730         fi
 731         if test -n "$SOURCE_USER"; then
 732             User=$SOURCE_USER
 733         else
 734             User=${USER:-${LOGNAME:-`id -nu`}}
 735         fi
 736         if test -d "$srcdir/.git"; then
 737             GitCommit=`git rev-parse HEAD`
 738             GitBranch=`git rev-parse --abbrev-ref HEAD`
 739             if test "x$GitBranch" = master; then
 740                 GitDesc=`git describe --all --dirty`
 741             else
 742                 GitDesc=`git describe --tags --match 'heimdal-*' --dirty`
 743             fi
 744         else
 745             GitCommit='<commit-unknown>'
 746             GitBranch='<branch-unknown>'
 747             GitDesc='<tag-unknown>'
 748         fi
 749         mv -f include/newversion.h.in include/version.h.in
 750         sed -e "s/@HOST@/$Host/" \
 751             -e "s;@USER@;$User;" \
 752             -e "s;@DATE@;$Date;" \
 753             -e "s;@BRANCH@;$GitBranch;" \
 754             -e "s;@TAG@;$GitDesc;" \
 755             -e "s;@COMMIT@;$GitCommit;" \
 756             include/version.h.in > include/version.h
 757 fi