ConfigureChecks.cmake

   1 # ConfigureChecks.cmake
   2 #
   3 # Wireshark - Network traffic analyzer
   4 # By Gerald Combs <gerald@wireshark.org>
   5 # Copyright 1998 Gerald Combs
   6 #
   7 # This program is free software; you can redistribute it and/or
   8 # modify it under the terms of the GNU General Public License
   9 # as published by the Free Software Foundation; either version 2
  10 # of the License, or (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  20 #
  21
  22 include(CMakePushCheckState)
  23
  24 #check system for includes
  25 include(CheckIncludeFile)
  26 check_include_file("arpa/inet.h"         HAVE_ARPA_INET_H)
  27 check_include_file("arpa/nameser.h"      HAVE_ARPA_NAMESER_H)
  28 check_include_file("dlfcn.h"             HAVE_DLFCN_H)
  29 check_include_file("fcntl.h"             HAVE_FCNTL_H)
  30 check_include_file("getopt.h"            HAVE_GETOPT_H)
  31 check_include_file("grp.h"               HAVE_GRP_H)
  32 check_include_file("inttypes.h"          HAVE_INTTYPES_H)
  33 check_include_file("netinet/in.h"        HAVE_NETINET_IN_H)
  34 check_include_file("netdb.h"             HAVE_NETDB_H)
  35 # We need to set the path to Wpdpack in order to find Ntddndis.h
  36 #cmake_push_check_state()
  37 #set(CMAKE_REQUIRED_INCLUDES %{PCAP_INCLUDE_DIRS})
  38 #check_include_file("Ntddndis.h"          HAVE_NTDDNDIS_H)
  39 #cmake_pop_check_state()
  40 check_include_file("portaudio.h"         HAVE_PORTAUDIO_H)
  41 check_include_file("pwd.h"               HAVE_PWD_H)
  42 check_include_file("stdint.h"            HAVE_STDINT_H)
  43 check_include_file("sys/ioctl.h"         HAVE_SYS_IOCTL_H)
  44 check_include_file("sys/param.h"         HAVE_SYS_PARAM_H)
  45 check_include_file("sys/socket.h"        HAVE_SYS_SOCKET_H)
  46 check_include_file("sys/sockio.h"        HAVE_SYS_SOCKIO_H)
  47 check_include_file("sys/stat.h"          HAVE_SYS_STAT_H)
  48 check_include_file("sys/time.h"          HAVE_SYS_TIME_H)
  49 check_include_file("sys/types.h"         HAVE_SYS_TYPES_H)
  50 check_include_file("sys/utsname.h"       HAVE_SYS_UTSNAME_H)
  51 check_include_file("sys/wait.h"          HAVE_SYS_WAIT_H)
  52 check_include_file("unistd.h"            HAVE_UNISTD_H)
  53 check_include_file("windows.h"           HAVE_WINDOWS_H)
  54 check_include_file("winsock2.h"          HAVE_WINSOCK2_H)
  55
  56 #Functions
  57 include(CheckFunctionExists)
  58 include(CheckSymbolExists)
  59 check_function_exists("chown"            HAVE_CHOWN)
  60
  61 cmake_push_check_state()
  62 set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_DL_LIBS})
  63 check_function_exists("dladdr"           HAVE_DLADDR)
  64 cmake_pop_check_state()
  65
  66 #
  67 # Use check_symbol_exists just in case math.h does something magic
  68 # and there's not actually a function named floorl()
  69 #
  70 check_symbol_exists("floorl" "math.h"    HAVE_FLOORL)
  71 check_function_exists("getaddrinfo"      HAVE_GETADDRINFO)
  72 check_function_exists("getopt_long"      HAVE_GETOPT_LONG)
  73 if(HAVE_GETOPT_LONG)
  74     if(HAVE_GETOPT_H)
  75         check_symbol_exists("optreset" "getopt.h" HAVE_OPTRESET)
  76     else()
  77         check_symbol_exists("optreset"           HAVE_OPTRESET)
  78     endif()
  79 endif()
  80 check_function_exists("getprotobynumber" HAVE_GETPROTOBYNUMBER)
  81 check_function_exists("inet_aton"        HAVE_INET_ATON)
  82 check_function_exists("inet_ntop"        HAVE_INET_NTOP_PROTO)
  83 check_function_exists("issetugid"        HAVE_ISSETUGID)
  84 check_function_exists("mkdtemp"          HAVE_MKDTEMP)
  85 check_function_exists("mkstemp"          HAVE_MKSTEMP)
  86 check_function_exists("popcount"         HAVE_POPCOUNT)
  87 check_function_exists("setresgid"        HAVE_SETRESGID)
  88 check_function_exists("setresuid"        HAVE_SETRESUID)
  89 check_function_exists("strptime"         HAVE_STRPTIME)
  90 check_function_exists("sysconf"          HAVE_SYSCONF)
  91 if (APPLE)
  92         cmake_push_check_state()
  93         set(CMAKE_REQUIRED_LIBRARIES ${APPLE_CORE_FOUNDATION_LIBRARY})
  94         check_function_exists("CFPropertyListCreateWithStream" HAVE_CFPROPERTYLISTCREATEWITHSTREAM)
  95         cmake_pop_check_state()
  96 endif()
  97
  98 #Struct members
  99 include(CheckStructHasMember)
 100 check_struct_has_member("struct sockaddr" sa_len   sys/socket.h HAVE_SA_LEN)
 101 check_struct_has_member("struct stat"     st_flags sys/stat.h   HAVE_ST_FLAGS)
 102 check_struct_has_member("struct tm"       tm_zone  time.h       HAVE_TM_ZONE)
 103
 104 #Symbols but NOT enums or types
 105 check_symbol_exists(tzname "time.h" HAVE_TZNAME)
 106
 107 # Check for stuff that isn't testable via the tests above
 108 #include(CheckCSourceCompiles)
 109
 110 #
 111 # *If* we found libnl, check if we can use nl80211 stuff with it.
 112 #
 113 if (NL_FOUND)
 114         check_c_source_compiles(
 115                 "#include <linux/nl80211.h>
 116                 int main() {
 117                         int x = NL80211_FREQUENCY_ATTR_MAX_TX_POWER;
 118                         x |= NL80211_ATTR_SUPPORTED_IFTYPES;
 119                         x |= NL80211_ATTR_SUPPORTED_COMMANDS;
 120                         x |= NL80211_ATTR_WIPHY_FREQ;
 121                         x |= NL80211_CHAN_NO_HT;
 122                         (void)x;
 123                 }"
 124                 HAVE_NL80211
 125         )
 126         check_c_source_compiles(
 127                 "#include <linux/nl80211.h>
 128                 int main() {
 129                         enum nl80211_commands x = NL80211_CMD_SET_CHANNEL;
 130                 }"
 131                 HAVE_NL80211_CMD_SET_CHANNEL
 132         )
 133         check_c_source_compiles(
 134                 "#include <linux/nl80211.h>
 135                 int main() {
 136                         enum nl80211_protocol_features x = NL80211_PROTOCOL_FEATURE_SPLIT_WIPHY_DUMP;
 137                 }"
 138                 HAVE_NL80211_SPLIT_WIPHY_DUMP
 139         )
 140 endif()
 141
 142 #
 143 # Check whether GLib's printf supports thousands grouping. (This might
 144 # be different from the system's printf since GLib can optionally use
 145 # its own printf implementation.)
 146 #
 147 if (CMAKE_CROSSCOMPILING OR WIN32)
 148         #
 149         # Play it safe when cross-compiling.
 150         #
 151         # XXX - compiling and trying to run the test below appears
 152         # to loop infinitely on Windows, and the locale is wrong in
 153         # any case, so we don't do this on Window for now.
 154         #
 155         set(HAVE_GLIB_PRINTF_GROUPING FALSE)
 156 else()
 157         cmake_push_check_state()
 158         set(CMAKE_REQUIRED_INCLUDES ${GLIB2_INCLUDE_DIRS})
 159         set(CMAKE_REQUIRED_LIBRARIES ${GLIB2_LIBRARIES})
 160         check_c_source_runs(
 161                 "#include <glib.h>
 162                 #include <locale.h>
 163                 #include <stdio.h>
 164                 #include <string.h>
 165
 166                 int
 167                 main ()
 168                 {
 169                   gchar *str;
 170                   setlocale(LC_ALL, \"en_US.UTF-8\");
 171                   str = g_strdup_printf(\"%'u\", 123456);
 172                   return (strcmp (str, \"123,456\") != 0);
 173                 }" HAVE_GLIB_PRINTF_GROUPING)
 174         cmake_pop_check_state()
 175 endif()