configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Revision$)
   3 AC_PREREQ(2.62)
   4 test -z "$CFLAGS" && CFLAGS="-g"
   5 AC_INIT([Heimdal],[1.2.99],[heimdal-bugs@h5l.org])
   6 AC_CONFIG_SRCDIR([kuser/kinit.c])
   7 AC_CONFIG_HEADERS(include/config.h)
   8 AC_CONFIG_MACRO_DIR([cf])
   9
  10 AM_INIT_AUTOMAKE([foreign 1.10])
  11 AM_MAINTAINER_MODE
  12
  13 dnl Checks for programs.
  14 AC_PROG_CC
  15 AM_PROG_CC_C_O
  16 AC_PROG_CPP
  17
  18 AC_PREFIX_DEFAULT(/usr/heimdal)
  19
  20 test "$sysconfdir" = '${prefix}/etc' && sysconfdir='/etc'
  21 test "$localstatedir" = '${prefix}/var' && localstatedir='/var/heimdal'
  22
  23 AC_CANONICAL_HOST
  24 CANONICAL_HOST=$host
  25 AC_SUBST(CANONICAL_HOST)
  26
  27 dnl Hints for autobuild
  28 AB_INIT
  29
  30 rk_SYS_LARGEFILE
  31
  32 dnl
  33 dnl this is needed to run the configure tests against glibc
  34 dnl
  35 AC_DEFINE([_GNU_SOURCE], 1,
  36         [Define to enable extensions on glibc-based systems such as Linux.])
  37
  38 AC_OBJEXT
  39 AC_EXEEXT
  40
  41 dnl AC_KRB_PROG_YACC
  42 AC_PROG_YACC
  43 AM_PROG_LEX
  44 dnl AC_PROG_RANLIB
  45 AC_PROG_AWK
  46 AC_KRB_PROG_LN_S
  47
  48 AC_MIPS_ABI
  49 CC="$CC $abi"
  50 libdir="$libdir$abilibdirext"
  51
  52 AC_C___ATTRIBUTE__
  53
  54 LT_PREREQ([2.2])
  55 LT_INIT([shared static win32-dll])
  56
  57 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = "yes")
  58 rk_VERSIONSCRIPT
  59
  60 rk_TEST_PACKAGE(openldap,
  61 [#include <lber.h>
  62 #include <ldap.h>],
  63 [-lldap -llber],,,OPENLDAP)
  64
  65 AC_ARG_ENABLE(hdb-openldap-module,
  66         AS_HELP_STRING([--enable-hdb-openldap-module],
  67                 [if you want support to build openldap hdb as shared object]))
  68 if test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes; then
  69     AC_DEFINE(OPENLDAP_MODULE, 1, [Define if you want support for hdb ldap module])
  70 fi
  71 AM_CONDITIONAL(OPENLDAP_MODULE, test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes)
  72
  73 AC_ARG_ENABLE(pk-init,
  74         AS_HELP_STRING([--disable-pk-init],
  75                 [if you want disable to PK-INIT support]))
  76 if test "$enable_pk_init" != no ;then
  77         AC_DEFINE([PKINIT], 1, [Define to enable PKINIT.])
  78 fi
  79 AM_CONDITIONAL(PKINIT, test "$enable_pk_init" != no)
  80
  81 dnl Check for sqlite
  82 rk_TEST_PACKAGE(sqlite3,
  83 [#include <sqlite3.h>],
  84 [-lsqlite3],,,SQLITE3)
  85
  86 if test "X$with_sqlite3" != Xyes ; then
  87    INCLUDE_sqlite3="-I\$(top_srcdir)/lib/sqlite"
  88    LIB_sqlite3="\$(top_builddir)/lib/sqlite/libsqlite.la"
  89 fi
  90 AM_CONDITIONAL(SQLITE3,  test "X$with_sqlite3" = Xyes)
  91
  92 dnl path where the hdb directory is stored
  93 AC_ARG_WITH([hdbdir],
  94         [AS_HELP_STRING([--with-hdbdir],[Default location for KDC database @<:@default=/var/heimdal@:>@])],
  95         [],
  96         [with_hdbdir=/var/heimdal])
  97 DIR_hdbdir="$with_hdbdir"
  98 AC_SUBST([DIR_hdbdir])
  99
 100
 101 dnl no kerberos4 any more
 102 with_krb4=no
 103 AC_SUBST(INCLUDE_krb4)
 104 AC_SUBST(LIB_krb4)
 105 AM_CONDITIONAL(KRB4, false)
 106
 107 AM_CONDITIONAL(KRB5, true)
 108 AM_CONDITIONAL(do_roken_rename, true)
 109
 110 AC_DEFINE(KRB5, 1, [Enable Kerberos 5 support in applications.])dnl
 111 AC_SUBST(LIB_kdb)dnl
 112
 113 KRB_CRYPTO
 114
 115 KRB_PTHREADS
 116
 117 AC_ARG_ENABLE(dce,
 118         AS_HELP_STRING([--enable-dce],[if you want support for DCE/DFS PAG's]))
 119 if test "$enable_dce" = yes; then
 120     AC_DEFINE(DCE, 1, [Define if you want support for DCE/DFS PAG's.])
 121 fi
 122 AM_CONDITIONAL(DCE, test "$enable_dce" = yes)
 123
 124 ## XXX quite horrible:
 125 if test -f /etc/ibmcxx.cfg; then
 126         dpagaix_ldadd=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/libraries/{;s/^[[^=]]*=\(.*\)/\1/;s/,/ /gp;}'`
 127         dpagaix_cflags=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/options/{;s/^[[^=]]*=\(.*\)/\1/;s/-q[^,]*//;s/,/ /gp;}'`
 128         dpagaix_ldflags=
 129 else
 130         dpagaix_cflags="-D_THREAD_SAFE -D_AIX_PTHREADS_D7 -D_AIX32_THREADS=1 -D_AES_SOURCE -D_AIX41 -I/usr/include/dce"
 131         dpagaix_ldadd="-L/usr/lib/threads -ldcelibc_r -ldcepthreads -lpthreads_compat lpthreads -lc_r"
 132         dpagaix_ldflags="-Wl,-bI:dfspag.exp"
 133 fi
 134 AC_SUBST(dpagaix_cflags)
 135 AC_SUBST(dpagaix_ldadd)
 136 AC_SUBST(dpagaix_ldflags)
 137
 138 AC_ARG_ENABLE([afs-support],
 139         AS_HELP_STRING([--disable-afs-support],[if you don't want support for AFS]))
 140 if test "$enable_afs_support" = no; then
 141         AC_DEFINE(NO_AFS, 1, [Define if you don't wan't support for AFS.])
 142 fi
 143
 144 rk_DB
 145
 146 dnl AC_ROKEN(10,[/usr/heimdal /usr/athena],[lib/roken],[$(top_builddir)/lib/roken/libroken.la],[-I$(top_builddir)/lib/roken -I$(top_srcdir)/lib/roken])
 147
 148 rk_ROKEN(lib/roken)
 149 LIBADD_roken="$LIB_roken"
 150 AC_SUBST(LIBADD_roken)dnl
 151 LIB_roken="\$(top_builddir)/lib/vers/libvers.la $LIB_roken"
 152
 153 rk_OTP
 154
 155 AC_CHECK_OSFC2
 156
 157 AC_ARG_ENABLE(mmap,
 158         AS_HELP_STRING([--disable-mmap],[disable use of mmap]))
 159 if test "$enable_mmap" = "no"; then
 160         AC_DEFINE(NO_MMAP, 1, [Define if you don't want to use mmap.])
 161 fi
 162
 163 AC_ARG_ENABLE(afs-string-to-key,
 164         AS_HELP_STRING([--disable-afs-string-to-key],
 165         [disable use of weak AFS string-to-key functions]),
 166         [], [enable_afs_string_to_key=yes])
 167
 168 if test "$enable_afs_string_to_key" = "yes"; then
 169         AC_DEFINE(ENABLE_AFS_STRING_TO_KEY, 1, [Define if want to use the weak AFS string to key functions.])
 170 fi
 171
 172
 173 rk_CHECK_MAN
 174
 175 rk_TEST_PACKAGE(readline,
 176 [#include <stdio.h>
 177  #include <readline.h>],-lreadline,,, READLINE)
 178
 179 rk_TEST_PACKAGE(hesiod,[#include <hesiod.h>],-lhesiod,,, HESIOD)
 180
 181 KRB_C_BIGENDIAN
 182 AC_C_INLINE
 183
 184 rk_AIX
 185 rk_IRIX
 186 rk_SUNOS
 187
 188 KRB_CHECK_X
 189
 190 AM_CONDITIONAL(HAVE_X, test "$no_x" != yes)
 191
 192 AC_CHECK_XAU
 193
 194 dnl AM_C_PROTOTYPES
 195
 196 dnl Checks for typedefs, structures, and compiler characteristics.
 197 AC_C_CONST
 198 AC_TYPE_OFF_T
 199 AC_CHECK_TYPE_EXTRA(mode_t, unsigned short, [])
 200 AC_CHECK_TYPE_EXTRA(sig_atomic_t, int, [#include <signal.h>])
 201 AC_HAVE_TYPE([long long])
 202 AC_HEADER_TIME
 203 AC_STRUCT_TM
 204
 205 dnl Checks for header files.
 206 AC_HEADER_STDC
 207
 208 AC_CHECK_HEADERS([\
 209         arpa/ftp.h                              \
 210         arpa/telnet.h                           \
 211         asl.h                                   \
 212         bind/bitypes.h                          \
 213         bsdsetjmp.h                             \
 214         curses.h                                \
 215         dlfcn.h                                 \
 216         fnmatch.h                               \
 217         inttypes.h                              \
 218         io.h                                    \
 219         libutil.h                               \
 220         limits.h                                \
 221         maillock.h                              \
 222         netgroup.h                              \
 223         netinet/in6_machtypes.h                 \
 224         netinfo/ni.h                            \
 225         pthread.h                               \
 226         pty.h                                   \
 227         sac.h                                   \
 228         sgtty.h                                 \
 229         siad.h                                  \
 230         signal.h                                \
 231         strings.h                               \
 232         stropts.h                               \
 233         sys/bitypes.h                           \
 234         sys/category.h                          \
 235         sys/file.h                              \
 236         sys/filio.h                             \
 237         sys/ioccom.h                            \
 238         sys/mman.h                              \
 239         sys/param.h                             \
 240         sys/pty.h                               \
 241         sys/ptyio.h                             \
 242         sys/select.h                            \
 243         sys/socket.h                            \
 244         sys/str_tty.h                           \
 245         sys/stream.h                            \
 246         sys/stropts.h                           \
 247         sys/syscall.h                           \
 248         sys/termio.h                            \
 249         sys/timeb.h                             \
 250         sys/times.h                             \
 251         sys/types.h                             \
 252         sys/un.h                                \
 253         termcap.h                               \
 254         termio.h                                \
 255         termios.h                               \
 256         time.h                                  \
 257         tmpdir.h                                \
 258         udb.h                                   \
 259         util.h                                  \
 260         utmp.h                                  \
 261         utmpx.h                                 \
 262 ])
 263
 264 dnl On Solaris 8 there's a compilation warning for term.h because
 265 dnl it doesn't define `bool'.
 266 AC_CHECK_HEADERS(term.h, , , -)
 267
 268 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
 269 #if HAVE_SYS_SOCKET_H
 270 #include <sys/socket.h>
 271 #endif])
 272
 273 AC_CHECK_HEADERS(sys/ptyvar.h, , , [AC_INCLUDES_DEFAULT
 274 #if HAVE_SYS_TTY_H
 275 #include <sys/tty.h>
 276 #endif])
 277
 278 AC_CHECK_HEADERS(sys/strtty.h, , , [AC_INCLUDES_DEFAULT
 279 #if HAVE_TERMIOS_H
 280 #include <termios.h>
 281 #endif
 282 #if HAVE_SYS_STREAM_H
 283 #include <sys/stream.h>
 284 #endif])
 285
 286 AC_CHECK_HEADERS(sys/ucred.h, , , [AC_INCLUDES_DEFAULT
 287 #if HAVE_SYS_TYPES_H
 288 #include <sys/types.h>
 289 #endif
 290 #if HAVE_SYS_PARAM_H
 291 #include <sys/param.h>
 292 #endif])
 293
 294 AC_CHECK_HEADERS(security/pam_modules.h, , , [AC_INCLUDES_DEFAULT
 295 #include <security/pam_appl.h>
 296 ])
 297
 298 AC_ARG_ENABLE(netinfo,
 299         AS_HELP_STRING([--enable-netinfo],[enable netinfo for configuration lookup]))
 300
 301 if test "$ac_cv_header_netinfo_ni_h" = yes -a "$enable_netinfo" = yes; then
 302        AC_DEFINE(HAVE_NETINFO, 1,
 303                [Define if you want to use Netinfo instead of krb5.conf.])
 304 fi
 305
 306 dnl export symbols
 307 rk_WIN32_EXPORT(BUILD_KRB5_LIB, KRB5_LIB)
 308 rk_WIN32_EXPORT(BUILD_ROKEN_LIB, ROKEN_LIB)
 309 rk_WIN32_EXPORT(BUILD_GSSAPI_LIB, GSSAPI_LIB)
 310
 311 dnl Checks for libraries.
 312
 313 AC_FIND_FUNC_NO_LIBS(logwtmp, util,[
 314 #ifdef HAVE_UTIL_H
 315 #include <util.h>
 316 #endif
 317 ],[0,0,0])
 318 AC_FIND_FUNC_NO_LIBS(logout, util,[
 319 #ifdef HAVE_UTIL_H
 320 #include <util.h>
 321 #endif
 322 ],[0])
 323 AC_FIND_FUNC_NO_LIBS(openpty, util,[
 324 #ifdef HAVE_UTIL_H
 325 #include <util.h>
 326 #endif
 327 ],[0,0,0,0,0])
 328
 329 AC_FIND_FUNC_NO_LIBS(tgetent, termcap ncurses curses,[
 330 #ifdef HAVE_TERMCAP_H
 331 #include <termcap.h>
 332 #endif
 333 #ifdef HAVE_CURSES_H
 334 #include <curses.h>
 335 #endif
 336 ],[0,0])
 337
 338 dnl Checks for library functions.
 339
 340 AC_CHECK_FUNCS([                                \
 341         _getpty                                 \
 342         _scrsize                                \
 343         arc4random                              \
 344         fcntl                                   \
 345         getpeereid                              \
 346         getpeerucred                            \
 347         grantpt                                 \
 348         mktime                                  \
 349         ptsname                                 \
 350         rand                                    \
 351         revoke                                  \
 352         select                                  \
 353         setitimer                               \
 354         setpcred                                \
 355         setpgid                                 \
 356         setproctitle                            \
 357         setregid                                \
 358         setresgid                               \
 359         setresuid                               \
 360         setreuid                                \
 361         setsid                                  \
 362         setutent                                \
 363         sigaction                               \
 364         strstr                                  \
 365         ttyname                                 \
 366         ttyslot                                 \
 367         umask                                   \
 368         unlockpt                                \
 369         vhangup                                 \
 370         yp_get_default_domain                   \
 371 ])
 372
 373 AC_FUNC_MMAP
 374
 375 KRB_CAPABILITIES
 376
 377 AC_CHECK_GETPWNAM_R_POSIX
 378
 379 dnl detect doors on solaris
 380 if test "$enable_pthread_support" != no; then
 381    saved_LIBS="$LIBS"
 382    LIBS="$LIBS $PTHREADS_LIBS"
 383    AC_FIND_FUNC_NO_LIBS(door_create, door)
 384    LIBS="$saved_LIBS"
 385 fi
 386
 387 AC_ARG_ENABLE(kcm,
 388         AS_HELP_STRING([--enable-kcm],[enable Kerberos Credentials Manager]),
 389 ,[enable_kcm=yes])
 390
 391 if test "$enable_kcm" = yes ; then
 392    if test  "$ac_cv_header_sys_un_h" != yes -a "$ac_cv_funclib_door_create" != yes ; then
 393         enable_kcm=no
 394    fi
 395 fi
 396 if test "$enable_kcm" = yes; then
 397        AC_DEFINE(HAVE_KCM, 1,
 398                [Define if you want to use the Kerberos Credentials Manager.])
 399 fi
 400 AM_CONDITIONAL(KCM, test "$enable_kcm" = yes)
 401
 402
 403
 404 dnl Cray stuff
 405 AC_CHECK_FUNCS(getudbnam setlim)
 406
 407 dnl AC_KRB_FUNC_GETCWD_BROKEN
 408
 409 dnl
 410 dnl Check for fields in struct utmp
 411 dnl
 412
 413 AC_HAVE_STRUCT_FIELD(struct utmp, ut_addr, [#include <utmp.h>])
 414 AC_HAVE_STRUCT_FIELD(struct utmp, ut_host, [#include <utmp.h>])
 415 AC_HAVE_STRUCT_FIELD(struct utmp, ut_id, [#include <utmp.h>])
 416 AC_HAVE_STRUCT_FIELD(struct utmp, ut_pid, [#include <utmp.h>])
 417 AC_HAVE_STRUCT_FIELD(struct utmp, ut_type, [#include <utmp.h>])
 418 AC_HAVE_STRUCT_FIELD(struct utmp, ut_user, [#include <utmp.h>])
 419 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_exit, [#include <utmpx.h>])
 420 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_syslen, [#include <utmpx.h>])
 421
 422 AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t,
 423         u_int8_t, u_int16_t, u_int32_t, u_int64_t,
 424         uint8_t, uint16_t, uint32_t, uint64_t],,,[
 425 #ifdef HAVE_INTTYPES_H
 426 #include <inttypes.h>
 427 #endif
 428 #ifdef HAVE_SYS_TYPES_H
 429 #include <sys/types.h>
 430 #endif
 431 #ifdef HAVE_SYS_BITYPES_H
 432 #include <sys/bitypes.h>
 433 #endif
 434 #ifdef HAVE_BIND_BITYPES_H
 435 #include <bind/bitypes.h>
 436 #endif
 437 #ifdef HAVE_NETINET_IN6_MACHTYPES_H
 438 #include <netinet/in6_machtypes.h>
 439 #endif
 440 ])
 441
 442 rk_FRAMEWORK_SECURITY
 443
 444 KRB_READLINE
 445
 446 rk_TELNET
 447
 448 dnl Some operating systems already have com_err and compile_et
 449 CHECK_COMPILE_ET
 450
 451 rk_AUTH_MODULES([sia afskauthlib])
 452
 453 rk_DESTDIRS
 454
 455 rk_WFLAGS([-Wall -Wmissing-prototypes -Wpointer-arith -Wbad-function-cast -Wmissing-declarations -Wnested-externs])
 456
 457
 458 AH_BOTTOM([#ifdef ROKEN_RENAME
 459 #include "roken_rename.h"
 460 #endif])
 461
 462 AC_CONFIG_FILES(Makefile                \
 463         etc/Makefile                    \
 464         include/Makefile                \
 465         include/gssapi/Makefile         \
 466         include/hcrypto/Makefile        \
 467         include/kadm5/Makefile          \
 468         lib/Makefile                    \
 469         lib/45/Makefile                 \
 470         lib/auth/Makefile               \
 471         lib/auth/afskauthlib/Makefile   \
 472         lib/auth/pam/Makefile           \
 473         lib/auth/sia/Makefile           \
 474         lib/asn1/Makefile               \
 475         lib/com_err/Makefile            \
 476         lib/hcrypto/Makefile            \
 477         lib/editline/Makefile           \
 478         lib/hx509/Makefile              \
 479         lib/gssapi/Makefile             \
 480         lib/ntlm/Makefile               \
 481         lib/hdb/Makefile                \
 482         lib/kadm5/Makefile              \
 483         lib/kafs/Makefile               \
 484         lib/kdfs/Makefile               \
 485         lib/krb5/Makefile               \
 486         lib/otp/Makefile                \
 487         lib/roken/Makefile              \
 488         lib/sl/Makefile                 \
 489         lib/sqlite/Makefile             \
 490         lib/vers/Makefile               \
 491         lib/wind/Makefile               \
 492         kuser/Makefile                  \
 493         kpasswd/Makefile                \
 494         kadmin/Makefile                 \
 495         admin/Makefile                  \
 496         kcm/Makefile                    \
 497         kdc/Makefile                    \
 498         appl/Makefile                   \
 499         appl/afsutil/Makefile           \
 500         appl/ftp/Makefile               \
 501         appl/ftp/common/Makefile        \
 502         appl/ftp/ftp/Makefile           \
 503         appl/ftp/ftpd/Makefile          \
 504         appl/gssmask/Makefile           \
 505         appl/kx/Makefile                \
 506         appl/login/Makefile             \
 507         appl/otp/Makefile               \
 508         appl/popper/Makefile            \
 509         appl/push/Makefile              \
 510         appl/rsh/Makefile               \
 511         appl/rcp/Makefile               \
 512         appl/su/Makefile                \
 513         appl/xnlock/Makefile            \
 514         appl/telnet/Makefile            \
 515         appl/telnet/libtelnet/Makefile  \
 516         appl/telnet/telnet/Makefile     \
 517         appl/telnet/telnetd/Makefile    \
 518         appl/test/Makefile              \
 519         appl/kf/Makefile                \
 520         appl/dceutils/Makefile          \
 521         tests/Makefile                  \
 522         tests/can/Makefile              \
 523         tests/db/Makefile               \
 524         tests/kdc/Makefile              \
 525         tests/ldap/Makefile             \
 526         tests/gss/Makefile              \
 527         tests/java/Makefile             \
 528         tests/plugin/Makefile           \
 529         packages/Makefile               \
 530         packages/mac/Makefile           \
 531         packages/debian/Makefile        \
 532         doc/Makefile                    \
 533         tools/Makefile                  \
 534 )
 535
 536 AC_OUTPUT
 537
 538 dnl
 539 dnl This is the release version name-number[beta]
 540 dnl
 541
 542 cat > include/newversion.h.in <<EOF
 543 const char *heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ ($host) @DATE@ \$";
 544 const char *heimdal_version = "AC_PACKAGE_STRING";
 545 EOF
 546
 547 if test -f include/version.h && cmp -s include/newversion.h.in include/version.h.in; then
 548         echo "include/version.h is unchanged"
 549         rm -f include/newversion.h.in
 550 else
 551         echo "creating include/version.h"
 552         User=${USER-${LOGNAME}}
 553         Host=`(hostname || uname -n || echo unknown) 2>/dev/null | sed 1q`
 554         Date=`date`
 555         mv -f include/newversion.h.in include/version.h.in
 556         sed -e "s/@USER@/$User/" -e "s/@HOST@/$Host/" -e "s/@DATE@/$Date/" include/version.h.in > include/version.h
 557 fi