ConfigureChecks.cmake

   1 include(CheckIncludeFile)
   2 include(CheckSymbolExists)
   3 include(CheckFunctionExists)
   4 include(CheckLibraryExists)
   5 include(CheckTypeSize)
   6 include(CheckStructHasMember)
   7 include(CheckPrototypeDefinition)
   8 include(TestBigEndian)
   9
  10 set(PACKAGE ${APPLICATION_NAME})
  11 set(VERSION ${APPLICATION_VERSION})
  12 set(DATADIR ${DATA_INSTALL_DIR})
  13 set(LIBDIR ${LIB_INSTALL_DIR})
  14 set(PLUGINDIR "${PLUGIN_INSTALL_DIR}-${LIBRARY_SOVERSION}")
  15 set(SYSCONFDIR ${SYSCONF_INSTALL_DIR})
  16
  17 set(BINARYDIR ${CMAKE_BINARY_DIR})
  18 set(SOURCEDIR ${CMAKE_SOURCE_DIR})
  19
  20 function(COMPILER_DUMPVERSION _OUTPUT_VERSION)
  21     # Remove whitespaces from the argument.
  22     # This is needed for CC="ccache gcc" cmake ..
  23     string(REPLACE " " "" _C_COMPILER_ARG "${CMAKE_C_COMPILER_ARG1}")
  24
  25     execute_process(
  26         COMMAND
  27             ${CMAKE_C_COMPILER} ${_C_COMPILER_ARG} -dumpversion
  28         OUTPUT_VARIABLE _COMPILER_VERSION
  29     )
  30
  31     string(REGEX REPLACE "([0-9])\\.([0-9])(\\.[0-9])?" "\\1\\2"
  32            _COMPILER_VERSION "${_COMPILER_VERSION}")
  33
  34     set(${_OUTPUT_VERSION} ${_COMPILER_VERSION} PARENT_SCOPE)
  35 endfunction()
  36
  37 if(CMAKE_COMPILER_IS_GNUCC AND NOT MINGW AND NOT OS2)
  38     compiler_dumpversion(GNUCC_VERSION)
  39     if (NOT GNUCC_VERSION EQUAL 34)
  40         set(CMAKE_REQUIRED_FLAGS "-fvisibility=hidden")
  41         check_c_source_compiles(
  42 "void __attribute__((visibility(\"default\"))) test() {}
  43 int main(void){ return 0; }
  44 " WITH_VISIBILITY_HIDDEN)
  45         set(CMAKE_REQUIRED_FLAGS "")
  46     endif (NOT GNUCC_VERSION EQUAL 34)
  47 endif(CMAKE_COMPILER_IS_GNUCC AND NOT MINGW AND NOT OS2)
  48
  49 # HEADERS
  50 check_include_file(sys/types.h HAVE_SYS_TYPES_H)
  51 check_include_file(pwd.h HAVE_PWD_H)
  52 check_include_file(grp.h HAVE_GRP_H)
  53 check_include_file(nss.h HAVE_NSS_H)
  54 check_include_file(nss_common.h HAVE_NSS_COMMON_H)
  55
  56 # FUNCTIONS
  57 check_function_exists(strncpy HAVE_STRNCPY)
  58 check_function_exists(vsnprintf HAVE_VSNPRINTF)
  59 check_function_exists(snprintf HAVE_SNPRINTF)
  60
  61 check_function_exists(getpwnam_r HAVE_GETPWNAM_R)
  62 check_function_exists(getpwuid_r HAVE_GETPWUID_R)
  63 check_function_exists(getpwent_r HAVE_GETPWENT_R)
  64
  65 check_function_exists(getgrnam_r HAVE_GETGRNAM_R)
  66 check_function_exists(getgrgid_r HAVE_GETGRGID_R)
  67 check_function_exists(getgrent_r HAVE_GETGRENT_R)
  68
  69 check_function_exists(getgrouplist HAVE_GETGROUPLIST)
  70
  71 check_function_exists(gethostbyaddr_r HAVE_GETHOSTBYADDR_R)
  72 check_function_exists(gethostbyname_r HAVE_GETHOSTBYNAME_R)
  73
  74 if (WIN32)
  75     check_function_exists(_vsnprintf_s HAVE__VSNPRINTF_S)
  76     check_function_exists(_vsnprintf HAVE__VSNPRINTF)
  77     check_function_exists(_snprintf HAVE__SNPRINTF)
  78     check_function_exists(_snprintf_s HAVE__SNPRINTF_S)
  79 endif (WIN32)
  80
  81 if (SOLARIS)
  82     check_function_exists(__posix_getpwnam_r HAVE___POSIX_GETPWNAM_R)
  83     check_function_exists(__posix_getpwuid_r HAVE___POSIX_GETPWUID_R)
  84
  85     check_function_exists(__posix_getgrgid_r HAVE___POSIX_GETGRGID_R)
  86     check_function_exists(__posix_getgrnam_r HAVE___POSIX_GETGRNAM_R)
  87 endif (SOLARIS)
  88
  89 check_function_exists(asprintf HAVE_ASPRINTF)
  90 if (UNIX AND HAVE_ASPRINTF)
  91     add_definitions(-D_GNU_SOURCE)
  92 endif (UNIX AND HAVE_ASPRINTF)
  93
  94 set(CMAKE_REQUIRED_DEFINITIONS -D_POSIX_PTHREAD_SEMANTICS)
  95 check_prototype_definition(getpwent_r
  96     "struct passwd *getpwent_r(struct passwd *src, char *buf, int buflen)"
  97     "NULL"
  98     "unistd.h;pwd.h"
  99     HAVE_SOLARIS_GETPWENT_R)
 100
 101 check_prototype_definition(getpwnam_r
 102     "int getpwnam_r(const char *name, struct passwd *pwd, char *buf, int buflen, struct passwd **ppwd)"
 103     "-1"
 104     "unistd.h;pwd.h"
 105     HAVE_SOLARIS_GETPWNAM_R)
 106
 107 check_prototype_definition(getpwuid_r
 108     "int getpwuid_r(uid_t uid, struct passwd *pwd, char *buf, int buflen, struct passwd **ppwd)"
 109     "-1"
 110     "unistd.h;pwd.h"
 111     HAVE_SOLARIS_GETPWUID_R)
 112
 113 check_prototype_definition(getgrent_r
 114     "struct group *getgrent_r(struct group *src, char *buf, int buflen)"
 115     "NULL"
 116     "unistd.h;grp.h"
 117     HAVE_SOLARIS_GETGRENT_R)
 118
 119 check_prototype_definition(getgrnam_r
 120     "int getgrnam_r(const char *name, struct group *grp, char *buf, int buflen, struct group **pgrp)"
 121     "-1"
 122     "unistd.h;grp.h"
 123     HAVE_SOLARIS_GETGRNAM_R)
 124
 125 check_prototype_definition(sethostent
 126     "int sethostent(int stayopen)"
 127     "-1"
 128     "unistd.h;netdb.h"
 129     HAVE_SOLARIS_SETHOSTENT)
 130
 131 check_prototype_definition(endhostent
 132     "int endhostent(void)"
 133     "-1"
 134     "unistd.h;netdb.h"
 135     HAVE_SOLARIS_ENDHOSTENT)
 136
 137 check_prototype_definition(gethostname
 138     "int gethostname(char *name, int len)"
 139     "-1"
 140     "unistd.h;netdb.h"
 141     HAVE_SOLARIS_GETHOSTNAME)
 142 set(CMAKE_REQUIRED_DEFINITIONS)
 143
 144 check_prototype_definition(setgrent
 145     "int setgrent(void)"
 146     "-1"
 147     "unistd.h;grp.h"
 148     HAVE_BSD_SETGRENT)
 149
 150 check_prototype_definition(getnameinfo
 151     "int getnameinfo (const struct sockaddr *sa, socklen_t salen, char *host, socklen_t __hostlen, char *serv, socklen_t servlen, int flags)"
 152     "-1"
 153     "unistd.h;netdb.h"
 154     HAVE_LINUX_GETNAMEINFO)
 155
 156 # STRUCT MEMBERS
 157 check_struct_has_member("struct sockaddr" sa_len "sys/socket.h netinet/in.h" HAVE_STRUCT_SOCKADDR_SA_LEN)
 158
 159 # IPV6
 160 check_c_source_compiles("
 161     #include <stdlib.h>
 162     #include <sys/socket.h>
 163     #include <netdb.h>
 164     #include <netinet/in.h>
 165     #include <net/if.h>
 166
 167 int main(void) {
 168     struct sockaddr_storage sa_store;
 169     struct addrinfo *ai = NULL;
 170     struct in6_addr in6addr;
 171     int idx = if_nametoindex(\"iface1\");
 172     int s = socket(AF_INET6, SOCK_STREAM, 0);
 173     int ret = getaddrinfo(NULL, NULL, NULL, &ai);
 174     if (ret != 0) {
 175         const char *es = gai_strerror(ret);
 176     }
 177
 178     freeaddrinfo(ai);
 179     {
 180         int val = 1;
 181 #ifdef HAVE_LINUX_IPV6_V6ONLY_26
 182 #define IPV6_V6ONLY 26
 183 #endif
 184         ret = setsockopt(s, IPPROTO_IPV6, IPV6_V6ONLY,
 185                          (const void *)&val, sizeof(val));
 186     }
 187
 188     return 0;
 189 }" HAVE_IPV6)
 190
 191 check_library_exists(dl dlopen "" HAVE_LIBDL)
 192 if (HAVE_LIBDL)
 193     find_library(DLFCN_LIBRARY dl)
 194     set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} ${DLFCN_LIBRARY})
 195 endif (HAVE_LIBDL)
 196
 197 # ENDIAN
 198 if (NOT WIN32)
 199     test_big_endian(WORDS_BIGENDIAN)
 200 endif (NOT WIN32)
 201
 202 set(NSSWRAP_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} CACHE INTERNAL "nsswrap required system libraries")