ConfigureChecks.cmake

   1 # ConfigureChecks.cmake
   2 #
   3 # Wireshark - Network traffic analyzer
   4 # By Gerald Combs <gerald@wireshark.org>
   5 # Copyright 1998 Gerald Combs
   6 #
   7 # This program is free software; you can redistribute it and/or
   8 # modify it under the terms of the GNU General Public License
   9 # as published by the Free Software Foundation; either version 2
  10 # of the License, or (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  20 #
  21
  22 include(CMakePushCheckState)
  23
  24 #check system for includes
  25 include(CheckIncludeFile)
  26 check_include_file("arpa/inet.h"         HAVE_ARPA_INET_H)
  27 check_include_file("arpa/nameser.h"      HAVE_ARPA_NAMESER_H)
  28 check_include_file("dlfcn.h"             HAVE_DLFCN_H)
  29 check_include_file("fcntl.h"             HAVE_FCNTL_H)
  30 check_include_file("getopt.h"            HAVE_GETOPT_H)
  31 check_include_file("grp.h"               HAVE_GRP_H)
  32 check_include_file("inttypes.h"          HAVE_INTTYPES_H)
  33 check_include_file("netinet/in.h"        HAVE_NETINET_IN_H)
  34 check_include_file("netdb.h"             HAVE_NETDB_H)
  35 # We need to set the path to Wpdpack in order to find Ntddndis.h
  36 #cmake_push_check_state()
  37 #set(CMAKE_REQUIRED_INCLUDES %{PCAP_INCLUDE_DIRS})
  38 #check_include_file("Ntddndis.h"          HAVE_NTDDNDIS_H)
  39 #cmake_pop_check_state()
  40 check_include_file("portaudio.h"         HAVE_PORTAUDIO_H)
  41 check_include_file("pwd.h"               HAVE_PWD_H)
  42 check_include_file("stdint.h"            HAVE_STDINT_H)
  43 check_include_file("sys/ioctl.h"         HAVE_SYS_IOCTL_H)
  44 check_include_file("sys/param.h"         HAVE_SYS_PARAM_H)
  45 check_include_file("sys/socket.h"        HAVE_SYS_SOCKET_H)
  46 check_include_file("sys/sockio.h"        HAVE_SYS_SOCKIO_H)
  47 check_include_file("sys/stat.h"          HAVE_SYS_STAT_H)
  48 check_include_file("sys/time.h"          HAVE_SYS_TIME_H)
  49 check_include_file("sys/types.h"         HAVE_SYS_TYPES_H)
  50 check_include_file("sys/utsname.h"       HAVE_SYS_UTSNAME_H)
  51 check_include_file("sys/wait.h"          HAVE_SYS_WAIT_H)
  52 check_include_file("unistd.h"            HAVE_UNISTD_H)
  53 check_include_file("windows.h"           HAVE_WINDOWS_H)
  54 check_include_file("winsock2.h"          HAVE_WINSOCK2_H)
  55
  56 #Functions
  57 include(CheckFunctionExists)
  58 include(CheckSymbolExists)
  59 check_function_exists("chown"            HAVE_CHOWN)
  60
  61 cmake_push_check_state()
  62 set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_DL_LIBS})
  63 check_function_exists("dladdr"           HAVE_DLADDR)
  64 cmake_pop_check_state()
  65
  66 #
  67 # Use check_symbol_exists just in case math.h does something magic
  68 # and there's not actually a function named floorl()
  69 #
  70 check_symbol_exists("floorl" "math.h"    HAVE_FLOORL)
  71 check_function_exists("getaddrinfo"      HAVE_GETADDRINFO)
  72 check_function_exists("gethostbyname"    HAVE_GETHOSTBYNAME)
  73 check_function_exists("gethostbyname2"   HAVE_GETHOSTBYNAME2)
  74 check_function_exists("getopt_long"      HAVE_GETOPT_LONG)
  75 if(HAVE_GETOPT_LONG)
  76     if(HAVE_GETOPT_H)
  77         check_symbol_exists("optreset" "getopt.h" HAVE_OPTRESET)
  78     else()
  79         check_symbol_exists("optreset"           HAVE_OPTRESET)
  80     endif()
  81 endif()
  82 check_function_exists("getprotobynumber" HAVE_GETPROTOBYNUMBER)
  83 check_function_exists("inet_aton"        HAVE_INET_ATON)
  84 check_function_exists("inet_ntop"        HAVE_INET_NTOP_PROTO)
  85 check_function_exists("issetugid"        HAVE_ISSETUGID)
  86 check_function_exists("mkdtemp"          HAVE_MKDTEMP)
  87 check_function_exists("mkstemp"          HAVE_MKSTEMP)
  88 check_function_exists("popcount"         HAVE_POPCOUNT)
  89 check_function_exists("setresgid"        HAVE_SETRESGID)
  90 check_function_exists("setresuid"        HAVE_SETRESUID)
  91 check_function_exists("strptime"         HAVE_STRPTIME)
  92 check_function_exists("sysconf"          HAVE_SYSCONF)
  93 if (APPLE)
  94         cmake_push_check_state()
  95         set(CMAKE_REQUIRED_LIBRARIES ${APPLE_CORE_FOUNDATION_LIBRARY})
  96         check_function_exists("CFPropertyListCreateWithStream" HAVE_CFPROPERTYLISTCREATEWITHSTREAM)
  97         cmake_pop_check_state()
  98 endif()
  99
 100 #Struct members
 101 include(CheckStructHasMember)
 102 check_struct_has_member("struct sockaddr" sa_len   sys/socket.h HAVE_SA_LEN)
 103 check_struct_has_member("struct stat"     st_flags sys/stat.h   HAVE_ST_FLAGS)
 104 check_struct_has_member("struct tm"       tm_zone  time.h       HAVE_TM_ZONE)
 105
 106 #Symbols but NOT enums or types
 107 check_symbol_exists(tzname "time.h" HAVE_TZNAME)
 108
 109 # Check for stuff that isn't testable via the tests above
 110 #include(CheckCSourceCompiles)
 111
 112 #
 113 # *If* we found libnl, check if we can use nl80211 stuff with it.
 114 #
 115 if (NL_FOUND)
 116         check_c_source_compiles(
 117                 "#include <linux/nl80211.h>
 118                 int main() {
 119                         int x = NL80211_FREQUENCY_ATTR_MAX_TX_POWER;
 120                         x |= NL80211_ATTR_SUPPORTED_IFTYPES;
 121                         x |= NL80211_ATTR_SUPPORTED_COMMANDS;
 122                         x |= NL80211_ATTR_WIPHY_FREQ;
 123                         x |= NL80211_CHAN_NO_HT;
 124                         (void)x;
 125                 }"
 126                 HAVE_NL80211
 127         )
 128         check_c_source_compiles(
 129                 "#include <linux/nl80211.h>
 130                 int main() {
 131                         enum nl80211_commands x = NL80211_CMD_SET_CHANNEL;
 132                 }"
 133                 HAVE_NL80211_CMD_SET_CHANNEL
 134         )
 135         check_c_source_compiles(
 136                 "#include <linux/nl80211.h>
 137                 int main() {
 138                         enum nl80211_protocol_features x = NL80211_PROTOCOL_FEATURE_SPLIT_WIPHY_DUMP;
 139                 }"
 140                 HAVE_NL80211_SPLIT_WIPHY_DUMP
 141         )
 142 endif()
 143
 144 #
 145 # Check whether GLib's printf supports thousands grouping. (This might
 146 # be different from the system's printf since GLib can optionally use
 147 # its own printf implementation.)
 148 #
 149 if (CMAKE_CROSSCOMPILING OR WIN32)
 150         #
 151         # Play it safe when cross-compiling.
 152         #
 153         # XXX - compiling and trying to run the test below appears
 154         # to loop infinitely on Windows, and the locale is wrong in
 155         # any case, so we don't do this on Window for now.
 156         #
 157         set(HAVE_GLIB_PRINTF_GROUPING FALSE)
 158 else()
 159         cmake_push_check_state()
 160         set(CMAKE_REQUIRED_INCLUDES ${GLIB2_INCLUDE_DIRS})
 161         set(CMAKE_REQUIRED_LIBRARIES ${GLIB2_LIBRARIES})
 162         check_c_source_runs(
 163                 "#include <glib.h>
 164                 #include <locale.h>
 165                 #include <stdio.h>
 166                 #include <string.h>
 167
 168                 int
 169                 main ()
 170                 {
 171                   gchar *str;
 172                   setlocale(LC_ALL, \"en_US.UTF-8\");
 173                   str = g_strdup_printf(\"%'u\", 123456);
 174                   return (strcmp (str, \"123,456\") != 0);
 175                 }" HAVE_GLIB_PRINTF_GROUPING)
 176         cmake_pop_check_state()
 177 endif()