configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Revision$)
   3 AC_PREREQ([2.59])
   4 test -z "$CFLAGS" && CFLAGS="-g"
   5 AC_INIT([Heimdal],[0.9rc4],[heimdal-bugs@h5l.se])
   6 AC_CONFIG_SRCDIR([kuser/kinit.c])
   7 AC_CONFIG_HEADERS(include/config.h)
   8
   9 AM_INIT_AUTOMAKE([foreign no-dependencies 1.8])
  10 AM_MAINTAINER_MODE
  11
  12 dnl Checks for programs.
  13 AC_PROG_CC
  14 AM_PROG_CC_C_O
  15 AC_PROG_CPP
  16
  17 AC_PREFIX_DEFAULT(/usr/heimdal)
  18
  19 test "$sysconfdir" = '${prefix}/etc' && sysconfdir='/etc'
  20 test "$localstatedir" = '${prefix}/var' && localstatedir='/var/heimdal'
  21
  22 AC_CANONICAL_HOST
  23 CANONICAL_HOST=$host
  24 AC_SUBST(CANONICAL_HOST)
  25
  26 dnl Hints for autobuild
  27 AB_INIT
  28
  29 rk_SYS_LARGEFILE
  30
  31 dnl
  32 dnl this is needed to run the configure tests against glibc
  33 dnl
  34 AC_DEFINE([_GNU_SOURCE], 1,
  35         [Define to enable extensions on glibc-based systems such as Linux.])
  36
  37 AC_OBJEXT
  38 AC_EXEEXT
  39
  40 dnl AC_KRB_PROG_YACC
  41 AC_PROG_YACC
  42 AM_PROG_LEX
  43 dnl AC_PROG_RANLIB
  44 AC_PROG_AWK
  45 AC_KRB_PROG_LN_S
  46
  47 AC_MIPS_ABI
  48 CC="$CC $abi"
  49 libdir="$libdir$abilibdirext"
  50
  51 AC_C___ATTRIBUTE__
  52
  53 AC_PROG_LIBTOOL
  54
  55 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = "yes")
  56 rk_VERSIONSCRIPT
  57
  58 rk_TEST_PACKAGE(openldap,
  59 [#include <lber.h>
  60 #include <ldap.h>],
  61 [-lldap -llber],,,OPENLDAP)
  62
  63 AC_ARG_ENABLE(hdb-openldap-module,
  64         AS_HELP_STRING([--enable-hdb-openldap-module],
  65                 [if you want support to build openldap hdb as shared object]))
  66 if test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes; then
  67     AC_DEFINE(OPENLDAP_MODULE, 1, [Define if you want support for hdb ldap module])
  68 fi
  69 AM_CONDITIONAL(OPENLDAP_MODULE, test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes)
  70
  71 AC_ARG_ENABLE(pk-init,
  72         AS_HELP_STRING([--disable-pk-init],
  73                 [if you want disable to PK-INIT support]))
  74 if test "$enable_pk_init" != no ;then
  75         AC_DEFINE([PKINIT], 1, [Define to enable PKINIT.])
  76 fi
  77 AM_CONDITIONAL(PKINIT, test "$enable_pk_init" != no)
  78
  79
  80 dnl no kerberos4 any more
  81 with_krb4=no
  82 AC_SUBST(INCLUDE_krb4)
  83 AC_SUBST(LIB_krb4)
  84 AM_CONDITIONAL(KRB4, false)
  85
  86 AM_CONDITIONAL(KRB5, true)
  87 AM_CONDITIONAL(do_roken_rename, true)
  88
  89 AC_DEFINE(KRB5, 1, [Enable Kerberos 5 support in applications.])dnl
  90 AC_SUBST(LIB_kdb)dnl
  91
  92 KRB_CRYPTO
  93
  94 KRB_PTHREADS
  95
  96 AC_ARG_ENABLE(dce,
  97         AS_HELP_STRING([--enable-dce],[if you want support for DCE/DFS PAG's]))
  98 if test "$enable_dce" = yes; then
  99     AC_DEFINE(DCE, 1, [Define if you want support for DCE/DFS PAG's.])
 100 fi
 101 AM_CONDITIONAL(DCE, test "$enable_dce" = yes)
 102
 103 ## XXX quite horrible:
 104 if test -f /etc/ibmcxx.cfg; then
 105         dpagaix_ldadd=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/libraries/{;s/^[[^=]]*=\(.*\)/\1/;s/,/ /gp;}'`
 106         dpagaix_cflags=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/options/{;s/^[[^=]]*=\(.*\)/\1/;s/-q[^,]*//;s/,/ /gp;}'`
 107         dpagaix_ldflags=
 108 else
 109         dpagaix_cflags="-D_THREAD_SAFE -D_AIX_PTHREADS_D7 -D_AIX32_THREADS=1 -D_AES_SOURCE -D_AIX41 -I/usr/include/dce"
 110         dpagaix_ldadd="-L/usr/lib/threads -ldcelibc_r -ldcepthreads -lpthreads_compat lpthreads -lc_r"
 111         dpagaix_ldflags="-Wl,-bI:dfspag.exp"
 112 fi
 113 AC_SUBST(dpagaix_cflags)
 114 AC_SUBST(dpagaix_ldadd)
 115 AC_SUBST(dpagaix_ldflags)
 116
 117 AC_ARG_ENABLE([afs-support],
 118         AC_HELP_STRING([--disable-afs-support],
 119                 [if you don't want support for AFS]))
 120 if test "$enable_afs_support" = no; then
 121         AC_DEFINE(NO_AFS, 1, [Define if you don't wan't support for AFS.])
 122 fi
 123
 124 rk_DB
 125
 126 dnl AC_ROKEN(10,[/usr/heimdal /usr/athena],[lib/roken],[$(top_builddir)/lib/roken/libroken.la],[-I$(top_builddir)/lib/roken -I$(top_srcdir)/lib/roken])
 127
 128 rk_ROKEN(lib/roken)
 129 LIBADD_roken="$LIB_roken"
 130 AC_SUBST(LIBADD_roken)dnl
 131 LIB_roken="\$(top_builddir)/lib/vers/libvers.la $LIB_roken"
 132
 133 rk_OTP
 134
 135 AC_CHECK_OSFC2
 136
 137 AC_ARG_ENABLE(mmap,
 138         AS_HELP_STRING([--disable-mmap],[disable use of mmap]))
 139 if test "$enable_mmap" = "no"; then
 140         AC_DEFINE(NO_MMAP, 1, [Define if you don't want to use mmap.])
 141 fi
 142
 143 AC_ARG_ENABLE(afs-string-to-key,
 144         AS_HELP_STRING([--disable-afs-string-to-key],
 145         [disable use of weak AFS string-to-key functions]),
 146         [], [enable_afs_string_to_key=yes])
 147
 148 if test "$enable_afs_string_to_key" = "yes"; then
 149         AC_DEFINE(ENABLE_AFS_STRING_TO_KEY, 1, [Define if want to use the weak AFS string to key functions.])
 150 fi
 151
 152
 153 rk_CHECK_MAN
 154
 155 rk_TEST_PACKAGE(readline,
 156 [#include <stdio.h>
 157  #include <readline.h>],-lreadline,,, READLINE)
 158
 159 rk_TEST_PACKAGE(hesiod,[#include <hesiod.h>],-lhesiod,,, HESIOD)
 160
 161 KRB_C_BIGENDIAN
 162 AC_C_INLINE
 163
 164 rk_AIX
 165 rk_IRIX
 166 rk_SUNOS
 167
 168 KRB_CHECK_X
 169
 170 AM_CONDITIONAL(HAVE_X, test "$no_x" != yes)
 171
 172 AC_CHECK_XAU
 173
 174 dnl AM_C_PROTOTYPES
 175
 176 dnl Checks for typedefs, structures, and compiler characteristics.
 177 AC_C_CONST
 178 AC_TYPE_OFF_T
 179 AC_CHECK_TYPE_EXTRA(mode_t, unsigned short, [])
 180 AC_CHECK_TYPE_EXTRA(sig_atomic_t, int, [#include <signal.h>])
 181 AC_HAVE_TYPE([long long])
 182 AC_HEADER_TIME
 183 AC_STRUCT_TM
 184
 185 dnl Checks for header files.
 186 AC_HEADER_STDC
 187
 188 AC_CHECK_HEADERS([\
 189         arpa/ftp.h                              \
 190         arpa/telnet.h                           \
 191         bind/bitypes.h                          \
 192         bsdsetjmp.h                             \
 193         curses.h                                \
 194         dlfcn.h                                 \
 195         fnmatch.h                               \
 196         inttypes.h                              \
 197         io.h                                    \
 198         libutil.h                               \
 199         limits.h                                \
 200         maillock.h                              \
 201         netgroup.h                              \
 202         netinet/in6_machtypes.h                 \
 203         netinfo/ni.h                            \
 204         pthread.h                               \
 205         pty.h                                   \
 206         sac.h                                   \
 207         sgtty.h                                 \
 208         siad.h                                  \
 209         signal.h                                \
 210         strings.h                               \
 211         stropts.h                               \
 212         sys/bitypes.h                           \
 213         sys/category.h                          \
 214         sys/file.h                              \
 215         sys/filio.h                             \
 216         sys/ioccom.h                            \
 217         sys/mman.h                              \
 218         sys/param.h                             \
 219         sys/pty.h                               \
 220         sys/ptyio.h                             \
 221         sys/select.h                            \
 222         sys/socket.h                            \
 223         sys/str_tty.h                           \
 224         sys/stream.h                            \
 225         sys/stropts.h                           \
 226         sys/syscall.h                           \
 227         sys/termio.h                            \
 228         sys/timeb.h                             \
 229         sys/times.h                             \
 230         sys/types.h                             \
 231         sys/un.h                                \
 232         termcap.h                               \
 233         termio.h                                \
 234         termios.h                               \
 235         time.h                                  \
 236         tmpdir.h                                \
 237         udb.h                                   \
 238         util.h                                  \
 239         utmp.h                                  \
 240         utmpx.h                                 \
 241 ])
 242
 243 dnl On Solaris 8 there's a compilation warning for term.h because
 244 dnl it doesn't define `bool'.
 245 AC_CHECK_HEADERS(term.h, , , -)
 246
 247 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
 248 #if HAVE_SYS_SOCKET_H
 249 #include <sys/socket.h>
 250 #endif])
 251
 252 AC_CHECK_HEADERS(sys/ptyvar.h, , , [AC_INCLUDES_DEFAULT
 253 #if HAVE_SYS_TTY_H
 254 #include <sys/tty.h>
 255 #endif])
 256
 257 AC_CHECK_HEADERS(sys/strtty.h, , , [AC_INCLUDES_DEFAULT
 258 #if HAVE_TERMIOS_H
 259 #include <termios.h>
 260 #endif
 261 #if HAVE_SYS_STREAM_H
 262 #include <sys/stream.h>
 263 #endif])
 264
 265 AC_CHECK_HEADERS(sys/ucred.h, , , [AC_INCLUDES_DEFAULT
 266 #if HAVE_SYS_TYPES_H
 267 #include <sys/types.h>
 268 #endif
 269 #if HAVE_SYS_PARAM_H
 270 #include <sys/param.h>
 271 #endif])
 272
 273 AC_CHECK_HEADERS(security/pam_modules.h, , , [AC_INCLUDES_DEFAULT
 274 #include <security/pam_appl.h>
 275 ])
 276
 277 AC_ARG_ENABLE(netinfo,
 278         AS_HELP_STRING([--enable-netinfo],[enable netinfo for configuration lookup]))
 279
 280 if test "$ac_cv_header_netinfo_ni_h" = yes -a "$enable_netinfo" = yes; then
 281        AC_DEFINE(HAVE_NETINFO, 1,
 282                [Define if you want to use Netinfo instead of krb5.conf.])
 283 fi
 284
 285 dnl export symbols
 286 rk_WIN32_EXPORT(BUILD_KRB5_LIB, KRB5_LIB_FUNCTION)
 287 rk_WIN32_EXPORT(BUILD_ROKEN_LIB, ROKEN_LIB_FUNCTION)
 288
 289 dnl Checks for libraries.
 290
 291 AC_FIND_FUNC_NO_LIBS(logwtmp, util,[
 292 #ifdef HAVE_UTIL_H
 293 #include <util.h>
 294 #endif
 295 ],[0,0,0])
 296 AC_FIND_FUNC_NO_LIBS(logout, util,[
 297 #ifdef HAVE_UTIL_H
 298 #include <util.h>
 299 #endif
 300 ],[0])
 301 AC_FIND_FUNC_NO_LIBS(openpty, util,[
 302 #ifdef HAVE_UTIL_H
 303 #include <util.h>
 304 #endif
 305 ],[0,0,0,0,0])
 306
 307 AC_FIND_FUNC_NO_LIBS(tgetent, termcap ncurses curses,[
 308 #ifdef HAVE_TERMCAP_H
 309 #include <termcap.h>
 310 #endif
 311 #ifdef HAVE_CURSES_H
 312 #include <curses.h>
 313 #endif
 314 ],[0,0])
 315
 316 dnl Checks for library functions.
 317
 318 AC_CHECK_FUNCS([                                \
 319         _getpty                                 \
 320         _scrsize                                \
 321         arc4random                              \
 322         fcntl                                   \
 323         getpeereid                              \
 324         getpeerucred                            \
 325         grantpt                                 \
 326         mktime                                  \
 327         ptsname                                 \
 328         rand                                    \
 329         revoke                                  \
 330         select                                  \
 331         setitimer                               \
 332         setpcred                                \
 333         setpgid                                 \
 334         setproctitle                            \
 335         setregid                                \
 336         setresgid                               \
 337         setresuid                               \
 338         setreuid                                \
 339         setsid                                  \
 340         setutent                                \
 341         sigaction                               \
 342         strstr                                  \
 343         ttyname                                 \
 344         ttyslot                                 \
 345         umask                                   \
 346         unlockpt                                \
 347         vhangup                                 \
 348         yp_get_default_domain                   \
 349 ])
 350
 351 AC_FUNC_MMAP
 352
 353 KRB_CAPABILITIES
 354
 355 AC_CHECK_GETPWNAM_R_POSIX
 356
 357 dnl detect doors on solaris
 358 if test "$enable_pthread_support" != no; then
 359    saved_LIBS="$LIBS"
 360    LIBS="$LIBS $PTHREADS_LIBS"
 361    AC_FIND_FUNC_NO_LIBS(door_create, door)
 362    LIBS="$saved_LIBS"
 363 fi
 364
 365 AC_ARG_ENABLE(kcm,
 366         AS_HELP_STRING([--enable-kcm],[enable Kerberos Credentials Manager]),
 367 ,[enable_kcm=yes])
 368
 369 if test "$enable_kcm" = yes ; then
 370    if test  "$ac_cv_header_sys_un_h" != yes -a "$ac_cv_funclib_door_create" != yes ; then
 371         enable_kcm=no
 372    fi
 373 fi
 374 if test "$enable_kcm" = yes; then
 375        AC_DEFINE(HAVE_KCM, 1,
 376                [Define if you want to use the Kerberos Credentials Manager.])
 377 fi
 378 AM_CONDITIONAL(KCM, test "$enable_kcm" = yes)
 379
 380
 381
 382 dnl Cray stuff
 383 AC_CHECK_FUNCS(getudbnam setlim)
 384
 385 dnl AC_KRB_FUNC_GETCWD_BROKEN
 386
 387 dnl
 388 dnl Check for fields in struct utmp
 389 dnl
 390
 391 AC_HAVE_STRUCT_FIELD(struct utmp, ut_addr, [#include <utmp.h>])
 392 AC_HAVE_STRUCT_FIELD(struct utmp, ut_host, [#include <utmp.h>])
 393 AC_HAVE_STRUCT_FIELD(struct utmp, ut_id, [#include <utmp.h>])
 394 AC_HAVE_STRUCT_FIELD(struct utmp, ut_pid, [#include <utmp.h>])
 395 AC_HAVE_STRUCT_FIELD(struct utmp, ut_type, [#include <utmp.h>])
 396 AC_HAVE_STRUCT_FIELD(struct utmp, ut_user, [#include <utmp.h>])
 397 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_exit, [#include <utmpx.h>])
 398 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_syslen, [#include <utmpx.h>])
 399
 400 AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t,
 401         u_int8_t, u_int16_t, u_int32_t, u_int64_t,
 402         uint8_t, uint16_t, uint32_t, uint64_t],,,[
 403 #ifdef HAVE_INTTYPES_H
 404 #include <inttypes.h>
 405 #endif
 406 #ifdef HAVE_SYS_TYPES_H
 407 #include <sys/types.h>
 408 #endif
 409 #ifdef HAVE_SYS_BITYPES_H
 410 #include <sys/bitypes.h>
 411 #endif
 412 #ifdef HAVE_BIND_BITYPES_H
 413 #include <bind/bitypes.h>
 414 #endif
 415 #ifdef HAVE_NETINET_IN6_MACHTYPES_H
 416 #include <netinet/in6_machtypes.h>
 417 #endif
 418 ])
 419
 420 rk_FRAMEWORK_SECURITY
 421
 422 KRB_READLINE
 423
 424 rk_TELNET
 425
 426 dnl Some operating systems already have com_err and compile_et
 427 CHECK_COMPILE_ET
 428
 429 rk_AUTH_MODULES([sia afskauthlib])
 430
 431 rk_DESTDIRS
 432
 433 rk_WFLAGS([-Wall -Wmissing-prototypes -Wpointer-arith -Wbad-function-cast -Wmissing-declarations -Wnested-externs])
 434
 435
 436 AH_BOTTOM([#ifdef ROKEN_RENAME
 437 #include "roken_rename.h"
 438 #endif])
 439
 440 AC_CONFIG_FILES(Makefile                \
 441         etc/Makefile                    \
 442         include/Makefile                \
 443         include/gssapi/Makefile         \
 444         include/hcrypto/Makefile        \
 445         include/kadm5/Makefile          \
 446         lib/Makefile                    \
 447         lib/45/Makefile                 \
 448         lib/auth/Makefile               \
 449         lib/auth/afskauthlib/Makefile   \
 450         lib/auth/pam/Makefile           \
 451         lib/auth/sia/Makefile           \
 452         lib/asn1/Makefile               \
 453         lib/com_err/Makefile            \
 454         lib/hcrypto/Makefile            \
 455         lib/editline/Makefile           \
 456         lib/hx509/Makefile              \
 457         lib/gssapi/Makefile             \
 458         lib/ntlm/Makefile               \
 459         lib/hdb/Makefile                \
 460         lib/kadm5/Makefile              \
 461         lib/kafs/Makefile               \
 462         lib/kdfs/Makefile               \
 463         lib/krb5/Makefile               \
 464         lib/otp/Makefile                \
 465         lib/roken/Makefile              \
 466         lib/sl/Makefile                 \
 467         lib/vers/Makefile               \
 468         kuser/Makefile                  \
 469         kpasswd/Makefile                \
 470         kadmin/Makefile                 \
 471         admin/Makefile                  \
 472         kcm/Makefile                    \
 473         kdc/Makefile                    \
 474         appl/Makefile                   \
 475         appl/afsutil/Makefile           \
 476         appl/ftp/Makefile               \
 477         appl/ftp/common/Makefile        \
 478         appl/ftp/ftp/Makefile           \
 479         appl/ftp/ftpd/Makefile          \
 480         appl/gssmask/Makefile           \
 481         appl/kx/Makefile                \
 482         appl/login/Makefile             \
 483         appl/otp/Makefile               \
 484         appl/popper/Makefile            \
 485         appl/push/Makefile              \
 486         appl/rsh/Makefile               \
 487         appl/rcp/Makefile               \
 488         appl/su/Makefile                \
 489         appl/xnlock/Makefile            \
 490         appl/telnet/Makefile            \
 491         appl/telnet/libtelnet/Makefile  \
 492         appl/telnet/telnet/Makefile     \
 493         appl/telnet/telnetd/Makefile    \
 494         appl/test/Makefile              \
 495         appl/kf/Makefile                \
 496         appl/dceutils/Makefile          \
 497         tests/Makefile                  \
 498         tests/can/Makefile              \
 499         tests/db/Makefile               \
 500         tests/kdc/Makefile              \
 501         tests/ldap/Makefile             \
 502         tests/gss/Makefile              \
 503         tests/java/Makefile             \
 504         tests/plugin/Makefile           \
 505         packages/Makefile               \
 506         packages/mac/Makefile           \
 507         doc/Makefile                    \
 508         tools/Makefile                  \
 509 )
 510
 511 AC_OUTPUT
 512
 513 dnl
 514 dnl This is the release version name-number[beta]
 515 dnl
 516
 517 cat > include/newversion.h.in <<EOF
 518 const char *heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ ($host) @DATE@ \$";
 519 const char *heimdal_version = "AC_PACKAGE_STRING";
 520 EOF
 521
 522 if test -f include/version.h && cmp -s include/newversion.h.in include/version.h.in; then
 523         echo "include/version.h is unchanged"
 524         rm -f include/newversion.h.in
 525 else
 526         echo "creating include/version.h"
 527         User=${USER-${LOGNAME}}
 528         Host=`(hostname || uname -n || echo unknown) 2>/dev/null | sed 1q`
 529         Date=`date`
 530         mv -f include/newversion.h.in include/version.h.in
 531         sed -e "s/@USER@/$User/" -e "s/@HOST@/$Host/" -e "s/@DATE@/$Date/" include/version.h.in > include/version.h
 532 fi