configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([rsync],[3.2.0pre2],[http://rsync.samba.org/bugzilla.html])
   4
   5 AC_CONFIG_MACRO_DIR([m4])
   6 AC_CONFIG_SRCDIR([byteorder.h])
   7 AC_CONFIG_HEADER(config.h)
   8 AC_PREREQ([2.69])
   9
  10 AC_SUBST(RSYNC_VERSION, $PACKAGE_VERSION)
  11 AC_MSG_NOTICE([Configuring rsync $PACKAGE_VERSION])
  12
  13 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$PACKAGE_VERSION"], [rsync release version])
  14
  15 LDFLAGS=${LDFLAGS-""}
  16
  17 AC_CANONICAL_HOST
  18
  19 dnl define the directory for replacement function since AC_LIBOBJ does not
  20 dnl officially support subdirs and fails with automake
  21 AC_CONFIG_LIBOBJ_DIR([lib])
  22
  23 # We must decide this before testing the compiler.
  24
  25 # Please allow this to default to yes, so that your users have more
  26 # chance of getting a useful stack trace if problems occur.
  27
  28 AC_MSG_CHECKING([whether to include debugging symbols])
  29 AC_ARG_ENABLE(debug,
  30         AS_HELP_STRING([--disable-debug],[disable debugging symbols and features]))
  31
  32 if test x"$enable_debug" = x"no"; then
  33     AC_MSG_RESULT(no)
  34     ac_cv_prog_cc_g=no
  35 else
  36     AC_MSG_RESULT([yes])
  37     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  38     # leave ac_cv_prog_cc_g alone; AC_PROG_CC will try to include -g if it can
  39 fi
  40
  41 dnl Checks for programs.
  42 AC_PROG_CC
  43 AC_PROG_CPP
  44 AC_PROG_CXX
  45 AC_PROG_EGREP
  46 AC_PROG_INSTALL
  47 AC_PROG_MKDIR_P
  48 AC_PROG_CC_STDC
  49 AC_SUBST(SHELL)
  50 AC_PATH_PROG([PERL], [perl])
  51 AC_PATH_PROG([PYTHON3], [python3])
  52
  53 AC_DEFINE([_GNU_SOURCE], 1,
  54           [Define _GNU_SOURCE so that we get all necessary prototypes])
  55
  56 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  57         AC_MSG_WARN([rsync requires an ANSI C compiler and you do not seem to have one])
  58 fi
  59
  60 AC_ARG_ENABLE(profile,
  61         AS_HELP_STRING([--enable-profile],[turn on CPU profiling]))
  62 if test x"$enable_profile" = x"yes"; then
  63         CFLAGS="$CFLAGS -pg"
  64 fi
  65
  66 AC_MSG_CHECKING([if md2man can create man pages])
  67 if test x"$ac_cv_path_PYTHON3" = x; then
  68     AC_MSG_RESULT(no - python3 not found)
  69     md2man_works=no
  70 else
  71     md2man_out=`"$srcdir/md2man" --test "$srcdir/rsync.1.md" 2>&1`
  72     if test $? = 0; then
  73         AC_MSG_RESULT(yes)
  74         md2man_works=yes
  75     else
  76         AC_MSG_RESULT(no)
  77         md2man_works=no
  78         echo "$md2man_out"
  79     fi
  80 fi
  81
  82 AC_MSG_CHECKING([if we require man-page building])
  83 AC_ARG_ENABLE([md2man],
  84         AS_HELP_STRING([--disable-md2man],[disable md2man for man page creation]))
  85 if test x"$enable_md2man" != x"no"; then
  86     if test -f "$srcdir/rsync.1"; then
  87         AC_MSG_RESULT(optional)
  88     else
  89         AC_MSG_RESULT(required)
  90         if test x"$md2man_works" = x"no"; then
  91             AC_MSG_ERROR(You need python3 and the cmarkgfm OR commonmark python3 lib in order to build man pages.
  92 You can specify --disable-md2man if you want to skip building them.)
  93         fi
  94     fi
  95     MAKE_MAN=man
  96 else
  97     AC_MSG_RESULT(no)
  98     MAKE_MAN=''
  99 fi
 100
 101 # Specifically, this turns on panic_action handling.
 102 AC_ARG_ENABLE(maintainer-mode,
 103         AS_HELP_STRING([--enable-maintainer-mode],[turn on extra debug features]))
 104 if test x"$enable_maintainer_mode" = x"yes"; then
 105         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
 106 fi
 107
 108 # This is needed for our included version of popt.  Kind of silly, but
 109 # I don't want our version too far out of sync.
 110 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
 111
 112 # If GCC, turn on warnings.
 113 if test x"$GCC" = x"yes"; then
 114         CFLAGS="$CFLAGS -Wall -W"
 115 fi
 116
 117 AC_ARG_WITH(included-popt,
 118         AS_HELP_STRING([--with-included-popt],[use bundled popt library, not from system]))
 119
 120 AC_ARG_WITH(included-zlib,
 121         AS_HELP_STRING([--with-included-zlib],[use bundled zlib library, not from system]))
 122
 123 AC_ARG_WITH(protected-args,
 124         AS_HELP_STRING([--with-protected-args],[make --protected-args option the default]))
 125 if test x"$with_protected_args" = x"yes"; then
 126         AC_DEFINE_UNQUOTED(RSYNC_USE_PROTECTED_ARGS, 1, [Define to 1 if --protected-args should be the default])
 127 fi
 128
 129 AC_ARG_WITH(rsync-path,
 130         AS_HELP_STRING([--with-rsync-path=PATH],[set default --rsync-path to PATH (default: rsync)]),
 131         [ RSYNC_PATH="$with_rsync_path" ],
 132         [ RSYNC_PATH="rsync" ])
 133
 134 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
 135
 136 AC_ARG_WITH(rsyncd-conf,
 137         AS_HELP_STRING([--with-rsyncd-conf=PATH],[set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
 138         [ if test ! -z "$with_rsyncd_conf" ; then
 139                 case $with_rsyncd_conf in
 140                         yes|no)
 141                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 142                                 ;;
 143                         /*)
 144                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
 145                                 ;;
 146                         *)
 147                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 148                                 ;;
 149                 esac
 150         else
 151                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 152         fi ],
 153         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 154
 155 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 156
 157 AC_ARG_WITH(rsh,
 158         AS_HELP_STRING([--with-rsh=CMD],[set remote shell command to CMD (default: ssh)]))
 159
 160 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 161 if test x$HAVE_REMSH = x1; then
 162         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 163 fi
 164
 165 if test x"$with_rsh" != x; then
 166         RSYNC_RSH="$with_rsh"
 167 else
 168         RSYNC_RSH="ssh"
 169 fi
 170 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 171
 172 # Some programs on solaris are only found in /usr/xpg4/bin (or work better than others versions).
 173 AC_PATH_PROG(SHELL_PATH, sh, /bin/sh, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 174 AC_PATH_PROG(FAKEROOT_PATH, fakeroot, /usr/bin/fakeroot, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 175
 176 AC_ARG_WITH(nobody-group,
 177     AS_HELP_STRING([--with-nobody-group=GROUP],[set the default unprivileged group (default nobody or nogroup)]),
 178     [ NOBODY_GROUP="$with_nobody_group" ])
 179
 180 if test x"$with_nobody_group" = x; then
 181     AC_MSG_CHECKING([the group for user "nobody"])
 182     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 183         NOBODY_GROUP=nobody
 184     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 185         NOBODY_GROUP=nogroup
 186     else
 187         NOBODY_GROUP=nobody # test for others?
 188     fi
 189     AC_MSG_RESULT($NOBODY_GROUP)
 190 fi
 191
 192 AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody])
 193 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 194
 195 # SIMD optimizations
 196 SIMD=
 197
 198 AC_MSG_CHECKING([whether to enable SIMD optimizations])
 199 AC_ARG_ENABLE(simd,
 200     AS_HELP_STRING([--disable-simd],[disable SIMD optimizations (requires g++)]))
 201
 202 if test x"$enable_simd" != x"no"; then
 203     # For x86-64 SIMD, g++ is also required
 204     if test x"$build_cpu" = x"x86_64"; then
 205         if test x"$CXX" = x"g++"; then
 206             # AC_MSG_RESULT() called below
 207             SIMD="$SIMD x86_64"
 208         else
 209             AC_MSG_RESULT(no)
 210             case "$host_os" in
 211             *linux*)
 212                 AC_MSG_ERROR(Failed to find g++ for SIMD speedups. Use --disable-simd to continue without it.)
 213                 ;;
 214             *)
 215                 ;;
 216             esac
 217         fi
 218     fi
 219 fi
 220
 221 if test x"$SIMD" != x""; then
 222     SIMD=`echo "$SIMD" | sed -e 's/^ *//'`
 223     AC_MSG_RESULT([yes ($SIMD)])
 224     AC_DEFINE(HAVE_SIMD, 1, [Define to 1 to enable SIMD optimizations])
 225     SIMD=`echo "$SIMD" | sed -e 's/[[^ ]]\+/$(SIMD_&)/g'`
 226     # We only use g++ for its target attribute dispatching, disable unneeded bulky features
 227     CXXFLAGS="$CXXFLAGS -fno-exceptions -fno-rtti"
 228 else
 229     AC_MSG_RESULT(no)
 230 fi
 231
 232 AC_SUBST(SIMD)
 233
 234 # arrgh. libc in some old debian version screwed up the largefile
 235 # stuff, getting byte range locking wrong
 236 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 237 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 238 #define _FILE_OFFSET_BITS 64
 239 #include <stdio.h>
 240 #include <fcntl.h>
 241 #include <sys/types.h>
 242 #include <sys/wait.h>
 243 #if HAVE_UNISTD_H
 244 #include <unistd.h>
 245 #endif
 246
 247 int main(void)
 248 {
 249         struct flock lock;
 250         int status;
 251         char tpl[32] = "/tmp/locktest.XXXXXX";
 252         int fd = mkstemp(tpl);
 253         if (fd < 0) {
 254                 strcpy(tpl, "conftest.dat");
 255                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 256         }
 257
 258         lock.l_type = F_WRLCK;
 259         lock.l_whence = SEEK_SET;
 260         lock.l_start = 0;
 261         lock.l_len = 1;
 262         lock.l_pid = 0;
 263         fcntl(fd,F_SETLK,&lock);
 264         if (fork() == 0) {
 265                 lock.l_start = 1;
 266                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 267         }
 268         wait(&status);
 269         unlink(tpl);
 270         return WEXITSTATUS(status);
 271 }
 272 ]])],[rsync_cv_HAVE_BROKEN_LARGEFILE=yes],[rsync_cv_HAVE_BROKEN_LARGEFILE=no],[rsync_cv_HAVE_BROKEN_LARGEFILE=cross])])
 273 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 274    AC_SYS_LARGEFILE
 275 fi
 276
 277 ipv6type=unknown
 278 ipv6lib=none
 279 ipv6trylibc=yes
 280
 281 AC_ARG_ENABLE(ipv6,
 282         AS_HELP_STRING([--disable-ipv6],[turn off IPv6 support]))
 283 if test x"$enable_ipv6" != x"no"; then
 284         AC_MSG_CHECKING([ipv6 stack type])
 285         for i in inria kame linux-glibc linux-inet6 solaris toshiba v6d zeta cygwin; do
 286                 case $i in
 287                 inria)
 288                         # http://www.kame.net/
 289                         AC_EGREP_CPP(yes, [
 290 #include <netinet/in.h>
 291 #ifdef IPV6_INRIA_VERSION
 292 yes
 293 #endif],
 294                                 [ipv6type=$i;
 295                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 296                                 ])
 297                         ;;
 298                 kame)
 299                         # http://www.kame.net/
 300                         AC_EGREP_CPP(yes, [
 301 #include <netinet/in.h>
 302 #ifdef __KAME__
 303 yes
 304 #endif],
 305                                 [ipv6type=$i;
 306                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 307                         ;;
 308                 linux-glibc)
 309                         # http://www.v6.linux.or.jp/
 310                         AC_EGREP_CPP(yes, [
 311 #include <features.h>
 312 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 313 yes
 314 #endif],
 315                                 [ipv6type=$i;
 316 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 317                         ;;
 318                 linux-inet6)
 319                         # http://www.v6.linux.or.jp/
 320                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 321                                 ipv6type=$i
 322                                 ipv6lib=inet6
 323                                 ipv6libdir=/usr/inet6/lib
 324                                 ipv6trylibc=yes;
 325                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 326                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 327                         fi
 328                         ;;
 329                 solaris)
 330                         # http://www.sun.com
 331                         AC_EGREP_CPP(yes, [
 332 #include <netinet/ip6.h>
 333 #ifdef __sun
 334 yes
 335 #endif],
 336                                 [ipv6type=$i;
 337                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 338                         ;;
 339                 toshiba)
 340                         AC_EGREP_CPP(yes, [
 341 #include <sys/param.h>
 342 #ifdef _TOSHIBA_INET6
 343 yes
 344 #endif],
 345                                 [ipv6type=$i;
 346                                 ipv6lib=inet6;
 347                                 ipv6libdir=/usr/local/v6/lib;
 348                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 349                         ;;
 350                 v6d)
 351                         AC_EGREP_CPP(yes, [
 352 #include </usr/local/v6/include/sys/v6config.h>
 353 #ifdef __V6D__
 354 yes
 355 #endif],
 356                                 [ipv6type=$i;
 357                                 ipv6lib=v6;
 358                                 ipv6libdir=/usr/local/v6/lib;
 359                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 360                         ;;
 361                 zeta)
 362                         AC_EGREP_CPP(yes, [
 363 #include <sys/param.h>
 364 #ifdef _ZETA_MINAMI_INET6
 365 yes
 366 #endif],
 367                                 [ipv6type=$i;
 368                                 ipv6lib=inet6;
 369                                 ipv6libdir=/usr/local/v6/lib;
 370                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 371                         ;;
 372                 cygwin)
 373                         AC_EGREP_CPP(yes, [
 374 #include <netinet/in.h>
 375 #ifdef _CYGWIN_IN6_H
 376 yes
 377 #endif],
 378                                 [ipv6type=$i;
 379                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 380                         ;;
 381                 esac
 382                 if test "$ipv6type" != "unknown"; then
 383                         break
 384                 fi
 385         done
 386         AC_MSG_RESULT($ipv6type)
 387
 388         AC_SEARCH_LIBS(getaddrinfo, inet6)
 389 fi
 390
 391 dnl Do you want to disable use of locale functions
 392 AC_ARG_ENABLE([locale],
 393         AS_HELP_STRING([--disable-locale],[disable locale features]))
 394 AH_TEMPLATE([CONFIG_LOCALE],
 395 [Undefine if you do not want locale features.  By default this is defined.])
 396 if test x"$enable_locale" != x"no"; then
 397         AC_DEFINE(CONFIG_LOCALE)
 398 fi
 399
 400 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 401 case $host_os in
 402         *cygwin* ) AC_MSG_RESULT(yes)
 403                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 404                             [Define to 1 if sockets need to be shutdown])
 405                    ;;
 406                * ) AC_MSG_RESULT(no);;
 407 esac
 408
 409 AC_C_BIGENDIAN
 410 AC_HEADER_DIRENT
 411 AC_HEADER_TIME
 412 AC_HEADER_SYS_WAIT
 413 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
 414     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
 415     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
 416     sys/un.h sys/attr.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
 417     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h \
 418     sys/acl.h acl/libacl.h attr/xattr.h sys/xattr.h sys/extattr.h \
 419     popt.h popt/popt.h linux/falloc.h netinet/in_systm.h netinet/ip.h \
 420     zlib.h xxhash.h openssl/md4.h openssl/md5.h zstd.h lz4.h)
 421 AC_HEADER_MAJOR_FIXED
 422
 423 AC_MSG_CHECKING([whether to enable use of openssl crypto library])
 424 AC_ARG_ENABLE([openssl],
 425         AS_HELP_STRING([--disable-openssl],[disable openssl crypto library]))
 426 AH_TEMPLATE([USE_OPENSSL],
 427 [Undefine if you do not want to use openssl crypto library.  By default this is defined.])
 428 if test x"$enable_openssl" != x"no"; then
 429     if test x"$ac_cv_header_openssl_md4_h" = x"yes" && test x"$ac_cv_header_openssl_md5_h" = x"yes"; then
 430       AC_MSG_RESULT(yes)
 431       AC_SEARCH_LIBS(MD5_Init, crypto,
 432           [AC_DEFINE(USE_OPENSSL)],
 433           [AC_MSG_ERROR(Failed to find MD5_Init function in openssl crypto lib.
 434 Use --disable-openssl to continue without openssl crypto lib support.)])
 435     else
 436         AC_MSG_RESULT(no)
 437         AC_MSG_ERROR(Failed to find openssl/md4.h and openssl/md5.h for openssl crypto lib support.
 438 Use --disable-openssl to continue without it.)
 439     fi
 440 else
 441     AC_MSG_RESULT(no)
 442 fi
 443
 444 AC_MSG_CHECKING([whether to enable xxhash checksum support])
 445 AC_ARG_ENABLE([xxhash],
 446         AS_HELP_STRING([--disable-xxhash],[disable xxhash checksums]))
 447 AH_TEMPLATE([SUPPORT_XXHASH],
 448 [Undefine if you do not want xxhash checksums.  By default this is defined.])
 449 if test x"$enable_xxhash" != x"no"; then
 450     if test x"$ac_cv_header_xxhash_h" = x"yes"; then
 451         AC_MSG_RESULT(yes)
 452         AC_SEARCH_LIBS(XXH64_createState, xxhash,
 453             [AC_DEFINE(SUPPORT_XXHASH)],
 454             [AC_MSG_ERROR(Failed to find XXH64_createState function in xxhash lib.
 455 Use --disable-xxhash to continue without xxhash checksums.)])
 456     else
 457         AC_MSG_RESULT(no)
 458         AC_MSG_ERROR(Failed to find xxhash.h for xxhash checksum support.
 459 Use --disable-xxhash to continue without it.)
 460     fi
 461 else
 462     AC_MSG_RESULT(no)
 463 fi
 464
 465 AC_MSG_CHECKING([whether to enable zstd compression])
 466 AC_ARG_ENABLE([zstd],
 467         AC_HELP_STRING([--disable-zstd], [disable zstd compression]))
 468 AH_TEMPLATE([SUPPORT_ZSTD],
 469 [Undefine if you do not want zstd compression.  By default this is defined.])
 470 if test x"$enable_zstd" != x"no"; then
 471     if test x"$ac_cv_header_zstd_h" = x"yes"; then
 472         AC_MSG_RESULT(yes)
 473         AC_SEARCH_LIBS(ZSTD_minCLevel, zstd,
 474             [AC_DEFINE(SUPPORT_ZSTD)],
 475             [AC_MSG_ERROR(Failed to find ZSTD_minCLevel function in zstd lib.
 476 Use --disable-zstd to continue without zstd compression.)])
 477     else
 478         AC_MSG_RESULT(no)
 479         AC_MSG_ERROR(Failed to find zstd.h for zstd compression support.
 480 Use --disable-zstd to continue without it.)
 481     fi
 482 else
 483     AC_MSG_RESULT(no)
 484 fi
 485
 486 AC_MSG_CHECKING([whether to enable LZ4 compression])
 487 AC_ARG_ENABLE([lz4],
 488         AC_HELP_STRING([--disable-lz4], [disable LZ4 compression]))
 489 AH_TEMPLATE([SUPPORT_LZ4],
 490 [Undefine if you do not want LZ4 compression.  By default this is defined.])
 491 if test x"$enable_lz4" != x"no"; then
 492     if test x"$ac_cv_header_lz4_h" = x"yes"; then
 493         AC_MSG_RESULT(yes)
 494         AC_SEARCH_LIBS(LZ4_compress_default, lz4,
 495             [AC_DEFINE(SUPPORT_LZ4)],
 496             [AC_MSG_ERROR(Failed to find LZ4_compress_default function in lz4 lib.
 497 Use --disable-lz4 to continue without lz4 compression.)])
 498     else
 499         AC_MSG_RESULT(no)
 500         AC_MSG_ERROR(Failed to find lz4.h for lz4 compression support.
 501 Use --disable-lz4 to continue without it.)
 502     fi
 503 else
 504     AC_MSG_RESULT(no)
 505 fi
 506
 507 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
 508 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 509 #include <sys/types.h>
 510 #ifdef MAJOR_IN_MKDEV
 511 #include <sys/mkdev.h>
 512 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
 513 #  define makedev mkdev
 514 # endif
 515 #elif defined MAJOR_IN_SYSMACROS
 516 #include <sys/sysmacros.h>
 517 #endif
 518
 519 int main(void)
 520 {
 521         dev_t dev = makedev(0, 5, 7);
 522         if (major(dev) != 5 || minor(dev) != 7)
 523                 return 1;
 524         return 0;
 525 }
 526 ]])],[rsync_cv_MAKEDEV_TAKES_3_ARGS=yes],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no])])
 527 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
 528    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
 529 fi
 530
 531 AC_CHECK_SIZEOF(int)
 532 AC_CHECK_SIZEOF(long)
 533 AC_CHECK_SIZEOF(long long)
 534 AC_CHECK_SIZEOF(short)
 535 AC_CHECK_SIZEOF(int16_t)
 536 AC_CHECK_SIZEOF(uint16_t)
 537 AC_CHECK_SIZEOF(int32_t)
 538 AC_CHECK_SIZEOF(uint32_t)
 539 AC_CHECK_SIZEOF(int64_t)
 540 AC_CHECK_SIZEOF(off_t)
 541 AC_CHECK_SIZEOF(off64_t)
 542 AC_CHECK_SIZEOF(time_t)
 543 AC_CHECK_SIZEOF(char*)
 544
 545 AC_C_INLINE
 546
 547 AC_TYPE_LONG_DOUBLE_WIDER
 548 ac_cv_c_long_double=$ac_cv_type_long_double_wider
 549 if test $ac_cv_c_long_double = yes; then
 550   AC_DEFINE([HAVE_LONG_DOUBLE],[1],[Define to 1 if the type `long double' works and has more range or precision than `double'.])
 551 fi
 552
 553 AC_TYPE_UID_T
 554 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
 555 AC_TYPE_GETGROUPS
 556 AC_CHECK_MEMBERS([struct stat.st_rdev,
 557                   struct stat.st_mtimensec,
 558                   struct stat.st_mtimespec.tv_nsec,
 559                   struct stat.st_mtim.tv_nsec],,,[
 560 #ifdef HAVE_SYS_TYPES_H
 561 #include <sys/types.h>
 562 #endif
 563 #ifdef HAVE_SYS_STAT_H
 564 #include <sys/stat.h>
 565 #endif
 566 #ifdef HAVE_UNISTD_H
 567 #include <unistd.h>
 568 #endif])
 569
 570 TYPE_SOCKLEN_T
 571
 572 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 573     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]], [[int i = errno]])],[rsync_cv_errno=yes],[rsync_cv_have_errno_decl=no])])
 574 if test x"$rsync_cv_errno" = x"yes"; then
 575    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 576 fi
 577
 578 # The following test taken from the cvs sources
 579 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 580 # These need checks to be before checks for any other functions that
 581 #    might be in the same libraries.
 582 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 583 # libsocket.so which has a bad implementation of gethostbyname (it
 584 # only looks in /etc/hosts), so we only look for -lsocket if we need
 585 # it.
 586 AC_CHECK_FUNCS(connect)
 587 if test x"$ac_cv_func_connect" = x"no"; then
 588     case "$LIBS" in
 589     *-lnsl*) ;;
 590     *) AC_CHECK_LIB(nsl_s, printf) ;;
 591     esac
 592     case "$LIBS" in
 593     *-lnsl*) ;;
 594     *) AC_CHECK_LIB(nsl, printf) ;;
 595     esac
 596     case "$LIBS" in
 597     *-lsocket*) ;;
 598     *) AC_CHECK_LIB(socket, connect) ;;
 599     esac
 600     case "$LIBS" in
 601     *-linet*) ;;
 602     *) AC_CHECK_LIB(inet, connect) ;;
 603     esac
 604     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 605     dnl has been cached.
 606     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 607        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 608         # ac_cv_func_connect=yes
 609         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 610         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 611     fi
 612 fi
 613
 614 AC_SEARCH_LIBS(inet_ntop, resolv)
 615
 616 # For OS X, Solaris, HP-UX, etc.: figure out if -liconv is needed.  We'll
 617 # accept either iconv_open or libiconv_open, since some include files map
 618 # the former to the latter.
 619 AC_SEARCH_LIBS(iconv_open, iconv)
 620 AC_SEARCH_LIBS(libiconv_open, iconv)
 621
 622 AC_MSG_CHECKING([for iconv declaration])
 623 AC_CACHE_VAL(am_cv_proto_iconv, [
 624     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 625 #include <stdlib.h>
 626 #include <iconv.h>
 627 extern
 628 #ifdef __cplusplus
 629 "C"
 630 #endif
 631 #if defined(__STDC__) || defined(__cplusplus)
 632 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 633 #else
 634 size_t iconv();
 635 #endif
 636 ]], [[]])],[am_cv_proto_iconv_arg1=""],[am_cv_proto_iconv_arg1="const"])
 637       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 638     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed -e 's/( /(/'`
 639 AC_MSG_RESULT([$]{ac_t:-
 640          }[$]am_cv_proto_iconv)
 641 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 642                    [Define as const if the declaration of iconv() needs const.])
 643
 644 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 645
 646 AC_REPLACE_FUNCS([inet_ntop inet_pton])
 647
 648 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
 649 AC_HAVE_TYPE([struct sockaddr_storage], [#include <sys/types.h>
 650 #include <sys/socket.h>])
 651
 652 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 653 #   builtin getaddrinfo if one of the defines don't exist
 654 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 655                rsync_cv_HAVE_GETADDR_DEFINES,[
 656                         AC_EGREP_CPP(yes, [
 657                         #include <sys/types.h>
 658                         #include <sys/socket.h>
 659                         #include <netdb.h>
 660                         #ifdef AI_PASSIVE
 661                         yes
 662                         #endif],
 663                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 664                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 665 AS_IF([test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" -a x"$ac_cv_type_struct_addrinfo" = x"yes"],[
 666         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 667         # something else so we must include <netdb.h> to get the
 668         # redefinition.
 669         AC_CHECK_FUNCS(getaddrinfo, ,
 670                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 671                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 672                 #include <sys/socket.h>
 673                 #include <netdb.h>]], [[getaddrinfo(NULL, NULL, NULL, NULL);]])],[AC_MSG_RESULT([yes])
 674                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 675                                 [Define to 1 if you have the "getaddrinfo" function and required types.])],[AC_MSG_RESULT([no])
 676                         AC_LIBOBJ([getaddrinfo])])])
 677     ],[AC_LIBOBJ([getaddrinfo])])
 678
 679 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 680                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 681                 [],
 682                 [
 683 #include <sys/types.h>
 684 #include <sys/socket.h>
 685 ])
 686
 687 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 688                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 689                 [],
 690                 [
 691 #include <sys/types.h>
 692 #include <sys/socket.h>
 693 #include <netinet/in.h>
 694 ])
 695
 696 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 697                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 698                 [],
 699                 [
 700 #include <sys/types.h>
 701 #include <sys/socket.h>
 702 #include <netinet/in.h>
 703 ])
 704
 705 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 706                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 707                 [],
 708                 [
 709 #include <sys/types.h>
 710 #include <sys/socket.h>
 711 #include <netinet/in.h>
 712 ])
 713
 714 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
 715 #if HAVE_SYS_TYPES_H
 716 # include <sys/types.h>
 717 #endif
 718 #if HAVE_SYS_STAT_H
 719 # include <sys/stat.h>
 720 #endif
 721 #if STDC_HEADERS
 722 # include <stdlib.h>
 723 # include <stddef.h>
 724 #else
 725 # if HAVE_STDLIB_H
 726 #  include <stdlib.h>
 727 # endif
 728 #endif
 729 ])
 730
 731 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 732 #
 733 AC_CHECK_FUNCS(strcasecmp)
 734 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 735     AC_CHECK_LIB(resolv, strcasecmp)
 736 fi
 737
 738 AC_CHECK_FUNCS(aclsort)
 739 if test x"$ac_cv_func_aclsort" = x"no"; then
 740     AC_CHECK_LIB(sec, aclsort)
 741 fi
 742
 743 dnl At the moment we don't test for a broken memcmp(), because all we
 744 dnl need to do is test for equality, not comparison, and it seems that
 745 dnl every platform has a memcmp that can do at least that.
 746 dnl AC_FUNC_MEMCMP
 747
 748 AC_FUNC_UTIME_NULL
 749 AC_FUNC_ALLOCA
 750 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup chown chmod lchmod mknod mkfifo \
 751     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 752     chflags getattrlist \
 753     memmove lchown vsnprintf snprintf vasprintf asprintf setsid strpbrk \
 754     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
 755     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 756     seteuid strerror putenv iconv_open locale_charset nl_langinfo getxattr \
 757     extattr_get_link sigaction sigprocmask setattrlist getgrouplist \
 758     initgroups utimensat posix_fallocate attropen setvbuf nanosleep usleep)
 759
 760 dnl cygwin iconv.h defines iconv_open as libiconv_open
 761 if test x"$ac_cv_func_iconv_open" != x"yes"; then
 762     AC_CHECK_FUNC(libiconv_open, [ac_cv_func_iconv_open=yes; AC_DEFINE(HAVE_ICONV_OPEN, 1)])
 763 fi
 764
 765 dnl Preallocation stuff (also fallocate, posix_fallocate function tests above):
 766
 767 AC_CACHE_CHECK([for useable fallocate],rsync_cv_have_fallocate,[
 768 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <fcntl.h>
 769 #include <sys/types.h>]], [[fallocate(0, 0, 0, 0);]])],[rsync_cv_have_fallocate=yes],[rsync_cv_have_fallocate=no])])
 770 if test x"$rsync_cv_have_fallocate" = x"yes"; then
 771     AC_DEFINE(HAVE_FALLOCATE, 1, [Define to 1 if you have the fallocate function and it compiles and links without error])
 772 fi
 773
 774 AC_MSG_CHECKING([for FALLOC_FL_PUNCH_HOLE])
 775 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 776         #define _GNU_SOURCE 1
 777         #include <linux/falloc.h>
 778         #ifndef FALLOC_FL_PUNCH_HOLE
 779         #error FALLOC_FL_PUNCH_HOLE is missing
 780         #endif
 781     ]])], [
 782         AC_MSG_RESULT([yes])
 783         AC_DEFINE([HAVE_FALLOC_FL_PUNCH_HOLE], [1], [Define if FALLOC_FL_PUNCH_HOLE is available.])
 784     ], [
 785         AC_MSG_RESULT([no])
 786     ]
 787 )
 788
 789 AC_MSG_CHECKING([for FALLOC_FL_ZERO_RANGE])
 790 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 791         #define _GNU_SOURCE 1
 792         #include <linux/falloc.h>
 793         #ifndef FALLOC_FL_ZERO_RANGE
 794         #error FALLOC_FL_ZERO_RANGE is missing
 795         #endif
 796     ]])], [
 797         AC_MSG_RESULT([yes])
 798         AC_DEFINE([HAVE_FALLOC_FL_ZERO_RANGE], [1], [Define if FALLOC_FL_ZERO_RANGE is available.])
 799     ], [
 800         AC_MSG_RESULT([no])
 801     ]
 802 )
 803
 804 AC_CACHE_CHECK([for SYS_fallocate],rsync_cv_have_sys_fallocate,[
 805 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/syscall.h>
 806 #include <unistd.h>
 807 #include <sys/types.h>]], [[syscall(SYS_fallocate, 0, 0, (loff_t)0, (loff_t)0);]])],[rsync_cv_have_sys_fallocate=yes],[rsync_cv_have_sys_fallocate=no])])
 808 if test x"$rsync_cv_have_sys_fallocate" = x"yes"; then
 809     AC_DEFINE(HAVE_SYS_FALLOCATE, 1, [Define to 1 if you have the SYS_fallocate syscall number])
 810 fi
 811
 812 if test x"$ac_cv_func_posix_fallocate" = x"yes"; then
 813     AC_MSG_CHECKING([whether posix_fallocate is efficient])
 814     case $host_os in
 815     *cygwin*)
 816         AC_MSG_RESULT(yes)
 817         AC_DEFINE(HAVE_EFFICIENT_POSIX_FALLOCATE, 1,
 818                   [Define if posix_fallocate is efficient (Cygwin)])
 819         ;;
 820     *)
 821         AC_MSG_RESULT(no)
 822         ;;
 823     esac
 824 fi
 825
 826 dnl End of preallocation stuff
 827
 828 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 829 if test $ac_cv_func_getpgrp = yes; then
 830     AC_FUNC_GETPGRP
 831 fi
 832
 833 AC_ARG_ENABLE(iconv-open,
 834     AS_HELP_STRING([--disable-iconv-open],[disable all use of iconv_open() function]),
 835     [], [enable_iconv_open=$ac_cv_func_iconv_open])
 836
 837 if test x"$enable_iconv_open" != x"no"; then
 838     AC_DEFINE(USE_ICONV_OPEN, 1, [Define to 1 if you want rsync to make use of iconv_open()])
 839 fi
 840
 841 AC_ARG_ENABLE(iconv,
 842     AS_HELP_STRING([--disable-iconv],[disable rsync's --iconv option]),
 843     [], [enable_iconv=$enable_iconv_open])
 844 AH_TEMPLATE([ICONV_OPTION],
 845 [Define if you want the --iconv option.  Specifying a value will set the
 846 default iconv setting (a NULL means no --iconv processing by default).])
 847 if test x"$enable_iconv" != x"no"; then
 848         if test x"$enable_iconv" = x"yes"; then
 849                 AC_DEFINE(ICONV_OPTION, NULL)
 850         else
 851                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
 852         fi
 853         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
 854 fi
 855
 856 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
 857   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 858 #if HAVE_UNISTD_H
 859 # include <unistd.h>
 860 #endif
 861 #include <stdlib.h>
 862 #include <errno.h>
 863 int main(void) {
 864         char const *dangling_symlink = "conftest.dangle";
 865         unlink(dangling_symlink);
 866         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 867         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) return 1;
 868         return 0;
 869     }]])],[rsync_cv_chown_modifies_symlink=yes],[rsync_cv_chown_modifies_symlink=no],[rsync_cv_chown_modifies_symlink=no])])
 870 if test $rsync_cv_chown_modifies_symlink = yes; then
 871   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 872 fi
 873
 874 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
 875   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 876 #if HAVE_UNISTD_H
 877 # include <unistd.h>
 878 #endif
 879 #include <stdlib.h>
 880 #include <errno.h>
 881 #define FILENAME "conftest.dangle"
 882 int main(void) {
 883         unlink(FILENAME);
 884         if (symlink("conftest.no-such", FILENAME) < 0) abort();
 885         unlink(FILENAME "2");
 886         if (link(FILENAME, FILENAME "2") < 0) return 1;
 887         return 0;
 888     }]])],[rsync_cv_can_hardlink_symlink=yes],[rsync_cv_can_hardlink_symlink=no],[rsync_cv_can_hardlink_symlink=no])])
 889 if test $rsync_cv_can_hardlink_symlink = yes; then
 890   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
 891 fi
 892
 893 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
 894   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 895 #if HAVE_UNISTD_H
 896 # include <unistd.h>
 897 #endif
 898 #ifdef HAVE_SYS_STAT_H
 899 #include <sys/stat.h>
 900 #endif
 901 #include <stdlib.h>
 902 #include <errno.h>
 903 #define FILENAME "conftest.fifi"
 904 int main(void) {
 905         unlink(FILENAME);
 906         if (mkfifo(FILENAME, 0777) < 0) abort();
 907         unlink(FILENAME "2");
 908         if (link(FILENAME, FILENAME "2") < 0) return 1;
 909         return 0;
 910     }]])],[rsync_cv_can_hardlink_special=yes],[rsync_cv_can_hardlink_special=no],[rsync_cv_can_hardlink_special=no])])
 911 if test $rsync_cv_can_hardlink_special = yes; then
 912     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
 913 fi
 914
 915 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 916 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 917 #include <sys/types.h>
 918 #include <sys/socket.h>
 919
 920 int main(void) {
 921        int fd[2];
 922        return (socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1;
 923 }]])],[rsync_cv_HAVE_SOCKETPAIR=yes],[rsync_cv_HAVE_SOCKETPAIR=no],[rsync_cv_HAVE_SOCKETPAIR=cross])])
 924 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 925     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
 926 fi
 927
 928 AC_REPLACE_FUNCS([getpass])
 929
 930 if test x"$with_included_popt" != x"yes"; then
 931     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 932 fi
 933 if test x"$ac_cv_header_popt_popt_h" = x"yes"; then
 934     # If the system has /usr/include/popt/popt.h, we enable the
 935     # included popt because an attempt to "#include <popt/popt.h>"
 936     # would use our included header file anyway (due to -I.), and
 937     # might conflict with the system popt.
 938     with_included_popt=yes
 939 elif test x"$ac_cv_header_popt_h" != x"yes"; then
 940     with_included_popt=yes
 941 fi
 942
 943 AC_MSG_CHECKING([whether to use included libpopt])
 944 if test x"$with_included_popt" = x"yes"; then
 945     AC_MSG_RESULT($srcdir/popt)
 946     BUILD_POPT='$(popt_OBJS)'
 947     CFLAGS="-I$srcdir/popt $CFLAGS"
 948     if test x"$ALLOCA" != x
 949     then
 950         # this can be removed when/if we add an included alloca.c;
 951         #  see autoconf documentation on AC_FUNC_ALLOCA
 952         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
 953     fi
 954 else
 955     AC_MSG_RESULT(no)
 956 fi
 957
 958 # We default to using our zlib unless --with-included-zlib=no is given.
 959 if test x"$with_included_zlib" != x"no"; then
 960     with_included_zlib=yes
 961 elif test x"$ac_cv_header_zlib_h" != x"yes"; then
 962     with_included_zlib=yes
 963 fi
 964 if test x"$with_included_zlib" != x"yes"; then
 965     AC_CHECK_LIB(z, deflateParams, , [with_included_zlib=yes])
 966 fi
 967
 968 AC_MSG_CHECKING([whether to use included zlib])
 969 if test x"$with_included_zlib" = x"yes"; then
 970     AC_MSG_RESULT($srcdir/zlib)
 971     BUILD_ZLIB='$(zlib_OBJS)'
 972     CFLAGS="-I$srcdir/zlib $CFLAGS"
 973 else
 974     AC_DEFINE(EXTERNAL_ZLIB, 1, [Define to 1 if using external zlib])
 975     AC_MSG_RESULT(no)
 976 fi
 977
 978 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
 979 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[signed char *s = ""]])],[rsync_cv_SIGNED_CHAR_OK=yes],[rsync_cv_SIGNED_CHAR_OK=no])])
 980 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
 981     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
 982 fi
 983
 984 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
 985 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <sys/types.h>
 986 #include <dirent.h>
 987 int main(void) { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 988 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 989 di->d_name[0] == 0) return 0; return 1;} ]])],[rsync_cv_HAVE_BROKEN_READDIR=yes],[rsync_cv_HAVE_BROKEN_READDIR=no],[rsync_cv_HAVE_BROKEN_READDIR=cross])])
 990 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 991     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
 992 fi
 993
 994 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
 995 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 996 #include <utime.h>]], [[struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; return utime("foo.c",&tbuf);]])],[rsync_cv_HAVE_STRUCT_UTIMBUF=yes],[rsync_cv_HAVE_STRUCT_UTIMBUF=no])])
 997 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
 998     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
 999 fi
1000
1001 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
1002 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/time.h>
1003 #include <unistd.h>]], [[struct timeval tv; return gettimeofday(&tv, NULL);]])],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=no])])
1004 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
1005     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
1006 fi
1007
1008 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
1009 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1010 #include <sys/types.h>
1011 #include <stdarg.h>
1012 #include <stdio.h>
1013 #include <stdlib.h>
1014 #include <string.h>
1015 void foo(const char *format, ...) {
1016        va_list ap;
1017        int len;
1018        static char buf[] = "12345678901234567890";
1019
1020        va_start(ap, format);
1021        len = vsnprintf(0, 0, format, ap);
1022        va_end(ap);
1023        if (len != 5) exit(1);
1024
1025        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
1026 }
1027 int main(void) { foo("hello"); return 0; }
1028 ]])],[rsync_cv_HAVE_C99_VSNPRINTF=yes],[rsync_cv_HAVE_C99_VSNPRINTF=no],[rsync_cv_HAVE_C99_VSNPRINTF=cross])])
1029 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
1030     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
1031 fi
1032
1033
1034 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
1035 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1036 #include <sys/types.h>
1037 #include <sys/stat.h>
1038 #include <unistd.h>
1039 int main(void) {
1040   struct stat st;
1041   char tpl[20]="/tmp/test.XXXXXX";
1042   int fd = mkstemp(tpl);
1043   if (fd == -1) return 1;
1044   unlink(tpl);
1045   if (fstat(fd, &st) != 0) return 1;
1046   if ((st.st_mode & 0777) != 0600) return 1;
1047   return 0;
1048 }]])],[rsync_cv_HAVE_SECURE_MKSTEMP=yes],[rsync_cv_HAVE_SECURE_MKSTEMP=no],[rsync_cv_HAVE_SECURE_MKSTEMP=cross])])
1049 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
1050     case $host_os in
1051     hpux*)
1052         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
1053         dnl so we noisily skip using it.  See HP change request JAGaf34426
1054         dnl for details. (sbonds)
1055         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
1056         ;;
1057     *)
1058         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
1059         ;;
1060     esac
1061 fi
1062
1063
1064 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
1065 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1066 #include <stdio.h>
1067 #include <sys/stat.h>
1068 #include <errno.h>
1069 #if HAVE_UNISTD_H
1070 # include <unistd.h>
1071 #endif
1072 int main(void) { int rc, ec; char *fn = "fifo-test";
1073 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
1074 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1075 return 0;}]])],[rsync_cv_MKNOD_CREATES_FIFOS=yes],[rsync_cv_MKNOD_CREATES_FIFOS=no],[rsync_cv_MKNOD_CREATES_FIFOS=cross])])
1076 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
1077     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
1078 fi
1079
1080 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
1081 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1082 #include <stdio.h>
1083 #include <sys/stat.h>
1084 #include <errno.h>
1085 #if HAVE_UNISTD_H
1086 # include <unistd.h>
1087 #endif
1088 int main(void) { int rc, ec; char *fn = "sock-test";
1089 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
1090 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1091 return 0;}]])],[rsync_cv_MKNOD_CREATES_SOCKETS=yes],[rsync_cv_MKNOD_CREATES_SOCKETS=no],[rsync_cv_MKNOD_CREATES_SOCKETS=cross])])
1092 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
1093     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
1094 fi
1095
1096 #
1097 # The following test was mostly taken from the tcl/tk plus patches
1098 #
1099 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
1100 rm -rf conftest*
1101 cat > conftest.$ac_ext <<EOF
1102 int main(void) { return 0; }
1103 EOF
1104 ${CC-cc} -c -o conftest..o conftest.$ac_ext
1105 if test -f conftest..o; then
1106     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
1107 else
1108     rsync_cv_DASHC_WORKS_WITH_DASHO=no
1109 fi
1110 rm -rf conftest*
1111 ])
1112 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
1113     OBJ_SAVE="#"
1114     OBJ_RESTORE="#"
1115     CC_SHOBJ_FLAG='-o $@'
1116 else
1117     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
1118     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
1119     CC_SHOBJ_FLAG=""
1120 fi
1121
1122 AC_SUBST(OBJ_SAVE)
1123 AC_SUBST(OBJ_RESTORE)
1124 AC_SUBST(CC_SHOBJ_FLAG)
1125 AC_SUBST(BUILD_POPT)
1126 AC_SUBST(BUILD_ZLIB)
1127 AC_SUBST(MAKE_MAN)
1128
1129 AC_CHECK_FUNCS(_acl __acl _facl __facl)
1130 #################################################
1131 # check for ACL support
1132
1133 AC_MSG_CHECKING([whether to support ACLs])
1134 AC_ARG_ENABLE(acl-support,
1135         AS_HELP_STRING([--disable-acl-support],[disable ACL support]))
1136
1137 if test x"$enable_acl_support" = x"no"; then
1138     AC_MSG_RESULT(no)
1139 else
1140     case "$host_os" in
1141     *sysv5*)
1142         AC_MSG_RESULT(Using UnixWare ACLs)
1143         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
1144         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
1145         ;;
1146     solaris*)
1147         AC_MSG_RESULT(Using solaris ACLs)
1148         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
1149         AC_DEFINE(SUPPORT_ACLS, 1)
1150         ;;
1151     *hpux*)
1152         AC_MSG_RESULT(Using HPUX ACLs)
1153         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
1154         AC_DEFINE(SUPPORT_ACLS, 1)
1155         ;;
1156     *irix*)
1157         AC_MSG_RESULT(Using IRIX ACLs)
1158         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
1159         AC_DEFINE(SUPPORT_ACLS, 1)
1160         ;;
1161     *aix*)
1162         AC_MSG_RESULT(Using AIX ACLs)
1163         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
1164         AC_DEFINE(SUPPORT_ACLS, 1)
1165         ;;
1166     *osf*)
1167         AC_MSG_RESULT(Using Tru64 ACLs)
1168         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
1169         AC_DEFINE(SUPPORT_ACLS, 1)
1170         LIBS="$LIBS -lpacl"
1171         ;;
1172     darwin*)
1173         AC_MSG_RESULT(Using OS X ACLs)
1174         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
1175         AC_DEFINE(SUPPORT_ACLS, 1)
1176         ;;
1177     *)
1178         AC_MSG_RESULT(running tests:)
1179         AC_CHECK_LIB(acl,acl_get_file)
1180         AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
1181             AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1182 #include <sys/acl.h>]], [[ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);]])],[samba_cv_HAVE_POSIX_ACLS=yes],[samba_cv_HAVE_POSIX_ACLS=no])])
1183         AC_MSG_CHECKING(ACL test results)
1184         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
1185             AC_MSG_RESULT(Using posix ACLs)
1186             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
1187             AC_DEFINE(SUPPORT_ACLS, 1)
1188             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
1189                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1190 #include <sys/acl.h>]], [[ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);]])],[samba_cv_HAVE_ACL_GET_PERM_NP=yes],[samba_cv_HAVE_ACL_GET_PERM_NP=no])])
1191             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
1192                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
1193             fi
1194         else
1195             if test x"$enable_acl_support" = x"yes"; then
1196                 AC_MSG_ERROR(Failed to find ACL support)
1197             else
1198                 AC_MSG_RESULT(No ACL support found)
1199             fi
1200         fi
1201         ;;
1202     esac
1203 fi
1204
1205 #################################################
1206 # check for extended attribute support
1207 AC_MSG_CHECKING(whether to support extended attributes)
1208 AC_ARG_ENABLE(xattr-support,
1209     AS_HELP_STRING([--disable-xattr-support],[disable extended attributes]),
1210     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link$ac_cv_func_attropen" in
1211         *yes*) enable_xattr_support=maybe ;;
1212         *) enable_xattr_support=no ;;
1213         esac])
1214 AH_TEMPLATE([SUPPORT_XATTRS],
1215 [Define to 1 to add support for extended attributes])
1216 if test x"$enable_xattr_support" = x"no"; then
1217     AC_MSG_RESULT(no)
1218 else
1219     case "$host_os" in
1220     *linux*|*netbsd*)
1221         AC_MSG_RESULT(Using Linux xattrs)
1222         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs (or equivalent)])
1223         AC_DEFINE(SUPPORT_XATTRS, 1)
1224         AC_DEFINE(NO_SYMLINK_USER_XATTRS, 1, [True if symlinks do not support user xattrs])
1225         AC_CHECK_LIB(attr,getxattr)
1226         ;;
1227     darwin*)
1228         AC_MSG_RESULT(Using OS X xattrs)
1229         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
1230         AC_DEFINE(SUPPORT_XATTRS, 1)
1231         AC_DEFINE(NO_DEVICE_XATTRS, 1, [True if device files do not support xattrs])
1232         AC_DEFINE(NO_SPECIAL_XATTRS, 1, [True if special files do not support xattrs])
1233         ;;
1234     freebsd*)
1235         AC_MSG_RESULT(Using FreeBSD extattrs)
1236         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
1237         AC_DEFINE(SUPPORT_XATTRS, 1)
1238         ;;
1239     solaris*)
1240         AC_MSG_RESULT(Using Solaris xattrs)
1241         AC_DEFINE(HAVE_SOLARIS_XATTRS, 1, [True if you have Solaris xattrs])
1242         AC_DEFINE(SUPPORT_XATTRS, 1)
1243         AC_DEFINE(NO_SYMLINK_XATTRS, 1, [True if symlinks do not support xattrs])
1244         ;;
1245     *)
1246         if test x"$enable_xattr_support" = x"yes"; then
1247             AC_MSG_ERROR(Failed to find extended attribute support)
1248         else
1249             AC_MSG_RESULT(No extended attribute support found)
1250         fi
1251         ;;
1252     esac
1253 fi
1254
1255 if test x"$enable_acl_support" = x"no" -o x"$enable_xattr_support" = x"no" -o x"$enable_iconv" = x"no"; then
1256     AC_MSG_CHECKING([whether $CC supports -Wno-unused-parameter])
1257     OLD_CFLAGS="$CFLAGS"
1258     CFLAGS="$CFLAGS -Wno-unused-parameter"
1259     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]], [[printf("hello\n");]])],[rsync_warn_flag=yes],[rsync_warn_flag=no])
1260     AC_MSG_RESULT([$rsync_warn_flag])
1261     if test x"$rsync_warn_flag" = x"no"; then
1262         CFLAGS="$OLD_CFLAGS"
1263     fi
1264 fi
1265
1266 case "$CC" in
1267 ' checker'*|checker*)
1268     AC_DEFINE(FORCE_FD_ZERO_MEMSET, 1, [Used to make "checker" understand that FD_ZERO() clears memory.])
1269     ;;
1270 esac
1271
1272 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
1273 AC_OUTPUT
1274
1275 AC_MSG_RESULT()
1276 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
1277 AC_MSG_RESULT()