pidl/lib/Parse/Pidl/Samba4/NDR/Parser.pm

   1 ###################################################
   2 # Samba4 NDR parser generator for IDL structures
   3 # Copyright tridge@samba.org 2000-2003
   4 # Copyright tpot@samba.org 2001
   5 # Copyright jelmer@samba.org 2004-2006
   6 # released under the GNU GPL
   7
   8 package Parse::Pidl::Samba4::NDR::Parser;
   9
  10 require Exporter;
  11 @ISA = qw(Exporter);
  12 @EXPORT_OK = qw(check_null_pointer NeededFunction NeededElement NeededType $res NeededInterface TypeFunctionName ParseElementPrint);
  13
  14 use strict;
  15 use Parse::Pidl::Typelist qw(hasType getType mapTypeName typeHasBody);
  16 use Parse::Pidl::Util qw(has_property ParseExpr ParseExprExt print_uuid unmake_str);
  17 use Parse::Pidl::CUtil qw(get_pointer_to get_value_of get_array_element);
  18 use Parse::Pidl::NDR qw(GetPrevLevel GetNextLevel ContainsDeferred ContainsPipe is_charset_array);
  19 use Parse::Pidl::Samba4 qw(is_intree choose_header ArrayDynamicallyAllocated);
  20 use Parse::Pidl::Samba4::Header qw(GenerateFunctionInEnv GenerateFunctionOutEnv EnvSubstituteValue GenerateStructEnv);
  21 use Parse::Pidl qw(warning);
  22
  23 use vars qw($VERSION);
  24 $VERSION = '0.01';
  25
  26 # list of known types
  27 my %typefamily;
  28
  29 sub new($$) {
  30         my ($class) = @_;
  31         my $self = { res => "", res_hdr => "", deferred => [], tabs => "", defer_tabs => "" };
  32         bless($self, $class);
  33 }
  34
  35 sub get_typefamily($)
  36 {
  37         my $n = shift;
  38         return $typefamily{$n};
  39 }
  40
  41 sub append_prefix($$)
  42 {
  43         my ($e, $var_name) = @_;
  44         my $pointers = 0;
  45         my $arrays = 0;
  46
  47         foreach my $l (@{$e->{LEVELS}}) {
  48                 if ($l->{TYPE} eq "POINTER") {
  49                         $pointers++;
  50                 } elsif ($l->{TYPE} eq "ARRAY") {
  51                         $arrays++;
  52                         if (($pointers == 0) and
  53                             (not $l->{IS_FIXED}) and
  54                             (not $l->{IS_INLINE})) {
  55                                 return get_value_of($var_name);
  56                         }
  57                 } elsif ($l->{TYPE} eq "DATA") {
  58                         if (Parse::Pidl::Typelist::scalar_is_reference($l->{DATA_TYPE})) {
  59                                 return get_value_of($var_name) unless ($pointers or $arrays);
  60                         }
  61                 }
  62         }
  63
  64         return $var_name;
  65 }
  66
  67 sub has_fast_array($$)
  68 {
  69         my ($e,$l) = @_;
  70
  71         return 0 if ($l->{TYPE} ne "ARRAY");
  72
  73         my $nl = GetNextLevel($e,$l);
  74         return 0 unless ($nl->{TYPE} eq "DATA");
  75         return 0 unless (hasType($nl->{DATA_TYPE}));
  76
  77         my $t = getType($nl->{DATA_TYPE});
  78
  79         # Only uint8 and string have fast array functions at the moment
  80         return ($t->{NAME} eq "uint8") or ($t->{NAME} eq "string");
  81 }
  82
  83
  84 ####################################
  85 # pidl() is our basic output routine
  86 sub pidl($$)
  87 {
  88         my ($self, $d) = @_;
  89         if ($d) {
  90                 $self->{res} .= $self->{tabs};
  91                 $self->{res} .= $d;
  92         }
  93         $self->{res} .="\n";
  94 }
  95
  96 sub pidl_hdr($$) { my ($self, $d) = @_; $self->{res_hdr} .= "$d\n"; }
  97
  98 ####################################
  99 # defer() is like pidl(), but adds to
 100 # a deferred buffer which is then added to the
 101 # output buffer at the end of the structure/union/function
 102 # This is needed to cope with code that must be pushed back
 103 # to the end of a block of elements
 104 sub defer_indent($) { my ($self) = @_; $self->{defer_tabs}.="\t"; }
 105 sub defer_deindent($) { my ($self) = @_; $self->{defer_tabs}=substr($self->{defer_tabs}, 0, -1); }
 106
 107 sub defer($$)
 108 {
 109         my ($self, $d) = @_;
 110         if ($d) {
 111                 push(@{$self->{deferred}}, $self->{defer_tabs}.$d);
 112         }
 113 }
 114
 115 ########################################
 116 # add the deferred content to the current
 117 # output
 118 sub add_deferred($)
 119 {
 120         my ($self) = @_;
 121         $self->pidl($_) foreach (@{$self->{deferred}});
 122         $self->{deferred} = [];
 123         $self->{defer_tabs} = "";
 124 }
 125
 126 sub indent($)
 127 {
 128         my ($self) = @_;
 129         $self->{tabs} .= "\t";
 130 }
 131
 132 sub deindent($)
 133 {
 134         my ($self) = @_;
 135         $self->{tabs} = substr($self->{tabs}, 0, -1);
 136 }
 137
 138 #####################################################################
 139 # declare a function public or static, depending on its attributes
 140 sub fn_declare($$$$)
 141 {
 142         my ($self,$type,$fn,$decl) = @_;
 143
 144         if (has_property($fn, "no$type")) {
 145                 $self->pidl_hdr("$decl;");
 146                 return 0;
 147         }
 148
 149         if (has_property($fn, "public")) {
 150                 $self->pidl_hdr("$decl;");
 151                 $self->pidl("_PUBLIC_ $decl");
 152         } else {
 153                 $self->pidl("static $decl");
 154         }
 155
 156         return 1;
 157 }
 158
 159 ###################################################################
 160 # setup any special flags for an element or structure
 161 sub start_flags($$$)
 162 {
 163         my ($self, $e, $ndr) = @_;
 164         my $flags = has_property($e, "flag");
 165         if (defined $flags) {
 166                 $self->pidl("{");
 167                 $self->indent;
 168                 $self->pidl("uint32_t _flags_save_$e->{TYPE} = $ndr->flags;");
 169                 $self->pidl("ndr_set_flags(&$ndr->flags, $flags);");
 170         }
 171 }
 172
 173 ###################################################################
 174 # end any special flags for an element or structure
 175 sub end_flags($$$)
 176 {
 177         my ($self, $e, $ndr) = @_;
 178         my $flags = has_property($e, "flag");
 179         if (defined $flags) {
 180                 $self->pidl("$ndr->flags = _flags_save_$e->{TYPE};");
 181                 $self->deindent;
 182                 $self->pidl("}");
 183         }
 184 }
 185
 186 #####################################################################
 187 # parse the data of an array - push side
 188 sub ParseArrayPushHeader($$$$$$)
 189 {
 190         my ($self,$e,$l,$ndr,$var_name,$env) = @_;
 191
 192         my $size;
 193         my $length;
 194
 195         if ($l->{IS_ZERO_TERMINATED}) {
 196                 if (has_property($e, "charset")) {
 197                         $size = $length = "ndr_charset_length($var_name, CH_$e->{PROPERTIES}->{charset})";
 198                 } else {
 199                         $size = $length = "ndr_string_length($var_name, sizeof(*$var_name))";
 200                 }
 201                 if (defined($l->{SIZE_IS})) {
 202                         $size = ParseExpr($l->{SIZE_IS}, $env, $e);
 203                 }
 204                 if (defined($l->{LENGTH_IS})) {
 205                         $length = ParseExpr($l->{LENGTH_IS}, $env, $e);
 206                 }
 207         } else {
 208                 $size = ParseExpr($l->{SIZE_IS}, $env, $e);
 209                 $length = ParseExpr($l->{LENGTH_IS}, $env, $e);
 210         }
 211
 212         if ((!$l->{IS_SURROUNDING}) and $l->{IS_CONFORMANT}) {
 213                 $self->pidl("NDR_CHECK(ndr_push_uint3264($ndr, NDR_SCALARS, $size));");
 214         }
 215
 216         if ($l->{IS_VARYING}) {
 217                 $self->pidl("NDR_CHECK(ndr_push_uint3264($ndr, NDR_SCALARS, 0));");  # array offset
 218                 $self->pidl("NDR_CHECK(ndr_push_uint3264($ndr, NDR_SCALARS, $length));");
 219         }
 220
 221         return $length;
 222 }
 223
 224 sub check_fully_dereferenced($$)
 225 {
 226         my ($element, $env) = @_;
 227
 228         return sub ($) {
 229                 my $origvar = shift;
 230                 my $check = 0;
 231
 232                 # Figure out the number of pointers in $ptr
 233                 my $expandedvar = $origvar;
 234                 $expandedvar =~ s/^(\**)//;
 235                 my $ptr = $1;
 236
 237                 my $var = undef;
 238                 foreach (keys %$env) {
 239                         if ($env->{$_} eq $expandedvar) {
 240                                 $var = $_;
 241                                 last;
 242                         }
 243                 }
 244
 245                 return($origvar) unless (defined($var));
 246                 my $e;
 247                 foreach (@{$element->{PARENT}->{ELEMENTS}}) {
 248                         if ($_->{NAME} eq $var) {
 249                                 $e = $_;
 250                                 last;
 251                         }
 252                 }
 253
 254                 $e or die("Environment doesn't match siblings");
 255
 256                 # See if pointer at pointer level $level
 257                 # needs to be checked.
 258                 my $nump = 0;
 259                 foreach (@{$e->{LEVELS}}) {
 260                         if ($_->{TYPE} eq "POINTER") {
 261                                 $nump = $_->{POINTER_INDEX}+1;
 262                         }
 263                 }
 264                 warning($element->{ORIGINAL}, "Got pointer for `$e->{NAME}', expected fully derefenced variable") if ($nump > length($ptr));
 265                 return ($origvar);
 266         }
 267 }
 268
 269 sub check_null_pointer($$$$)
 270 {
 271         my ($element, $env, $print_fn, $return) = @_;
 272
 273         return sub ($) {
 274                 my $expandedvar = shift;
 275                 my $check = 0;
 276
 277                 # Figure out the number of pointers in $ptr
 278                 $expandedvar =~ s/^(\**)//;
 279                 my $ptr = $1;
 280
 281                 my $var = undef;
 282                 foreach (keys %$env) {
 283                         if ($env->{$_} eq $expandedvar) {
 284                                 $var = $_;
 285                                 last;
 286                         }
 287                 }
 288
 289                 if (defined($var)) {
 290                         my $e;
 291                         # lookup ptr in $e
 292                         foreach (@{$element->{PARENT}->{ELEMENTS}}) {
 293                                 if ($_->{NAME} eq $var) {
 294                                         $e = $_;
 295                                         last;
 296                                 }
 297                         }
 298
 299                         $e or die("Environment doesn't match siblings");
 300
 301                         # See if pointer at pointer level $level
 302                         # needs to be checked.
 303                         foreach my $l (@{$e->{LEVELS}}) {
 304                                 if ($l->{TYPE} eq "POINTER" and
 305                                         $l->{POINTER_INDEX} == length($ptr)) {
 306                                         # No need to check ref pointers
 307                                         $check = ($l->{POINTER_TYPE} ne "ref");
 308                                         last;
 309                                 }
 310
 311                                 if ($l->{TYPE} eq "DATA") {
 312                                         warning($element, "too much dereferences for `$var'");
 313                                 }
 314                         }
 315                 } else {
 316                         warning($element, "unknown dereferenced expression `$expandedvar'");
 317                         $check = 1;
 318                 }
 319
 320                 $print_fn->("if ($ptr$expandedvar == NULL) $return") if $check;
 321         }
 322 }
 323
 324 sub ParseArrayPullGetSize($$$$$$)
 325 {
 326         my ($self,$e,$l,$ndr,$var_name,$env) = @_;
 327
 328         my $size;
 329
 330         if ($l->{IS_CONFORMANT}) {
 331                 $size = "ndr_get_array_size($ndr, " . get_pointer_to($var_name) . ")";
 332         } elsif ($l->{IS_ZERO_TERMINATED} and $l->{SIZE_IS} == 0 and $l->{LENGTH_IS} == 0) { # Noheader arrays
 333                 $size = "ndr_get_string_size($ndr, sizeof(*$var_name))";
 334         } else {
 335                 $size = ParseExprExt($l->{SIZE_IS}, $env, $e->{ORIGINAL},
 336                         check_null_pointer($e, $env, sub { $self->pidl(shift); },
 337                                            "return ndr_pull_error($ndr, NDR_ERR_INVALID_POINTER, \"NULL Pointer for size_is()\");"),
 338                         check_fully_dereferenced($e, $env));
 339         }
 340
 341         my $array_size = $size;
 342
 343         return $array_size;
 344 }
 345
 346 #####################################################################
 347 # parse an array - pull side
 348 sub ParseArrayPullGetLength($$$$$$;$)
 349 {
 350         my ($self,$e,$l,$ndr,$var_name,$env,$array_size) = @_;
 351
 352         if (not defined($array_size)) {
 353                 $array_size = $self->ParseArrayPullGetSize($e, $l, $ndr, $var_name, $env);
 354         }
 355
 356         my $array_length = $array_size;
 357         if ($l->{IS_VARYING}) {
 358                 my $length = "ndr_get_array_length($ndr, " . get_pointer_to($var_name) .")";
 359                 $array_length = $length;
 360         }
 361
 362         return $array_length;
 363 }
 364
 365 #####################################################################
 366 # parse an array - pull side
 367 sub ParseArrayPullHeader($$$$$$)
 368 {
 369         my ($self,$e,$l,$ndr,$var_name,$env) = @_;
 370
 371         if ((!$l->{IS_SURROUNDING}) and $l->{IS_CONFORMANT}) {
 372                 $self->pidl("NDR_CHECK(ndr_pull_array_size($ndr, " . get_pointer_to($var_name) . "));");
 373         }
 374
 375         if ($l->{IS_VARYING}) {
 376                 $self->pidl("NDR_CHECK(ndr_pull_array_length($ndr, " . get_pointer_to($var_name) . "));");
 377         }
 378
 379         my $array_size = $self->ParseArrayPullGetSize($e, $l, $ndr, $var_name, $env);
 380         my $array_length = $self->ParseArrayPullGetLength($e, $l, $ndr, $var_name, $env, $array_size);
 381
 382         if ($array_length ne $array_size) {
 383                 $self->pidl("if ($array_length > $array_size) {");
 384                 $self->indent;
 385                 $self->pidl("return ndr_pull_error($ndr, NDR_ERR_ARRAY_SIZE, \"Bad array size %u should exceed array length %u\", $array_size, $array_length);");
 386                 $self->deindent;
 387                 $self->pidl("}");
 388         }
 389
 390         if ($l->{IS_CONFORMANT} and (defined($l->{SIZE_IS}) or not $l->{IS_ZERO_TERMINATED})) {
 391                 $self->defer("if ($var_name) {");
 392                 $self->defer_indent;
 393                 my $size = ParseExprExt($l->{SIZE_IS}, $env, $e->{ORIGINAL},
 394                         check_null_pointer($e, $env, sub { $self->defer(shift); },
 395                                            "return ndr_pull_error($ndr, NDR_ERR_INVALID_POINTER, \"NULL Pointer for size_is()\");"),
 396                         check_fully_dereferenced($e, $env));
 397                 $self->defer("NDR_CHECK(ndr_check_array_size($ndr, (void*)" . get_pointer_to($var_name) . ", $size));");
 398                 $self->defer_deindent;
 399                 $self->defer("}");
 400         }
 401
 402         if ($l->{IS_VARYING} and (defined($l->{LENGTH_IS}) or not $l->{IS_ZERO_TERMINATED})) {
 403                 $self->defer("if ($var_name) {");
 404                 $self->defer_indent;
 405                 my $length = ParseExprExt($l->{LENGTH_IS}, $env, $e->{ORIGINAL},
 406                         check_null_pointer($e, $env, sub { $self->defer(shift); },
 407                                            "return ndr_pull_error($ndr, NDR_ERR_INVALID_POINTER, \"NULL Pointer for length_is()\");"),
 408                         check_fully_dereferenced($e, $env));
 409                 $self->defer("NDR_CHECK(ndr_check_array_length($ndr, (void*)" . get_pointer_to($var_name) . ", $length));");
 410                 $self->defer_deindent;
 411                 $self->defer("}");
 412         }
 413
 414         if (ArrayDynamicallyAllocated($e,$l) and not is_charset_array($e,$l)) {
 415                 $self->AllocateArrayLevel($e,$l,$ndr,$var_name,$array_size);
 416         }
 417
 418         return $array_length;
 419 }
 420
 421 sub compression_alg($$)
 422 {
 423         my ($e, $l) = @_;
 424         my ($alg, $clen, $dlen) = split(/,/, $l->{COMPRESSION});
 425
 426         return $alg;
 427 }
 428
 429 sub compression_clen($$$)
 430 {
 431         my ($e, $l, $env) = @_;
 432         my ($alg, $clen, $dlen) = split(/,/, $l->{COMPRESSION});
 433
 434         return ParseExpr($clen, $env, $e->{ORIGINAL});
 435 }
 436
 437 sub compression_dlen($$$)
 438 {
 439         my ($e,$l,$env) = @_;
 440         my ($alg, $clen, $dlen) = split(/,/, $l->{COMPRESSION});
 441
 442         return ParseExpr($dlen, $env, $e->{ORIGINAL});
 443 }
 444
 445 sub ParseCompressionPushStart($$$$$)
 446 {
 447         my ($self,$e,$l,$ndr,$env) = @_;
 448         my $comndr = "$ndr\_compressed";
 449         my $alg = compression_alg($e, $l);
 450         my $dlen = compression_dlen($e, $l, $env);
 451
 452         $self->pidl("{");
 453         $self->indent;
 454         $self->pidl("struct ndr_push *$comndr;");
 455         $self->pidl("NDR_CHECK(ndr_push_compression_start($ndr, &$comndr, $alg, $dlen));");
 456
 457         return $comndr;
 458 }
 459
 460 sub ParseCompressionPushEnd($$$$$)
 461 {
 462         my ($self,$e,$l,$ndr,$env) = @_;
 463         my $comndr = "$ndr\_compressed";
 464         my $alg = compression_alg($e, $l);
 465         my $dlen = compression_dlen($e, $l, $env);
 466
 467         $self->pidl("NDR_CHECK(ndr_push_compression_end($ndr, $comndr, $alg, $dlen));");
 468         $self->deindent;
 469         $self->pidl("}");
 470 }
 471
 472 sub ParseCompressionPullStart($$$$$)
 473 {
 474         my ($self,$e,$l,$ndr,$env) = @_;
 475         my $comndr = "$ndr\_compressed";
 476         my $alg = compression_alg($e, $l);
 477         my $dlen = compression_dlen($e, $l, $env);
 478
 479         $self->pidl("{");
 480         $self->indent;
 481         $self->pidl("struct ndr_pull *$comndr;");
 482         $self->pidl("NDR_CHECK(ndr_pull_compression_start($ndr, &$comndr, $alg, $dlen));");
 483
 484         return $comndr;
 485 }
 486
 487 sub ParseCompressionPullEnd($$$$$)
 488 {
 489         my ($self,$e,$l,$ndr,$env) = @_;
 490         my $comndr = "$ndr\_compressed";
 491         my $alg = compression_alg($e, $l);
 492         my $dlen = compression_dlen($e, $l, $env);
 493
 494         $self->pidl("NDR_CHECK(ndr_pull_compression_end($ndr, $comndr, $alg, $dlen));");
 495         $self->deindent;
 496         $self->pidl("}");
 497 }
 498
 499 sub ParseSubcontextPushStart($$$$$)
 500 {
 501         my ($self,$e,$l,$ndr,$env) = @_;
 502         my $subndr = "_ndr_$e->{NAME}";
 503         my $subcontext_size = ParseExpr($l->{SUBCONTEXT_SIZE}, $env, $e->{ORIGINAL});
 504
 505         $self->pidl("{");
 506         $self->indent;
 507         $self->pidl("struct ndr_push *$subndr;");
 508         $self->pidl("NDR_CHECK(ndr_push_subcontext_start($ndr, &$subndr, $l->{HEADER_SIZE}, $subcontext_size));");
 509
 510         if (defined $l->{COMPRESSION}) {
 511                 $subndr = $self->ParseCompressionPushStart($e, $l, $subndr, $env);
 512         }
 513
 514         return $subndr;
 515 }
 516
 517 sub ParseSubcontextPushEnd($$$$$)
 518 {
 519         my ($self,$e,$l,$ndr,$env) = @_;
 520         my $subndr = "_ndr_$e->{NAME}";
 521         my $subcontext_size = ParseExpr($l->{SUBCONTEXT_SIZE}, $env, $e->{ORIGINAL});
 522
 523         if (defined $l->{COMPRESSION}) {
 524                 $self->ParseCompressionPushEnd($e, $l, $subndr, $env);
 525         }
 526
 527         $self->pidl("NDR_CHECK(ndr_push_subcontext_end($ndr, $subndr, $l->{HEADER_SIZE}, $subcontext_size));");
 528         $self->deindent;
 529         $self->pidl("}");
 530 }
 531
 532 sub ParseSubcontextPullStart($$$$$)
 533 {
 534         my ($self,$e,$l,$ndr,$env) = @_;
 535         my $subndr = "_ndr_$e->{NAME}";
 536         my $subcontext_size = ParseExpr($l->{SUBCONTEXT_SIZE}, $env, $e->{ORIGINAL});
 537
 538         $self->pidl("{");
 539         $self->indent;
 540         $self->pidl("struct ndr_pull *$subndr;");
 541         $self->pidl("NDR_CHECK(ndr_pull_subcontext_start($ndr, &$subndr, $l->{HEADER_SIZE}, $subcontext_size));");
 542
 543         if (defined $l->{COMPRESSION}) {
 544                 $subndr = $self->ParseCompressionPullStart($e, $l, $subndr, $env);
 545         }
 546
 547         return $subndr;
 548 }
 549
 550 sub ParseSubcontextPullEnd($$$$$)
 551 {
 552         my ($self,$e,$l,$ndr,$env) = @_;
 553         my $subndr = "_ndr_$e->{NAME}";
 554         my $subcontext_size = ParseExpr($l->{SUBCONTEXT_SIZE}, $env, $e->{ORIGINAL});
 555
 556         if (defined $l->{COMPRESSION}) {
 557                 $self->ParseCompressionPullEnd($e, $l, $subndr, $env);
 558         }
 559
 560         $self->pidl("NDR_CHECK(ndr_pull_subcontext_end($ndr, $subndr, $l->{HEADER_SIZE}, $subcontext_size));");
 561         $self->deindent;
 562         $self->pidl("}");
 563 }
 564
 565 sub ParseElementPushLevel
 566 {
 567         my ($self,$e,$l,$ndr,$var_name,$env,$primitives,$deferred) = @_;
 568
 569         my $ndr_flags = CalcNdrFlags($l, $primitives, $deferred);
 570
 571         if ($l->{TYPE} eq "ARRAY" and ($l->{IS_CONFORMANT} or $l->{IS_VARYING})) {
 572                 $var_name = get_pointer_to($var_name);
 573         }
 574
 575         if (defined($ndr_flags)) {
 576                 if ($l->{TYPE} eq "SUBCONTEXT") {
 577                         my $subndr = $self->ParseSubcontextPushStart($e, $l, $ndr, $env);
 578                         $self->ParseElementPushLevel($e, GetNextLevel($e, $l), $subndr, $var_name, $env, 1, 1);
 579                         $self->ParseSubcontextPushEnd($e, $l, $ndr, $env);
 580                 } elsif ($l->{TYPE} eq "POINTER") {
 581                         $self->ParsePtrPush($e, $l, $ndr, $var_name);
 582                 } elsif ($l->{TYPE} eq "ARRAY") {
 583                         my $length = $self->ParseArrayPushHeader($e, $l, $ndr, $var_name, $env);
 584
 585                         my $nl = GetNextLevel($e, $l);
 586
 587                         # Allow speedups for arrays of scalar types
 588                         if (is_charset_array($e,$l)) {
 589                                 $self->pidl("NDR_CHECK(ndr_push_charset($ndr, $ndr_flags, $var_name, $length, sizeof(" . mapTypeName($nl->{DATA_TYPE}) . "), CH_$e->{PROPERTIES}->{charset}));");
 590                                 return;
 591                         } elsif (has_fast_array($e,$l)) {
 592                                 $self->pidl("NDR_CHECK(ndr_push_array_$nl->{DATA_TYPE}($ndr, $ndr_flags, $var_name, $length));");
 593                                 return;
 594                         }
 595                 } elsif ($l->{TYPE} eq "SWITCH") {
 596                         $self->ParseSwitchPush($e, $l, $ndr, $var_name, $env);
 597                 } elsif ($l->{TYPE} eq "DATA") {
 598                         $self->ParseDataPush($e, $l, $ndr, $var_name, $primitives, $deferred);
 599                 } elsif ($l->{TYPE} eq "TYPEDEF") {
 600                         $typefamily{$e->{DATA}->{TYPE}}->{PUSH_FN_BODY}->($self, $e->{DATA}, $ndr, $var_name);
 601                 }
 602         }
 603
 604         if ($l->{TYPE} eq "POINTER" and $l->{POINTER_TYPE} eq "ignore") {
 605                 $self->pidl("/* [ignore] '$e->{NAME}' */");
 606         } elsif ($l->{TYPE} eq "POINTER" and $deferred) {
 607                 my $rel_var_name = $var_name;
 608                 if ($l->{POINTER_TYPE} ne "ref") {
 609                         $self->pidl("if ($var_name) {");
 610                         $self->indent;
 611                         if ($l->{POINTER_TYPE} eq "relative") {
 612                                 $self->pidl("NDR_CHECK(ndr_push_relative_ptr2_start($ndr, $rel_var_name));");
 613                         }
 614                         if ($l->{POINTER_TYPE} eq "relative_short") {
 615                                 $self->pidl("NDR_CHECK(ndr_push_short_relative_ptr2($ndr, $var_name));");
 616                         }
 617                 }
 618                 $var_name = get_value_of($var_name);
 619                 $self->ParseElementPushLevel($e, GetNextLevel($e, $l), $ndr, $var_name, $env, 1, 1);
 620
 621                 if ($l->{POINTER_TYPE} ne "ref") {
 622                         if ($l->{POINTER_TYPE} eq "relative") {
 623                                 $self->pidl("NDR_CHECK(ndr_push_relative_ptr2_end($ndr, $rel_var_name));");
 624                         }
 625                         $self->deindent;
 626                         $self->pidl("}");
 627                 }
 628         } elsif ($l->{TYPE} eq "ARRAY" and not has_fast_array($e,$l) and
 629                 not is_charset_array($e, $l)) {
 630                 my $length = ParseExpr($l->{LENGTH_IS}, $env, $e->{ORIGINAL});
 631                 my $counter = "cntr_$e->{NAME}_$l->{LEVEL_INDEX}";
 632
 633                 my $array_pointless = ($length eq "0");
 634
 635                 if ($array_pointless) {
 636                         warning($e->{ORIGINAL}, "pointless array `$e->{NAME}' will always have size 0");
 637                 }
 638
 639                 $var_name = get_array_element($var_name, $counter);
 640
 641                 if ((($primitives and not $l->{IS_DEFERRED}) or ($deferred and $l->{IS_DEFERRED})) and not $array_pointless) {
 642                         $self->pidl("for ($counter = 0; $counter < $length; $counter++) {");
 643                         $self->indent;
 644                         $self->ParseElementPushLevel($e, GetNextLevel($e, $l), $ndr, $var_name, $env, 1, 0);
 645                         $self->deindent;
 646                         $self->pidl("}");
 647                 }
 648
 649                 if ($deferred and ContainsDeferred($e, $l) and not $array_pointless) {
 650                         $self->pidl("for ($counter = 0; $counter < $length; $counter++) {");
 651                         $self->indent;
 652                         $self->ParseElementPushLevel($e, GetNextLevel($e, $l), $ndr, $var_name, $env, 0, 1);
 653                         $self->deindent;
 654                         $self->pidl("}");
 655                 }
 656         } elsif ($l->{TYPE} eq "SWITCH") {
 657                 $self->ParseElementPushLevel($e, GetNextLevel($e, $l), $ndr, $var_name, $env, $primitives, $deferred);
 658         }
 659 }
 660
 661 #####################################################################
 662 # parse scalars in a structure element
 663 sub ParseElementPush($$$$$$)
 664 {
 665         my ($self,$e,$ndr,$env,$primitives,$deferred) = @_;
 666         my $subndr = undef;
 667
 668         my $var_name = $env->{$e->{NAME}};
 669
 670         return if ContainsPipe($e, $e->{LEVELS}[0]);
 671
 672         return unless $primitives or ($deferred and ContainsDeferred($e, $e->{LEVELS}[0]));
 673
 674         # Representation type is different from transmit_as
 675         if ($e->{REPRESENTATION_TYPE} ne $e->{TYPE}) {
 676                 $self->pidl("{");
 677                 $self->indent;
 678                 my $transmit_name = "_transmit_$e->{NAME}";
 679                 $self->pidl(mapTypeName($e->{TYPE}) ." $transmit_name;");
 680                 $self->pidl("NDR_CHECK(ndr_$e->{REPRESENTATION_TYPE}_to_$e->{TYPE}($var_name, " . get_pointer_to($transmit_name) . "));");
 681                 $var_name = $transmit_name;
 682         }
 683
 684         $var_name = append_prefix($e, $var_name);
 685
 686         $self->start_flags($e, $ndr);
 687
 688         if (defined(my $value = has_property($e, "value"))) {
 689                 $var_name = ParseExpr($value, $env, $e->{ORIGINAL});
 690         }
 691
 692         $self->ParseElementPushLevel($e, $e->{LEVELS}[0], $ndr, $var_name, $env, $primitives, $deferred);
 693
 694         $self->end_flags($e, $ndr);
 695
 696         if ($e->{REPRESENTATION_TYPE} ne $e->{TYPE}) {
 697                 $self->deindent;
 698                 $self->pidl("}");
 699         }
 700 }
 701
 702 #####################################################################
 703 # parse a pointer in a struct element or function
 704 sub ParsePtrPush($$$$$)
 705 {
 706         my ($self,$e,$l,$ndr,$var_name) = @_;
 707
 708         if ($l->{POINTER_TYPE} eq "ref") {
 709                 $self->pidl("if ($var_name == NULL) {");
 710                 $self->indent;
 711                 $self->pidl("return ndr_push_error($ndr, NDR_ERR_INVALID_POINTER, \"NULL [ref] pointer\");");
 712                 $self->deindent;
 713                 $self->pidl("}");
 714                 if ($l->{LEVEL} eq "EMBEDDED") {
 715                         $self->pidl("NDR_CHECK(ndr_push_ref_ptr(ndr));");
 716                 }
 717         } elsif ($l->{POINTER_TYPE} eq "relative") {
 718                 $self->pidl("NDR_CHECK(ndr_push_relative_ptr1($ndr, $var_name));");
 719         } elsif ($l->{POINTER_TYPE} eq "relative_short") {
 720                 $self->pidl("NDR_CHECK(ndr_push_short_relative_ptr1($ndr, $var_name));");
 721         } elsif ($l->{POINTER_TYPE} eq "unique") {
 722                 $self->pidl("NDR_CHECK(ndr_push_unique_ptr($ndr, $var_name));");
 723         } elsif ($l->{POINTER_TYPE} eq "full") {
 724                 $self->pidl("NDR_CHECK(ndr_push_full_ptr($ndr, $var_name));");
 725         } elsif ($l->{POINTER_TYPE} eq "ignore") {
 726                 # We don't want this pointer to appear on the wire at all
 727                 $self->pidl("NDR_CHECK(ndr_push_uint3264(ndr, NDR_SCALARS, 0));");
 728         } else {
 729                 die("Unhandled pointer type $l->{POINTER_TYPE}");
 730         }
 731 }
 732
 733 sub need_pointer_to($$$)
 734 {
 735         my ($e, $l, $scalar_only) = @_;
 736
 737         my $t;
 738         if (ref($l->{DATA_TYPE})) {
 739                 $t = "$l->{DATA_TYPE}->{TYPE}_$l->{DATA_TYPE}->{NAME}";
 740         } else {
 741                 $t = $l->{DATA_TYPE};
 742         }
 743
 744         if (not Parse::Pidl::Typelist::is_scalar($t)) {
 745                 return 1 if $scalar_only;
 746         }
 747
 748         my $arrays = 0;
 749
 750         foreach my $tl (@{$e->{LEVELS}}) {
 751                 last if $l == $tl;
 752                 if ($tl->{TYPE} eq "ARRAY") {
 753                         $arrays++;
 754                 }
 755         }
 756
 757         if (Parse::Pidl::Typelist::scalar_is_reference($t)) {
 758                 return 1 unless $arrays;
 759         }
 760
 761         return 0;
 762 }
 763
 764 sub ParseDataPrint($$$$$)
 765 {
 766         my ($self, $e, $l, $ndr, $var_name) = @_;
 767
 768         if (not ref($l->{DATA_TYPE}) or defined($l->{DATA_TYPE}->{NAME})) {
 769
 770                 if (need_pointer_to($e, $l, 1)) {
 771                         $var_name = get_pointer_to($var_name);
 772                 }
 773
 774                 $self->pidl(TypeFunctionName("ndr_print", $l->{DATA_TYPE})."($ndr, \"$e->{NAME}\", $var_name);");
 775         } else {
 776                 $self->ParseTypePrint($l->{DATA_TYPE}, $ndr, $var_name);
 777         }
 778 }
 779
 780 #####################################################################
 781 # print scalars in a structure element
 782 sub ParseElementPrint($$$$$)
 783 {
 784         my($self, $e, $ndr, $var_name, $env) = @_;
 785
 786         return if (has_property($e, "noprint"));
 787         my $cur_depth = 0;
 788         my $ignore_depth = 0xFFFF;
 789
 790         if ($e->{REPRESENTATION_TYPE} ne $e->{TYPE}) {
 791                 $self->pidl("ndr_print_$e->{REPRESENTATION_TYPE}($ndr, \"$e->{NAME}\", $var_name);");
 792                 return;
 793         }
 794
 795         $var_name = append_prefix($e, $var_name);
 796
 797         if (defined(my $value = has_property($e, "value"))) {
 798                 $var_name = "($ndr->flags & LIBNDR_PRINT_SET_VALUES)?" . ParseExpr($value,$env, $e->{ORIGINAL}) . ":$var_name";
 799         }
 800
 801         foreach my $l (@{$e->{LEVELS}}) {
 802                 $cur_depth += 1;
 803
 804                 if ($cur_depth > $ignore_depth) {
 805                         next;
 806                 }
 807
 808                 if ($l->{TYPE} eq "POINTER") {
 809                         $self->pidl("ndr_print_ptr($ndr, \"$e->{NAME}\", $var_name);");
 810                         if ($l->{POINTER_TYPE} eq "ignore") {
 811                                 $self->pidl("/* [ignore] '$e->{NAME}' */");
 812                                 $ignore_depth = $cur_depth;
 813                                 last;
 814                         }
 815                         $self->pidl("$ndr->depth++;");
 816                         if ($l->{POINTER_TYPE} ne "ref") {
 817                                 $self->pidl("if ($var_name) {");
 818                                 $self->indent;
 819                         }
 820                         $var_name = get_value_of($var_name);
 821                 } elsif ($l->{TYPE} eq "ARRAY") {
 822                         my $length;
 823
 824                         if ($l->{IS_CONFORMANT} or $l->{IS_VARYING}) {
 825                                 $var_name = get_pointer_to($var_name);
 826                         }
 827
 828                         if ($l->{IS_ZERO_TERMINATED} and not defined($l->{LENGTH_IS})) {
 829                                 $length = "ndr_string_length($var_name, sizeof(*$var_name))";
 830                         } else {
 831                                 $length = ParseExprExt($l->{LENGTH_IS}, $env, $e->{ORIGINAL},
 832                                                         check_null_pointer($e, $env, sub { $self->pidl(shift); }, "return;"), check_fully_dereferenced($e, $env));
 833                         }
 834
 835                         if (is_charset_array($e,$l)) {
 836                                 $self->pidl("ndr_print_string($ndr, \"$e->{NAME}\", $var_name);");
 837                                 last;
 838                         } elsif (has_fast_array($e, $l)) {
 839                                 my $nl = GetNextLevel($e, $l);
 840                                 $self->pidl("ndr_print_array_$nl->{DATA_TYPE}($ndr, \"$e->{NAME}\", $var_name, $length);");
 841                                 last;
 842                         } else {
 843                                 my $counter = "cntr_$e->{NAME}_$l->{LEVEL_INDEX}";
 844
 845                                 $self->pidl("$ndr->print($ndr, \"\%s: ARRAY(\%d)\", \"$e->{NAME}\", (int)$length);");
 846                                 $self->pidl("$ndr->depth++;");
 847                                 $self->pidl("for ($counter=0;$counter<$length;$counter++) {");
 848                                 $self->indent;
 849
 850                                 $var_name = get_array_element($var_name, $counter);
 851                         }
 852                 } elsif ($l->{TYPE} eq "DATA") {
 853                         $self->ParseDataPrint($e, $l, $ndr, $var_name);
 854                 } elsif ($l->{TYPE} eq "SWITCH") {
 855                         my $switch_var = ParseExprExt($l->{SWITCH_IS}, $env, $e->{ORIGINAL},
 856                                                 check_null_pointer($e, $env, sub { $self->pidl(shift); }, "return;"), check_fully_dereferenced($e, $env));
 857                         $self->pidl("ndr_print_set_switch_value($ndr, " . get_pointer_to($var_name) . ", $switch_var);");
 858                 }
 859         }
 860
 861         foreach my $l (reverse @{$e->{LEVELS}}) {
 862                 $cur_depth -= 1;
 863
 864                 if ($cur_depth > $ignore_depth) {
 865                         next;
 866                 }
 867
 868                 if ($l->{TYPE} eq "POINTER") {
 869                         if ($l->{POINTER_TYPE} eq "ignore") {
 870                                 next;
 871                         }
 872
 873                         if ($l->{POINTER_TYPE} ne "ref") {
 874                                 $self->deindent;
 875                                 $self->pidl("}");
 876                         }
 877                         $self->pidl("$ndr->depth--;");
 878                 } elsif (($l->{TYPE} eq "ARRAY")
 879                         and not is_charset_array($e,$l)
 880                         and not has_fast_array($e,$l)) {
 881                         $self->deindent;
 882                         $self->pidl("}");
 883                         $self->pidl("$ndr->depth--;");
 884                 }
 885         }
 886 }
 887
 888 #####################################################################
 889 # parse scalars in a structure element - pull size
 890 sub ParseSwitchPull($$$$$$)
 891 {
 892         my($self,$e,$l,$ndr,$var_name,$env) = @_;
 893         my $switch_var = ParseExprExt($l->{SWITCH_IS}, $env, $e->{ORIGINAL},
 894                 check_null_pointer($e, $env, sub { $self->pidl(shift); },
 895                                    "return ndr_pull_error($ndr, NDR_ERR_INVALID_POINTER, \"NULL Pointer for switch_is()\");"),
 896                 check_fully_dereferenced($e, $env));
 897
 898         $var_name = get_pointer_to($var_name);
 899         $self->pidl("NDR_CHECK(ndr_pull_set_switch_value($ndr, $var_name, $switch_var));");
 900 }
 901
 902 #####################################################################
 903 # push switch element
 904 sub ParseSwitchPush($$$$$$)
 905 {
 906         my($self,$e,$l,$ndr,$var_name,$env) = @_;
 907         my $switch_var = ParseExprExt($l->{SWITCH_IS}, $env, $e->{ORIGINAL},
 908                 check_null_pointer($e, $env, sub { $self->pidl(shift); },
 909                                    "return ndr_push_error($ndr, NDR_ERR_INVALID_POINTER, \"NULL Pointer for switch_is()\");"),
 910                 check_fully_dereferenced($e, $env));
 911
 912         $var_name = get_pointer_to($var_name);
 913         $self->pidl("NDR_CHECK(ndr_push_set_switch_value($ndr, $var_name, $switch_var));");
 914 }
 915
 916 sub ParseDataPull($$$$$$$)
 917 {
 918         my ($self,$e,$l,$ndr,$var_name,$primitives,$deferred) = @_;
 919
 920         if (not ref($l->{DATA_TYPE}) or defined($l->{DATA_TYPE}->{NAME})) {
 921
 922                 my $ndr_flags = CalcNdrFlags($l, $primitives, $deferred);
 923
 924                 if (need_pointer_to($e, $l, 0)) {
 925                         $var_name = get_pointer_to($var_name);
 926                 }
 927
 928                 $var_name = get_pointer_to($var_name);
 929
 930                 $self->pidl("NDR_CHECK(".TypeFunctionName("ndr_pull", $l->{DATA_TYPE})."($ndr, $ndr_flags, $var_name));");
 931
 932                 my $pl = GetPrevLevel($e, $l);
 933
 934                 my $range = has_property($e, "range");
 935                 if ($range and $pl->{TYPE} ne "ARRAY") {
 936                         $var_name = get_value_of($var_name);
 937                         my $signed = Parse::Pidl::Typelist::is_signed($l->{DATA_TYPE});
 938                         my ($low, $high) = split(/,/, $range, 2);
 939                         if ($low < 0 and not $signed) {
 940                                 warning(0, "$low is invalid for the range of an unsigned type");
 941                         }
 942                         if ($low == 0 and not $signed) {
 943                                 $self->pidl("if ($var_name > $high) {");
 944                         } else {
 945                                 $self->pidl("if ($var_name < $low || $var_name > $high) {");
 946                         }
 947                         $self->pidl("\treturn ndr_pull_error($ndr, NDR_ERR_RANGE, \"value out of range\");");
 948                         $self->pidl("}");
 949                 }
 950         } else {
 951                 $self->ParseTypePull($l->{DATA_TYPE}, $ndr, $var_name, $primitives, $deferred);
 952         }
 953 }
 954
 955 sub ParseDataPush($$$$$$$)
 956 {
 957         my ($self,$e,$l,$ndr,$var_name,$primitives,$deferred) = @_;
 958
 959         if (not ref($l->{DATA_TYPE}) or defined($l->{DATA_TYPE}->{NAME})) {
 960
 961                 my $ndr_flags = CalcNdrFlags($l, $primitives, $deferred);
 962
 963                 # strings are passed by value rather than reference
 964                 if (need_pointer_to($e, $l, 1)) {
 965                         $var_name = get_pointer_to($var_name);
 966                 }
 967
 968                 $self->pidl("NDR_CHECK(".TypeFunctionName("ndr_push", $l->{DATA_TYPE})."($ndr, $ndr_flags, $var_name));");
 969         } else {
 970                 $self->ParseTypePush($l->{DATA_TYPE}, $ndr, $var_name, $primitives, $deferred);
 971         }
 972 }
 973
 974 sub CalcNdrFlags($$$)
 975 {
 976         my ($l,$primitives,$deferred) = @_;
 977
 978         my $scalars = 0;
 979         my $buffers = 0;
 980
 981         # Add NDR_SCALARS if this one is deferred
 982         # and deferreds may be pushed
 983         $scalars = 1 if ($l->{IS_DEFERRED} and $deferred);
 984
 985         # Add NDR_SCALARS if this one is not deferred and
 986         # primitives may be pushed
 987         $scalars = 1 if (!$l->{IS_DEFERRED} and $primitives);
 988
 989         # Add NDR_BUFFERS if this one contains deferred stuff
 990         # and deferreds may be pushed
 991         $buffers = 1 if ($l->{CONTAINS_DEFERRED} and $deferred);
 992
 993         return "NDR_SCALARS|NDR_BUFFERS" if ($scalars and $buffers);
 994         return "NDR_SCALARS" if ($scalars);
 995         return "NDR_BUFFERS" if ($buffers);
 996         return undef;
 997 }
 998
 999 sub ParseMemCtxPullFlags($$$$)
1000 {
1001         my ($self, $e, $l) = @_;
1002
1003         return undef unless ($l->{TYPE} eq "POINTER" or $l->{TYPE} eq "ARRAY");
1004         return undef if (($l->{TYPE} eq "POINTER") and ($l->{POINTER_TYPE} eq "ignore"));
1005
1006         return undef unless ($l->{TYPE} ne "ARRAY" or ArrayDynamicallyAllocated($e,$l));
1007         return undef if has_fast_array($e, $l);
1008         return undef if is_charset_array($e, $l);
1009
1010         my $mem_flags = "0";
1011
1012         if (($l->{TYPE} eq "POINTER") and ($l->{POINTER_TYPE} eq "ref")) {
1013                 my $nl = GetNextLevel($e, $l);
1014                 return undef if ($nl->{TYPE} eq "PIPE");
1015                 return undef if ($nl->{TYPE} eq "ARRAY");
1016                 return undef if (($nl->{TYPE} eq "DATA") and ($nl->{DATA_TYPE} eq "string"));
1017
1018                 if ($l->{LEVEL} eq "TOP") {
1019                         $mem_flags = "LIBNDR_FLAG_REF_ALLOC";
1020                 }
1021         }
1022
1023         return $mem_flags;
1024 }
1025
1026 sub ParseMemCtxPullStart($$$$$)
1027 {
1028         my ($self, $e, $l, $ndr, $ptr_name) = @_;
1029
1030         my $mem_r_ctx = "_mem_save_$e->{NAME}_$l->{LEVEL_INDEX}";
1031         my $mem_c_ctx = $ptr_name;
1032         my $mem_c_flags = $self->ParseMemCtxPullFlags($e, $l);
1033
1034         return unless defined($mem_c_flags);
1035
1036         $self->pidl("$mem_r_ctx = NDR_PULL_GET_MEM_CTX($ndr);");
1037         $self->pidl("NDR_PULL_SET_MEM_CTX($ndr, $mem_c_ctx, $mem_c_flags);");
1038 }
1039
1040 sub ParseMemCtxPullEnd($$$$)
1041 {
1042         my ($self, $e, $l, $ndr) = @_;
1043
1044         my $mem_r_ctx = "_mem_save_$e->{NAME}_$l->{LEVEL_INDEX}";
1045         my $mem_r_flags = $self->ParseMemCtxPullFlags($e, $l);
1046
1047         return unless defined($mem_r_flags);
1048
1049         $self->pidl("NDR_PULL_SET_MEM_CTX($ndr, $mem_r_ctx, $mem_r_flags);");
1050 }
1051
1052 sub CheckStringTerminator($$$$$)
1053 {
1054         my ($self,$ndr,$e,$l,$length) = @_;
1055         my $nl = GetNextLevel($e, $l);
1056
1057         # Make sure last element is zero!
1058         $self->pidl("NDR_CHECK(ndr_check_string_terminator($ndr, $length, sizeof($nl->{DATA_TYPE}_t)));");
1059 }
1060
1061 sub ParseElementPullLevel
1062 {
1063         my($self,$e,$l,$ndr,$var_name,$env,$primitives,$deferred) = @_;
1064
1065         my $ndr_flags = CalcNdrFlags($l, $primitives, $deferred);
1066
1067         if ($l->{TYPE} eq "ARRAY" and ($l->{IS_VARYING} or $l->{IS_CONFORMANT})) {
1068                 $var_name = get_pointer_to($var_name);
1069         }
1070
1071         # Only pull something if there's actually something to be pulled
1072         if (defined($ndr_flags)) {
1073                 if ($l->{TYPE} eq "SUBCONTEXT") {
1074                         my $subndr = $self->ParseSubcontextPullStart($e, $l, $ndr, $env);
1075                         $self->ParseElementPullLevel($e, GetNextLevel($e,$l), $subndr, $var_name, $env, 1, 1);
1076                         $self->ParseSubcontextPullEnd($e, $l, $ndr, $env);
1077                 } elsif ($l->{TYPE} eq "ARRAY") {
1078                         my $length = $self->ParseArrayPullHeader($e, $l, $ndr, $var_name, $env);
1079
1080                         if (my $range = has_property($e, "range")) {
1081                                 my ($low, $high) = split(/,/, $range, 2);
1082                                 if ($low < 0) {
1083                                         warning(0, "$low is invalid for the range of an array size");
1084                                 }
1085                                 if ($low == 0) {
1086                                         $self->pidl("if ($length > $high) {");
1087                                 } else {
1088                                         $self->pidl("if ($length < $low || $length > $high) {");
1089                                 }
1090                                 $self->pidl("\treturn ndr_pull_error($ndr, NDR_ERR_RANGE, \"value out of range\");");
1091                                 $self->pidl("}");
1092                         }
1093
1094                         my $nl = GetNextLevel($e, $l);
1095
1096                         if (is_charset_array($e,$l)) {
1097                                 if ($l->{IS_ZERO_TERMINATED}) {
1098                                         $self->CheckStringTerminator($ndr, $e, $l, $length);
1099                                 }
1100                                 if ($l->{IS_TO_NULL}) {
1101                                         $self->pidl("NDR_CHECK(ndr_pull_charset_to_null($ndr, $ndr_flags, ".get_pointer_to($var_name).", $length, sizeof(" . mapTypeName($nl->{DATA_TYPE}) . "), CH_$e->{PROPERTIES}->{charset}));");
1102                                 } else {
1103                                         $self->pidl("NDR_CHECK(ndr_pull_charset($ndr, $ndr_flags, ".get_pointer_to($var_name).", $length, sizeof(" . mapTypeName($nl->{DATA_TYPE}) . "), CH_$e->{PROPERTIES}->{charset}));");
1104                                 }
1105                                 return;
1106                         } elsif (has_fast_array($e, $l)) {
1107                                 if ($l->{IS_ZERO_TERMINATED}) {
1108                                         $self->CheckStringTerminator($ndr,$e,$l,$length);
1109                                 }
1110                                 $self->pidl("NDR_CHECK(ndr_pull_array_$nl->{DATA_TYPE}($ndr, $ndr_flags, $var_name, $length));");
1111                                 return;
1112                         }
1113                 } elsif ($l->{TYPE} eq "POINTER") {
1114                         $self->ParsePtrPull($e, $l, $ndr, $var_name);
1115                 } elsif ($l->{TYPE} eq "SWITCH") {
1116                         $self->ParseSwitchPull($e, $l, $ndr, $var_name, $env);
1117                 } elsif ($l->{TYPE} eq "DATA") {
1118                         $self->ParseDataPull($e, $l, $ndr, $var_name, $primitives, $deferred);
1119                 } elsif ($l->{TYPE} eq "TYPEDEF") {
1120                         $typefamily{$e->{DATA}->{TYPE}}->{PULL_FN_BODY}->($self, $e->{DATA}, $ndr, $var_name);
1121                 }
1122         }
1123
1124         # add additional constructions
1125         if ($l->{TYPE} eq "POINTER" and $l->{POINTER_TYPE} eq "ignore") {
1126                 $self->pidl("/* [ignore] '$e->{NAME}' */");
1127         } elsif ($l->{TYPE} eq "POINTER" and $deferred) {
1128                 if ($l->{POINTER_TYPE} ne "ref") {
1129                         $self->pidl("if ($var_name) {");
1130                         $self->indent;
1131
1132                         if ($l->{POINTER_TYPE} eq "relative" or $l->{POINTER_TYPE} eq "relative_short") {
1133                                 $self->pidl("uint32_t _relative_save_offset;");
1134                                 $self->pidl("_relative_save_offset = $ndr->offset;");
1135                                 $self->pidl("NDR_CHECK(ndr_pull_relative_ptr2($ndr, $var_name));");
1136                         }
1137                 }
1138
1139                 $self->ParseMemCtxPullStart($e, $l, $ndr, $var_name);
1140
1141                 $var_name = get_value_of($var_name);
1142                 $self->ParseElementPullLevel($e, GetNextLevel($e,$l), $ndr, $var_name, $env, 1, 1);
1143
1144                 $self->ParseMemCtxPullEnd($e, $l, $ndr);
1145
1146                 if ($l->{POINTER_TYPE} ne "ref") {
1147                         if ($l->{POINTER_TYPE} eq "relative") {
1148                                 $self->pidl("if ($ndr->offset > $ndr->relative_highest_offset) {");
1149                                 $self->indent;
1150                                 $self->pidl("$ndr->relative_highest_offset = $ndr->offset;");
1151                                 $self->deindent;
1152                                 $self->pidl("}");
1153                                 $self->pidl("$ndr->offset = _relative_save_offset;");
1154                         }
1155                         $self->deindent;
1156                         $self->pidl("}");
1157                 }
1158         } elsif ($l->{TYPE} eq "ARRAY" and
1159                         not has_fast_array($e,$l) and not is_charset_array($e, $l)) {
1160                 my $length = $self->ParseArrayPullGetLength($e, $l, $ndr, $var_name, $env);
1161                 my $counter = "cntr_$e->{NAME}_$l->{LEVEL_INDEX}";
1162                 my $array_name = $var_name;
1163
1164                 if (my $range = has_property($e, "range")) {
1165                         my ($low, $high) = split(/,/, $range, 2);
1166                         if ($low < 0) {
1167                                 warning(0, "$low is invalid for the range of an array size");
1168                         }
1169                         if ($low == 0) {
1170                                 $self->pidl("if ($length > $high) {");
1171                         } else {
1172                                 $self->pidl("if ($length < $low || $length > $high) {");
1173                         }
1174                         $self->pidl("\treturn ndr_pull_error($ndr, NDR_ERR_RANGE, \"value out of range\");");
1175                         $self->pidl("}");
1176                 }
1177
1178                 $var_name = get_array_element($var_name, $counter);
1179
1180                 $self->ParseMemCtxPullStart($e, $l, $ndr, $array_name);
1181
1182                 if (($primitives and not $l->{IS_DEFERRED}) or ($deferred and $l->{IS_DEFERRED})) {
1183                         my $nl = GetNextLevel($e,$l);
1184
1185                         if ($l->{IS_ZERO_TERMINATED}) {
1186                                 $self->CheckStringTerminator($ndr,$e,$l,$length);
1187                         }
1188
1189                         $self->pidl("for ($counter = 0; $counter < $length; $counter++) {");
1190                         $self->indent;
1191                         $self->ParseElementPullLevel($e, $nl, $ndr, $var_name, $env, 1, 0);
1192                         $self->deindent;
1193                         $self->pidl("}");
1194                 }
1195
1196                 if ($deferred and ContainsDeferred($e, $l)) {
1197                         $self->pidl("for ($counter = 0; $counter < $length; $counter++) {");
1198                         $self->indent;
1199                         $self->ParseElementPullLevel($e,GetNextLevel($e,$l), $ndr, $var_name, $env, 0, 1);
1200                         $self->deindent;
1201                         $self->pidl("}");
1202                 }
1203
1204                 $self->ParseMemCtxPullEnd($e, $l, $ndr);
1205
1206         } elsif ($l->{TYPE} eq "SWITCH") {
1207                 $self->ParseElementPullLevel($e, GetNextLevel($e,$l), $ndr, $var_name, $env, $primitives, $deferred);
1208         }
1209 }
1210
1211 #####################################################################
1212 # parse scalars in a structure element - pull size
1213 sub ParseElementPull($$$$$$)
1214 {
1215         my($self,$e,$ndr,$env,$primitives,$deferred) = @_;
1216
1217         my $var_name = $env->{$e->{NAME}};
1218         my $represent_name;
1219         my $transmit_name;
1220
1221         return if ContainsPipe($e, $e->{LEVELS}[0]);
1222
1223         return unless $primitives or ($deferred and ContainsDeferred($e, $e->{LEVELS}[0]));
1224
1225         if ($e->{REPRESENTATION_TYPE} ne $e->{TYPE}) {
1226                 $self->pidl("{");
1227                 $self->indent;
1228                 $represent_name = $var_name;
1229                 $transmit_name = "_transmit_$e->{NAME}";
1230                 $var_name = $transmit_name;
1231                 $self->pidl(mapTypeName($e->{TYPE})." $var_name;");
1232         }
1233
1234         $var_name = append_prefix($e, $var_name);
1235
1236         $self->start_flags($e, $ndr);
1237
1238         $self->ParseElementPullLevel($e,$e->{LEVELS}[0],$ndr,$var_name,$env,$primitives,$deferred);
1239
1240         $self->end_flags($e, $ndr);
1241
1242         # Representation type is different from transmit_as
1243         if ($e->{REPRESENTATION_TYPE} ne $e->{TYPE}) {
1244                 $self->pidl("NDR_CHECK(ndr_$e->{TYPE}_to_$e->{REPRESENTATION_TYPE}($transmit_name, ".get_pointer_to($represent_name)."));");
1245                 $self->deindent;
1246                 $self->pidl("}");
1247         }
1248 }
1249
1250 #####################################################################
1251 # parse a pointer in a struct element or function
1252 sub ParsePtrPull($$$$$)
1253 {
1254         my($self, $e,$l,$ndr,$var_name) = @_;
1255
1256         my $nl = GetNextLevel($e, $l);
1257         my $next_is_array = ($nl->{TYPE} eq "ARRAY");
1258         my $next_is_string = (($nl->{TYPE} eq "DATA") and
1259                                                  ($nl->{DATA_TYPE} eq "string"));
1260
1261         if ($l->{POINTER_TYPE} eq "ref" and $l->{LEVEL} eq "TOP") {
1262
1263                 if (!$next_is_array and !$next_is_string) {
1264                         $self->pidl("if ($ndr->flags & LIBNDR_FLAG_REF_ALLOC) {");
1265                         $self->pidl("\tNDR_PULL_ALLOC($ndr, $var_name);");
1266                         $self->pidl("}");
1267                 }
1268
1269                 return;
1270         } elsif ($l->{POINTER_TYPE} eq "ref" and $l->{LEVEL} eq "EMBEDDED") {
1271                 $self->pidl("NDR_CHECK(ndr_pull_ref_ptr($ndr, &_ptr_$e->{NAME}));");
1272         } elsif (($l->{POINTER_TYPE} eq "unique") or
1273                  ($l->{POINTER_TYPE} eq "relative") or
1274                  ($l->{POINTER_TYPE} eq "full")) {
1275                 $self->pidl("NDR_CHECK(ndr_pull_generic_ptr($ndr, &_ptr_$e->{NAME}));");
1276         } elsif ($l->{POINTER_TYPE} eq "relative_short") {
1277                 $self->pidl("NDR_CHECK(ndr_pull_relative_ptr_short($ndr, &_ptr_$e->{NAME}));");
1278         } elsif ($l->{POINTER_TYPE} eq "ignore") {
1279                 #We want to consume the pointer bytes, but ignore the pointer value
1280                 $self->pidl("NDR_CHECK(ndr_pull_uint3264(ndr, NDR_SCALARS, &_ptr_$e->{NAME}));");
1281                 $self->pidl("_ptr_$e->{NAME} = 0;");
1282         } else {
1283                 die("Unhandled pointer type $l->{POINTER_TYPE}");
1284         }
1285
1286         $self->pidl("if (_ptr_$e->{NAME}) {");
1287         $self->indent;
1288
1289         if ($l->{POINTER_TYPE} eq "ignore") {
1290                 # Don't do anything, we don't want to do the
1291                 # allocation, as we forced it to NULL just above, and
1292                 # we may not know the declared type anyway.
1293         } else {
1294                 # Don't do this for arrays, they're allocated at the actual level
1295                 # of the array
1296                 unless ($next_is_array or $next_is_string) {
1297                        $self->pidl("NDR_PULL_ALLOC($ndr, $var_name);");
1298                 } else {
1299                        # FIXME: Yes, this is nasty.
1300                        # We allocate an array twice
1301                        # - once just to indicate that it's there,
1302                        # - then the real allocation...
1303                        $self->pidl("NDR_PULL_ALLOC($ndr, $var_name);");
1304                 }
1305         }
1306
1307         #$self->pidl("memset($var_name, 0, sizeof($var_name));");
1308         if ($l->{POINTER_TYPE} eq "relative" or $l->{POINTER_TYPE} eq "relative_short") {
1309                 $self->pidl("NDR_CHECK(ndr_pull_relative_ptr1($ndr, $var_name, _ptr_$e->{NAME}));");
1310         }
1311         $self->deindent;
1312         $self->pidl("} else {");
1313         $self->pidl("\t$var_name = NULL;");
1314         $self->pidl("}");
1315 }
1316
1317 sub ParseStructPushPrimitives($$$$$)
1318 {
1319         my ($self, $struct, $ndr, $varname, $env) = @_;
1320
1321         # see if the structure contains a conformant array. If it
1322         # does, then it must be the last element of the structure, and
1323         # we need to push the conformant length early, as it fits on
1324         # the wire before the structure (and even before the structure
1325         # alignment)
1326         if (defined($struct->{SURROUNDING_ELEMENT})) {
1327                 my $e = $struct->{SURROUNDING_ELEMENT};
1328
1329                 if (defined($e->{LEVELS}[0]) and
1330                         $e->{LEVELS}[0]->{TYPE} eq "ARRAY") {
1331                         my $size;
1332
1333                         if ($e->{LEVELS}[0]->{IS_ZERO_TERMINATED}) {
1334                                 if (has_property($e, "charset")) {
1335                                         $size = "ndr_charset_length($varname->$e->{NAME}, CH_$e->{PROPERTIES}->{charset})";
1336                                 } else {
1337                                         $size = "ndr_string_length($varname->$e->{NAME}, sizeof(*$varname->$e->{NAME}))";
1338                                 }
1339                                 if (defined($e->{LEVELS}[0]->{SIZE_IS})) {
1340                                         $size = ParseExpr($e->{LEVELS}[0]->{SIZE_IS}, $env, $e->{ORIGINAL});
1341                                 }
1342                         } else {
1343                                 $size = ParseExpr($e->{LEVELS}[0]->{SIZE_IS}, $env, $e->{ORIGINAL});
1344                         }
1345
1346                         $self->pidl("NDR_CHECK(ndr_push_uint3264($ndr, NDR_SCALARS, $size));");
1347                 } else {
1348                         $self->pidl("NDR_CHECK(ndr_push_uint3264($ndr, NDR_SCALARS, ndr_string_array_size($ndr, $varname->$e->{NAME})));");
1349                 }
1350         }
1351
1352         $self->pidl("NDR_CHECK(ndr_push_align($ndr, $struct->{ALIGN}));");
1353
1354         if (defined($struct->{PROPERTIES}{relative_base})) {
1355                 # set the current offset as base for relative pointers
1356                 # and store it based on the toplevel struct/union
1357                 $self->pidl("NDR_CHECK(ndr_push_setup_relative_base_offset1($ndr, $varname, $ndr->offset));");
1358         }
1359
1360         $self->ParseElementPush($_, $ndr, $env, 1, 0) foreach (@{$struct->{ELEMENTS}});
1361
1362         $self->pidl("NDR_CHECK(ndr_push_trailer_align($ndr, $struct->{ALIGN}));");
1363 }
1364
1365 sub ParseStructPushDeferred($$$$)
1366 {
1367         my ($self, $struct, $ndr, $varname, $env) = @_;
1368         if (defined($struct->{PROPERTIES}{relative_base})) {
1369                 # retrieve the current offset as base for relative pointers
1370                 # based on the toplevel struct/union
1371                 $self->pidl("NDR_CHECK(ndr_push_setup_relative_base_offset2($ndr, $varname));");
1372         }
1373         $self->ParseElementPush($_, $ndr, $env, 0, 1) foreach (@{$struct->{ELEMENTS}});
1374 }
1375
1376 #####################################################################
1377 # parse a struct
1378 sub ParseStructPush($$$$)
1379 {
1380         my ($self, $struct, $ndr, $varname) = @_;
1381
1382         return unless defined($struct->{ELEMENTS});
1383
1384         my $env = GenerateStructEnv($struct, $varname);
1385
1386         EnvSubstituteValue($env, $struct);
1387
1388         $self->DeclareArrayVariablesNoZero($_, $env) foreach (@{$struct->{ELEMENTS}});
1389
1390         $self->start_flags($struct, $ndr);
1391
1392         $self->pidl("NDR_PUSH_CHECK_FLAGS(ndr, ndr_flags);");
1393         $self->pidl("if (ndr_flags & NDR_SCALARS) {");
1394         $self->indent;
1395         $self->ParseStructPushPrimitives($struct, $ndr, $varname, $env);
1396         $self->deindent;
1397         $self->pidl("}");
1398
1399         $self->pidl("if (ndr_flags & NDR_BUFFERS) {");
1400         $self->indent;
1401         $self->ParseStructPushDeferred($struct, $ndr, $varname, $env);
1402         $self->deindent;
1403         $self->pidl("}");
1404
1405         $self->end_flags($struct, $ndr);
1406 }
1407
1408 #####################################################################
1409 # generate a push function for an enum
1410 sub ParseEnumPush($$$$)
1411 {
1412         my($self,$enum,$ndr,$varname) = @_;
1413         my($type_fn) = $enum->{BASE_TYPE};
1414
1415         $self->start_flags($enum, $ndr);
1416         $self->pidl("NDR_CHECK(ndr_push_enum_$type_fn($ndr, NDR_SCALARS, $varname));");
1417         $self->end_flags($enum, $ndr);
1418 }
1419
1420 #####################################################################
1421 # generate a pull function for an enum
1422 sub ParseEnumPull($$$$)
1423 {
1424         my($self,$enum,$ndr,$varname) = @_;
1425         my($type_fn) = $enum->{BASE_TYPE};
1426         my($type_v_decl) = mapTypeName($type_fn);
1427
1428         $self->pidl("$type_v_decl v;");
1429         $self->start_flags($enum, $ndr);
1430         $self->pidl("NDR_CHECK(ndr_pull_enum_$type_fn($ndr, NDR_SCALARS, &v));");
1431         $self->pidl("*$varname = v;");
1432
1433         $self->end_flags($enum, $ndr);
1434 }
1435
1436 #####################################################################
1437 # generate a print function for an enum
1438 sub ParseEnumPrint($$$$$)
1439 {
1440         my($self,$enum,$ndr,$name,$varname) = @_;
1441
1442         $self->pidl("const char *val = NULL;");
1443         $self->pidl("");
1444
1445         $self->start_flags($enum, $ndr);
1446
1447         $self->pidl("switch ($varname) {");
1448         $self->indent;
1449         my $els = \@{$enum->{ELEMENTS}};
1450         foreach my $i (0 .. $#{$els}) {
1451                 my $e = ${$els}[$i];
1452                 chomp $e;
1453                 if ($e =~ /^(.*)=/) {
1454                         $e = $1;
1455                 }
1456                 $self->pidl("case $e: val = \"$e\"; break;");
1457         }
1458
1459         $self->deindent;
1460         $self->pidl("}");
1461
1462         $self->pidl("ndr_print_enum($ndr, name, \"$enum->{TYPE}\", val, $varname);");
1463
1464         $self->end_flags($enum, $ndr);
1465 }
1466
1467 sub DeclEnum($$$$)
1468 {
1469         my ($e,$t,$name,$varname) = @_;
1470         return "enum $name " .
1471                 ($t eq "pull"?"*":"") . $varname;
1472 }
1473
1474 $typefamily{ENUM} = {
1475         DECL => \&DeclEnum,
1476         PUSH_FN_BODY => \&ParseEnumPush,
1477         PULL_FN_BODY => \&ParseEnumPull,
1478         PRINT_FN_BODY => \&ParseEnumPrint,
1479 };
1480
1481 #####################################################################
1482 # generate a push function for a bitmap
1483 sub ParseBitmapPush($$$$)
1484 {
1485         my($self,$bitmap,$ndr,$varname) = @_;
1486         my($type_fn) = $bitmap->{BASE_TYPE};
1487
1488         $self->start_flags($bitmap, $ndr);
1489
1490         $self->pidl("NDR_CHECK(ndr_push_$type_fn($ndr, NDR_SCALARS, $varname));");
1491
1492         $self->end_flags($bitmap, $ndr);
1493 }
1494
1495 #####################################################################
1496 # generate a pull function for an bitmap
1497 sub ParseBitmapPull($$$$)
1498 {
1499         my($self,$bitmap,$ndr,$varname) = @_;
1500         my $type_fn = $bitmap->{BASE_TYPE};
1501         my($type_decl) = mapTypeName($bitmap->{BASE_TYPE});
1502
1503         $self->pidl("$type_decl v;");
1504         $self->start_flags($bitmap, $ndr);
1505         $self->pidl("NDR_CHECK(ndr_pull_$type_fn($ndr, NDR_SCALARS, &v));");
1506         $self->pidl("*$varname = v;");
1507
1508         $self->end_flags($bitmap, $ndr);
1509 }
1510
1511 #####################################################################
1512 # generate a print function for an bitmap
1513 sub ParseBitmapPrintElement($$$$$$)
1514 {
1515         my($self,$e,$bitmap,$ndr,$name,$varname) = @_;
1516         my($type_decl) = mapTypeName($bitmap->{BASE_TYPE});
1517         my($type_fn) = $bitmap->{BASE_TYPE};
1518         my($flag);
1519
1520         if ($e =~ /^(\w+) .*$/) {
1521                 $flag = "$1";
1522         } else {
1523                 die "Bitmap: \"$name\" invalid Flag: \"$e\"";
1524         }
1525
1526         $self->pidl("ndr_print_bitmap_flag($ndr, sizeof($type_decl), \"$flag\", $flag, $varname);");
1527 }
1528
1529 #####################################################################
1530 # generate a print function for an bitmap
1531 sub ParseBitmapPrint($$$$$)
1532 {
1533         my($self,$bitmap,$ndr,$name,$varname) = @_;
1534         my($type_decl) = mapTypeName($bitmap->{TYPE});
1535         my($type_fn) = $bitmap->{BASE_TYPE};
1536
1537         $self->start_flags($bitmap, $ndr);
1538
1539         $self->pidl("ndr_print_$type_fn($ndr, name, $varname);");
1540
1541         $self->pidl("$ndr->depth++;");
1542         foreach my $e (@{$bitmap->{ELEMENTS}}) {
1543                 $self->ParseBitmapPrintElement($e, $bitmap, $ndr, $name, $varname);
1544         }
1545         $self->pidl("$ndr->depth--;");
1546
1547         $self->end_flags($bitmap, $ndr);
1548 }
1549
1550 sub DeclBitmap($$$$)
1551 {
1552         my ($e,$t,$name,$varname) = @_;
1553         return mapTypeName(Parse::Pidl::Typelist::bitmap_type_fn($e)) .
1554                 ($t eq "pull"?" *":" ") . $varname;
1555 }
1556
1557 $typefamily{BITMAP} = {
1558         DECL => \&DeclBitmap,
1559         PUSH_FN_BODY => \&ParseBitmapPush,
1560         PULL_FN_BODY => \&ParseBitmapPull,
1561         PRINT_FN_BODY => \&ParseBitmapPrint,
1562 };
1563
1564 #####################################################################
1565 # generate a struct print function
1566 sub ParseStructPrint($$$$$)
1567 {
1568         my($self,$struct,$ndr,$name,$varname) = @_;
1569
1570         return unless defined $struct->{ELEMENTS};
1571
1572         my $env = GenerateStructEnv($struct, $varname);
1573
1574         $self->DeclareArrayVariables($_) foreach (@{$struct->{ELEMENTS}});
1575
1576         $self->pidl("ndr_print_struct($ndr, name, \"$name\");");
1577         $self->pidl("if (r == NULL) { ndr_print_null($ndr); return; }");
1578
1579         $self->start_flags($struct, $ndr);
1580
1581         $self->pidl("$ndr->depth++;");
1582
1583         $self->ParseElementPrint($_, $ndr, $env->{$_->{NAME}}, $env)
1584                 foreach (@{$struct->{ELEMENTS}});
1585         $self->pidl("$ndr->depth--;");
1586
1587         $self->end_flags($struct, $ndr);
1588 }
1589
1590 sub DeclarePtrVariables($$)
1591 {
1592         my ($self,$e) = @_;
1593         foreach my $l (@{$e->{LEVELS}}) {
1594                 my $size = 32;
1595                 if ($l->{TYPE} eq "POINTER" and
1596                         not ($l->{POINTER_TYPE} eq "ref" and $l->{LEVEL} eq "TOP")) {
1597                         if ($l->{POINTER_TYPE} eq "relative_short") {
1598                                 $size = 16;
1599                         }
1600                         $self->pidl("uint${size}_t _ptr_$e->{NAME};");
1601                         last;
1602                 }
1603         }
1604 }
1605
1606 sub DeclareArrayVariables($$)
1607 {
1608         my ($self,$e) = @_;
1609
1610         foreach my $l (@{$e->{LEVELS}}) {
1611                 next if ($l->{TYPE} ne "ARRAY");
1612                 next if has_fast_array($e,$l);
1613                 next if is_charset_array($e,$l);
1614                 $self->pidl("uint32_t cntr_$e->{NAME}_$l->{LEVEL_INDEX};");
1615         }
1616 }
1617
1618 sub DeclareArrayVariablesNoZero($$$)
1619 {
1620         my ($self,$e,$env) = @_;
1621
1622         foreach my $l (@{$e->{LEVELS}}) {
1623                 next if ($l->{TYPE} ne "ARRAY");
1624                 next if has_fast_array($e,$l);
1625                 next if is_charset_array($e,$l);
1626                 my $length = ParseExpr($l->{LENGTH_IS}, $env, $e->{ORIGINAL});
1627                 if ($length eq "0") {
1628                         warning($e->{ORIGINAL}, "pointless array cntr: 'cntr_$e->{NAME}_$l->{LEVEL_INDEX}': length=$length");
1629                 } else {
1630                         $self->pidl("uint32_t cntr_$e->{NAME}_$l->{LEVEL_INDEX};");
1631                 }
1632         }
1633 }
1634
1635 sub DeclareMemCtxVariables($$)
1636 {
1637         my ($self,$e) = @_;
1638         foreach my $l (@{$e->{LEVELS}}) {
1639                 my $mem_flags = $self->ParseMemCtxPullFlags($e, $l);
1640
1641                 if (($l->{TYPE} eq "POINTER") and ($l->{POINTER_TYPE} eq "ignore")) {
1642                         last;
1643                 }
1644
1645                 if (defined($mem_flags)) {
1646                         $self->pidl("TALLOC_CTX *_mem_save_$e->{NAME}_$l->{LEVEL_INDEX};");
1647                 }
1648         }
1649 }
1650
1651 sub ParseStructPullPrimitives($$$$$)
1652 {
1653         my($self,$struct,$ndr,$varname,$env) = @_;
1654
1655         if (defined $struct->{SURROUNDING_ELEMENT}) {
1656                 $self->pidl("NDR_CHECK(ndr_pull_array_size($ndr, &$varname->$struct->{SURROUNDING_ELEMENT}->{NAME}));");
1657         }
1658
1659         $self->pidl("NDR_CHECK(ndr_pull_align($ndr, $struct->{ALIGN}));");
1660
1661         if (defined($struct->{PROPERTIES}{relative_base})) {
1662                 # set the current offset as base for relative pointers
1663                 # and store it based on the toplevel struct/union
1664                 $self->pidl("NDR_CHECK(ndr_pull_setup_relative_base_offset1($ndr, $varname, $ndr->offset));");
1665         }
1666
1667         $self->ParseElementPull($_, $ndr, $env, 1, 0) foreach (@{$struct->{ELEMENTS}});
1668
1669         $self->add_deferred();
1670
1671         $self->pidl("NDR_CHECK(ndr_pull_trailer_align($ndr, $struct->{ALIGN}));");
1672 }
1673
1674 sub ParseStructPullDeferred($$$$$)
1675 {
1676         my ($self,$struct,$ndr,$varname,$env) = @_;
1677
1678         if (defined($struct->{PROPERTIES}{relative_base})) {
1679                 # retrieve the current offset as base for relative pointers
1680                 # based on the toplevel struct/union
1681                 $self->pidl("NDR_CHECK(ndr_pull_setup_relative_base_offset2($ndr, $varname));");
1682         }
1683         foreach my $e (@{$struct->{ELEMENTS}}) {
1684                 $self->ParseElementPull($e, $ndr, $env, 0, 1);
1685         }
1686
1687         $self->add_deferred();
1688 }
1689
1690 #####################################################################
1691 # parse a struct - pull side
1692 sub ParseStructPull($$$$)
1693 {
1694         my($self,$struct,$ndr,$varname) = @_;
1695
1696         return unless defined $struct->{ELEMENTS};
1697
1698         # declare any internal pointers we need
1699         foreach my $e (@{$struct->{ELEMENTS}}) {
1700                 $self->DeclarePtrVariables($e);
1701                 $self->DeclareArrayVariables($e);
1702                 $self->DeclareMemCtxVariables($e);
1703         }
1704
1705         $self->start_flags($struct, $ndr);
1706
1707         my $env = GenerateStructEnv($struct, $varname);
1708
1709         $self->pidl("NDR_PULL_CHECK_FLAGS(ndr, ndr_flags);");
1710         $self->pidl("if (ndr_flags & NDR_SCALARS) {");
1711         $self->indent;
1712         $self->ParseStructPullPrimitives($struct,$ndr,$varname,$env);
1713         $self->deindent;
1714         $self->pidl("}");
1715         $self->pidl("if (ndr_flags & NDR_BUFFERS) {");
1716         $self->indent;
1717         $self->ParseStructPullDeferred($struct,$ndr,$varname,$env);
1718         $self->deindent;
1719         $self->pidl("}");
1720
1721         $self->end_flags($struct, $ndr);
1722 }
1723
1724 #####################################################################
1725 # calculate size of ndr struct
1726 sub ParseStructNdrSize($$$$)
1727 {
1728         my ($self,$t, $name, $varname) = @_;
1729         my $sizevar;
1730
1731         if (my $flags = has_property($t, "flag")) {
1732                 $self->pidl("flags |= $flags;");
1733         }
1734         $self->pidl("return ndr_size_struct($varname, flags, (ndr_push_flags_fn_t)ndr_push_$name);");
1735 }
1736
1737 sub DeclStruct($$$$)
1738 {
1739         my ($e,$t,$name,$varname) = @_;
1740         return ($t ne "pull"?"const ":"") . "struct $name *$varname";
1741 }
1742
1743 sub ArgsStructNdrSize($$$)
1744 {
1745         my ($d, $name, $varname) = @_;
1746         return "const struct $name *$varname, int flags";
1747 }
1748
1749 $typefamily{STRUCT} = {
1750         PUSH_FN_BODY => \&ParseStructPush,
1751         DECL => \&DeclStruct,
1752         PULL_FN_BODY => \&ParseStructPull,
1753         PRINT_FN_BODY => \&ParseStructPrint,
1754         SIZE_FN_BODY => \&ParseStructNdrSize,
1755         SIZE_FN_ARGS => \&ArgsStructNdrSize,
1756 };
1757
1758 #####################################################################
1759 # calculate size of ndr struct
1760 sub ParseUnionNdrSize($$$)
1761 {
1762         my ($self, $t, $name, $varname) = @_;
1763         my $sizevar;
1764
1765         if (my $flags = has_property($t, "flag")) {
1766                 $self->pidl("flags |= $flags;");
1767         }
1768
1769         $self->pidl("return ndr_size_union($varname, flags, level, (ndr_push_flags_fn_t)ndr_push_$name);");
1770 }
1771
1772 sub ParseUnionPushPrimitives($$$$)
1773 {
1774         my ($self, $e, $ndr ,$varname) = @_;
1775
1776         my $have_default = 0;
1777
1778         $self->pidl("uint32_t level = ndr_push_get_switch_value($ndr, $varname);");
1779
1780         if (defined($e->{SWITCH_TYPE})) {
1781                 if (defined($e->{ALIGN})) {
1782                         $self->pidl("NDR_CHECK(ndr_push_union_align($ndr, $e->{ALIGN}));");
1783                 }
1784
1785                 $self->pidl("NDR_CHECK(ndr_push_$e->{SWITCH_TYPE}($ndr, NDR_SCALARS, level));");
1786         }
1787
1788         if (defined($e->{ALIGN})) {
1789                 if ($e->{IS_MS_UNION}) {
1790                         $self->pidl("/* ms_union is always aligned to the largest union arm*/");
1791                         $self->pidl("NDR_CHECK(ndr_push_align($ndr, $e->{ALIGN}));");
1792                 } else {
1793                         $self->pidl("NDR_CHECK(ndr_push_union_align($ndr, $e->{ALIGN}));");
1794                 }
1795         }
1796
1797         $self->pidl("switch (level) {");
1798         $self->indent;
1799         foreach my $el (@{$e->{ELEMENTS}}) {
1800                 if ($el->{CASE} eq "default") {
1801                         $have_default = 1;
1802                 }
1803                 $self->pidl("$el->{CASE}: {");
1804
1805                 if ($el->{TYPE} ne "EMPTY") {
1806                         $self->indent;
1807                         if (defined($e->{PROPERTIES}{relative_base})) {
1808                                 $self->pidl("NDR_CHECK(ndr_push_align($ndr, $el->{ALIGN}));");
1809                                 # set the current offset as base for relative pointers
1810                                 # and store it based on the toplevel struct/union
1811                                 $self->pidl("NDR_CHECK(ndr_push_setup_relative_base_offset1($ndr, $varname, $ndr->offset));");
1812                         }
1813                         $self->DeclareArrayVariables($el);
1814                         $self->ParseElementPush($el, $ndr, {$el->{NAME} => "$varname->$el->{NAME}"}, 1, 0);
1815                         $self->deindent;
1816                 }
1817                 $self->pidl("break; }");
1818                 $self->pidl("");
1819         }
1820         if (! $have_default) {
1821                 $self->pidl("default:");
1822                 $self->pidl("\treturn ndr_push_error($ndr, NDR_ERR_BAD_SWITCH, \"Bad switch value \%u at \%s\", level, __location__);");
1823         }
1824         $self->deindent;
1825         $self->pidl("}");
1826 }
1827
1828 sub ParseUnionPushDeferred($$$$)
1829 {
1830         my ($self,$e,$ndr,$varname) = @_;
1831
1832         my $have_default = 0;
1833
1834         $self->pidl("uint32_t level = ndr_push_get_switch_value($ndr, $varname);");
1835         if (defined($e->{PROPERTIES}{relative_base})) {
1836                 # retrieve the current offset as base for relative pointers
1837                 # based on the toplevel struct/union
1838                 $self->pidl("NDR_CHECK(ndr_push_setup_relative_base_offset2($ndr, $varname));");
1839         }
1840         $self->pidl("switch (level) {");
1841         $self->indent;
1842         foreach my $el (@{$e->{ELEMENTS}}) {
1843                 if ($el->{CASE} eq "default") {
1844                         $have_default = 1;
1845                 }
1846
1847                 $self->pidl("$el->{CASE}:");
1848                 if ($el->{TYPE} ne "EMPTY") {
1849                         $self->indent;
1850                         $self->ParseElementPush($el, $ndr, {$el->{NAME} => "$varname->$el->{NAME}"}, 0, 1);
1851                         $self->deindent;
1852                 }
1853                 $self->pidl("break;");
1854                 $self->pidl("");
1855         }
1856         if (! $have_default) {
1857                 $self->pidl("default:");
1858                 $self->pidl("\treturn ndr_push_error($ndr, NDR_ERR_BAD_SWITCH, \"Bad switch value \%u at \%s\", level, __location__);");
1859         }
1860         $self->deindent;
1861         $self->pidl("}");
1862 }
1863
1864 #####################################################################
1865 # parse a union - push side
1866 sub ParseUnionPush($$$$)
1867 {
1868         my ($self,$e,$ndr,$varname) = @_;
1869         my $have_default = 0;
1870
1871         $self->start_flags($e, $ndr);
1872
1873         $self->pidl("NDR_PUSH_CHECK_FLAGS(ndr, ndr_flags);");
1874         $self->pidl("if (ndr_flags & NDR_SCALARS) {");
1875         $self->indent;
1876         $self->ParseUnionPushPrimitives($e, $ndr, $varname);
1877         $self->deindent;
1878         $self->pidl("}");
1879         $self->pidl("if (ndr_flags & NDR_BUFFERS) {");
1880         $self->indent;
1881         $self->ParseUnionPushDeferred($e, $ndr, $varname);
1882         $self->deindent;
1883         $self->pidl("}");
1884         $self->end_flags($e, $ndr);
1885 }
1886
1887 #####################################################################
1888 # print a union
1889 sub ParseUnionPrint($$$$$)
1890 {
1891         my ($self,$e,$ndr,$name,$varname) = @_;
1892         my $have_default = 0;
1893
1894         $self->pidl("uint32_t level;");
1895         foreach my $el (@{$e->{ELEMENTS}}) {
1896                 $self->DeclareArrayVariables($el);
1897         }
1898
1899         $self->start_flags($e, $ndr);
1900
1901         $self->pidl("level = ndr_print_get_switch_value($ndr, $varname);");
1902
1903         $self->pidl("ndr_print_union($ndr, name, level, \"$name\");");
1904
1905         $self->pidl("switch (level) {");
1906         $self->indent;
1907         foreach my $el (@{$e->{ELEMENTS}}) {
1908                 if ($el->{CASE} eq "default") {
1909                         $have_default = 1;
1910                 }
1911                 $self->pidl("$el->{CASE}:");
1912                 if ($el->{TYPE} ne "EMPTY") {
1913                         $self->indent;
1914                         $self->ParseElementPrint($el, $ndr, "$varname->$el->{NAME}", {});
1915                         $self->deindent;
1916                 }
1917                 $self->pidl("break;");
1918                 $self->pidl("");
1919         }
1920         if (! $have_default) {
1921                 $self->pidl("default:");
1922                 $self->pidl("\tndr_print_bad_level($ndr, name, level);");
1923         }
1924         $self->deindent;
1925         $self->pidl("}");
1926
1927         $self->end_flags($e, $ndr);
1928 }
1929
1930 sub ParseUnionPullPrimitives($$$$$)
1931 {
1932         my ($self,$e,$ndr,$varname,$switch_type) = @_;
1933         my $have_default = 0;
1934
1935
1936         if (defined($switch_type)) {
1937                 if (defined($e->{ALIGN})) {
1938                         $self->pidl("NDR_CHECK(ndr_pull_union_align($ndr, $e->{ALIGN}));");
1939                 }
1940
1941                 $self->pidl("NDR_CHECK(ndr_pull_$switch_type($ndr, NDR_SCALARS, &_level));");
1942                 $self->pidl("if (_level != level) {");
1943                 $self->pidl("\treturn ndr_pull_error($ndr, NDR_ERR_BAD_SWITCH, \"Bad switch value %u for $varname at \%s\", _level, __location__);");
1944                 $self->pidl("}");
1945         }
1946
1947         if (defined($e->{ALIGN})) {
1948                 if ($e->{IS_MS_UNION}) {
1949                         $self->pidl("/* ms_union is always aligned to the largest union arm*/");
1950                         $self->pidl("NDR_CHECK(ndr_pull_align($ndr, $e->{ALIGN}));");
1951                 } else {
1952                         $self->pidl("NDR_CHECK(ndr_pull_union_align($ndr, $e->{ALIGN}));");
1953                 }
1954         }
1955
1956         $self->pidl("switch (level) {");
1957         $self->indent;
1958         foreach my $el (@{$e->{ELEMENTS}}) {
1959                 if ($el->{CASE} eq "default") {
1960                         $have_default = 1;
1961                 }
1962                 $self->pidl("$el->{CASE}: {");
1963
1964                 if ($el->{TYPE} ne "EMPTY") {
1965                         $self->indent;
1966                         if (defined($e->{PROPERTIES}{relative_base})) {
1967                                 $self->pidl("NDR_CHECK(ndr_pull_align($ndr, $el->{ALIGN}));");
1968                                 # set the current offset as base for relative pointers
1969                                 # and store it based on the toplevel struct/union
1970                                 $self->pidl("NDR_CHECK(ndr_pull_setup_relative_base_offset1($ndr, $varname, $ndr->offset));");
1971                         }
1972                         $self->ParseElementPull($el, $ndr, {$el->{NAME} => "$varname->$el->{NAME}"}, 1, 0);
1973                         $self->deindent;
1974                 }
1975                 $self->pidl("break; }");
1976                 $self->pidl("");
1977         }
1978         if (! $have_default) {
1979                 $self->pidl("default:");
1980                 $self->pidl("\treturn ndr_pull_error($ndr, NDR_ERR_BAD_SWITCH, \"Bad switch value \%u at \%s\", level, __location__);");
1981         }
1982         $self->deindent;
1983         $self->pidl("}");
1984 }
1985
1986 sub ParseUnionPullDeferred($$$$)
1987 {
1988         my ($self,$e,$ndr,$varname) = @_;
1989         my $have_default = 0;
1990
1991         if (defined($e->{PROPERTIES}{relative_base})) {
1992                 # retrieve the current offset as base for relative pointers
1993                 # based on the toplevel struct/union
1994                 $self->pidl("NDR_CHECK(ndr_pull_setup_relative_base_offset2($ndr, $varname));");
1995         }
1996         $self->pidl("switch (level) {");
1997         $self->indent;
1998         foreach my $el (@{$e->{ELEMENTS}}) {
1999                 if ($el->{CASE} eq "default") {
2000                         $have_default = 1;
2001                 }
2002
2003                 $self->pidl("$el->{CASE}:");
2004                 if ($el->{TYPE} ne "EMPTY") {
2005                         $self->indent;
2006                         $self->ParseElementPull($el, $ndr, {$el->{NAME} => "$varname->$el->{NAME}"}, 0, 1);
2007                         $self->deindent;
2008                 }
2009                 $self->pidl("break;");
2010                 $self->pidl("");
2011         }
2012         if (! $have_default) {
2013                 $self->pidl("default:");
2014                 $self->pidl("\treturn ndr_pull_error($ndr, NDR_ERR_BAD_SWITCH, \"Bad switch value \%u at \%s\", level, __location__);");
2015         }
2016         $self->deindent;
2017         $self->pidl("}");
2018
2019
2020 }
2021
2022 #####################################################################
2023 # parse a union - pull side
2024 sub ParseUnionPull($$$$)
2025 {
2026         my ($self,$e,$ndr,$varname) = @_;
2027         my $switch_type = $e->{SWITCH_TYPE};
2028
2029         $self->pidl("uint32_t level;");
2030         if (defined($switch_type)) {
2031                 if (Parse::Pidl::Typelist::typeIs($switch_type, "ENUM")) {
2032                         $switch_type = Parse::Pidl::Typelist::enum_type_fn(getType($switch_type)->{DATA});
2033                 }
2034                 $self->pidl(mapTypeName($switch_type) . " _level;");
2035         }
2036
2037         my %double_cases = ();
2038         foreach my $el (@{$e->{ELEMENTS}}) {
2039                 next if ($el->{TYPE} eq "EMPTY");
2040                 next if ($double_cases{"$el->{NAME}"});
2041                 $self->DeclareMemCtxVariables($el);
2042                 $self->DeclarePtrVariables($el);
2043                 $self->DeclareArrayVariables($el);
2044                 $double_cases{"$el->{NAME}"} = 1;
2045         }
2046
2047         $self->start_flags($e, $ndr);
2048
2049         $self->pidl("level = ndr_pull_get_switch_value($ndr, $varname);");
2050
2051         $self->pidl("NDR_PULL_CHECK_FLAGS(ndr, ndr_flags);");
2052         $self->pidl("if (ndr_flags & NDR_SCALARS) {");
2053         $self->indent;
2054         $self->ParseUnionPullPrimitives($e,$ndr,$varname,$switch_type);
2055         $self->deindent;
2056         $self->pidl("}");
2057
2058         $self->pidl("if (ndr_flags & NDR_BUFFERS) {");
2059         $self->indent;
2060         $self->ParseUnionPullDeferred($e,$ndr,$varname);
2061         $self->deindent;
2062         $self->pidl("}");
2063
2064         $self->add_deferred();
2065
2066         $self->end_flags($e, $ndr);
2067 }
2068
2069 sub DeclUnion($$$$)
2070 {
2071         my ($e,$t,$name,$varname) = @_;
2072         return ($t ne "pull"?"const ":"") . "union $name *$varname";
2073 }
2074
2075 sub ArgsUnionNdrSize($$)
2076 {
2077         my ($d,$name) = @_;
2078         return "const union $name *r, uint32_t level, int flags";
2079 }
2080
2081 $typefamily{UNION} = {
2082         PUSH_FN_BODY => \&ParseUnionPush,
2083         DECL => \&DeclUnion,
2084         PULL_FN_BODY => \&ParseUnionPull,
2085         PRINT_FN_BODY => \&ParseUnionPrint,
2086         SIZE_FN_ARGS => \&ArgsUnionNdrSize,
2087         SIZE_FN_BODY => \&ParseUnionNdrSize,
2088 };
2089
2090 #####################################################################
2091 # parse a typedef - push side
2092 sub ParseTypedefPush($$$$)
2093 {
2094         my($self,$e,$ndr,$varname) = @_;
2095
2096         my $env;
2097
2098         $env->{$e->{NAME}} = $varname;
2099
2100         $self->ParseElementPushLevel($e, $e->{LEVELS}[0], $ndr, $varname, $env, 1, 1);
2101 }
2102
2103 #####################################################################
2104 # parse a typedef - pull side
2105 sub ParseTypedefPull($$$$)
2106 {
2107         my($self,$e,$ndr,$varname) = @_;
2108
2109         my $env;
2110
2111         $env->{$e->{NAME}} = $varname;
2112
2113         $self->ParseElementPullLevel($e, $e->{LEVELS}[0], $ndr, $varname, $env, 1, 1);
2114 }
2115
2116 #####################################################################
2117 # parse a typedef - print side
2118 sub ParseTypedefPrint($$$$$)
2119 {
2120         my($self,$e,$ndr,$name,$varname) = @_;
2121
2122         $typefamily{$e->{DATA}->{TYPE}}->{PRINT_FN_BODY}->($self, $e->{DATA}, $ndr, $name, $varname);
2123 }
2124
2125 #####################################################################
2126 ## calculate the size of a structure
2127 sub ParseTypedefNdrSize($$$$)
2128 {
2129         my($self,$t,$name,$varname) = @_;
2130
2131         $typefamily{$t->{DATA}->{TYPE}}->{SIZE_FN_BODY}->($self, $t->{DATA}, $name, $varname);
2132 }
2133
2134 sub DeclTypedef($$$$)
2135 {
2136         my ($e, $t, $name, $varname) = @_;
2137
2138         return $typefamily{$e->{DATA}->{TYPE}}->{DECL}->($e->{DATA}, $t, $name, $varname);
2139 }
2140
2141 sub ArgsTypedefNdrSize($$$)
2142 {
2143         my ($d, $name, $varname) = @_;
2144         return $typefamily{$d->{DATA}->{TYPE}}->{SIZE_FN_ARGS}->($d->{DATA}, $name, $varname);
2145 }
2146
2147 $typefamily{TYPEDEF} = {
2148         PUSH_FN_BODY => \&ParseTypedefPush,
2149         DECL => \&DeclTypedef,
2150         PULL_FN_BODY => \&ParseTypedefPull,
2151         PRINT_FN_BODY => \&ParseTypedefPrint,
2152         SIZE_FN_ARGS => \&ArgsTypedefNdrSize,
2153         SIZE_FN_BODY => \&ParseTypedefNdrSize,
2154 };
2155
2156 sub ParsePipePushChunk($$)
2157 {
2158         my ($self, $t) = @_;
2159
2160         my $pipe = $t;
2161         $pipe = $t->{DATA} if ($t->{TYPE} eq "TYPEDEF");
2162         my $struct = $pipe->{DATA};
2163
2164         my $name = "$struct->{NAME}";
2165         my $ndr = "ndr";
2166         my $varname = "r";
2167
2168         my $args = $typefamily{$struct->{TYPE}}->{DECL}->($struct, "push", $name, $varname);
2169
2170         $self->fn_declare("push", $struct, "enum ndr_err_code ndr_push_$name(struct ndr_push *$ndr, int ndr_flags, $args)") or return;
2171
2172         return if has_property($t, "nopush");
2173
2174         $self->pidl("{");
2175         $self->indent;
2176
2177         $self->ParseStructPush($struct, $ndr, $varname);
2178         $self->pidl("");
2179
2180         $self->pidl("NDR_CHECK(ndr_push_pipe_chunk_trailer(ndr, ndr_flags, $varname->count));");
2181         $self->pidl("");
2182
2183         $self->pidl("return NDR_ERR_SUCCESS;");
2184         $self->deindent;
2185         $self->pidl("}");
2186         $self->pidl("");
2187 }
2188
2189 sub ParsePipePullChunk($$)
2190 {
2191         my ($self, $t) = @_;
2192
2193         my $pipe = $t;
2194         $pipe = $t->{DATA} if ($t->{TYPE} eq "TYPEDEF");
2195         my $struct = $pipe->{DATA};
2196
2197         my $name = "$struct->{NAME}";
2198         my $ndr = "ndr";
2199         my $varname = "r";
2200
2201         my $args = $typefamily{$struct->{TYPE}}->{DECL}->($struct, "pull", $name, $varname);
2202
2203         $self->fn_declare("pull", $struct, "enum ndr_err_code ndr_pull_$name(struct ndr_pull *$ndr, int ndr_flags, $args)") or return;
2204
2205         return if has_property($struct, "nopull");
2206
2207         $self->pidl("{");
2208         $self->indent;
2209
2210         $self->ParseStructPull($struct, $ndr, $varname);
2211         $self->pidl("");
2212
2213         $self->pidl("NDR_CHECK(ndr_check_pipe_chunk_trailer($ndr, ndr_flags, $varname->count));");
2214         $self->pidl("");
2215
2216         $self->pidl("return NDR_ERR_SUCCESS;");
2217         $self->deindent;
2218         $self->pidl("}");
2219         $self->pidl("");
2220 }
2221
2222 sub ParsePipePrintChunk($$)
2223 {
2224         my ($self, $t) = @_;
2225
2226         my $pipe = $t;
2227         $pipe = $t->{DATA} if ($t->{TYPE} eq "TYPEDEF");
2228         my $struct = $pipe->{DATA};
2229
2230         my $name = "$struct->{NAME}";
2231         my $ndr = "ndr";
2232         my $varname = "r";
2233
2234         my $args = $typefamily{$struct->{TYPE}}->{DECL}->($struct, "print", $name, $varname);
2235
2236         $self->pidl_hdr("void ndr_print_$name(struct ndr_print *ndr, const char *name, $args);");
2237
2238         return if (has_property($t, "noprint"));
2239
2240         $self->pidl("_PUBLIC_ void ndr_print_$name(struct ndr_print *$ndr, const char *name, $args)");
2241         $self->pidl("{");
2242         $self->indent;
2243         $self->ParseTypePrint($struct, $ndr, $varname);
2244         $self->deindent;
2245         $self->pidl("}");
2246         $self->pidl("");
2247 }
2248
2249 #####################################################################
2250 # parse a function - print side
2251 sub ParseFunctionPrint($$)
2252 {
2253         my($self, $fn) = @_;
2254         my $ndr = "ndr";
2255
2256         $self->pidl_hdr("void ndr_print_$fn->{NAME}(struct ndr_print *$ndr, const char *name, int flags, const struct $fn->{NAME} *r);");
2257
2258         return if has_property($fn, "noprint");
2259
2260         $self->pidl("_PUBLIC_ void ndr_print_$fn->{NAME}(struct ndr_print *$ndr, const char *name, int flags, const struct $fn->{NAME} *r)");
2261         $self->pidl("{");
2262         $self->indent;
2263
2264         foreach my $e (@{$fn->{ELEMENTS}}) {
2265                 $self->DeclareArrayVariables($e);
2266         }
2267
2268         $self->pidl("ndr_print_struct($ndr, name, \"$fn->{NAME}\");");
2269         $self->pidl("if (r == NULL) { ndr_print_null($ndr); return; }");
2270         $self->pidl("$ndr->depth++;");
2271
2272         $self->pidl("if (flags & NDR_SET_VALUES) {");
2273         $self->pidl("\t$ndr->flags |= LIBNDR_PRINT_SET_VALUES;");
2274         $self->pidl("}");
2275
2276         $self->pidl("if (flags & NDR_IN) {");
2277         $self->indent;
2278         $self->pidl("ndr_print_struct($ndr, \"in\", \"$fn->{NAME}\");");
2279         $self->pidl("$ndr->depth++;");
2280
2281         my $env = GenerateFunctionInEnv($fn);
2282
2283         foreach my $e (@{$fn->{ELEMENTS}}) {
2284                 if (grep(/in/,@{$e->{DIRECTION}})) {
2285                         $self->ParseElementPrint($e, $ndr, $env->{$e->{NAME}}, $env);
2286                 }
2287         }
2288         $self->pidl("$ndr->depth--;");
2289         $self->deindent;
2290         $self->pidl("}");
2291
2292         $self->pidl("if (flags & NDR_OUT) {");
2293         $self->indent;
2294         $self->pidl("ndr_print_struct($ndr, \"out\", \"$fn->{NAME}\");");
2295         $self->pidl("$ndr->depth++;");
2296
2297         $env = GenerateFunctionOutEnv($fn);
2298         foreach my $e (@{$fn->{ELEMENTS}}) {
2299                 if (grep(/out/,@{$e->{DIRECTION}})) {
2300                         $self->ParseElementPrint($e, $ndr, $env->{$e->{NAME}}, $env);
2301                 }
2302         }
2303         if ($fn->{RETURN_TYPE}) {
2304                 $self->pidl("ndr_print_$fn->{RETURN_TYPE}($ndr, \"result\", r->out.result);");
2305         }
2306         $self->pidl("$ndr->depth--;");
2307         $self->deindent;
2308         $self->pidl("}");
2309
2310         $self->pidl("$ndr->depth--;");
2311         $self->deindent;
2312         $self->pidl("}");
2313         $self->pidl("");
2314 }
2315
2316 #####################################################################
2317 # parse a function
2318 sub ParseFunctionPush($$)
2319 {
2320         my($self, $fn) = @_;
2321         my $ndr = "ndr";
2322
2323         $self->fn_declare("push", $fn, "enum ndr_err_code ndr_push_$fn->{NAME}(struct ndr_push *$ndr, int flags, const struct $fn->{NAME} *r)") or return;
2324
2325         return if has_property($fn, "nopush");
2326
2327         $self->pidl("{");
2328         $self->indent;
2329
2330         foreach my $e (@{$fn->{ELEMENTS}}) {
2331                 $self->DeclareArrayVariables($e);
2332         }
2333
2334         $self->pidl("NDR_PUSH_CHECK_FN_FLAGS(ndr, flags);");
2335
2336         $self->pidl("if (flags & NDR_IN) {");
2337         $self->indent;
2338
2339         my $env = GenerateFunctionInEnv($fn);
2340
2341         EnvSubstituteValue($env, $fn);
2342
2343         foreach my $e (@{$fn->{ELEMENTS}}) {
2344                 if (grep(/in/,@{$e->{DIRECTION}})) {
2345                         $self->ParseElementPush($e, $ndr, $env, 1, 1);
2346                 }
2347         }
2348
2349         $self->deindent;
2350         $self->pidl("}");
2351
2352         $self->pidl("if (flags & NDR_OUT) {");
2353         $self->indent;
2354
2355         $env = GenerateFunctionOutEnv($fn);
2356         foreach my $e (@{$fn->{ELEMENTS}}) {
2357                 if (grep(/out/,@{$e->{DIRECTION}})) {
2358                         $self->ParseElementPush($e, $ndr, $env, 1, 1);
2359                 }
2360         }
2361
2362         if ($fn->{RETURN_TYPE}) {
2363                 $self->pidl("NDR_CHECK(ndr_push_$fn->{RETURN_TYPE}($ndr, NDR_SCALARS, r->out.result));");
2364         }
2365
2366         $self->deindent;
2367         $self->pidl("}");
2368         $self->pidl("return NDR_ERR_SUCCESS;");
2369         $self->deindent;
2370         $self->pidl("}");
2371         $self->pidl("");
2372 }
2373
2374 sub AllocateArrayLevel($$$$$$)
2375 {
2376         my ($self,$e,$l,$ndr,$var,$size) = @_;
2377
2378         my $pl = GetPrevLevel($e, $l);
2379         if (defined($pl) and
2380             $pl->{TYPE} eq "POINTER" and
2381             $pl->{POINTER_TYPE} eq "ref"
2382             and not $l->{IS_ZERO_TERMINATED}) {
2383                 $self->pidl("if ($ndr->flags & LIBNDR_FLAG_REF_ALLOC) {");
2384                 $self->pidl("\tNDR_PULL_ALLOC_N($ndr, $var, $size);");
2385                 $self->pidl("}");
2386                 if (grep(/in/,@{$e->{DIRECTION}}) and
2387                     grep(/out/,@{$e->{DIRECTION}})) {
2388                         $self->pidl("memcpy(r->out.$e->{NAME}, r->in.$e->{NAME}, ($size) * sizeof(*r->in.$e->{NAME}));");
2389                 }
2390                 return;
2391         }
2392
2393         $self->pidl("NDR_PULL_ALLOC_N($ndr, $var, $size);");
2394 }
2395
2396 #####################################################################
2397 # parse a function
2398 sub ParseFunctionPull($$)
2399 {
2400         my($self,$fn) = @_;
2401         my $ndr = "ndr";
2402
2403         # pull function args
2404         $self->fn_declare("pull", $fn, "enum ndr_err_code ndr_pull_$fn->{NAME}(struct ndr_pull *$ndr, int flags, struct $fn->{NAME} *r)") or return;
2405
2406         $self->pidl("{");
2407         $self->indent;
2408
2409         # declare any internal pointers we need
2410         foreach my $e (@{$fn->{ELEMENTS}}) {
2411                 $self->DeclarePtrVariables($e);
2412                 $self->DeclareArrayVariables($e);
2413         }
2414
2415         my %double_cases = ();
2416         foreach my $e (@{$fn->{ELEMENTS}}) {
2417                 next if ($e->{TYPE} eq "EMPTY");
2418                 next if ($double_cases{"$e->{NAME}"});
2419                 $self->DeclareMemCtxVariables($e);
2420                 $double_cases{"$e->{NAME}"} = 1;
2421         }
2422
2423         $self->pidl("NDR_PULL_CHECK_FN_FLAGS(ndr, flags);");
2424
2425         $self->pidl("if (flags & NDR_IN) {");
2426         $self->indent;
2427
2428         # auto-init the out section of a structure. I originally argued that
2429         # this was a bad idea as it hides bugs, but coping correctly
2430         # with initialisation and not wiping ref vars is turning
2431         # out to be too tricky (tridge)
2432         foreach my $e (@{$fn->{ELEMENTS}}) {
2433                 next unless grep(/out/, @{$e->{DIRECTION}});
2434                 $self->pidl("ZERO_STRUCT(r->out);");
2435                 $self->pidl("");
2436                 last;
2437         }
2438
2439         my $env = GenerateFunctionInEnv($fn);
2440
2441         foreach my $e (@{$fn->{ELEMENTS}}) {
2442                 next unless (grep(/in/, @{$e->{DIRECTION}}));
2443                 $self->ParseElementPull($e, $ndr, $env, 1, 1);
2444         }
2445
2446         # allocate the "simple" out ref variables. FIXME: Shouldn't this have it's
2447         # own flag rather than be in NDR_IN ?
2448
2449         foreach my $e (@{$fn->{ELEMENTS}}) {
2450                 next unless (grep(/out/, @{$e->{DIRECTION}}));
2451                 next unless ($e->{LEVELS}[0]->{TYPE} eq "POINTER" and
2452                              $e->{LEVELS}[0]->{POINTER_TYPE} eq "ref");
2453                 next if (($e->{LEVELS}[1]->{TYPE} eq "DATA") and
2454                                  ($e->{LEVELS}[1]->{DATA_TYPE} eq "string"));
2455                 next if ($e->{LEVELS}[1]->{TYPE} eq "PIPE");
2456                 next if (($e->{LEVELS}[1]->{TYPE} eq "ARRAY")
2457                         and   $e->{LEVELS}[1]->{IS_ZERO_TERMINATED});
2458
2459                 if ($e->{LEVELS}[1]->{TYPE} eq "ARRAY") {
2460                         my $size = ParseExprExt($e->{LEVELS}[1]->{SIZE_IS}, $env, $e->{ORIGINAL},
2461                                 check_null_pointer($e, $env, sub { $self->pidl(shift); },
2462                                                    "return ndr_pull_error($ndr, NDR_ERR_INVALID_POINTER, \"NULL Pointer for size_is()\");"),
2463                                 check_fully_dereferenced($e, $env));
2464                         $self->pidl("NDR_PULL_ALLOC_N($ndr, r->out.$e->{NAME}, $size);");
2465
2466                         if (grep(/in/, @{$e->{DIRECTION}})) {
2467                                 $self->pidl("memcpy(r->out.$e->{NAME}, r->in.$e->{NAME}, ($size) * sizeof(*r->in.$e->{NAME}));");
2468                         } else {
2469                                 $self->pidl("memset(r->out.$e->{NAME}, 0, ($size) * sizeof(*r->out.$e->{NAME}));");
2470                         }
2471                 } elsif ($e->{LEVELS}[1]->{TYPE} eq "ARRAY") {
2472                         if (grep(/in/, @{$e->{DIRECTION}})) {
2473                                 $self->pidl("r->out.$e->{NAME} = r->in.$e->{NAME};");
2474                         } else {
2475                                 $self->pidl("r->out.$e->{NAME} = NULL;");
2476                         }
2477                 } else {
2478                         $self->pidl("NDR_PULL_ALLOC($ndr, r->out.$e->{NAME});");
2479
2480                         if (grep(/in/, @{$e->{DIRECTION}})) {
2481                                 $self->pidl("*r->out.$e->{NAME} = *r->in.$e->{NAME};");
2482                         } else {
2483                                 $self->pidl("ZERO_STRUCTP(r->out.$e->{NAME});");
2484                         }
2485                 }
2486         }
2487
2488         $self->add_deferred();
2489         $self->deindent;
2490         $self->pidl("}");
2491
2492         $self->pidl("if (flags & NDR_OUT) {");
2493         $self->indent;
2494
2495         $env = GenerateFunctionOutEnv($fn);
2496         foreach my $e (@{$fn->{ELEMENTS}}) {
2497                 next unless grep(/out/, @{$e->{DIRECTION}});
2498                 $self->ParseElementPull($e, $ndr, $env, 1, 1);
2499         }
2500
2501         if ($fn->{RETURN_TYPE}) {
2502                 $self->pidl("NDR_CHECK(ndr_pull_$fn->{RETURN_TYPE}($ndr, NDR_SCALARS, &r->out.result));");
2503         }
2504
2505         $self->add_deferred();
2506         $self->deindent;
2507         $self->pidl("}");
2508
2509         $self->pidl("return NDR_ERR_SUCCESS;");
2510         $self->deindent;
2511         $self->pidl("}");
2512         $self->pidl("");
2513 }
2514
2515 sub AuthServiceStruct($$$)
2516 {
2517         my ($self, $ifacename, $authservice) = @_;
2518         my @a = split /,/, $authservice;
2519         my $authservice_count = $#a + 1;
2520
2521         $self->pidl("static const char * const $ifacename\_authservice_strings[] = {");
2522         foreach my $ap (@a) {
2523                 $self->pidl("\t$ap, ");
2524         }
2525         $self->pidl("};");
2526         $self->pidl("");
2527
2528         $self->pidl("static const struct ndr_interface_string_array $ifacename\_authservices = {");
2529         $self->pidl("\t.count\t= $authservice_count,");
2530         $self->pidl("\t.names\t= $ifacename\_authservice_strings");
2531         $self->pidl("};");
2532         $self->pidl("");
2533 }
2534
2535 sub ParseGeneratePipeArray($$$)
2536 {
2537         my ($self, $fn, $direction) = @_;
2538
2539         $self->pidl("static const struct ndr_interface_call_pipe $fn->{NAME}\_$direction\_pipes[] = {");
2540         $self->indent;
2541
2542         foreach my $e (@{$fn->{ELEMENTS}}) {
2543                 next unless ContainsPipe($e, $e->{LEVELS}[0]);
2544                 next unless (grep(/$direction/, @{$e->{DIRECTION}}));
2545
2546                 my $cname = "$e->{TYPE}_chunk";
2547
2548                 $self->pidl("{");
2549                 $self->indent;
2550                 $self->pidl("\"$direction.$e->{NAME}\",");
2551                 $self->pidl("\"$cname\",");
2552                 $self->pidl("sizeof(struct $cname),");
2553                 $self->pidl("(ndr_push_flags_fn_t) ndr_push_$cname,");
2554                 $self->pidl("(ndr_pull_flags_fn_t) ndr_pull_$cname,");
2555                 $self->pidl("(ndr_print_fn_t) ndr_print_$cname,");
2556                 $self->deindent;
2557                 $self->pidl("},");
2558         }
2559         $self->pidl("{ NULL, NULL, 0, NULL, NULL, NULL }");
2560         $self->deindent;
2561         $self->pidl("};");
2562         $self->pidl("");
2563 }
2564
2565 sub FunctionCallPipes($$)
2566 {
2567         my ($self, $d) = @_;
2568         return if not defined($d->{OPNUM});
2569
2570         my $in_pipes = 0;
2571         my $out_pipes = 0;
2572
2573         foreach my $e (@{$d->{ELEMENTS}}) {
2574                 next unless ContainsPipe($e, $e->{LEVELS}[0]);
2575
2576                 if (grep(/in/, @{$e->{DIRECTION}})) {
2577                         $in_pipes++;
2578                 }
2579                 if (grep(/out/, @{$e->{DIRECTION}})) {
2580                         $out_pipes++;
2581                 }
2582         }
2583
2584         if ($in_pipes) {
2585                 $self->ParseGeneratePipeArray($d, "in");
2586         }
2587
2588         if ($out_pipes) {
2589                 $self->ParseGeneratePipeArray($d, "out");
2590         }
2591 }
2592
2593 sub FunctionCallEntry($$)
2594 {
2595         my ($self, $d) = @_;
2596         return 0 if not defined($d->{OPNUM});
2597
2598         my $in_pipes = 0;
2599         my $out_pipes = 0;
2600
2601         foreach my $e (@{$d->{ELEMENTS}}) {
2602                 next unless ContainsPipe($e, $e->{LEVELS}[0]);
2603
2604                 if (grep(/in/, @{$e->{DIRECTION}})) {
2605                         $in_pipes++;
2606                 }
2607                 if (grep(/out/, @{$e->{DIRECTION}})) {
2608                         $out_pipes++;
2609                 }
2610         }
2611
2612         my $in_pipes_ptr = "NULL";
2613         my $out_pipes_ptr = "NULL";
2614
2615         if ($in_pipes) {
2616                 $in_pipes_ptr = "$d->{NAME}_in_pipes";
2617         }
2618
2619         if ($out_pipes) {
2620                 $out_pipes_ptr = "$d->{NAME}_out_pipes";
2621         }
2622
2623         $self->pidl("\t{");
2624         $self->pidl("\t\t\"$d->{NAME}\",");
2625         $self->pidl("\t\tsizeof(struct $d->{NAME}),");
2626         $self->pidl("\t\t(ndr_push_flags_fn_t) ndr_push_$d->{NAME},");
2627         $self->pidl("\t\t(ndr_pull_flags_fn_t) ndr_pull_$d->{NAME},");
2628         $self->pidl("\t\t(ndr_print_function_t) ndr_print_$d->{NAME},");
2629         $self->pidl("\t\t{ $in_pipes, $in_pipes_ptr },");
2630         $self->pidl("\t\t{ $out_pipes, $out_pipes_ptr },");
2631         $self->pidl("\t},");
2632         return 1;
2633 }
2634
2635 #####################################################################
2636 # produce a function call table
2637 sub FunctionTable($$)
2638 {
2639         my($self,$interface) = @_;
2640         my $count = 0;
2641         my $uname = uc $interface->{NAME};
2642
2643         return if ($#{$interface->{FUNCTIONS}}+1 == 0);
2644         return unless defined ($interface->{PROPERTIES}->{uuid});
2645
2646         foreach my $d (@{$interface->{INHERITED_FUNCTIONS}},@{$interface->{FUNCTIONS}}) {
2647                 $self->FunctionCallPipes($d);
2648         }
2649
2650         $self->pidl("static const struct ndr_interface_call $interface->{NAME}\_calls[] = {");
2651
2652         foreach my $d (@{$interface->{INHERITED_FUNCTIONS}},@{$interface->{FUNCTIONS}}) {
2653                 $count += $self->FunctionCallEntry($d);
2654         }
2655         $self->pidl("\t{ NULL, 0, NULL, NULL, NULL }");
2656         $self->pidl("};");
2657         $self->pidl("");
2658
2659         $self->pidl("static const char * const $interface->{NAME}\_endpoint_strings[] = {");
2660         foreach my $ep (@{$interface->{ENDPOINTS}}) {
2661                 $self->pidl("\t$ep, ");
2662         }
2663         my $endpoint_count = $#{$interface->{ENDPOINTS}}+1;
2664
2665         $self->pidl("};");
2666         $self->pidl("");
2667
2668         $self->pidl("static const struct ndr_interface_string_array $interface->{NAME}\_endpoints = {");
2669         $self->pidl("\t.count\t= $endpoint_count,");
2670         $self->pidl("\t.names\t= $interface->{NAME}\_endpoint_strings");
2671         $self->pidl("};");
2672         $self->pidl("");
2673
2674         if (! defined $interface->{PROPERTIES}->{authservice}) {
2675                 $interface->{PROPERTIES}->{authservice} = "\"host\"";
2676         }
2677
2678         $self->AuthServiceStruct($interface->{NAME},
2679                                      $interface->{PROPERTIES}->{authservice});
2680
2681         $self->pidl("\nconst struct ndr_interface_table ndr_table_$interface->{NAME} = {");
2682         $self->pidl("\t.name\t\t= \"$interface->{NAME}\",");
2683         $self->pidl("\t.syntax_id\t= {");
2684         $self->pidl("\t\t" . print_uuid($interface->{UUID}) .",");
2685         $self->pidl("\t\tNDR_$uname\_VERSION");
2686         $self->pidl("\t},");
2687         $self->pidl("\t.helpstring\t= NDR_$uname\_HELPSTRING,");
2688         $self->pidl("\t.num_calls\t= $count,");
2689         $self->pidl("\t.calls\t\t= $interface->{NAME}\_calls,");
2690         $self->pidl("\t.endpoints\t= &$interface->{NAME}\_endpoints,");
2691         $self->pidl("\t.authservices\t= &$interface->{NAME}\_authservices");
2692         $self->pidl("};");
2693         $self->pidl("");
2694
2695 }
2696
2697 #####################################################################
2698 # generate include statements for imported idl files
2699 sub HeaderImport
2700 {
2701         my $self = shift;
2702         my @imports = @_;
2703         foreach (@imports) {
2704                 $_ = unmake_str($_);
2705                 s/\.idl$//;
2706                 $self->pidl(choose_header("librpc/gen_ndr/ndr_$_\.h", "gen_ndr/ndr_$_.h"));
2707         }
2708 }
2709
2710 #####################################################################
2711 # generate include statements for included header files
2712 sub HeaderInclude
2713 {
2714         my $self = shift;
2715         my @includes = @_;
2716         foreach (@includes) {
2717                 $self->pidl_hdr("#include $_");
2718         }
2719 }
2720
2721 #####################################################################
2722 # generate prototypes and defines for the interface definitions
2723 # FIXME: these prototypes are for the DCE/RPC client functions, not the
2724 # NDR parser and so do not belong here, technically speaking
2725 sub HeaderInterface($$$)
2726 {
2727         my($self,$interface,$needed) = @_;
2728
2729         my $count = 0;
2730
2731         if ($needed->{"compression"}) {
2732                 $self->pidl(choose_header("librpc/ndr/ndr_compression.h", "ndr/compression.h"));
2733         }
2734
2735         if (has_property($interface, "object")) {
2736                 $self->pidl(choose_header("librpc/gen_ndr/ndr_orpc.h", "ndr/orpc.h"));
2737         }
2738
2739         if (defined $interface->{PROPERTIES}->{helper}) {
2740                 $self->HeaderInclude(split /,/, $interface->{PROPERTIES}->{helper});
2741         }
2742
2743         if (defined $interface->{PROPERTIES}->{uuid}) {
2744                 my $name = uc $interface->{NAME};
2745                 $self->pidl_hdr("#define NDR_$name\_UUID " .
2746                 Parse::Pidl::Util::make_str(lc($interface->{UUID})));
2747
2748                 $self->pidl_hdr("#define NDR_$name\_VERSION $interface->{VERSION}");
2749
2750                 $self->pidl_hdr("#define NDR_$name\_NAME \"$interface->{NAME}\"");
2751
2752                 if(!defined $interface->{PROPERTIES}->{helpstring}) { $interface->{PROPERTIES}->{helpstring} = "NULL"; }
2753                 $self->pidl_hdr("#define NDR_$name\_HELPSTRING $interface->{PROPERTIES}->{helpstring}");
2754
2755                 $self->pidl_hdr("extern const struct ndr_interface_table ndr_table_$interface->{NAME};");
2756         }
2757
2758         foreach (@{$interface->{FUNCTIONS}}) {
2759                 next if has_property($_, "noopnum");
2760                 next if grep(/^$_->{NAME}$/,@{$interface->{INHERITED_FUNCTIONS}});
2761                 my $u_name = uc $_->{NAME};
2762
2763                 my $val = sprintf("0x%02x", $count);
2764                 if (defined($interface->{BASE})) {
2765                         $val .= " + NDR_" . uc $interface->{BASE} . "_CALL_COUNT";
2766                 }
2767
2768                 $self->pidl_hdr("#define NDR_$u_name ($val)");
2769
2770                 $self->pidl_hdr("");
2771                 $count++;
2772         }
2773
2774         my $val = $count;
2775
2776         if (defined($interface->{BASE})) {
2777                 $val .= " + NDR_" . uc $interface->{BASE} . "_CALL_COUNT";
2778         }
2779
2780         $self->pidl_hdr("#define NDR_" . uc $interface->{NAME} . "_CALL_COUNT ($val)");
2781
2782 }
2783
2784 sub ParseTypePush($$$$$$)
2785 {
2786         my ($self,$e, $ndr, $varname, $primitives, $deferred) = @_;
2787
2788         # save the old relative_base_offset
2789         $self->pidl("uint32_t _save_relative_base_offset = ndr_push_get_relative_base_offset($ndr);") if defined(has_property($e, "relative_base"));
2790         $typefamily{$e->{TYPE}}->{PUSH_FN_BODY}->($self, $e, $ndr, $varname);
2791         # restore the old relative_base_offset
2792         $self->pidl("ndr_push_restore_relative_base_offset($ndr, _save_relative_base_offset);") if defined(has_property($e, "relative_base"));
2793 }
2794
2795 sub ParseTypePushFunction($$$)
2796 {
2797         my ($self, $e, $varname) = @_;
2798         my $ndr = "ndr";
2799
2800         my $args = $typefamily{$e->{TYPE}}->{DECL}->($e, "push", $e->{NAME}, $varname);
2801
2802         $self->fn_declare("push", $e, "enum ndr_err_code ".TypeFunctionName("ndr_push", $e)."(struct ndr_push *$ndr, int ndr_flags, $args)") or return;
2803
2804         $self->pidl("{");
2805         $self->indent;
2806         $self->ParseTypePush($e, $ndr, $varname, 1, 1);
2807         $self->pidl("return NDR_ERR_SUCCESS;");
2808         $self->deindent;
2809         $self->pidl("}");
2810         $self->pidl("");;
2811 }
2812
2813 sub ParseTypePull($$$$$$)
2814 {
2815         my ($self, $e, $ndr, $varname, $primitives, $deferred) = @_;
2816
2817         # save the old relative_base_offset
2818         $self->pidl("uint32_t _save_relative_base_offset = ndr_pull_get_relative_base_offset($ndr);") if defined(has_property($e, "relative_base"));
2819         $typefamily{$e->{TYPE}}->{PULL_FN_BODY}->($self, $e, $ndr, $varname);
2820         # restore the old relative_base_offset
2821         $self->pidl("ndr_pull_restore_relative_base_offset($ndr, _save_relative_base_offset);") if defined(has_property($e, "relative_base"));
2822 }
2823
2824 sub ParseTypePullFunction($$)
2825 {
2826         my ($self, $e, $varname) = @_;
2827         my $ndr = "ndr";
2828
2829         my $args = $typefamily{$e->{TYPE}}->{DECL}->($e, "pull", $e->{NAME}, $varname);
2830
2831         $self->fn_declare("pull", $e, "enum ndr_err_code ".TypeFunctionName("ndr_pull", $e)."(struct ndr_pull *$ndr, int ndr_flags, $args)") or return;
2832
2833         $self->pidl("{");
2834         $self->indent;
2835         $self->ParseTypePull($e, $ndr, $varname, 1, 1);
2836         $self->pidl("return NDR_ERR_SUCCESS;");
2837         $self->deindent;
2838         $self->pidl("}");
2839         $self->pidl("");
2840 }
2841
2842 sub ParseTypePrint($$$$)
2843 {
2844         my ($self, $e, $ndr, $varname) = @_;
2845
2846         $typefamily{$e->{TYPE}}->{PRINT_FN_BODY}->($self, $e, $ndr, $e->{NAME}, $varname);
2847 }
2848
2849 sub ParseTypePrintFunction($$$)
2850 {
2851         my ($self, $e, $varname) = @_;
2852         my $ndr = "ndr";
2853
2854         my $args = $typefamily{$e->{TYPE}}->{DECL}->($e, "print", $e->{NAME}, $varname);
2855
2856         $self->pidl_hdr("void ".TypeFunctionName("ndr_print", $e)."(struct ndr_print *ndr, const char *name, $args);");
2857
2858         return if (has_property($e, "noprint"));
2859
2860         $self->pidl("_PUBLIC_ void ".TypeFunctionName("ndr_print", $e)."(struct ndr_print *$ndr, const char *name, $args)");
2861         $self->pidl("{");
2862         $self->indent;
2863         $self->ParseTypePrint($e, $ndr, $varname);
2864         $self->deindent;
2865         $self->pidl("}");
2866         $self->pidl("");
2867 }
2868
2869 sub ParseTypeNdrSize($$)
2870 {
2871         my ($self,$t) = @_;
2872
2873         my $varname = "r";
2874         my $tf = $typefamily{$t->{TYPE}};
2875         my $args = $tf->{SIZE_FN_ARGS}->($t, $t->{NAME}, $varname);
2876
2877         $self->fn_declare("size", $t, "size_t ndr_size_$t->{NAME}($args)") or return;
2878
2879         $self->pidl("{");
2880         $self->indent;
2881         $typefamily{$t->{TYPE}}->{SIZE_FN_BODY}->($self,$t, $t->{NAME}, $varname);
2882         $self->deindent;
2883         $self->pidl("}");
2884         $self->pidl("");
2885 }
2886
2887 #####################################################################
2888 # parse the interface definitions
2889 sub ParseInterface($$$)
2890 {
2891         my($self,$interface,$needed) = @_;
2892
2893         $self->pidl_hdr("#ifndef _HEADER_NDR_$interface->{NAME}");
2894         $self->pidl_hdr("#define _HEADER_NDR_$interface->{NAME}");
2895
2896         $self->pidl_hdr("");
2897
2898         $self->HeaderInterface($interface, $needed);
2899
2900         # Typedefs
2901         foreach my $d (@{$interface->{TYPES}}) {
2902                 if (Parse::Pidl::Typelist::typeIs($d, "PIPE")) {
2903                         ($needed->{TypeFunctionName("ndr_push", $d)}) &&
2904                                 $self->ParsePipePushChunk($d);
2905                         ($needed->{TypeFunctionName("ndr_pull", $d)}) &&
2906                                 $self->ParsePipePullChunk($d);
2907                         ($needed->{TypeFunctionName("ndr_print", $d)}) &&
2908                                 $self->ParsePipePrintChunk($d);
2909
2910                         $needed->{TypeFunctionName("ndr_pull", $d)} = 0;
2911                         $needed->{TypeFunctionName("ndr_push", $d)} = 0;
2912                         $needed->{TypeFunctionName("ndr_print", $d)} = 0;
2913                         next;
2914                 }
2915
2916                 next unless(typeHasBody($d));
2917
2918                 ($needed->{TypeFunctionName("ndr_push", $d)}) && $self->ParseTypePushFunction($d, "r");
2919                 ($needed->{TypeFunctionName("ndr_pull", $d)}) && $self->ParseTypePullFunction($d, "r");
2920                 ($needed->{TypeFunctionName("ndr_print", $d)}) && $self->ParseTypePrintFunction($d, "r");
2921
2922                 # Make sure we don't generate a function twice...
2923                 $needed->{TypeFunctionName("ndr_push", $d)} =
2924                     $needed->{TypeFunctionName("ndr_pull", $d)} =
2925                         $needed->{TypeFunctionName("ndr_print", $d)} = 0;
2926
2927                 ($needed->{"ndr_size_$d->{NAME}"}) && $self->ParseTypeNdrSize($d);
2928         }
2929
2930         # Functions
2931         foreach my $d (@{$interface->{FUNCTIONS}}) {
2932                 ($needed->{"ndr_push_$d->{NAME}"}) && $self->ParseFunctionPush($d);
2933                 ($needed->{"ndr_pull_$d->{NAME}"}) && $self->ParseFunctionPull($d);
2934                 ($needed->{"ndr_print_$d->{NAME}"}) && $self->ParseFunctionPrint($d);
2935         }
2936
2937         $self->FunctionTable($interface);
2938
2939         $self->pidl_hdr("#endif /* _HEADER_NDR_$interface->{NAME} */");
2940 }
2941
2942 sub GenerateIncludes($)
2943 {
2944         my ($self) = @_;
2945         if (is_intree()) {
2946                 $self->pidl("#include \"includes.h\"");
2947         } else {
2948                 $self->pidl("#ifndef _GNU_SOURCE");
2949                 $self->pidl("#define _GNU_SOURCE");
2950                 $self->pidl("#endif");
2951                 $self->pidl("#include <stdint.h>");
2952                 $self->pidl("#include <stdlib.h>");
2953                 $self->pidl("#include <stdio.h>");
2954                 $self->pidl("#include <stdbool.h>");
2955                 $self->pidl("#include <stdarg.h>");
2956                 $self->pidl("#include <string.h>");
2957         }
2958 }
2959
2960 #####################################################################
2961 # parse a parsed IDL structure back into an IDL file
2962 sub Parse($$$$)
2963 {
2964         my($self, $ndr,$gen_header,$ndr_header) = @_;
2965
2966         $self->pidl_hdr("/* header auto-generated by pidl */");
2967         $self->pidl_hdr("");
2968         $self->pidl_hdr(choose_header("librpc/ndr/libndr.h", "ndr.h"));
2969         $self->pidl_hdr("#include \"$gen_header\"") if ($gen_header);
2970         $self->pidl_hdr("");
2971
2972         $self->pidl("/* parser auto-generated by pidl */");
2973         $self->pidl("");
2974         $self->GenerateIncludes();
2975         $self->pidl("#include \"$ndr_header\"") if ($ndr_header);
2976         $self->pidl("");
2977
2978         my %needed = ();
2979
2980         foreach (@{$ndr}) {
2981                 ($_->{TYPE} eq "INTERFACE") && NeededInterface($_, \%needed);
2982         }
2983
2984         foreach (@{$ndr}) {
2985                 ($_->{TYPE} eq "INTERFACE") && $self->ParseInterface($_, \%needed);
2986                 ($_->{TYPE} eq "IMPORT") && $self->HeaderImport(@{$_->{PATHS}});
2987                 ($_->{TYPE} eq "INCLUDE") && $self->HeaderInclude(@{$_->{PATHS}});
2988         }
2989
2990         return ($self->{res_hdr}, $self->{res});
2991 }
2992
2993 sub NeededElement($$$)
2994 {
2995         my ($e, $dir, $needed) = @_;
2996
2997         return if ($e->{TYPE} eq "EMPTY");
2998
2999         return if (ref($e->{TYPE}) eq "HASH" and
3000                        not defined($e->{TYPE}->{NAME}));
3001
3002         my ($t, $rt);
3003         if (ref($e->{TYPE}) eq "HASH") {
3004                 $t = $e->{TYPE}->{TYPE}."_".$e->{TYPE}->{NAME};
3005         } else {
3006                 $t = $e->{TYPE};
3007         }
3008
3009         if (ref($e->{REPRESENTATION_TYPE}) eq "HASH") {
3010                 $rt = $e->{REPRESENTATION_TYPE}->{TYPE}."_".$e->{REPRESENTATION_TYPE}->{NAME};
3011         } else {
3012                 $rt = $e->{REPRESENTATION_TYPE};
3013         }
3014
3015         die ("$e->{NAME} $t, $rt FOO") unless ($rt ne "");
3016
3017         my @fn = ();
3018         if ($dir eq "print") {
3019                 push(@fn, TypeFunctionName("ndr_print", $e->{REPRESENTATION_TYPE}));
3020         } elsif ($dir eq "pull") {
3021                 push (@fn, TypeFunctionName("ndr_pull", $e->{TYPE}));
3022                 push (@fn, "ndr_$t\_to_$rt")
3023                         if ($rt ne $t);
3024         } elsif ($dir eq "push") {
3025                 push (@fn, TypeFunctionName("ndr_push", $e->{TYPE}));
3026                 push (@fn, "ndr_$rt\_to_$t")
3027                         if ($rt ne $t);
3028         } else {
3029                 die("invalid direction `$dir'");
3030         }
3031
3032         foreach (@fn) {
3033                 unless (defined($needed->{$_})) {
3034                         $needed->{$_} = 1;
3035                 }
3036         }
3037 }
3038
3039 sub NeededFunction($$)
3040 {
3041         my ($fn,$needed) = @_;
3042         $needed->{"ndr_pull_$fn->{NAME}"} = 1;
3043         $needed->{"ndr_push_$fn->{NAME}"} = 1;
3044         $needed->{"ndr_print_$fn->{NAME}"} = 1;
3045         foreach my $e (@{$fn->{ELEMENTS}}) {
3046                 $e->{PARENT} = $fn;
3047                 NeededElement($e, $_, $needed) foreach ("pull", "push", "print");
3048         }
3049 }
3050
3051 sub NeededType($$$)
3052 {
3053         sub NeededType($$$);
3054         my ($t,$needed,$req) = @_;
3055
3056         NeededType($t->{DATA}, $needed, $req) if ($t->{TYPE} eq "TYPEDEF");
3057         NeededType($t->{DATA}, $needed, $req) if ($t->{TYPE} eq "PIPE");
3058
3059         if ($t->{TYPE} eq "STRUCT" or $t->{TYPE} eq "UNION") {
3060                 return unless defined($t->{ELEMENTS});
3061                 for my $e (@{$t->{ELEMENTS}}) {
3062                         $e->{PARENT} = $t;
3063                         if (has_property($e, "compression")) {
3064                                 $needed->{"compression"} = 1;
3065                         }
3066                         NeededElement($e, $req, $needed);
3067                         NeededType($e->{TYPE}, $needed, $req) if (ref($e->{TYPE}) eq "HASH");
3068                 }
3069         }
3070 }
3071
3072 #####################################################################
3073 # work out what parse functions are needed
3074 sub NeededInterface($$)
3075 {
3076         my ($interface,$needed) = @_;
3077         NeededFunction($_, $needed) foreach (@{$interface->{FUNCTIONS}});
3078         foreach (reverse @{$interface->{TYPES}}) {
3079
3080                 if (has_property($_, "public")) {
3081                         $needed->{TypeFunctionName("ndr_pull", $_)} = $needed->{TypeFunctionName("ndr_push", $_)} =
3082                                 $needed->{TypeFunctionName("ndr_print", $_)} = 1;
3083                 }
3084
3085                 NeededType($_, $needed, "pull") if ($needed->{TypeFunctionName("ndr_pull", $_)});
3086                 NeededType($_, $needed, "push") if ($needed->{TypeFunctionName("ndr_push", $_)});
3087                 NeededType($_, $needed, "print") if ($needed->{TypeFunctionName("ndr_print", $_)});
3088                 if (has_property($_, "gensize")) {
3089                         $needed->{"ndr_size_$_->{NAME}"} = 1;
3090                 }
3091         }
3092 }
3093
3094 sub TypeFunctionName($$)
3095 {
3096         my ($prefix, $t) = @_;
3097
3098         return "$prefix\_$t->{NAME}" if (ref($t) eq "HASH" and
3099                         $t->{TYPE} eq "TYPEDEF");
3100         return "$prefix\_$t->{TYPE}_$t->{NAME}" if (ref($t) eq "HASH");
3101         return "$prefix\_$t";
3102 }
3103
3104 1;