selftest/target/Samba3.pm

   1 #!/usr/bin/perl
   2 # Bootstrap Samba and run a number of tests against it.
   3 # Copyright (C) 2005-2007 Jelmer Vernooij <jelmer@samba.org>
   4 # Published under the GNU GPL, v3 or later.
   5
   6 package Samba3;
   7
   8 use strict;
   9 use Cwd qw(abs_path);
  10 use FindBin qw($RealBin);
  11 use POSIX;
  12 use target::Samba;
  13
  14 sub have_ads($) {
  15         my ($self) = @_;
  16         my $found_ads = 0;
  17         my $smbd_build_options = Samba::bindir_path($self, "smbd") . " -b|";
  18         open(IN, $smbd_build_options) or die("Unable to run $smbd_build_options: $!");
  19
  20         while (<IN>) {
  21                 if (/WITH_ADS/) {
  22                        $found_ads = 1;
  23                 }
  24         }
  25         close IN;
  26
  27         # If we were not built with ADS support, pretend we were never even available
  28         return $found_ads;
  29 }
  30
  31 sub new($$) {
  32         my ($classname, $bindir, $binary_mapping, $srcdir, $server_maxtime) = @_;
  33         my $self = { vars => {},
  34                      bindir => $bindir,
  35                      binary_mapping => $binary_mapping,
  36                      srcdir => $srcdir,
  37                      server_maxtime => $server_maxtime
  38         };
  39         bless $self;
  40         return $self;
  41 }
  42
  43 sub teardown_env($$)
  44 {
  45         my ($self, $envvars) = @_;
  46         my $count = 0;
  47
  48         # This should cause smbd to terminate gracefully
  49         close($envvars->{STDIN_PIPE});
  50
  51         my $smbdpid = $envvars->{SMBD_TL_PID};
  52         my $nmbdpid = $envvars->{NMBD_TL_PID};
  53         my $winbinddpid = $envvars->{WINBINDD_TL_PID};
  54
  55         # This should give it time to write out the gcov data
  56         until ($count > 20) {
  57             my $smbdchild = Samba::cleanup_child($smbdpid, "smbd");
  58             my $nmbdchild = Samba::cleanup_child($nmbdpid, "nmbd");
  59             my $winbinddchild = Samba::cleanup_child($winbinddpid, "winbindd");
  60             if ($smbdchild == -1
  61                 && $nmbdchild == -1
  62                 && $winbinddchild == -1) {
  63                 last;
  64             }
  65             sleep(1);
  66             $count++;
  67         }
  68
  69         if ($count <= 20 && kill(0, $smbdpid, $nmbdpid, $winbinddpid) == 0) {
  70             return;
  71         }
  72
  73         $self->stop_sig_term($smbdpid);
  74         $self->stop_sig_term($nmbdpid);
  75         $self->stop_sig_term($winbinddpid);
  76
  77         $count = 0;
  78         until ($count > 10) {
  79             my $smbdchild = Samba::cleanup_child($smbdpid, "smbd");
  80             my $nmbdchild = Samba::cleanup_child($nmbdpid, "nmbd");
  81             my $winbinddchild = Samba::cleanup_child($winbinddpid, "winbindd");
  82             if ($smbdchild == -1
  83                 && $nmbdchild == -1
  84                 && $winbinddchild == -1) {
  85                 last;
  86             }
  87             sleep(1);
  88             $count++;
  89         }
  90
  91         if ($count <= 10 && kill(0, $smbdpid, $nmbdpid, $winbinddpid) == 0) {
  92             return;
  93         }
  94
  95         warn("timelimit process did not quit on SIGTERM, sending SIGKILL");
  96         $self->stop_sig_kill($smbdpid);
  97         $self->stop_sig_kill($nmbdpid);
  98         $self->stop_sig_kill($winbinddpid);
  99
 100         return 0;
 101 }
 102
 103 sub getlog_env_app($$$)
 104 {
 105         my ($self, $envvars, $name) = @_;
 106
 107         my $title = "$name LOG of: $envvars->{NETBIOSNAME}\n";
 108         my $out = $title;
 109
 110         open(LOG, "<".$envvars->{$name."_TEST_LOG"});
 111
 112         seek(LOG, $envvars->{$name."_TEST_LOG_POS"}, SEEK_SET);
 113         while (<LOG>) {
 114                 $out .= $_;
 115         }
 116         $envvars->{$name."_TEST_LOG_POS"} = tell(LOG);
 117         close(LOG);
 118
 119         return "" if $out eq $title;
 120
 121         return $out;
 122 }
 123
 124 sub getlog_env($$)
 125 {
 126         my ($self, $envvars) = @_;
 127         my $ret = "";
 128
 129         $ret .= $self->getlog_env_app($envvars, "SMBD");
 130         $ret .= $self->getlog_env_app($envvars, "NMBD");
 131         $ret .= $self->getlog_env_app($envvars, "WINBINDD");
 132
 133         return $ret;
 134 }
 135
 136 sub check_env($$)
 137 {
 138         my ($self, $envvars) = @_;
 139
 140         my $childpid = waitpid(-1, WNOHANG);
 141
 142         # TODO ...
 143         return 1;
 144 }
 145
 146 sub setup_env($$$)
 147 {
 148         my ($self, $envname, $path) = @_;
 149
 150         if (defined($self->{vars}->{$envname})) {
 151                 return $self->{vars}->{$envname};
 152         }
 153
 154         if ($envname eq "s3dc") {
 155                 return $self->setup_s3dc("$path/s3dc");
 156         } elsif ($envname eq "secshare") {
 157                 return $self->setup_secshare("$path/secshare");
 158         } elsif ($envname eq "maptoguest") {
 159                 return $self->setup_maptoguest("$path/maptoguest");
 160         } elsif ($envname eq "ktest") {
 161                 return $self->setup_ktest("$path/ktest");
 162         } elsif ($envname eq "secserver") {
 163                 if (not defined($self->{vars}->{s3dc})) {
 164                         if (not defined($self->setup_s3dc("$path/s3dc"))) {
 165                                 return undef;
 166                         }
 167                 }
 168                 return $self->setup_secserver("$path/secserver", $self->{vars}->{s3dc});
 169         } elsif ($envname eq "member") {
 170                 if (not defined($self->{vars}->{s3dc})) {
 171                         if (not defined($self->setup_s3dc("$path/s3dc"))) {
 172                                 return undef;
 173                         }
 174                 }
 175                 return $self->setup_member("$path/member", $self->{vars}->{s3dc});
 176         } else {
 177                 return "UNKNOWN";
 178         }
 179 }
 180
 181 sub setup_s3dc($$)
 182 {
 183         my ($self, $path) = @_;
 184
 185         print "PROVISIONING S3DC...";
 186
 187         my $s3dc_options = "
 188         domain master = yes
 189         domain logons = yes
 190         lanman auth = yes
 191
 192         rpc_server:epmapper = external
 193         rpc_server:spoolss = external
 194         rpc_server:lsarpc = external
 195         rpc_server:samr = external
 196         rpc_server:netlogon = external
 197         rpc_server:register_embedded_np = yes
 198
 199         rpc_daemon:epmd = fork
 200         rpc_daemon:spoolssd = fork
 201         rpc_daemon:lsasd = fork
 202 ";
 203
 204         my $vars = $self->provision($path,
 205                                     "LOCALS3DC2",
 206                                     "locals3dc2pass",
 207                                     $s3dc_options);
 208
 209         $vars or return undef;
 210
 211         $self->check_or_start($vars,
 212                                "yes", "yes", "yes");
 213
 214         if (not $self->wait_for_start($vars)) {
 215                return undef;
 216         }
 217
 218         $vars->{DC_SERVER} = $vars->{SERVER};
 219         $vars->{DC_SERVER_IP} = $vars->{SERVER_IP};
 220         $vars->{DC_NETBIOSNAME} = $vars->{NETBIOSNAME};
 221         $vars->{DC_USERNAME} = $vars->{USERNAME};
 222         $vars->{DC_PASSWORD} = $vars->{PASSWORD};
 223
 224         $self->{vars}->{s3dc} = $vars;
 225
 226         return $vars;
 227 }
 228
 229 sub setup_member($$$)
 230 {
 231         my ($self, $prefix, $s3dcvars) = @_;
 232
 233         print "PROVISIONING MEMBER...";
 234
 235         my $member_options = "
 236         security = domain
 237         server signing = on
 238 ";
 239         my $ret = $self->provision($prefix,
 240                                    "LOCALMEMBER3",
 241                                    "localmember3pass",
 242                                    $member_options);
 243
 244         $ret or return undef;
 245
 246         my $net = Samba::bindir_path($self, "net");
 247         my $cmd = "";
 248         $cmd .= "SOCKET_WRAPPER_DEFAULT_IFACE=\"$ret->{SOCKET_WRAPPER_DEFAULT_IFACE}\" ";
 249         $cmd .= "$net join $ret->{CONFIGURATION} $s3dcvars->{DOMAIN} member";
 250         $cmd .= " -U$s3dcvars->{USERNAME}\%$s3dcvars->{PASSWORD}";
 251
 252         if (system($cmd) != 0) {
 253             warn("Join failed\n$cmd");
 254             return undef;
 255         }
 256
 257         $self->check_or_start($ret, "yes", "yes", "yes");
 258
 259         if (not $self->wait_for_start($ret)) {
 260                return undef;
 261         }
 262
 263         $ret->{DC_SERVER} = $s3dcvars->{SERVER};
 264         $ret->{DC_SERVER_IP} = $s3dcvars->{SERVER_IP};
 265         $ret->{DC_NETBIOSNAME} = $s3dcvars->{NETBIOSNAME};
 266         $ret->{DC_USERNAME} = $s3dcvars->{USERNAME};
 267         $ret->{DC_PASSWORD} = $s3dcvars->{PASSWORD};
 268
 269         return $ret;
 270 }
 271
 272 sub setup_admember($$$$)
 273 {
 274         my ($self, $prefix, $dcvars) = @_;
 275
 276         # If we didn't build with ADS, pretend this env was never available
 277         if (not $self->have_ads()) {
 278                 return "UNKNOWN";
 279         }
 280
 281         print "PROVISIONING S3 AD MEMBER...";
 282
 283         my $member_options = "
 284         security = ads
 285         server signing = on
 286         workgroup = $dcvars->{DOMAIN}
 287         realm = $dcvars->{REALM}
 288 ";
 289
 290         my $ret = $self->provision($prefix,
 291                                    "LOCALADMEMBER",
 292                                    "loCalMemberPass",
 293                                    $member_options);
 294
 295         $ret or return undef;
 296
 297         close(USERMAP);
 298         $ret->{DOMAIN} = $dcvars->{DOMAIN};
 299         $ret->{REALM} = $dcvars->{REALM};
 300
 301         my $ctx;
 302         my $prefix_abs = abs_path($prefix);
 303         $ctx = {};
 304         $ctx->{krb5_conf} = "$prefix_abs/lib/krb5.conf";
 305         $ctx->{domain} = $dcvars->{DOMAIN};
 306         $ctx->{realm} = $dcvars->{REALM};
 307         $ctx->{dnsname} = lc($dcvars->{REALM});
 308         $ctx->{kdc_ipv4} = $dcvars->{SERVER_IP};
 309         Samba::mk_krb5_conf($ctx, "");
 310
 311         $ret->{KRB5_CONFIG} = $ctx->{krb5_conf};
 312
 313         my $net = Samba::bindir_path($self, "net");
 314         my $cmd = "";
 315         $cmd .= "SOCKET_WRAPPER_DEFAULT_IFACE=\"$ret->{SOCKET_WRAPPER_DEFAULT_IFACE}\" ";
 316         $cmd .= "KRB5_CONFIG=\"$ret->{KRB5_CONFIG}\" ";
 317         $cmd .= "$net join $ret->{CONFIGURATION}";
 318         $cmd .= " -U$dcvars->{USERNAME}\%$dcvars->{PASSWORD}";
 319
 320         if (system($cmd) != 0) {
 321             warn("Join failed\n$cmd");
 322             return undef;
 323         }
 324
 325         # We need world access to this share, as otherwise the domain
 326         # administrator from the AD domain provided by Samba4 can't
 327         # access the share for tests.
 328         chmod 0777, "$prefix/share";
 329
 330         $self->check_or_start($ret,
 331                               "yes", "yes", "yes");
 332
 333         $self->wait_for_start($ret);
 334
 335         $ret->{DC_SERVER} = $dcvars->{SERVER};
 336         $ret->{DC_SERVER_IP} = $dcvars->{SERVER_IP};
 337         $ret->{DC_NETBIOSNAME} = $dcvars->{NETBIOSNAME};
 338         $ret->{DC_USERNAME} = $dcvars->{USERNAME};
 339         $ret->{DC_PASSWORD} = $dcvars->{PASSWORD};
 340
 341         # Special case, this is called from Samba4.pm but needs to use the Samba3 check_env and get_log_env
 342         $ret->{target} = $self;
 343
 344         return $ret;
 345 }
 346
 347 sub setup_secshare($$)
 348 {
 349         my ($self, $path) = @_;
 350         my $vfs_modulesdir_abs = $ENV{VFSLIBDIR};
 351
 352         print "PROVISIONING server with security=share...";
 353
 354         my $secshare_options = "
 355         security = share
 356         lanman auth = yes
 357         vfs objects = $vfs_modulesdir_abs/xattr_tdb.so $vfs_modulesdir_abs/streams_depot.so
 358 ";
 359
 360         my $vars = $self->provision($path,
 361                                     "LOCALSHARE4",
 362                                     "local4pass",
 363                                     $secshare_options);
 364
 365         $vars or return undef;
 366
 367         $self->check_or_start($vars, "yes", "no", "yes");
 368
 369         if (not $self->wait_for_start($vars)) {
 370                return undef;
 371         }
 372
 373         $self->{vars}->{secshare} = $vars;
 374
 375         return $vars;
 376 }
 377
 378 sub setup_secserver($$$)
 379 {
 380         my ($self, $prefix, $s3dcvars) = @_;
 381
 382         print "PROVISIONING server with security=server...";
 383
 384         my $secserver_options = "
 385         security = server
 386         password server = $s3dcvars->{SERVER_IP}
 387 ";
 388
 389         my $ret = $self->provision($prefix,
 390                                    "LOCALSERVER5",
 391                                    "localserver5pass",
 392                                    $secserver_options);
 393
 394         $ret or return undef;
 395
 396         $self->check_or_start($ret, "yes", "no", "yes");
 397
 398         if (not $self->wait_for_start($ret)) {
 399                return undef;
 400         }
 401
 402         $ret->{DC_SERVER} = $s3dcvars->{SERVER};
 403         $ret->{DC_SERVER_IP} = $s3dcvars->{SERVER_IP};
 404         $ret->{DC_NETBIOSNAME} = $s3dcvars->{NETBIOSNAME};
 405         $ret->{DC_USERNAME} = $s3dcvars->{USERNAME};
 406         $ret->{DC_PASSWORD} = $s3dcvars->{PASSWORD};
 407
 408         return $ret;
 409 }
 410
 411 sub setup_ktest($$$)
 412 {
 413         my ($self, $prefix) = @_;
 414
 415         # If we didn't build with ADS, pretend this env was never available
 416         if (not $self->have_ads()) {
 417                 return "UNKNOWN";
 418         }
 419
 420         print "PROVISIONING server with security=ads...";
 421
 422         my $ktest_options = "
 423         workgroup = KTEST
 424         realm = ktest.samba.example.com
 425         security = ads
 426         username map = $prefix/lib/username.map
 427         server signing = required
 428 ";
 429
 430         my $ret = $self->provision($prefix,
 431                                    "LOCALKTEST6",
 432                                    "localktest6pass",
 433                                    $ktest_options);
 434
 435         $ret or return undef;
 436
 437         my $ctx;
 438         my $prefix_abs = abs_path($prefix);
 439         $ctx = {};
 440         $ctx->{krb5_conf} = "$prefix_abs/lib/krb5.conf";
 441         $ctx->{domain} = "KTEST";
 442         $ctx->{realm} = "KTEST.SAMBA.EXAMPLE.COM";
 443         $ctx->{dnsname} = lc($ctx->{realm});
 444         $ctx->{kdc_ipv4} = "0.0.0.0";
 445         Samba::mk_krb5_conf($ctx, "");
 446
 447         $ret->{KRB5_CONFIG} = $ctx->{krb5_conf};
 448
 449         open(USERMAP, ">$prefix/lib/username.map") or die("Unable to open $prefix/lib/username.map");
 450         print USERMAP "
 451 $ret->{USERNAME} = KTEST\\Administrator
 452 ";
 453         close(USERMAP);
 454
 455 #This is the secrets.tdb created by 'net ads join' from Samba3 to a
 456 #Samba4 DC with the same parameters as are being used here.  The
 457 #domain SID is S-1-5-21-1071277805-689288055-3486227160
 458
 459         system("cp $self->{srcdir}/source3/selftest/ktest-secrets.tdb $prefix/private/secrets.tdb");
 460         chmod 0600, "$prefix/private/secrets.tdb";
 461
 462 #This uses a pre-calculated krb5 credentials cache, obtained by running Samba4 with:
 463 # "--option=kdc:service ticket lifetime=239232" "--option=kdc:user ticket lifetime=239232" "--option=kdc:renewal lifetime=239232"
 464 #
 465 #and having in krb5.conf:
 466 # ticket_lifetime = 799718400
 467 # renew_lifetime = 799718400
 468 #
 469 # The commands for the -2 keytab where were:
 470 # kinit administrator@KTEST.SAMBA.EXAMPLE.COM
 471 # kvno host/localktest6@KTEST.SAMBA.EXAMPLE.COM
 472 # kvno cifs/localktest6@KTEST.SAMBA.EXAMPLE.COM
 473 # kvno host/LOCALKTEST6@KTEST.SAMBA.EXAMPLE.COM
 474 # kvno cifs/LOCALKTEST6@KTEST.SAMBA.EXAMPLE.COM
 475 #
 476 # and then for the -3 keytab, I did
 477 #
 478 # net changetrustpw; kdestroy and the same again.
 479 #
 480 # This creates a credential cache with a very long lifetime (2036 at
 481 # at 2011-04), and shows that running 'net changetrustpw' does not
 482 # break existing logins (for the secrets.tdb method at least).
 483 #
 484
 485         $ret->{KRB5_CCACHE}="FILE:$prefix/krb5_ccache";
 486
 487         system("cp $self->{srcdir}/source3/selftest/ktest-krb5_ccache-2 $prefix/krb5_ccache-2");
 488         chmod 0600, "$prefix/krb5_ccache-2";
 489
 490         system("cp $self->{srcdir}/source3/selftest/ktest-krb5_ccache-3 $prefix/krb5_ccache-3");
 491         chmod 0600, "$prefix/krb5_ccache-3";
 492
 493         # We need world access to this share, as otherwise the domain
 494         # administrator from the AD domain provided by ktest can't
 495         # access the share for tests.
 496         chmod 0777, "$prefix/share";
 497
 498         $self->check_or_start($ret, "yes", "no", "yes");
 499
 500         if (not $self->wait_for_start($ret)) {
 501                return undef;
 502         }
 503         return $ret;
 504 }
 505
 506 sub setup_maptoguest($$)
 507 {
 508         my ($self, $path) = @_;
 509
 510         print "PROVISIONING maptoguest...";
 511
 512         my $options = "
 513 map to guest = bad user
 514 ";
 515
 516         my $vars = $self->provision($path,
 517                                     "maptoguest",
 518                                     "maptoguestpass",
 519                                     $options);
 520
 521         $vars or return undef;
 522
 523         $self->check_or_start($vars,
 524                                "yes", "no", "yes");
 525
 526         if (not $self->wait_for_start($vars)) {
 527                return undef;
 528         }
 529
 530         $self->{vars}->{s3maptoguest} = $vars;
 531
 532         return $vars;
 533 }
 534
 535 sub stop_sig_term($$) {
 536         my ($self, $pid) = @_;
 537         kill("USR1", $pid) or kill("ALRM", $pid) or warn("Unable to kill $pid: $!");
 538 }
 539
 540 sub stop_sig_kill($$) {
 541         my ($self, $pid) = @_;
 542         kill("ALRM", $pid) or warn("Unable to kill $pid: $!");
 543 }
 544
 545 sub write_pid($$$)
 546 {
 547         my ($env_vars, $app, $pid) = @_;
 548
 549         open(PID, ">$env_vars->{PIDDIR}/timelimit.$app.pid");
 550         print PID $pid;
 551         close(PID);
 552 }
 553
 554 sub read_pid($$)
 555 {
 556         my ($env_vars, $app) = @_;
 557
 558         open(PID, "<$env_vars->{PIDDIR}/timelimit.$app.pid");
 559         my $pid = <PID>;
 560         close(PID);
 561         return $pid;
 562 }
 563
 564 sub check_or_start($$$$$) {
 565         my ($self, $env_vars, $nmbd, $winbindd, $smbd) = @_;
 566
 567         # use a pipe for stdin in the child processes. This allows
 568         # those processes to monitor the pipe for EOF to ensure they
 569         # exit when the test script exits
 570         pipe(STDIN_READER, $env_vars->{STDIN_PIPE});
 571
 572         unlink($env_vars->{NMBD_TEST_LOG});
 573         print "STARTING NMBD...";
 574         my $pid = fork();
 575         if ($pid == 0) {
 576                 open STDOUT, ">$env_vars->{NMBD_TEST_LOG}";
 577                 open STDERR, '>&STDOUT';
 578
 579                 SocketWrapper::set_default_iface($env_vars->{SOCKET_WRAPPER_DEFAULT_IFACE});
 580
 581                 $ENV{KRB5_CONFIG} = $env_vars->{KRB5_CONFIG};
 582                 $ENV{WINBINDD_SOCKET_DIR} = $env_vars->{WINBINDD_SOCKET_DIR};
 583                 $ENV{NMBD_SOCKET_DIR} = $env_vars->{NMBD_SOCKET_DIR};
 584
 585                 $ENV{NSS_WRAPPER_PASSWD} = $env_vars->{NSS_WRAPPER_PASSWD};
 586                 $ENV{NSS_WRAPPER_GROUP} = $env_vars->{NSS_WRAPPER_GROUP};
 587                 $ENV{NSS_WRAPPER_WINBIND_SO_PATH} = $env_vars->{NSS_WRAPPER_WINBIND_SO_PATH};
 588
 589                 $ENV{UID_WRAPPER} = "1";
 590
 591                 if ($nmbd ne "yes") {
 592                         $SIG{USR1} = $SIG{ALRM} = $SIG{INT} = $SIG{QUIT} = $SIG{TERM} = sub {
 593                                 my $signame = shift;
 594                                 print("Skip nmbd received signal $signame");
 595                                 exit 0;
 596                         };
 597                         sleep($self->{server_maxtime});
 598                         exit 0;
 599                 }
 600
 601                 my @optargs = ("-d0");
 602                 if (defined($ENV{NMBD_OPTIONS})) {
 603                         @optargs = split(/ /, $ENV{NMBD_OPTIONS});
 604                 }
 605
 606                 $ENV{MAKE_TEST_BINARY} = Samba::bindir_path($self, "nmbd");
 607
 608                 my @preargs = (Samba::bindir_path($self, "timelimit"), $self->{server_maxtime});
 609                 if(defined($ENV{NMBD_VALGRIND})) {
 610                         @preargs = split(/ /, $ENV{NMBD_VALGRIND});
 611                 }
 612
 613                 close($env_vars->{STDIN_PIPE});
 614                 open STDIN, ">&", \*STDIN_READER or die "can't dup STDIN_READER to STDIN: $!";
 615
 616                 exec(@preargs, Samba::bindir_path($self, "nmbd"), "-F", "--no-process-group", "--log-stdout", "-s", $env_vars->{SERVERCONFFILE}, @optargs) or die("Unable to start nmbd: $!");
 617         }
 618         $env_vars->{NMBD_TL_PID} = $pid;
 619         write_pid($env_vars, "nmbd", $pid);
 620         print "DONE\n";
 621
 622         unlink($env_vars->{WINBINDD_TEST_LOG});
 623         print "STARTING WINBINDD...";
 624         $pid = fork();
 625         if ($pid == 0) {
 626                 open STDOUT, ">$env_vars->{WINBINDD_TEST_LOG}";
 627                 open STDERR, '>&STDOUT';
 628
 629                 SocketWrapper::set_default_iface($env_vars->{SOCKET_WRAPPER_DEFAULT_IFACE});
 630
 631                 $ENV{KRB5_CONFIG} = $env_vars->{KRB5_CONFIG};
 632                 $ENV{WINBINDD_SOCKET_DIR} = $env_vars->{WINBINDD_SOCKET_DIR};
 633                 $ENV{NMBD_SOCKET_DIR} = $env_vars->{NMBD_SOCKET_DIR};
 634
 635                 $ENV{NSS_WRAPPER_PASSWD} = $env_vars->{NSS_WRAPPER_PASSWD};
 636                 $ENV{NSS_WRAPPER_GROUP} = $env_vars->{NSS_WRAPPER_GROUP};
 637                 $ENV{NSS_WRAPPER_WINBIND_SO_PATH} = $env_vars->{NSS_WRAPPER_WINBIND_SO_PATH};
 638
 639                 $ENV{UID_WRAPPER} = "1";
 640
 641                 if ($winbindd ne "yes") {
 642                         $SIG{USR1} = $SIG{ALRM} = $SIG{INT} = $SIG{QUIT} = $SIG{TERM} = sub {
 643                                 my $signame = shift;
 644                                 print("Skip winbindd received signal $signame");
 645                                 exit 0;
 646                         };
 647                         sleep($self->{server_maxtime});
 648                         exit 0;
 649                 }
 650
 651                 my @optargs = ("-d0");
 652                 if (defined($ENV{WINBINDD_OPTIONS})) {
 653                         @optargs = split(/ /, $ENV{WINBINDD_OPTIONS});
 654                 }
 655
 656                 $ENV{MAKE_TEST_BINARY} = Samba::bindir_path($self, "winbindd");
 657
 658                 my @preargs = (Samba::bindir_path($self, "timelimit"), $self->{server_maxtime});
 659                 if(defined($ENV{WINBINDD_VALGRIND})) {
 660                         @preargs = split(/ /, $ENV{WINBINDD_VALGRIND});
 661                 }
 662
 663                 print "Starting winbindd with config $env_vars->{SERVERCONFFILE}\n";
 664
 665                 close($env_vars->{STDIN_PIPE});
 666                 open STDIN, ">&", \*STDIN_READER or die "can't dup STDIN_READER to STDIN: $!";
 667
 668                 exec(@preargs, Samba::bindir_path($self, "winbindd"), "-F", "--no-process-group", "--stdout", "-s", $env_vars->{SERVERCONFFILE}, @optargs) or die("Unable to start winbindd: $!");
 669         }
 670         $env_vars->{WINBINDD_TL_PID} = $pid;
 671         write_pid($env_vars, "winbindd", $pid);
 672         print "DONE\n";
 673
 674         unlink($env_vars->{SMBD_TEST_LOG});
 675         print "STARTING SMBD...";
 676         $pid = fork();
 677         if ($pid == 0) {
 678                 open STDOUT, ">$env_vars->{SMBD_TEST_LOG}";
 679                 open STDERR, '>&STDOUT';
 680
 681                 SocketWrapper::set_default_iface($env_vars->{SOCKET_WRAPPER_DEFAULT_IFACE});
 682
 683                 $ENV{KRB5_CONFIG} = $env_vars->{KRB5_CONFIG};
 684                 $ENV{WINBINDD_SOCKET_DIR} = $env_vars->{WINBINDD_SOCKET_DIR};
 685                 $ENV{NMBD_SOCKET_DIR} = $env_vars->{NMBD_SOCKET_DIR};
 686
 687                 $ENV{NSS_WRAPPER_PASSWD} = $env_vars->{NSS_WRAPPER_PASSWD};
 688                 $ENV{NSS_WRAPPER_GROUP} = $env_vars->{NSS_WRAPPER_GROUP};
 689                 $ENV{NSS_WRAPPER_WINBIND_SO_PATH} = $env_vars->{NSS_WRAPPER_WINBIND_SO_PATH};
 690
 691                 $ENV{UID_WRAPPER} = "1";
 692
 693                 if ($smbd ne "yes") {
 694                         $SIG{USR1} = $SIG{ALRM} = $SIG{INT} = $SIG{QUIT} = $SIG{TERM} = sub {
 695                                 my $signame = shift;
 696                                 print("Skip smbd received signal $signame");
 697                                 exit 0;
 698                         };
 699                         sleep($self->{server_maxtime});
 700                         exit 0;
 701                 }
 702
 703                 $ENV{MAKE_TEST_BINARY} = Samba::bindir_path($self, "smbd");
 704                 my @optargs = ("-d0");
 705                 if (defined($ENV{SMBD_OPTIONS})) {
 706                         @optargs = split(/ /, $ENV{SMBD_OPTIONS});
 707                 }
 708                 my @preargs = (Samba::bindir_path($self, "timelimit"), $self->{server_maxtime});
 709                 if(defined($ENV{SMBD_VALGRIND})) {
 710                         @preargs = split(/ /,$ENV{SMBD_VALGRIND});
 711                 }
 712
 713                 close($env_vars->{STDIN_PIPE});
 714                 open STDIN, ">&", \*STDIN_READER or die "can't dup STDIN_READER to STDIN: $!";
 715
 716                 exec(@preargs, Samba::bindir_path($self, "smbd"), "-F", "--no-process-group", "--log-stdout", "-s", $env_vars->{SERVERCONFFILE}, @optargs) or die("Unable to start smbd: $!");
 717         }
 718         $env_vars->{SMBD_TL_PID} = $pid;
 719         write_pid($env_vars, "smbd", $pid);
 720         print "DONE\n";
 721
 722         close(STDIN_READER);
 723
 724         return 0;
 725 }
 726
 727 sub provision($$$$$$)
 728 {
 729         my ($self, $prefix, $server, $password, $extra_options, $no_delete_prefix) = @_;
 730
 731         ##
 732         ## setup the various environment variables we need
 733         ##
 734
 735         my $swiface = Samba::get_interface($server);
 736         my %ret = ();
 737         my $server_ip = "127.0.0.$swiface";
 738         my $domain = "SAMBA-TEST";
 739
 740         my $unix_name = ($ENV{USER} or $ENV{LOGNAME} or `PATH=/usr/ucb:$ENV{PATH} whoami`);
 741         chomp $unix_name;
 742         my $unix_uid = $>;
 743         my $unix_gids_str = $);
 744         my @unix_gids = split(" ", $unix_gids_str);
 745
 746         my $prefix_abs = abs_path($prefix);
 747         my $bindir_abs = abs_path($self->{bindir});
 748         my $vfs_modulesdir_abs = ($ENV{VFSLIBDIR} or $bindir_abs);
 749
 750         my $dns_host_file = "$ENV{SELFTEST_PREFIX}/dns_host_file";
 751
 752         my @dirs = ();
 753
 754         my $shrdir="$prefix_abs/share";
 755         push(@dirs,$shrdir);
 756
 757         my $libdir="$prefix_abs/lib";
 758         push(@dirs,$libdir);
 759
 760         my $piddir="$prefix_abs/pid";
 761         push(@dirs,$piddir);
 762
 763         my $privatedir="$prefix_abs/private";
 764         push(@dirs,$privatedir);
 765
 766         my $lockdir="$prefix_abs/lockdir";
 767         push(@dirs,$lockdir);
 768
 769         my $eventlogdir="$prefix_abs/lockdir/eventlog";
 770         push(@dirs,$eventlogdir);
 771
 772         my $logdir="$prefix_abs/logs";
 773         push(@dirs,$logdir);
 774
 775         my $driver32dir="$shrdir/W32X86";
 776         push(@dirs,$driver32dir);
 777
 778         my $driver64dir="$shrdir/x64";
 779         push(@dirs,$driver64dir);
 780
 781         my $driver40dir="$shrdir/WIN40";
 782         push(@dirs,$driver40dir);
 783
 784         my $ro_shrdir="$shrdir/root-tmp";
 785         push(@dirs,$ro_shrdir);
 786
 787         my $msdfs_shrdir="$shrdir/msdfsshare";
 788         push(@dirs,$msdfs_shrdir);
 789
 790         my $msdfs_deeppath="$msdfs_shrdir/deeppath";
 791         push(@dirs,$msdfs_deeppath);
 792
 793         # this gets autocreated by winbindd
 794         my $wbsockdir="$prefix_abs/winbindd";
 795         my $wbsockprivdir="$lockdir/winbindd_privileged";
 796
 797         my $nmbdsockdir="$prefix_abs/nmbd";
 798         unlink($nmbdsockdir);
 799
 800         ##
 801         ## create the test directory layout
 802         ##
 803         die ("prefix_abs = ''") if $prefix_abs eq "";
 804         die ("prefix_abs = '/'") if $prefix_abs eq "/";
 805
 806         mkdir($prefix_abs, 0777);
 807         print "CREATE TEST ENVIRONMENT IN '$prefix'...";
 808         if (not defined($no_delete_prefix) or not $no_delete_prefix) {
 809             system("rm -rf $prefix_abs/*");
 810         }
 811         mkdir($_, 0777) foreach(@dirs);
 812
 813         ##
 814         ## create ro and msdfs share layout
 815         ##
 816
 817         chmod 0755, $ro_shrdir;
 818         my $unreadable_file = "$ro_shrdir/unreadable_file";
 819         unless (open(UNREADABLE_FILE, ">$unreadable_file")) {
 820                 warn("Unable to open $unreadable_file");
 821                 return undef;
 822         }
 823         close(UNREADABLE_FILE);
 824         chmod 0600, $unreadable_file;
 825
 826         my $msdfs_target = "$ro_shrdir/msdfs-target";
 827         unless (open(MSDFS_TARGET, ">$msdfs_target")) {
 828                 warn("Unable to open $msdfs_target");
 829                 return undef;
 830         }
 831         close(MSDFS_TARGET);
 832         chmod 0666, $msdfs_target;
 833         symlink "msdfs:$server_ip\\ro-tmp", "$msdfs_shrdir/msdfs-src1";
 834         symlink "msdfs:$server_ip\\ro-tmp", "$msdfs_shrdir/deeppath/msdfs-src2";
 835
 836         my $conffile="$libdir/server.conf";
 837
 838         my $nss_wrapper_pl = "$ENV{PERL} $self->{srcdir}/lib/nss_wrapper/nss_wrapper.pl";
 839         my $nss_wrapper_passwd = "$privatedir/passwd";
 840         my $nss_wrapper_group = "$privatedir/group";
 841
 842         my $mod_printer_pl = "$ENV{PERL} $self->{srcdir}/source3/script/tests/printing/modprinter.pl";
 843
 844         my @eventlog_list = ("dns server", "application");
 845
 846         ##
 847         ## calculate uids and gids
 848         ##
 849
 850         my ($max_uid, $max_gid);
 851         my ($uid_nobody, $uid_root);
 852         my ($gid_nobody, $gid_nogroup, $gid_root, $gid_domusers);
 853
 854         if ($unix_uid < 0xffff - 2) {
 855                 $max_uid = 0xffff;
 856         } else {
 857                 $max_uid = $unix_uid;
 858         }
 859
 860         $uid_root = $max_uid - 1;
 861         $uid_nobody = $max_uid - 2;
 862
 863         if ($unix_gids[0] < 0xffff - 3) {
 864                 $max_gid = 0xffff;
 865         } else {
 866                 $max_gid = $unix_gids[0];
 867         }
 868
 869         $gid_nobody = $max_gid - 1;
 870         $gid_nogroup = $max_gid - 2;
 871         $gid_root = $max_gid - 3;
 872         $gid_domusers = $max_gid - 4;
 873
 874         ##
 875         ## create conffile
 876         ##
 877
 878         unless (open(CONF, ">$conffile")) {
 879                 warn("Unable to open $conffile");
 880                 return undef;
 881         }
 882         print CONF "
 883 [global]
 884         netbios name = $server
 885         interfaces = $server_ip/8
 886         bind interfaces only = yes
 887         panic action = $self->{srcdir}/selftest/gdb_backtrace %d %\$(MAKE_TEST_BINARY)
 888
 889         workgroup = $domain
 890
 891         private dir = $privatedir
 892         pid directory = $piddir
 893         lock directory = $lockdir
 894         log file = $logdir/log.\%m
 895         log level = 1
 896         debug pid = yes
 897         max log size = 0
 898
 899         state directory = $lockdir
 900         cache directory = $lockdir
 901
 902         passdb backend = tdbsam
 903
 904         time server = yes
 905
 906         add user script =               $nss_wrapper_pl --passwd_path $nss_wrapper_passwd --type passwd --action add --name %u --gid $gid_nogroup
 907         add group script =              $nss_wrapper_pl --group_path  $nss_wrapper_group  --type group  --action add --name %g
 908         add machine script =            $nss_wrapper_pl --passwd_path $nss_wrapper_passwd --type passwd --action add --name %u --gid $gid_nogroup
 909         add user to group script =      $nss_wrapper_pl --passwd_path $nss_wrapper_passwd --type member --action add --member %u --name %g --group_path $nss_wrapper_group
 910         delete user script =            $nss_wrapper_pl --passwd_path $nss_wrapper_passwd --type passwd --action delete --name %u
 911         delete group script =           $nss_wrapper_pl --group_path  $nss_wrapper_group  --type group  --action delete --name %g
 912         delete user from group script = $nss_wrapper_pl --passwd_path $nss_wrapper_passwd --type member --action delete --member %u --name %g --group_path $nss_wrapper_group
 913
 914         addprinter command =            $mod_printer_pl -a -s $conffile --
 915         deleteprinter command =         $mod_printer_pl -d -s $conffile --
 916
 917         eventlog list = application \"dns server\"
 918
 919         kernel oplocks = no
 920         kernel change notify = no
 921
 922         syslog = no
 923         printing = bsd
 924         printcap name = /dev/null
 925
 926         winbindd:socket dir = $wbsockdir
 927         nmbd:socket dir = $nmbdsockdir
 928         idmap config * : range = 100000-200000
 929         winbind enum users = yes
 930         winbind enum groups = yes
 931
 932 #       min receivefile size = 4000
 933
 934         max protocol = SMB2
 935         read only = no
 936         server signing = auto
 937
 938         smbd:sharedelay = 100000
 939         smbd:writetimeupdatedelay = 500000
 940         map hidden = no
 941         map system = no
 942         map readonly = no
 943         store dos attributes = yes
 944         create mask = 755
 945         dos filemode = yes
 946         vfs objects = $vfs_modulesdir_abs/acl_xattr.so $vfs_modulesdir_abs/xattr_tdb.so $vfs_modulesdir_abs/streams_depot.so
 947
 948         printing = vlp
 949         print command = $bindir_abs/vlp tdbfile=$lockdir/vlp.tdb print %p %s
 950         lpq command = $bindir_abs/vlp tdbfile=$lockdir/vlp.tdb lpq %p
 951         lp rm command = $bindir_abs/vlp tdbfile=$lockdir/vlp.tdb lprm %p %j
 952         lp pause command = $bindir_abs/vlp tdbfile=$lockdir/vlp.tdb lppause %p %j
 953         lp resume command = $bindir_abs/vlp tdbfile=$lockdir/vlp.tdb lpresume %p %j
 954         queue pause command = $bindir_abs/vlp tdbfile=$lockdir/vlp.tdb queuepause %p
 955         queue resume command = $bindir_abs/vlp tdbfile=$lockdir/vlp.tdb queueresume %p
 956         lpq cache time = 0
 957
 958         ncalrpc dir = $prefix_abs/ncalrpc
 959         resolv:host file = $dns_host_file
 960
 961         # The samba3.blackbox.smbclient_s3 test uses this to test that
 962         # sending messages works, and that the %m sub works.
 963         message command = mv %s $shrdir/message.%m
 964
 965         # Begin extra options
 966         $extra_options
 967         # End extra options
 968
 969         #Include user defined custom parameters if set
 970 ";
 971
 972         if (defined($ENV{INCLUDE_CUSTOM_CONF})) {
 973                 print CONF "\t$ENV{INCLUDE_CUSTOM_CONF}\n";
 974         }
 975
 976         print CONF "
 977 [tmp]
 978         path = $shrdir
 979         comment = smb username is [%U]
 980 [tmpguest]
 981         path = $shrdir
 982         guest ok = yes
 983 [guestonly]
 984         path = $shrdir
 985         guest only = yes
 986         guest ok = yes
 987 [forceuser]
 988         path = $shrdir
 989         force user = $unix_name
 990         guest ok = yes
 991 [forcegroup]
 992         path = $shrdir
 993         force group = nogroup
 994         guest ok = yes
 995 [ro-tmp]
 996         path = $ro_shrdir
 997         guest ok = yes
 998 [msdfs-share]
 999         path = $msdfs_shrdir
1000         msdfs root = yes
1001         guest ok = yes
1002 [hideunread]
1003         copy = tmp
1004         hide unreadable = yes
1005 [tmpcase]
1006         copy = tmp
1007         case sensitive = yes
1008 [hideunwrite]
1009         copy = tmp
1010         hide unwriteable files = yes
1011 [print1]
1012         copy = tmp
1013         printable = yes
1014
1015 [print2]
1016         copy = print1
1017 [print3]
1018         copy = print1
1019 [lp]
1020         copy = print1
1021 [xcopy_share]
1022         path = $shrdir
1023         comment = smb username is [%U]
1024         create mask = 777
1025         force create mode = 777
1026 [print\$]
1027         copy = tmp
1028         ";
1029         close(CONF);
1030
1031         ##
1032         ## create a test account
1033         ##
1034
1035         unless (open(PASSWD, ">$nss_wrapper_passwd")) {
1036            warn("Unable to open $nss_wrapper_passwd");
1037            return undef;
1038         }
1039         print PASSWD "nobody:x:$uid_nobody:$gid_nobody:nobody gecos:$prefix_abs:/bin/false
1040 $unix_name:x:$unix_uid:$unix_gids[0]:$unix_name gecos:$prefix_abs:/bin/false
1041 ";
1042         if ($unix_uid != 0) {
1043                 print PASSWD "root:x:$uid_root:$gid_root:root gecos:$prefix_abs:/bin/false";
1044         }
1045         close(PASSWD);
1046
1047         unless (open(GROUP, ">$nss_wrapper_group")) {
1048              warn("Unable to open $nss_wrapper_group");
1049              return undef;
1050         }
1051         print GROUP "nobody:x:$gid_nobody:
1052 nogroup:x:$gid_nogroup:nobody
1053 $unix_name-group:x:$unix_gids[0]:
1054 domusers:X:$gid_domusers:
1055 ";
1056         if ($unix_gids[0] != 0) {
1057                 print GROUP "root:x:$gid_root:";
1058         }
1059
1060         close(GROUP);
1061
1062         foreach my $evlog (@eventlog_list) {
1063                 my $evlogtdb = "$eventlogdir/$evlog.tdb";
1064                 open(EVENTLOG, ">$evlogtdb") or die("Unable to open $evlogtdb");
1065                 close(EVENTLOG);
1066         }
1067
1068         $ENV{NSS_WRAPPER_PASSWD} = $nss_wrapper_passwd;
1069         $ENV{NSS_WRAPPER_GROUP} = $nss_wrapper_group;
1070
1071         my $cmd = Samba::bindir_path($self, "smbpasswd")." -c $conffile -L -s -a $unix_name > /dev/null";
1072         unless (open(PWD, "|$cmd")) {
1073              warn("Unable to set password for test account\n$cmd");
1074              return undef;
1075         }
1076         print PWD "$password\n$password\n";
1077         unless (close(PWD)) {
1078              warn("Unable to set password for test account\n$cmd");
1079              return undef;
1080         }
1081         print "DONE\n";
1082
1083         open(HOSTS, ">>$ENV{SELFTEST_PREFIX}/dns_host_file") or die("Unable to open $ENV{SELFTEST_PREFIX}/dns_host_file");
1084         print HOSTS "A $server. $server_ip
1085 ";
1086         close(HOSTS);
1087
1088         $ret{SERVER_IP} = $server_ip;
1089         $ret{NMBD_TEST_LOG} = "$prefix/nmbd_test.log";
1090         $ret{NMBD_TEST_LOG_POS} = 0;
1091         $ret{WINBINDD_TEST_LOG} = "$prefix/winbindd_test.log";
1092         $ret{WINBINDD_TEST_LOG_POS} = 0;
1093         $ret{SMBD_TEST_LOG} = "$prefix/smbd_test.log";
1094         $ret{SMBD_TEST_LOG_POS} = 0;
1095         $ret{SERVERCONFFILE} = $conffile;
1096         $ret{CONFIGURATION} ="-s $conffile";
1097         $ret{SERVER} = $server;
1098         $ret{USERNAME} = $unix_name;
1099         $ret{USERID} = $unix_uid;
1100         $ret{DOMAIN} = $domain;
1101         $ret{NETBIOSNAME} = $server;
1102         $ret{PASSWORD} = $password;
1103         $ret{PIDDIR} = $piddir;
1104         $ret{WINBINDD_SOCKET_DIR} = $wbsockdir;
1105         $ret{WINBINDD_PRIV_PIPE_DIR} = $wbsockprivdir;
1106         $ret{NMBD_SOCKET_DIR} = $nmbdsockdir;
1107         $ret{SOCKET_WRAPPER_DEFAULT_IFACE} = $swiface;
1108         $ret{NSS_WRAPPER_PASSWD} = $nss_wrapper_passwd;
1109         $ret{NSS_WRAPPER_GROUP} = $nss_wrapper_group;
1110         $ret{NSS_WRAPPER_WINBIND_SO_PATH} = $ENV{NSS_WRAPPER_WINBIND_SO_PATH};
1111         if (not defined($ret{NSS_WRAPPER_WINBIND_SO_PATH})) {
1112                 $ret{NSS_WRAPPER_WINBIND_SO_PATH} = Samba::bindir_path($self, "default/nsswitch/libnss-winbind.so");
1113         }
1114         $ret{LOCAL_PATH} = "$shrdir";
1115
1116         return \%ret;
1117 }
1118
1119 sub wait_for_start($$)
1120 {
1121         my ($self, $envvars) = @_;
1122
1123         # give time for nbt server to register its names
1124         print "delaying for nbt name registration\n";
1125         sleep(10);
1126         # This will return quickly when things are up, but be slow if we need to wait for (eg) SSL init
1127         system(Samba::bindir_path($self, "nmblookup3") ." $envvars->{CONFIGURATION} -U $envvars->{SERVER_IP} __SAMBA__");
1128         system(Samba::bindir_path($self, "nmblookup3") ." $envvars->{CONFIGURATION} __SAMBA__");
1129         system(Samba::bindir_path($self, "nmblookup3") ." $envvars->{CONFIGURATION} -U 127.255.255.255 __SAMBA__");
1130         system(Samba::bindir_path($self, "nmblookup3") ." $envvars->{CONFIGURATION} -U $envvars->{SERVER_IP} $envvars->{SERVER}");
1131         system(Samba::bindir_path($self, "nmblookup3") ." $envvars->{CONFIGURATION} $envvars->{SERVER}");
1132
1133         # make sure smbd is also up set
1134         print "wait for smbd\n";
1135
1136         my $count = 0;
1137         my $ret;
1138         do {
1139             $ret = system(Samba::bindir_path($self, "smbclient3") ." $envvars->{CONFIGURATION} -L $envvars->{SERVER} -U% -p 139");
1140             if ($ret != 0) {
1141                 sleep(2);
1142             }
1143             $count++
1144         } while ($ret != 0 && $count < 10);
1145         if ($count == 10) {
1146             print "SMBD failed to start up in a reasonable time (20sec)\n";
1147             teardown_env($self, $envvars);
1148             return 0;
1149         }
1150         # Ensure we have domain users mapped.
1151         $ret = system(Samba::bindir_path($self, "net") ." $envvars->{CONFIGURATION} groupmap add rid=513 unixgroup=domusers type=domain");
1152         if ($ret != 0) {
1153             return 1;
1154         }
1155
1156         print $self->getlog_env($envvars);
1157
1158         return 1;
1159 }
1160
1161 1;