configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([rsync],[3.2.0pre3],[http://rsync.samba.org/bugzilla.html])
   4
   5 AC_CONFIG_MACRO_DIR([m4])
   6 AC_CONFIG_SRCDIR([byteorder.h])
   7 AC_CONFIG_HEADER(config.h)
   8 AC_PREREQ([2.69])
   9
  10 AC_SUBST(RSYNC_VERSION, $PACKAGE_VERSION)
  11 AC_MSG_NOTICE([Configuring rsync $PACKAGE_VERSION])
  12
  13 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$PACKAGE_VERSION"], [rsync release version])
  14
  15 LDFLAGS=${LDFLAGS-""}
  16
  17 AC_CANONICAL_HOST
  18
  19 dnl define the directory for replacement function since AC_LIBOBJ does not
  20 dnl officially support subdirs and fails with automake
  21 AC_CONFIG_LIBOBJ_DIR([lib])
  22
  23 # We must decide this before testing the compiler.
  24
  25 # Please allow this to default to yes, so that your users have more
  26 # chance of getting a useful stack trace if problems occur.
  27
  28 AC_MSG_CHECKING([whether to include debugging symbols])
  29 AC_ARG_ENABLE(debug,
  30         AS_HELP_STRING([--disable-debug],[disable debugging symbols and features]))
  31
  32 if test x"$enable_debug" = x"no"; then
  33     AC_MSG_RESULT(no)
  34     ac_cv_prog_cc_g=no
  35 else
  36     AC_MSG_RESULT([yes])
  37     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  38     # leave ac_cv_prog_cc_g alone; AC_PROG_CC will try to include -g if it can
  39 fi
  40
  41 dnl Checks for programs.
  42 AC_PROG_CC
  43 AC_PROG_CPP
  44 AC_PROG_CXX
  45 AC_PROG_AWK
  46 AC_PROG_EGREP
  47 AC_PROG_INSTALL
  48 AC_PROG_MKDIR_P
  49 AC_PROG_CC_STDC
  50 AC_SUBST(SHELL)
  51 AC_PATH_PROG([PERL], [perl])
  52 AC_PATH_PROG([PYTHON3], [python3])
  53
  54 AC_DEFINE([_GNU_SOURCE], 1,
  55           [Define _GNU_SOURCE so that we get all necessary prototypes])
  56
  57 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  58         AC_MSG_WARN([rsync requires an ANSI C compiler and you do not seem to have one])
  59 fi
  60
  61 AC_ARG_ENABLE(profile,
  62         AS_HELP_STRING([--enable-profile],[turn on CPU profiling]))
  63 if test x"$enable_profile" = x"yes"; then
  64         CFLAGS="$CFLAGS -pg"
  65 fi
  66
  67 AC_MSG_CHECKING([if md2man can create man pages])
  68 if test x"$ac_cv_path_PYTHON3" = x; then
  69     AC_MSG_RESULT(no - python3 not found)
  70     md2man_works=no
  71 else
  72     md2man_out=`"$srcdir/md2man" --test "$srcdir/rsync.1.md" 2>&1`
  73     if test $? = 0; then
  74         AC_MSG_RESULT(yes)
  75         md2man_works=yes
  76     else
  77         AC_MSG_RESULT(no)
  78         md2man_works=no
  79         echo "$md2man_out"
  80     fi
  81 fi
  82
  83 AC_MSG_CHECKING([if we require man-page building])
  84 AC_ARG_ENABLE([md2man],
  85         AS_HELP_STRING([--disable-md2man],[disable md2man for man page creation]))
  86 if test x"$enable_md2man" != x"no"; then
  87     if test -f "$srcdir/rsync.1"; then
  88         AC_MSG_RESULT(optional)
  89     else
  90         AC_MSG_RESULT(required)
  91         if test x"$md2man_works" = x"no"; then
  92             AC_MSG_ERROR(You need python3 and the cmarkgfm OR commonmark python3 lib in order to build man pages.
  93 You can specify --disable-md2man if you want to skip building them.)
  94         fi
  95     fi
  96     MAKE_MAN=man
  97 else
  98     AC_MSG_RESULT(no)
  99     MAKE_MAN=''
 100 fi
 101
 102 # Specifically, this turns on panic_action handling.
 103 AC_ARG_ENABLE(maintainer-mode,
 104         AS_HELP_STRING([--enable-maintainer-mode],[turn on extra debug features]))
 105 if test x"$enable_maintainer_mode" = x"yes"; then
 106         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
 107 fi
 108
 109 # This is needed for our included version of popt.  Kind of silly, but
 110 # I don't want our version too far out of sync.
 111 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
 112
 113 # If GCC, turn on warnings.
 114 if test x"$GCC" = x"yes"; then
 115         CFLAGS="$CFLAGS -Wall -W"
 116 fi
 117
 118 AC_ARG_WITH(included-popt,
 119         AS_HELP_STRING([--with-included-popt],[use bundled popt library, not from system]))
 120
 121 AC_ARG_WITH(included-zlib,
 122         AS_HELP_STRING([--with-included-zlib],[use bundled zlib library, not from system]))
 123
 124 AC_ARG_WITH(protected-args,
 125         AS_HELP_STRING([--with-protected-args],[make --protected-args option the default]))
 126 if test x"$with_protected_args" = x"yes"; then
 127         AC_DEFINE_UNQUOTED(RSYNC_USE_PROTECTED_ARGS, 1, [Define to 1 if --protected-args should be the default])
 128 fi
 129
 130 AC_ARG_WITH(rsync-path,
 131         AS_HELP_STRING([--with-rsync-path=PATH],[set default --rsync-path to PATH (default: rsync)]),
 132         [ RSYNC_PATH="$with_rsync_path" ],
 133         [ RSYNC_PATH="rsync" ])
 134
 135 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
 136
 137 AC_ARG_WITH(rsyncd-conf,
 138         AS_HELP_STRING([--with-rsyncd-conf=PATH],[set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
 139         [ if test ! -z "$with_rsyncd_conf" ; then
 140                 case $with_rsyncd_conf in
 141                         yes|no)
 142                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 143                                 ;;
 144                         /*)
 145                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
 146                                 ;;
 147                         *)
 148                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 149                                 ;;
 150                 esac
 151         else
 152                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 153         fi ],
 154         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 155
 156 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 157
 158 AC_ARG_WITH(rsh,
 159         AS_HELP_STRING([--with-rsh=CMD],[set remote shell command to CMD (default: ssh)]))
 160
 161 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 162 if test x$HAVE_REMSH = x1; then
 163         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 164 fi
 165
 166 if test x"$with_rsh" != x; then
 167         RSYNC_RSH="$with_rsh"
 168 else
 169         RSYNC_RSH="ssh"
 170 fi
 171 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 172
 173 # Some programs on solaris are only found in /usr/xpg4/bin (or work better than others versions).
 174 AC_PATH_PROG(SHELL_PATH, sh, /bin/sh, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 175 AC_PATH_PROG(FAKEROOT_PATH, fakeroot, /usr/bin/fakeroot, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 176
 177 AC_ARG_WITH(nobody-group,
 178     AS_HELP_STRING([--with-nobody-group=GROUP],[set the default unprivileged group (default nobody or nogroup)]),
 179     [ NOBODY_GROUP="$with_nobody_group" ])
 180
 181 if test x"$with_nobody_group" = x; then
 182     AC_MSG_CHECKING([the group for user "nobody"])
 183     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 184         NOBODY_GROUP=nobody
 185     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 186         NOBODY_GROUP=nogroup
 187     else
 188         NOBODY_GROUP=nobody # test for others?
 189     fi
 190     AC_MSG_RESULT($NOBODY_GROUP)
 191 fi
 192
 193 AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody])
 194 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 195
 196 # SIMD optimizations
 197 SIMD=
 198
 199 AC_MSG_CHECKING([whether to enable SIMD optimizations])
 200 AC_ARG_ENABLE(simd,
 201     AS_HELP_STRING([--disable-simd],[disable SIMD optimizations (requires c++)]))
 202
 203 if test x"$enable_simd" != x"no"; then
 204     # For x86-64 SIMD, g++ >=5 or clang++ >=7 is required
 205     if test x"$build_cpu" = x"x86_64"; then
 206         CXX_OK=
 207         if test x"$CXX" != x""; then
 208             CXX_VERSION=`$CXX --version 2>/dev/null | head -n 1`
 209             case "$CXX_VERSION" in
 210             g++*)
 211                 CXX_VERSION=`$CXX -dumpversion | sed 's/\..*//g'`
 212                 if test "$CXX_VERSION" -ge "5"; then
 213                     CXX_OK=yes
 214                 fi
 215                 ;;
 216             *clang*)
 217                 # $CXX -dumpversion would have been ideal, but is broken on older clang
 218                 CXX_VERSION=`echo "$CXX_VERSION" | sed 's/.*version //g' | sed 's/\..*//g'`
 219                 if test "$CXX_VERSION" -ge "7"; then
 220                     CXX_OK=yes
 221                 fi
 222                 ;;
 223             *)
 224                 CXX_VERSION='Unknown'
 225                 ;;
 226             esac
 227         else
 228             CXX='No c++'
 229             CXX_VERSION='Unknown'
 230         fi
 231         if test x"$CXX_OK" = x"yes"; then
 232             # AC_MSG_RESULT() is called below.
 233             SIMD="$SIMD x86_64"
 234         else
 235             AC_MSG_RESULT(error)
 236             AC_MSG_ERROR([Failed to find g++ >=5 or clang++ >=7 for SIMD optimizations.
 237 Specify --disable-simd to continue without it. ($CXX, $CXX_VERSION)])
 238         fi
 239     elif test x"$enable_simd" = x"yes"; then
 240         AC_MSG_RESULT(unavailable)
 241         AC_MSG_ERROR(The SIMD optimizations are currently x86_64 only.
 242 Omit --enable-simd to continue without it.)
 243     fi
 244 fi
 245
 246 if test x"$SIMD" != x""; then
 247     SIMD=`echo "$SIMD" | sed 's/^ *//'`
 248     AC_MSG_RESULT([yes ($SIMD)])
 249     AC_DEFINE(HAVE_SIMD, 1, [Define to 1 to enable SIMD optimizations])
 250     SIMD=`echo "\\\$(SIMD_$SIMD)" | sed 's/ /) $(SIMD_/g'`
 251     # We only use c++ for its target attribute dispatching, disable unneeded bulky features
 252     CXXFLAGS="$CXXFLAGS -fno-exceptions -fno-rtti"
 253 else
 254     AC_MSG_RESULT(no)
 255 fi
 256
 257 AC_SUBST(SIMD)
 258
 259 # arrgh. libc in some old debian version screwed up the largefile
 260 # stuff, getting byte range locking wrong
 261 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 262 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 263 #define _FILE_OFFSET_BITS 64
 264 #include <stdio.h>
 265 #include <fcntl.h>
 266 #include <sys/types.h>
 267 #include <sys/wait.h>
 268 #if HAVE_UNISTD_H
 269 #include <unistd.h>
 270 #endif
 271
 272 int main(void)
 273 {
 274         struct flock lock;
 275         int status;
 276         char tpl[32] = "/tmp/locktest.XXXXXX";
 277         int fd = mkstemp(tpl);
 278         if (fd < 0) {
 279                 strcpy(tpl, "conftest.dat");
 280                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 281         }
 282
 283         lock.l_type = F_WRLCK;
 284         lock.l_whence = SEEK_SET;
 285         lock.l_start = 0;
 286         lock.l_len = 1;
 287         lock.l_pid = 0;
 288         fcntl(fd,F_SETLK,&lock);
 289         if (fork() == 0) {
 290                 lock.l_start = 1;
 291                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 292         }
 293         wait(&status);
 294         unlink(tpl);
 295         return WEXITSTATUS(status);
 296 }
 297 ]])],[rsync_cv_HAVE_BROKEN_LARGEFILE=yes],[rsync_cv_HAVE_BROKEN_LARGEFILE=no],[rsync_cv_HAVE_BROKEN_LARGEFILE=cross])])
 298 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 299    AC_SYS_LARGEFILE
 300 fi
 301
 302 ipv6type=unknown
 303 ipv6lib=none
 304 ipv6trylibc=yes
 305
 306 AC_ARG_ENABLE(ipv6,
 307         AS_HELP_STRING([--disable-ipv6],[turn off IPv6 support]))
 308 if test x"$enable_ipv6" != x"no"; then
 309         AC_MSG_CHECKING([ipv6 stack type])
 310         for i in inria kame linux-glibc linux-inet6 solaris toshiba v6d zeta cygwin; do
 311                 case $i in
 312                 inria)
 313                         # http://www.kame.net/
 314                         AC_EGREP_CPP(yes, [
 315 #include <netinet/in.h>
 316 #ifdef IPV6_INRIA_VERSION
 317 yes
 318 #endif],
 319                                 [ipv6type=$i;
 320                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 321                                 ])
 322                         ;;
 323                 kame)
 324                         # http://www.kame.net/
 325                         AC_EGREP_CPP(yes, [
 326 #include <netinet/in.h>
 327 #ifdef __KAME__
 328 yes
 329 #endif],
 330                                 [ipv6type=$i;
 331                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 332                         ;;
 333                 linux-glibc)
 334                         # http://www.v6.linux.or.jp/
 335                         AC_EGREP_CPP(yes, [
 336 #include <features.h>
 337 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 338 yes
 339 #endif],
 340                                 [ipv6type=$i;
 341 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 342                         ;;
 343                 linux-inet6)
 344                         # http://www.v6.linux.or.jp/
 345                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 346                                 ipv6type=$i
 347                                 ipv6lib=inet6
 348                                 ipv6libdir=/usr/inet6/lib
 349                                 ipv6trylibc=yes;
 350                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 351                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 352                         fi
 353                         ;;
 354                 solaris)
 355                         # http://www.sun.com
 356                         AC_EGREP_CPP(yes, [
 357 #include <netinet/ip6.h>
 358 #ifdef __sun
 359 yes
 360 #endif],
 361                                 [ipv6type=$i;
 362                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 363                         ;;
 364                 toshiba)
 365                         AC_EGREP_CPP(yes, [
 366 #include <sys/param.h>
 367 #ifdef _TOSHIBA_INET6
 368 yes
 369 #endif],
 370                                 [ipv6type=$i;
 371                                 ipv6lib=inet6;
 372                                 ipv6libdir=/usr/local/v6/lib;
 373                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 374                         ;;
 375                 v6d)
 376                         AC_EGREP_CPP(yes, [
 377 #include </usr/local/v6/include/sys/v6config.h>
 378 #ifdef __V6D__
 379 yes
 380 #endif],
 381                                 [ipv6type=$i;
 382                                 ipv6lib=v6;
 383                                 ipv6libdir=/usr/local/v6/lib;
 384                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 385                         ;;
 386                 zeta)
 387                         AC_EGREP_CPP(yes, [
 388 #include <sys/param.h>
 389 #ifdef _ZETA_MINAMI_INET6
 390 yes
 391 #endif],
 392                                 [ipv6type=$i;
 393                                 ipv6lib=inet6;
 394                                 ipv6libdir=/usr/local/v6/lib;
 395                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 396                         ;;
 397                 cygwin)
 398                         AC_EGREP_CPP(yes, [
 399 #include <netinet/in.h>
 400 #ifdef _CYGWIN_IN6_H
 401 yes
 402 #endif],
 403                                 [ipv6type=$i;
 404                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 405                         ;;
 406                 esac
 407                 if test "$ipv6type" != "unknown"; then
 408                         break
 409                 fi
 410         done
 411         AC_MSG_RESULT($ipv6type)
 412
 413         AC_SEARCH_LIBS(getaddrinfo, inet6)
 414 fi
 415
 416 dnl Do you want to disable use of locale functions
 417 AC_ARG_ENABLE([locale],
 418         AS_HELP_STRING([--disable-locale],[disable locale features]))
 419 AH_TEMPLATE([CONFIG_LOCALE],
 420 [Undefine if you do not want locale features.  By default this is defined.])
 421 if test x"$enable_locale" != x"no"; then
 422         AC_DEFINE(CONFIG_LOCALE)
 423 fi
 424
 425 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 426 case $host_os in
 427         *cygwin* ) AC_MSG_RESULT(yes)
 428                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 429                             [Define to 1 if sockets need to be shutdown])
 430                    ;;
 431                * ) AC_MSG_RESULT(no);;
 432 esac
 433
 434 AC_C_BIGENDIAN
 435 AC_HEADER_DIRENT
 436 AC_HEADER_TIME
 437 AC_HEADER_SYS_WAIT
 438 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
 439     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
 440     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
 441     sys/un.h sys/attr.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
 442     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h \
 443     sys/acl.h acl/libacl.h attr/xattr.h sys/xattr.h sys/extattr.h \
 444     popt.h popt/popt.h linux/falloc.h netinet/in_systm.h netinet/ip.h \
 445     zlib.h xxhash.h openssl/md4.h openssl/md5.h zstd.h lz4.h)
 446 AC_HEADER_MAJOR_FIXED
 447
 448 AC_MSG_CHECKING([whether to enable use of openssl crypto library])
 449 AC_ARG_ENABLE([openssl],
 450         AS_HELP_STRING([--disable-openssl],[disable openssl crypto library]))
 451 AH_TEMPLATE([USE_OPENSSL],
 452 [Undefine if you do not want to use openssl crypto library.  By default this is defined.])
 453 if test x"$enable_openssl" != x"no"; then
 454     if test x"$ac_cv_header_openssl_md4_h" = x"yes" && test x"$ac_cv_header_openssl_md5_h" = x"yes"; then
 455       AC_MSG_RESULT(yes)
 456       AC_SEARCH_LIBS(MD5_Init, crypto,
 457           [AC_DEFINE(USE_OPENSSL)],
 458           [AC_MSG_ERROR(Failed to find MD5_Init function in openssl crypto lib.
 459 Use --disable-openssl to continue without openssl crypto lib support.)])
 460     else
 461         AC_MSG_RESULT(no)
 462         AC_MSG_ERROR(Failed to find openssl/md4.h and openssl/md5.h for openssl crypto lib support.
 463 Use --disable-openssl to continue without it.)
 464     fi
 465 else
 466     AC_MSG_RESULT(no)
 467 fi
 468
 469 AC_MSG_CHECKING([whether to enable xxhash checksum support])
 470 AC_ARG_ENABLE([xxhash],
 471         AS_HELP_STRING([--disable-xxhash],[disable xxhash checksums]))
 472 AH_TEMPLATE([SUPPORT_XXHASH],
 473 [Undefine if you do not want xxhash checksums.  By default this is defined.])
 474 if test x"$enable_xxhash" != x"no"; then
 475     if test x"$ac_cv_header_xxhash_h" = x"yes"; then
 476         AC_MSG_RESULT(yes)
 477         AC_SEARCH_LIBS(XXH64_createState, xxhash,
 478             [AC_DEFINE(SUPPORT_XXHASH)],
 479             [AC_MSG_ERROR(Failed to find XXH64_createState function in xxhash lib.
 480 Use --disable-xxhash to continue without xxhash checksums.)])
 481     else
 482         AC_MSG_RESULT(no)
 483         AC_MSG_ERROR(Failed to find xxhash.h for xxhash checksum support.
 484 Use --disable-xxhash to continue without it.)
 485     fi
 486 else
 487     AC_MSG_RESULT(no)
 488 fi
 489
 490 AC_MSG_CHECKING([whether to enable zstd compression])
 491 AC_ARG_ENABLE([zstd],
 492         AC_HELP_STRING([--disable-zstd], [disable zstd compression]))
 493 AH_TEMPLATE([SUPPORT_ZSTD],
 494 [Undefine if you do not want zstd compression.  By default this is defined.])
 495 if test x"$enable_zstd" != x"no"; then
 496     if test x"$ac_cv_header_zstd_h" = x"yes"; then
 497         AC_MSG_RESULT(yes)
 498         AC_SEARCH_LIBS(ZSTD_minCLevel, zstd,
 499             [AC_DEFINE(SUPPORT_ZSTD)],
 500             [AC_MSG_ERROR(Failed to find ZSTD_minCLevel function in zstd lib.
 501 Use --disable-zstd to continue without zstd compression.)])
 502     else
 503         AC_MSG_RESULT(no)
 504         AC_MSG_ERROR(Failed to find zstd.h for zstd compression support.
 505 Use --disable-zstd to continue without it.)
 506     fi
 507 else
 508     AC_MSG_RESULT(no)
 509 fi
 510
 511 AC_MSG_CHECKING([whether to enable LZ4 compression])
 512 AC_ARG_ENABLE([lz4],
 513         AC_HELP_STRING([--disable-lz4], [disable LZ4 compression]))
 514 AH_TEMPLATE([SUPPORT_LZ4],
 515 [Undefine if you do not want LZ4 compression.  By default this is defined.])
 516 if test x"$enable_lz4" != x"no"; then
 517     if test x"$ac_cv_header_lz4_h" = x"yes"; then
 518         AC_MSG_RESULT(yes)
 519         AC_SEARCH_LIBS(LZ4_compress_default, lz4,
 520             [AC_DEFINE(SUPPORT_LZ4)],
 521             [AC_MSG_ERROR(Failed to find LZ4_compress_default function in lz4 lib.
 522 Use --disable-lz4 to continue without lz4 compression.)])
 523     else
 524         AC_MSG_RESULT(no)
 525         AC_MSG_ERROR(Failed to find lz4.h for lz4 compression support.
 526 Use --disable-lz4 to continue without it.)
 527     fi
 528 else
 529     AC_MSG_RESULT(no)
 530 fi
 531
 532 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
 533 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 534 #include <sys/types.h>
 535 #ifdef MAJOR_IN_MKDEV
 536 #include <sys/mkdev.h>
 537 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
 538 #  define makedev mkdev
 539 # endif
 540 #elif defined MAJOR_IN_SYSMACROS
 541 #include <sys/sysmacros.h>
 542 #endif
 543
 544 int main(void)
 545 {
 546         dev_t dev = makedev(0, 5, 7);
 547         if (major(dev) != 5 || minor(dev) != 7)
 548                 return 1;
 549         return 0;
 550 }
 551 ]])],[rsync_cv_MAKEDEV_TAKES_3_ARGS=yes],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no])])
 552 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
 553    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
 554 fi
 555
 556 AC_CHECK_SIZEOF(int)
 557 AC_CHECK_SIZEOF(long)
 558 AC_CHECK_SIZEOF(long long)
 559 AC_CHECK_SIZEOF(short)
 560 AC_CHECK_SIZEOF(int16_t)
 561 AC_CHECK_SIZEOF(uint16_t)
 562 AC_CHECK_SIZEOF(int32_t)
 563 AC_CHECK_SIZEOF(uint32_t)
 564 AC_CHECK_SIZEOF(int64_t)
 565 AC_CHECK_SIZEOF(off_t)
 566 AC_CHECK_SIZEOF(off64_t)
 567 AC_CHECK_SIZEOF(time_t)
 568 AC_CHECK_SIZEOF(char*)
 569
 570 AC_C_INLINE
 571
 572 AC_TYPE_LONG_DOUBLE_WIDER
 573 ac_cv_c_long_double=$ac_cv_type_long_double_wider
 574 if test $ac_cv_c_long_double = yes; then
 575   AC_DEFINE([HAVE_LONG_DOUBLE],[1],[Define to 1 if the type `long double' works and has more range or precision than `double'.])
 576 fi
 577
 578 AC_TYPE_UID_T
 579 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
 580 AC_TYPE_GETGROUPS
 581 AC_CHECK_MEMBERS([struct stat.st_rdev,
 582                   struct stat.st_mtimensec,
 583                   struct stat.st_mtimespec.tv_nsec,
 584                   struct stat.st_mtim.tv_nsec],,,[
 585 #ifdef HAVE_SYS_TYPES_H
 586 #include <sys/types.h>
 587 #endif
 588 #ifdef HAVE_SYS_STAT_H
 589 #include <sys/stat.h>
 590 #endif
 591 #ifdef HAVE_UNISTD_H
 592 #include <unistd.h>
 593 #endif])
 594
 595 TYPE_SOCKLEN_T
 596
 597 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 598     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]], [[int i = errno]])],[rsync_cv_errno=yes],[rsync_cv_have_errno_decl=no])])
 599 if test x"$rsync_cv_errno" = x"yes"; then
 600    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 601 fi
 602
 603 # The following test taken from the cvs sources
 604 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 605 # These need checks to be before checks for any other functions that
 606 #    might be in the same libraries.
 607 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 608 # libsocket.so which has a bad implementation of gethostbyname (it
 609 # only looks in /etc/hosts), so we only look for -lsocket if we need
 610 # it.
 611 AC_CHECK_FUNCS(connect)
 612 if test x"$ac_cv_func_connect" = x"no"; then
 613     case "$LIBS" in
 614     *-lnsl*) ;;
 615     *) AC_CHECK_LIB(nsl_s, printf) ;;
 616     esac
 617     case "$LIBS" in
 618     *-lnsl*) ;;
 619     *) AC_CHECK_LIB(nsl, printf) ;;
 620     esac
 621     case "$LIBS" in
 622     *-lsocket*) ;;
 623     *) AC_CHECK_LIB(socket, connect) ;;
 624     esac
 625     case "$LIBS" in
 626     *-linet*) ;;
 627     *) AC_CHECK_LIB(inet, connect) ;;
 628     esac
 629     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 630     dnl has been cached.
 631     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 632        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 633         # ac_cv_func_connect=yes
 634         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 635         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 636     fi
 637 fi
 638
 639 AC_SEARCH_LIBS(inet_ntop, resolv)
 640
 641 # For OS X, Solaris, HP-UX, etc.: figure out if -liconv is needed.  We'll
 642 # accept either iconv_open or libiconv_open, since some include files map
 643 # the former to the latter.
 644 AC_SEARCH_LIBS(iconv_open, iconv)
 645 AC_SEARCH_LIBS(libiconv_open, iconv)
 646
 647 AC_MSG_CHECKING([for iconv declaration])
 648 AC_CACHE_VAL(am_cv_proto_iconv, [
 649     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 650 #include <stdlib.h>
 651 #include <iconv.h>
 652 extern
 653 #ifdef __cplusplus
 654 "C"
 655 #endif
 656 #if defined(__STDC__) || defined(__cplusplus)
 657 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 658 #else
 659 size_t iconv();
 660 #endif
 661 ]], [[]])],[am_cv_proto_iconv_arg1=""],[am_cv_proto_iconv_arg1="const"])
 662       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 663     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed 's/( /(/'`
 664 AC_MSG_RESULT([$]{ac_t:-
 665          }[$]am_cv_proto_iconv)
 666 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 667                    [Define as const if the declaration of iconv() needs const.])
 668
 669 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 670
 671 AC_REPLACE_FUNCS([inet_ntop inet_pton])
 672
 673 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
 674 AC_HAVE_TYPE([struct sockaddr_storage], [#include <sys/types.h>
 675 #include <sys/socket.h>])
 676
 677 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 678 #   builtin getaddrinfo if one of the defines don't exist
 679 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 680                rsync_cv_HAVE_GETADDR_DEFINES,[
 681                         AC_EGREP_CPP(yes, [
 682                         #include <sys/types.h>
 683                         #include <sys/socket.h>
 684                         #include <netdb.h>
 685                         #ifdef AI_PASSIVE
 686                         yes
 687                         #endif],
 688                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 689                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 690 AS_IF([test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" -a x"$ac_cv_type_struct_addrinfo" = x"yes"],[
 691         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 692         # something else so we must include <netdb.h> to get the
 693         # redefinition.
 694         AC_CHECK_FUNCS(getaddrinfo, ,
 695                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 696                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 697                 #include <sys/socket.h>
 698                 #include <netdb.h>]], [[getaddrinfo(NULL, NULL, NULL, NULL);]])],[AC_MSG_RESULT([yes])
 699                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 700                                 [Define to 1 if you have the "getaddrinfo" function and required types.])],[AC_MSG_RESULT([no])
 701                         AC_LIBOBJ([getaddrinfo])])])
 702     ],[AC_LIBOBJ([getaddrinfo])])
 703
 704 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 705                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 706                 [],
 707                 [
 708 #include <sys/types.h>
 709 #include <sys/socket.h>
 710 ])
 711
 712 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 713                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 714                 [],
 715                 [
 716 #include <sys/types.h>
 717 #include <sys/socket.h>
 718 #include <netinet/in.h>
 719 ])
 720
 721 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 722                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 723                 [],
 724                 [
 725 #include <sys/types.h>
 726 #include <sys/socket.h>
 727 #include <netinet/in.h>
 728 ])
 729
 730 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 731                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 732                 [],
 733                 [
 734 #include <sys/types.h>
 735 #include <sys/socket.h>
 736 #include <netinet/in.h>
 737 ])
 738
 739 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
 740 #if HAVE_SYS_TYPES_H
 741 # include <sys/types.h>
 742 #endif
 743 #if HAVE_SYS_STAT_H
 744 # include <sys/stat.h>
 745 #endif
 746 #if STDC_HEADERS
 747 # include <stdlib.h>
 748 # include <stddef.h>
 749 #else
 750 # if HAVE_STDLIB_H
 751 #  include <stdlib.h>
 752 # endif
 753 #endif
 754 ])
 755
 756 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 757 #
 758 AC_CHECK_FUNCS(strcasecmp)
 759 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 760     AC_CHECK_LIB(resolv, strcasecmp)
 761 fi
 762
 763 AC_CHECK_FUNCS(aclsort)
 764 if test x"$ac_cv_func_aclsort" = x"no"; then
 765     AC_CHECK_LIB(sec, aclsort)
 766 fi
 767
 768 dnl At the moment we don't test for a broken memcmp(), because all we
 769 dnl need to do is test for equality, not comparison, and it seems that
 770 dnl every platform has a memcmp that can do at least that.
 771 dnl AC_FUNC_MEMCMP
 772
 773 AC_FUNC_UTIME_NULL
 774 AC_FUNC_ALLOCA
 775 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup chown chmod lchmod mknod mkfifo \
 776     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 777     chflags getattrlist \
 778     memmove lchown vsnprintf snprintf vasprintf asprintf setsid strpbrk \
 779     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
 780     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 781     seteuid strerror putenv iconv_open locale_charset nl_langinfo getxattr \
 782     extattr_get_link sigaction sigprocmask setattrlist getgrouplist \
 783     initgroups utimensat posix_fallocate attropen setvbuf nanosleep usleep)
 784
 785 dnl cygwin iconv.h defines iconv_open as libiconv_open
 786 if test x"$ac_cv_func_iconv_open" != x"yes"; then
 787     AC_CHECK_FUNC(libiconv_open, [ac_cv_func_iconv_open=yes; AC_DEFINE(HAVE_ICONV_OPEN, 1)])
 788 fi
 789
 790 dnl Preallocation stuff (also fallocate, posix_fallocate function tests above):
 791
 792 AC_CACHE_CHECK([for useable fallocate],rsync_cv_have_fallocate,[
 793 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <fcntl.h>
 794 #include <sys/types.h>]], [[fallocate(0, 0, 0, 0);]])],[rsync_cv_have_fallocate=yes],[rsync_cv_have_fallocate=no])])
 795 if test x"$rsync_cv_have_fallocate" = x"yes"; then
 796     AC_DEFINE(HAVE_FALLOCATE, 1, [Define to 1 if you have the fallocate function and it compiles and links without error])
 797 fi
 798
 799 AC_MSG_CHECKING([for FALLOC_FL_PUNCH_HOLE])
 800 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 801         #define _GNU_SOURCE 1
 802         #include <linux/falloc.h>
 803         #ifndef FALLOC_FL_PUNCH_HOLE
 804         #error FALLOC_FL_PUNCH_HOLE is missing
 805         #endif
 806     ]])], [
 807         AC_MSG_RESULT([yes])
 808         AC_DEFINE([HAVE_FALLOC_FL_PUNCH_HOLE], [1], [Define if FALLOC_FL_PUNCH_HOLE is available.])
 809     ], [
 810         AC_MSG_RESULT([no])
 811     ]
 812 )
 813
 814 AC_MSG_CHECKING([for FALLOC_FL_ZERO_RANGE])
 815 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 816         #define _GNU_SOURCE 1
 817         #include <linux/falloc.h>
 818         #ifndef FALLOC_FL_ZERO_RANGE
 819         #error FALLOC_FL_ZERO_RANGE is missing
 820         #endif
 821     ]])], [
 822         AC_MSG_RESULT([yes])
 823         AC_DEFINE([HAVE_FALLOC_FL_ZERO_RANGE], [1], [Define if FALLOC_FL_ZERO_RANGE is available.])
 824     ], [
 825         AC_MSG_RESULT([no])
 826     ]
 827 )
 828
 829 AC_CACHE_CHECK([for SYS_fallocate],rsync_cv_have_sys_fallocate,[
 830 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/syscall.h>
 831 #include <unistd.h>
 832 #include <sys/types.h>]], [[syscall(SYS_fallocate, 0, 0, (loff_t)0, (loff_t)0);]])],[rsync_cv_have_sys_fallocate=yes],[rsync_cv_have_sys_fallocate=no])])
 833 if test x"$rsync_cv_have_sys_fallocate" = x"yes"; then
 834     AC_DEFINE(HAVE_SYS_FALLOCATE, 1, [Define to 1 if you have the SYS_fallocate syscall number])
 835 fi
 836
 837 if test x"$ac_cv_func_posix_fallocate" = x"yes"; then
 838     AC_MSG_CHECKING([whether posix_fallocate is efficient])
 839     case $host_os in
 840     *cygwin*)
 841         AC_MSG_RESULT(yes)
 842         AC_DEFINE(HAVE_EFFICIENT_POSIX_FALLOCATE, 1,
 843                   [Define if posix_fallocate is efficient (Cygwin)])
 844         ;;
 845     *)
 846         AC_MSG_RESULT(no)
 847         ;;
 848     esac
 849 fi
 850
 851 dnl End of preallocation stuff
 852
 853 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 854 if test $ac_cv_func_getpgrp = yes; then
 855     AC_FUNC_GETPGRP
 856 fi
 857
 858 AC_ARG_ENABLE(iconv-open,
 859     AS_HELP_STRING([--disable-iconv-open],[disable all use of iconv_open() function]),
 860     [], [enable_iconv_open=$ac_cv_func_iconv_open])
 861
 862 if test x"$enable_iconv_open" != x"no"; then
 863     AC_DEFINE(USE_ICONV_OPEN, 1, [Define to 1 if you want rsync to make use of iconv_open()])
 864 fi
 865
 866 AC_ARG_ENABLE(iconv,
 867     AS_HELP_STRING([--disable-iconv],[disable rsync's --iconv option]),
 868     [], [enable_iconv=$enable_iconv_open])
 869 AH_TEMPLATE([ICONV_OPTION],
 870 [Define if you want the --iconv option.  Specifying a value will set the
 871 default iconv setting (a NULL means no --iconv processing by default).])
 872 if test x"$enable_iconv" != x"no"; then
 873         if test x"$enable_iconv" = x"yes"; then
 874                 AC_DEFINE(ICONV_OPTION, NULL)
 875         else
 876                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
 877         fi
 878         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
 879 fi
 880
 881 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
 882   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 883 #if HAVE_UNISTD_H
 884 # include <unistd.h>
 885 #endif
 886 #include <stdlib.h>
 887 #include <errno.h>
 888 int main(void) {
 889         char const *dangling_symlink = "conftest.dangle";
 890         unlink(dangling_symlink);
 891         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 892         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) return 1;
 893         return 0;
 894     }]])],[rsync_cv_chown_modifies_symlink=yes],[rsync_cv_chown_modifies_symlink=no],[rsync_cv_chown_modifies_symlink=no])])
 895 if test $rsync_cv_chown_modifies_symlink = yes; then
 896   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 897 fi
 898
 899 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
 900   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 901 #if HAVE_UNISTD_H
 902 # include <unistd.h>
 903 #endif
 904 #include <stdlib.h>
 905 #include <errno.h>
 906 #define FILENAME "conftest.dangle"
 907 int main(void) {
 908         unlink(FILENAME);
 909         if (symlink("conftest.no-such", FILENAME) < 0) abort();
 910         unlink(FILENAME "2");
 911         if (link(FILENAME, FILENAME "2") < 0) return 1;
 912         return 0;
 913     }]])],[rsync_cv_can_hardlink_symlink=yes],[rsync_cv_can_hardlink_symlink=no],[rsync_cv_can_hardlink_symlink=no])])
 914 if test $rsync_cv_can_hardlink_symlink = yes; then
 915   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
 916 fi
 917
 918 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
 919   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 920 #if HAVE_UNISTD_H
 921 # include <unistd.h>
 922 #endif
 923 #ifdef HAVE_SYS_STAT_H
 924 #include <sys/stat.h>
 925 #endif
 926 #include <stdlib.h>
 927 #include <errno.h>
 928 #define FILENAME "conftest.fifi"
 929 int main(void) {
 930         unlink(FILENAME);
 931         if (mkfifo(FILENAME, 0777) < 0) abort();
 932         unlink(FILENAME "2");
 933         if (link(FILENAME, FILENAME "2") < 0) return 1;
 934         return 0;
 935     }]])],[rsync_cv_can_hardlink_special=yes],[rsync_cv_can_hardlink_special=no],[rsync_cv_can_hardlink_special=no])])
 936 if test $rsync_cv_can_hardlink_special = yes; then
 937     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
 938 fi
 939
 940 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 941 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 942 #include <sys/types.h>
 943 #include <sys/socket.h>
 944
 945 int main(void) {
 946        int fd[2];
 947        return (socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1;
 948 }]])],[rsync_cv_HAVE_SOCKETPAIR=yes],[rsync_cv_HAVE_SOCKETPAIR=no],[rsync_cv_HAVE_SOCKETPAIR=cross])])
 949 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 950     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
 951 fi
 952
 953 AC_REPLACE_FUNCS([getpass])
 954
 955 if test x"$with_included_popt" != x"yes"; then
 956     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 957 fi
 958 if test x"$ac_cv_header_popt_popt_h" = x"yes"; then
 959     # If the system has /usr/include/popt/popt.h, we enable the
 960     # included popt because an attempt to "#include <popt/popt.h>"
 961     # would use our included header file anyway (due to -I.), and
 962     # might conflict with the system popt.
 963     with_included_popt=yes
 964 elif test x"$ac_cv_header_popt_h" != x"yes"; then
 965     with_included_popt=yes
 966 fi
 967
 968 AC_MSG_CHECKING([whether to use included libpopt])
 969 if test x"$with_included_popt" = x"yes"; then
 970     AC_MSG_RESULT($srcdir/popt)
 971     BUILD_POPT='$(popt_OBJS)'
 972     CFLAGS="-I$srcdir/popt $CFLAGS"
 973     if test x"$ALLOCA" != x
 974     then
 975         # this can be removed when/if we add an included alloca.c;
 976         #  see autoconf documentation on AC_FUNC_ALLOCA
 977         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
 978     fi
 979 else
 980     AC_MSG_RESULT(no)
 981 fi
 982
 983 # We default to using our zlib unless --with-included-zlib=no is given.
 984 if test x"$with_included_zlib" != x"no"; then
 985     with_included_zlib=yes
 986 elif test x"$ac_cv_header_zlib_h" != x"yes"; then
 987     with_included_zlib=yes
 988 fi
 989 if test x"$with_included_zlib" != x"yes"; then
 990     AC_CHECK_LIB(z, deflateParams, , [with_included_zlib=yes])
 991 fi
 992
 993 AC_MSG_CHECKING([whether to use included zlib])
 994 if test x"$with_included_zlib" = x"yes"; then
 995     AC_MSG_RESULT($srcdir/zlib)
 996     BUILD_ZLIB='$(zlib_OBJS)'
 997     CFLAGS="-I$srcdir/zlib $CFLAGS"
 998 else
 999     AC_DEFINE(EXTERNAL_ZLIB, 1, [Define to 1 if using external zlib])
1000     AC_MSG_RESULT(no)
1001 fi
1002
1003 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
1004 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[signed char *s = ""]])],[rsync_cv_SIGNED_CHAR_OK=yes],[rsync_cv_SIGNED_CHAR_OK=no])])
1005 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
1006     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
1007 fi
1008
1009 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
1010 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <sys/types.h>
1011 #include <dirent.h>
1012 int main(void) { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
1013 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
1014 di->d_name[0] == 0) return 0; return 1;} ]])],[rsync_cv_HAVE_BROKEN_READDIR=yes],[rsync_cv_HAVE_BROKEN_READDIR=no],[rsync_cv_HAVE_BROKEN_READDIR=cross])])
1015 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
1016     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
1017 fi
1018
1019 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
1020 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1021 #include <utime.h>]], [[struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; return utime("foo.c",&tbuf);]])],[rsync_cv_HAVE_STRUCT_UTIMBUF=yes],[rsync_cv_HAVE_STRUCT_UTIMBUF=no])])
1022 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
1023     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
1024 fi
1025
1026 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
1027 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/time.h>
1028 #include <unistd.h>]], [[struct timeval tv; return gettimeofday(&tv, NULL);]])],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=no])])
1029 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
1030     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
1031 fi
1032
1033 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
1034 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1035 #include <sys/types.h>
1036 #include <stdarg.h>
1037 #include <stdio.h>
1038 #include <stdlib.h>
1039 #include <string.h>
1040 void foo(const char *format, ...) {
1041        va_list ap;
1042        int len;
1043        static char buf[] = "12345678901234567890";
1044
1045        va_start(ap, format);
1046        len = vsnprintf(0, 0, format, ap);
1047        va_end(ap);
1048        if (len != 5) exit(1);
1049
1050        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
1051 }
1052 int main(void) { foo("hello"); return 0; }
1053 ]])],[rsync_cv_HAVE_C99_VSNPRINTF=yes],[rsync_cv_HAVE_C99_VSNPRINTF=no],[rsync_cv_HAVE_C99_VSNPRINTF=cross])])
1054 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
1055     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
1056 fi
1057
1058
1059 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
1060 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1061 #include <sys/types.h>
1062 #include <sys/stat.h>
1063 #include <unistd.h>
1064 int main(void) {
1065   struct stat st;
1066   char tpl[20]="/tmp/test.XXXXXX";
1067   int fd = mkstemp(tpl);
1068   if (fd == -1) return 1;
1069   unlink(tpl);
1070   if (fstat(fd, &st) != 0) return 1;
1071   if ((st.st_mode & 0777) != 0600) return 1;
1072   return 0;
1073 }]])],[rsync_cv_HAVE_SECURE_MKSTEMP=yes],[rsync_cv_HAVE_SECURE_MKSTEMP=no],[rsync_cv_HAVE_SECURE_MKSTEMP=cross])])
1074 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
1075     case $host_os in
1076     hpux*)
1077         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
1078         dnl so we noisily skip using it.  See HP change request JAGaf34426
1079         dnl for details. (sbonds)
1080         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
1081         ;;
1082     *)
1083         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
1084         ;;
1085     esac
1086 fi
1087
1088
1089 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
1090 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1091 #include <stdio.h>
1092 #include <sys/stat.h>
1093 #include <errno.h>
1094 #if HAVE_UNISTD_H
1095 # include <unistd.h>
1096 #endif
1097 int main(void) { int rc, ec; char *fn = "fifo-test";
1098 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
1099 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1100 return 0;}]])],[rsync_cv_MKNOD_CREATES_FIFOS=yes],[rsync_cv_MKNOD_CREATES_FIFOS=no],[rsync_cv_MKNOD_CREATES_FIFOS=cross])])
1101 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
1102     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
1103 fi
1104
1105 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
1106 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1107 #include <stdio.h>
1108 #include <sys/stat.h>
1109 #include <errno.h>
1110 #if HAVE_UNISTD_H
1111 # include <unistd.h>
1112 #endif
1113 int main(void) { int rc, ec; char *fn = "sock-test";
1114 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
1115 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1116 return 0;}]])],[rsync_cv_MKNOD_CREATES_SOCKETS=yes],[rsync_cv_MKNOD_CREATES_SOCKETS=no],[rsync_cv_MKNOD_CREATES_SOCKETS=cross])])
1117 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
1118     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
1119 fi
1120
1121 #
1122 # The following test was mostly taken from the tcl/tk plus patches
1123 #
1124 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
1125 rm -rf conftest*
1126 cat > conftest.$ac_ext <<EOF
1127 int main(void) { return 0; }
1128 EOF
1129 ${CC-cc} -c -o conftest..o conftest.$ac_ext
1130 if test -f conftest..o; then
1131     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
1132 else
1133     rsync_cv_DASHC_WORKS_WITH_DASHO=no
1134 fi
1135 rm -rf conftest*
1136 ])
1137 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
1138     OBJ_SAVE="#"
1139     OBJ_RESTORE="#"
1140     CC_SHOBJ_FLAG='-o $@'
1141 else
1142     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
1143     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
1144     CC_SHOBJ_FLAG=""
1145 fi
1146
1147 AC_SUBST(OBJ_SAVE)
1148 AC_SUBST(OBJ_RESTORE)
1149 AC_SUBST(CC_SHOBJ_FLAG)
1150 AC_SUBST(BUILD_POPT)
1151 AC_SUBST(BUILD_ZLIB)
1152 AC_SUBST(MAKE_MAN)
1153
1154 AC_CHECK_FUNCS(_acl __acl _facl __facl)
1155 #################################################
1156 # check for ACL support
1157
1158 AC_MSG_CHECKING([whether to support ACLs])
1159 AC_ARG_ENABLE(acl-support,
1160         AS_HELP_STRING([--disable-acl-support],[disable ACL support]))
1161
1162 if test x"$enable_acl_support" = x"no"; then
1163     AC_MSG_RESULT(no)
1164 else
1165     case "$host_os" in
1166     *sysv5*)
1167         AC_MSG_RESULT(Using UnixWare ACLs)
1168         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
1169         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
1170         ;;
1171     solaris*)
1172         AC_MSG_RESULT(Using solaris ACLs)
1173         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
1174         AC_DEFINE(SUPPORT_ACLS, 1)
1175         ;;
1176     *hpux*)
1177         AC_MSG_RESULT(Using HPUX ACLs)
1178         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
1179         AC_DEFINE(SUPPORT_ACLS, 1)
1180         ;;
1181     *irix*)
1182         AC_MSG_RESULT(Using IRIX ACLs)
1183         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
1184         AC_DEFINE(SUPPORT_ACLS, 1)
1185         ;;
1186     *aix*)
1187         AC_MSG_RESULT(Using AIX ACLs)
1188         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
1189         AC_DEFINE(SUPPORT_ACLS, 1)
1190         ;;
1191     *osf*)
1192         AC_MSG_RESULT(Using Tru64 ACLs)
1193         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
1194         AC_DEFINE(SUPPORT_ACLS, 1)
1195         LIBS="$LIBS -lpacl"
1196         ;;
1197     darwin*)
1198         AC_MSG_RESULT(Using OS X ACLs)
1199         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
1200         AC_DEFINE(SUPPORT_ACLS, 1)
1201         ;;
1202     *)
1203         AC_MSG_RESULT(running tests:)
1204         AC_CHECK_LIB(acl,acl_get_file)
1205         AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
1206             AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1207 #include <sys/acl.h>]], [[ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);]])],[samba_cv_HAVE_POSIX_ACLS=yes],[samba_cv_HAVE_POSIX_ACLS=no])])
1208         AC_MSG_CHECKING(ACL test results)
1209         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
1210             AC_MSG_RESULT(Using posix ACLs)
1211             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
1212             AC_DEFINE(SUPPORT_ACLS, 1)
1213             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
1214                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1215 #include <sys/acl.h>]], [[ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);]])],[samba_cv_HAVE_ACL_GET_PERM_NP=yes],[samba_cv_HAVE_ACL_GET_PERM_NP=no])])
1216             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
1217                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
1218             fi
1219         else
1220             if test x"$enable_acl_support" = x"yes"; then
1221                 AC_MSG_ERROR(Failed to find ACL support)
1222             else
1223                 AC_MSG_RESULT(No ACL support found)
1224             fi
1225         fi
1226         ;;
1227     esac
1228 fi
1229
1230 #################################################
1231 # check for extended attribute support
1232 AC_MSG_CHECKING(whether to support extended attributes)
1233 AC_ARG_ENABLE(xattr-support,
1234     AS_HELP_STRING([--disable-xattr-support],[disable extended attributes]),
1235     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link$ac_cv_func_attropen" in
1236         *yes*) enable_xattr_support=maybe ;;
1237         *) enable_xattr_support=no ;;
1238         esac])
1239 AH_TEMPLATE([SUPPORT_XATTRS],
1240 [Define to 1 to add support for extended attributes])
1241 if test x"$enable_xattr_support" = x"no"; then
1242     AC_MSG_RESULT(no)
1243 else
1244     case "$host_os" in
1245     *linux*|*netbsd*)
1246         AC_MSG_RESULT(Using Linux xattrs)
1247         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs (or equivalent)])
1248         AC_DEFINE(SUPPORT_XATTRS, 1)
1249         AC_DEFINE(NO_SYMLINK_USER_XATTRS, 1, [True if symlinks do not support user xattrs])
1250         AC_CHECK_LIB(attr,getxattr)
1251         ;;
1252     darwin*)
1253         AC_MSG_RESULT(Using OS X xattrs)
1254         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
1255         AC_DEFINE(SUPPORT_XATTRS, 1)
1256         AC_DEFINE(NO_DEVICE_XATTRS, 1, [True if device files do not support xattrs])
1257         AC_DEFINE(NO_SPECIAL_XATTRS, 1, [True if special files do not support xattrs])
1258         ;;
1259     freebsd*)
1260         AC_MSG_RESULT(Using FreeBSD extattrs)
1261         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
1262         AC_DEFINE(SUPPORT_XATTRS, 1)
1263         ;;
1264     solaris*)
1265         AC_MSG_RESULT(Using Solaris xattrs)
1266         AC_DEFINE(HAVE_SOLARIS_XATTRS, 1, [True if you have Solaris xattrs])
1267         AC_DEFINE(SUPPORT_XATTRS, 1)
1268         AC_DEFINE(NO_SYMLINK_XATTRS, 1, [True if symlinks do not support xattrs])
1269         ;;
1270     *)
1271         if test x"$enable_xattr_support" = x"yes"; then
1272             AC_MSG_ERROR(Failed to find extended attribute support)
1273         else
1274             AC_MSG_RESULT(No extended attribute support found)
1275         fi
1276         ;;
1277     esac
1278 fi
1279
1280 if test x"$enable_acl_support" = x"no" -o x"$enable_xattr_support" = x"no" -o x"$enable_iconv" = x"no"; then
1281     AC_MSG_CHECKING([whether $CC supports -Wno-unused-parameter])
1282     OLD_CFLAGS="$CFLAGS"
1283     CFLAGS="$CFLAGS -Wno-unused-parameter"
1284     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]], [[printf("hello\n");]])],[rsync_warn_flag=yes],[rsync_warn_flag=no])
1285     AC_MSG_RESULT([$rsync_warn_flag])
1286     if test x"$rsync_warn_flag" = x"no"; then
1287         CFLAGS="$OLD_CFLAGS"
1288     fi
1289 fi
1290
1291 case "$CC" in
1292 ' checker'*|checker*)
1293     AC_DEFINE(FORCE_FD_ZERO_MEMSET, 1, [Used to make "checker" understand that FD_ZERO() clears memory.])
1294     ;;
1295 esac
1296
1297 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
1298 AC_OUTPUT
1299
1300 AC_MSG_RESULT()
1301 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
1302 AC_MSG_RESULT()