configure.ac

   1 # $Id$
   2 #
   3
   4 m4_define([version_major], [1])
   5 m4_define([version_minor], [11])
   6 m4_define([version_micro], [3])
   7 m4_define([version_micro_extra], version_micro)
   8 m4_append([version_micro_extra], [])
   9
  10 AC_INIT(wireshark, [version_major.version_minor.version_micro_extra], http://bugs.wireshark.org/, , http://www.wireshark.org/)
  11 CONFIG_ARGS="$*"
  12 AC_SUBST(CONFIG_ARGS)
  13
  14 # Minimum autoconf version we require.
  15 AC_PREREQ(2.60)
  16 # Variable expansion doesn't work in AC_PREREQ()
  17 AC_MIN_VERSION=2.60
  18 AC_SUBST(AC_MIN_VERSION)
  19
  20 dnl Check for CPU / vendor / OS
  21 dnl The user is encouraged to use either `AC_CANONICAL_BUILD', or
  22 dnl `AC_CANONICAL_HOST', or `AC_CANONICAL_TARGET', depending on the
  23 dnl needs.  Using `AC_CANONICAL_TARGET' is enough to run the two other
  24 dnl macros.
  25 dnl
  26 dnl As nothing in the Wireshark is itself a build tool (we are not,
  27 dnl for example, a compiler that generates machine code), we probably
  28 dnl don't need AC_CANONICAL_TARGET, so, in theory, we should be able
  29 dnl to use AC_CANONICAL_BUILD and AC_CANONICAL_HOST - or perhaps just
  30 dnl AC_CANONICAL_HOST - instead.  Note that we do have tools, such as
  31 dnl lemon, that need to be built for the build machine, not for the
  32 dnl host machine, so we might need both.
  33 dnl
  34 dnl This has to be done *after* AC_INIT, otherwise autogen.sh fails.
  35
  36 dnl AC_CANONICAL_BUILD
  37 dnl AC_CANONICAL_HOST
  38 AC_CANONICAL_TARGET
  39
  40 AM_INIT_AUTOMAKE([1.9 tar-ustar dist-bzip2 no-dist-gzip])
  41
  42 # Make Wireshark's version available in config.h
  43 AC_DEFINE(VERSION_MAJOR, version_major, [Wireshark's major version])
  44 AC_DEFINE(VERSION_MINOR, version_minor, [Wireshark's minor version])
  45 AC_DEFINE(VERSION_MICRO, version_micro, [Wireshark's micro version])
  46
  47 AM_DISABLE_STATIC
  48
  49 #
  50 # Checks for programs used in the main build process.
  51 #
  52 AC_PROG_CC
  53 AM_PROG_CC_C_O
  54 AC_PROG_CXX
  55 AC_PROG_CPP
  56 AC_PROG_MKDIR_P
  57 AC_WIRESHARK_CLANG_CHECK
  58
  59 dnl Work around libtool bug (fixed in the version 1.5a?)
  60 AC_DEFUN([AC_PROVIDE_AC_LIBTOOL_DLOPEN], )
  61 AC_LIBTOOL_DLOPEN
  62 AC_PROG_LIBTOOL
  63 if test ! -z "$CXX"; then
  64         #
  65         # OK, we found something AC_LANG_CXX thinks is a C++ compiler,
  66         # but is it one?
  67         #
  68         # Some UN*Xes have, by default, a case-insensitive file
  69         # system, and AC_PROG_CXX looks for, among other things,
  70         # "CC" as a C++ compiler, and, if you have a case-insensitive
  71         # file system and a C compiler named "cc" (both true, by
  72         # default, on OS X), AC_PROG_CXX may end up thinking it's
  73         # the C++ compiler.
  74         #
  75         # So we check by feeding the purported C++ compiler a
  76         # program using C++ features (iostream).
  77         #
  78         # We do this after AC_PROG_LIBTOOL; if we did so before, and
  79         # cleared CXX if what we had isn't a C++ compiler, that'd
  80         # get undone by AC_PROG_LIBTOOL for some reason.
  81         #
  82         AC_MSG_CHECKING(whether $CXX is a C++ compiler)
  83         AC_LANG_PUSH([C++])
  84         AC_LINK_IFELSE([AC_LANG_PROGRAM(
  85         [
  86 #include <iostream>
  87         ],
  88         [
  89         std::cout << "Hello World! ";
  90         return 0;
  91         ])],
  92                 [AC_MSG_RESULT(yes)],
  93                 [
  94                         AC_MSG_RESULT(no)
  95                         CXX=""
  96                 ])
  97         AC_LANG_POP([C++])
  98 fi
  99 AC_PATH_PROG(PERL, perl)
 100
 101 # Check for Python.
 102 AC_PATH_PROG(PYTHON, python)
 103 if test ! -z "$PYTHON"; then
 104         #
 105         # OK, we found Python; is it Python 2.5 or later?
 106         # Note: we don't use named components for sys.version_info to get
 107         # the major version number, as named components for version_info
 108         # were apparently introduced in Python 2.7.
 109         #
 110         AC_MSG_CHECKING([whether $PYTHON is Python 2.5 or later])
 111         python_major_version=`$PYTHON -c 'import sys; print (sys.version_info[[0]])'`
 112         python_minor_version=`$PYTHON -c 'import sys; print (sys.version_info[[1]])'`
 113         if test "$python_major_version" -eq 2 -a "$python_minor_version" -lt 5 ; then
 114                 AC_MSG_RESULT(no)
 115                 AC_MSG_WARN([Building with Python $python_major_version.$python_minor_version may not work])
 116         else
 117                 AC_MSG_RESULT(yes)
 118         fi
 119 fi
 120
 121 #
 122 # XXX - should autogen.sh check for YACC/Bison and Flex?  A user building
 123 # from a distribution tarball shouldn't have to have YACC/Bison or Flex,
 124 # as the tarball should contain the results of running YACC/Bison on .y
 125 # files and running Flex on .l files, but a user building from SVN
 126 # will have to run YACC/Bison and Flex to process those files.
 127 #
 128 # On the other hand, what about users who use a distribution tarball to
 129 # do development?  They *shouldn't* - that's what the SVN repository is
 130 # for - but they might.  They'd get errors if they modify a .y or .l
 131 # file and try to do a build - but the error should tell them that they
 132 # need to get YACC/Bison and/or Flex.
 133 #
 134 # Then again, getting them shouldn't be too big of a burden.
 135 #
 136 # XXX - is the same true of pod2man and pod2html, or are they needed
 137 # even when building from a distribution tarball?
 138 #
 139 #
 140 AC_PROG_YACC
 141 AC_PATH_PROG(YACCDUMMY, $YACC)
 142 if test "x$YACCDUMMY" = x
 143 then
 144         AC_MSG_ERROR(I couldn't find yacc (or bison or ...); make sure it's installed and in your path)
 145 fi
 146 AM_PROG_LEX
 147 AC_PATH_PROG(LEX, flex)
 148 if test "x$LEX" = x
 149 then
 150         AC_MSG_ERROR(I couldn't find flex; make sure it's installed and in your path)
 151 fi
 152 AC_PATH_PROG(POD2MAN, pod2man)
 153 if test "x$POD2MAN" = x
 154 then
 155         #
 156         # The alternative is not to build the man pages....
 157         #
 158         AC_MSG_ERROR(I couldn't find pod2man; make sure it's installed and in your path)
 159 fi
 160 AC_PATH_PROG(POD2HTML, pod2html)
 161 if test "x$POD2HTML" = x
 162 then
 163         #
 164         # The alternative is not to build the HTML man pages....
 165         #
 166         AC_MSG_ERROR(I couldn't find pod2html; make sure it's installed and in your path)
 167 fi
 168
 169 #
 170 # Checks for programs used by Wireshark/TShark/etc.
 171 #
 172
 173 #
 174 # XXX - this looks for various HTML viewers on the host, not the target;
 175 # we really want to know what's available on the target, for cross-builds.
 176 # That would probably require us to, at run time, look for xdg-open and,
 177 # if we don't find it, look for mozilla, htmlview, etc.
 178 #
 179 AC_PATH_PROG(HTML_VIEWER, xdg-open)
 180 if test "x$HTML_VIEWER" != x
 181 then
 182         #
 183         # XXX - the HTML_VIEWER shell variable is the full path of xdg-open.
 184         # Define some variable to be that, so we just run that?
 185         #
 186         AC_DEFINE(HAVE_XDG_OPEN, 1, [Define if we have xdg-open])
 187
 188         #
 189         # XXX - we have to define HTML_VIEWER for the prefs.c code that
 190         # sets the default value of the Web browser preference, even
 191         # though that preference won't be offered.
 192         #
 193         AC_DEFINE_UNQUOTED(HTML_VIEWER, "xdg-open", [HTML viewer, e.g. mozilla])
 194 else
 195         AC_PATH_PROG(HTML_VIEWER, htmlview)
 196         if test "x$HTML_VIEWER" = x
 197         then
 198                 AC_DEFINE_UNQUOTED(HTML_VIEWER, "mozilla", [HTML viewer, e.g. mozilla])
 199         else
 200                 AC_DEFINE_UNQUOTED(HTML_VIEWER, "htmlview", [HTML viewer, e.g. mozilla])
 201         fi
 202 fi
 203
 204 #
 205 # Set "ac_supports_gcc_flags" if the compiler is known to support GCC-style
 206 # flags such as -pedantic, -W warning flags and -f feature flags.  Currently,
 207 # we assume GCC and clang do; other compilers should be added here.
 208 #
 209 # This is done to avoid getting tripped up by compilers that support
 210 # those flags but give them a different meaning.
 211 #
 212 if test "x$GCC" = "xyes" -o "x$CC" = "xclang" ; then
 213         ac_supports_gcc_flags=yes
 214 fi
 215
 216 #
 217 # Set "ac_supports_W_linker_passthrough" if the compiler is known to
 218 # support "-Wl,{options}" to pass options through to the linker.
 219 # Currently, we assume GCC, xlc, and clang do; other compilers should
 220 # be added here.
 221 #
 222 if test "x$GCC" = "xyes" -o "x$CC" = "xxlc" -o "x$CC" = "xclang" ; then
 223         ac_supports_W_linker_passthrough=yes
 224 fi
 225
 226 #
 227 # Set "ac_supports_attribute_unused" if the compiler is known to
 228 # support "__attribute__(unused)".
 229 # Currently, we assume GCC and clang do; other compilers should
 230 # be added here.
 231 #
 232 # XXX - do this with a compiler test?
 233 #
 234 if test "x$GCC" = "xyes" -o "x$CC" = "xclang" ; then
 235         ac_supports_W_linker_passthrough=yes
 236 fi
 237
 238 if test "x$CC_FOR_BUILD" = x
 239 then
 240        CC_FOR_BUILD=$CC
 241 fi
 242 AC_SUBST(CC_FOR_BUILD)
 243 AC_SUBST(CFLAGS_FOR_BUILD)
 244
 245 # Check for doxygen
 246 AC_PATH_PROG(DOXYGEN, doxygen)
 247 AC_CHECK_PROG(HAVE_DOXYGEN, doxygen, "yes", "no")
 248 AM_CONDITIONAL(HAVE_DOXYGEN, test x$HAVE_DOXYGEN = xyes)
 249
 250 #
 251 # Check for pkg-config and set PKG_CONFIG accordingly.
 252 #
 253 # This is referenced via AC_REQUIRE([PKG_PROG_PKG_CONFIG] in some macros
 254 # like PKG_CHECK_MODULES. If the first call to such a macro is under an
 255 # "if" statement, it's safer to call PKG_PROG_PKG_CONFIG directly, see
 256 # the comments in acolocal.m4
 257 #
 258 PKG_PROG_PKG_CONFIG
 259
 260 AC_ARG_ENABLE(osx-deploy-target,
 261   AC_HELP_STRING( [--enable-osx-deploy-target],
 262     [choose an OS X deployment target @<:@default=major release on which you're building@:>@]),
 263 [
 264         #
 265         # Is this OS X?
 266         #
 267         case "$host_os" in
 268         darwin*)
 269                 #
 270                 # Yes.
 271                 #
 272                 # Let the user specify an OS X release to use as a
 273                 # deplayment target; if they specify that we should
 274                 # have a deployment target but don't specify the
 275                 # deployment target, then, if we have SDKs available,
 276                 # pick the OS version on which the build is being done.
 277                 # This also causes the build to be done against an SDK
 278                 # rather than against the headers and libraries in
 279                 # /usr/include and /usr/lib.
 280                 #
 281                 # Check for an OS X deployment target early, so that
 282                 # as many tests using the compiler are done using the
 283                 # flags that we'll be using when building.
 284                 #
 285                 if test $enableval = no
 286                 then
 287                         #
 288                         # The user explicitly said
 289                         # --disable-osx-deploy-target, so don't build
 290                         # against an SDK.
 291                         #
 292                         deploy_target=
 293                 elif test $enableval = yes
 294                 then
 295                         #
 296                         # The user said --enable-osx-deploy-target, but
 297                         # didn't say what version to target; target the
 298                         # major version number of the version of OS X on
 299                         # which we're running.
 300                         #
 301                         # (We quote the command so that we can use
 302                         # autoconf's M4 quoting characters, [ and ], in
 303                         # the sed expression.)
 304                         #
 305                         [deploy_target=`sw_vers -productVersion | sed 's/\([0-9][0-9]*\)\.\([0-9][0-9]*\)\.[0-9]*/\1.\2/'`]
 306                 else
 307                         deploy_target="$enableval"
 308                 fi
 309                 ;;
 310
 311         *)
 312                 #
 313                 # No.  Fail, because whatever the user intended for us to
 314                 # do, we can't do it.
 315                 #
 316                 AC_MSG_ERROR([--enable-osx-deploy-target specified on an OS other than OS X])
 317                 ;;
 318         esac
 319 ],[
 320         #
 321         # Is this OS X?
 322         #
 323         case "$host_os" in
 324         darwin*)
 325                 #
 326                 # Yes.
 327                 #
 328                 # If we have SDKs available, default to targeting the major
 329                 # version number of the version of OS X on which we're
 330                 # running.
 331                 #
 332                 # (We quote the command so that we can use autoconf's
 333                 # M4 quoting characters, [ and ], in the sed expression.)
 334                 #
 335                 for i in /Developer/SDKs \
 336                     /Applications/Xcode.app/Contents/Developer/Platforms/MacOSX.platform/Developer/SDKs \
 337                     /Library/Developer/CommandLineTools/SDKs
 338                 do
 339                         if test -d "$i"
 340                         then
 341                                 [deploy_target=`sw_vers -productVersion | sed 's/\([0-9][0-9]*\)\.\([0-9][0-9]*\)\.[0-9]*/\1.\2/'`]
 342                                 break
 343                         fi
 344                 done
 345                 ;;
 346
 347         *)
 348                 #
 349                 # No.  There's nothing to do.
 350                 #
 351                 ;;
 352         esac
 353 ])
 354
 355 if test ! -z "$deploy_target"
 356 then
 357         AC_MSG_CHECKING([whether we can build for OS X $deploy_target])
 358         case $deploy_target in
 359
 360         10.0|10.1|10.2)
 361                 #
 362                 # I'm not sure this would even work.
 363                 #
 364                 AC_MSG_RESULT(no)
 365                 AC_ERROR([We don't support building for OS X $deploy_target])
 366                 ;;
 367
 368         10.3)
 369                 #
 370                 # XXX - never tested.
 371                 #
 372                 AC_MSG_RESULT(yes)
 373                 SDKPATH="/Developer/SDKs/MacOSX10.3.9.sdk"
 374                 ;;
 375
 376         *)
 377                 #
 378                 # XXX - for 10.4, do we need 10.4u?  We're
 379                 # not currently doing fat builds (we'd need
 380                 # fat versions of the support libraries for
 381                 # that to be useful), but, if we do, we'd
 382                 # need to use 10.4u.
 383                 #
 384                 for i in /Developer/SDKs \
 385                     /Applications/Xcode.app/Contents/Developer/Platforms/MacOSX.platform/Developer/SDKs \
 386                     /Library/Developer/CommandLineTools/SDKs
 387                 do
 388                         if test -d "$i"/"MacOSX$deploy_target.sdk"
 389                         then
 390                                 SDKPATH="$i"/"MacOSX$deploy_target.sdk"
 391                                 break
 392                         fi
 393                 done
 394                 if test -z "$SDKPATH"
 395                 then
 396                         AC_MSG_RESULT(no)
 397                         AC_MSG_ERROR([We couldn't find the SDK for OS X $deploy_target])
 398                 fi
 399                 AC_MSG_RESULT(yes)
 400                 ;;
 401         esac
 402
 403         #
 404         # Add a -mmacosx-version-min flag to force tests that
 405         # use the compiler, as well as the build itself, not to,
 406         # for example, use compiler or linker features not supported
 407         # by the minimum targeted version of the OS.
 408         #
 409         # Add an -isysroot flag to use the SDK.
 410         #
 411         CFLAGS="-mmacosx-version-min=$deploy_target -isysroot $SDKPATH $CFLAGS"
 412         CXXFLAGS="-mmacosx-version-min=$deploy_target -isysroot $SDKPATH $CXXFLAGS"
 413         LDFLAGS="-mmacosx-version-min=$deploy_target -isysroot $SDKPATH $LDFLAGS"
 414
 415         #
 416         # Add a -sdkroot flag to use with osx-app.sh.
 417         #
 418         OSX_APP_FLAGS="-sdkroot $SDKPATH"
 419
 420         #
 421         # XXX - do we need this to build the Wireshark wrapper?
 422         # XXX - is this still necessary with the -mmacosx-version-min
 423         # flag being set?
 424         #
 425         OSX_DEPLOY_TARGET="MACOSX_DEPLOYMENT_TARGET=$deploy_target"
 426
 427         #
 428         # In the installer package XML file, give the deployment target
 429         # as the minimum version.
 430         #
 431         OSX_MIN_VERSION="$deploy_target"
 432
 433         case $deploy_target in
 434
 435         10.4|10.5)
 436                 #
 437                 # Only 32-bit builds are supported.  10.5
 438                 # (and 10.4?) had a bug that causes some BPF
 439                 # functions not to work with 64-bit userland
 440                 # code, so capturing won't work.
 441                 #
 442                 CFLAGS="-m32 $CFLAGS"
 443                 CXXFLAGS="-m32 $CXXFLAGS"
 444                 LDFLAGS="-m32 $LDFLAGS"
 445                 ;;
 446         esac
 447 else
 448         #
 449         # Is this OS X?
 450         #
 451         case "$host_os" in
 452         darwin*)
 453                 #
 454                 # Yes.
 455                 #
 456                 # In the installer package XML file, give the current OS
 457                 # version, minor version and all, as the minimum version.
 458                 # We can't guarantee that the resulting binary will work
 459                 # on older OS versions, not even older minor versions
 460                 # (original release or earlier software updates).
 461                 #
 462                 OSX_MIN_VERSION=`sw_vers -productVersion`
 463                 ;;
 464         esac
 465 fi
 466 AC_SUBST(OSX_MIN_VERSION)
 467
 468 #
 469 # Try to arrange for large file support.
 470 #
 471 AC_SYS_LARGEFILE
 472
 473 #
 474 # GUI toolkit options
 475 #
 476 AC_ARG_WITH([qt],
 477   AC_HELP_STRING( [--with-qt=@<:@yes/no@:>@],
 478                   [use Qt @<:@default=yes@:>@]),
 479   with_qt="$withval", with_qt="unspecified")
 480
 481 AC_ARG_WITH([gtk2],
 482   AC_HELP_STRING( [--with-gtk2=@<:@yes/no@:>@],
 483                   [use GTK+ 2.0 @<:@default=no@:>@]),
 484   with_gtk2="$withval", with_gtk2="unspecified")
 485
 486 AC_ARG_WITH([gtk3],
 487   AC_HELP_STRING( [--with-gtk3=@<:@yes/no@:>@],
 488                   [use GTK+ 3.0 instead of 2.0 @<:@default=yes@:>@]),
 489   with_gtk3="$withval", with_gtk3="unspecified")
 490
 491 # GnuTLS
 492 # Version 3.0 switched from LGPLv2.1+ to LGPLv3+, then switched back to
 493 # LGPLv2.1+ in version 3.1.10
 494 tls_message="no"
 495 AC_ARG_WITH([gnutls],
 496   AC_HELP_STRING( [--with-gnutls=@<:@yes/no@:>@],
 497                   [use GnuTLS library @<:@default=yes@:>@]),
 498   with_gnutls="$withval", with_gnutls="yes")
 499 if test "x$with_gnutls" = "xyes"; then
 500   have_license_compatible_gnutls="no"
 501   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 3.1.10 ],
 502     [ have_license_compatible_gnutls="yes" ], [ echo "GnuTLS >= 3.1.10 not found " ]
 503   )
 504
 505   if test "x$have_license_compatible_gnutls" != "xyes"; then
 506     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 1.2.0 gnutls < 3],
 507       [ have_license_compatible_gnutls="yes" ] , [ echo "GnuTLS >= 1.2.0, < 3.0 not found " ]
 508     )
 509   fi
 510
 511   if test "x$have_license_compatible_gnutls" = "xyes"; then
 512     echo "GnuTLS found, enabling SSL decryption"
 513     AC_DEFINE(HAVE_LIBGNUTLS, 1, [Define to use GnuTLS library])
 514     tls_message="yes"
 515   else
 516     echo "GnuTLS with compatible license not found, disabling SSL decryption"
 517     tls_message="no"
 518   fi
 519 fi
 520
 521 # libgrypt
 522 gcrypt_message="no"
 523 AC_ARG_WITH([gcrypt],
 524   AC_HELP_STRING( [--with-gcrypt=@<:@yes/no@:>@],
 525                   [use gcrypt library @<:@default=yes@:>@]),
 526   with_gcrypt="$withval", with_gcrypt="yes")
 527 if test "x$with_gcrypt" = "xyes"; then
 528   AM_PATH_LIBGCRYPT(1.1.92,
 529         [
 530                 echo "libgcrypt found, enabling ipsec decryption"
 531                 AC_DEFINE(HAVE_LIBGCRYPT, 1, [Define to use libgcrypt])
 532                 gcrypt_message="yes"
 533         ]
 534         , [
 535                 if test x$libgcrypt_config_prefix != x ; then
 536                         AC_MSG_ERROR([[libgcrypt not found; install libgcrypt-devel package for your system]])
 537                 else
 538                         echo "libgcrypt not found, disabling ipsec decryption"
 539                         gcrypt_message="no"
 540                 fi
 541         ]
 542   )
 543 fi
 544
 545 AC_ARG_WITH(libnl,
 546   AC_HELP_STRING([--with-libnl@<:@=VERSION@:>@],
 547                  [use libnl (force version VERSION, if supplied) @<:@default: yes, if available@:>@]),
 548 [
 549         if test "x$withval" = "xno"
 550         then
 551                 want_libnl=no
 552         elif test "x$withval" = "xyes"
 553         then
 554                 want_libnl=yes
 555                 libnl_version=any
 556         elif test "x$withval" = "x1"
 557         then
 558                 want_libnl=yes
 559                 libnl_version=1
 560         elif test "x$withval" = "x2"
 561         then
 562                 want_libnl=yes
 563                 libnl_version=2
 564         elif test "x$withval" = "x3"
 565         then
 566                 want_libnl=yes
 567                 libnl_version=3
 568         else
 569                 AC_MSG_ERROR(["$withval" is not a valid argument to --with-libnl])
 570         fi
 571 ],[
 572         #
 573         # Use libnl if it's present, otherwise don't.
 574         #
 575         want_libnl=ifavailable
 576         libnl_version=any
 577 ])
 578 #
 579 # Libnl is Linux-specific.
 580 #
 581 libnl_message="no"
 582 case "$host_os" in
 583 linux*)
 584         AC_MSG_CHECKING(whether to use libnl for various network interface purposes)
 585
 586         if test x$want_libnl = "xno"; then
 587                 AC_MSG_RESULT(no)
 588         else
 589                 AC_MSG_RESULT(yes)
 590                 #
 591                 # Test for specific libnl versions only if no version
 592                 # was specified by the user or if the version in question
 593                 # was requested by the user.
 594                 #
 595                 if test x$libnl_version = "xany" -o x$libnl_version = "x3"; then
 596                         PKG_CHECK_MODULES(LIBNL3, [libnl-route-3.0 >= 3.0 libnl-genl-3.0] >= 3.0, [have_libnl3=yes], [have_libnl3=no])
 597                 fi
 598                 if test x$libnl_version = "xany" -o x$libnl_version = "x2"; then
 599                         PKG_CHECK_MODULES(LIBNL2, libnl-2.0 >= 2.0, [have_libnl2=yes], [have_libnl2=no])
 600                 fi
 601                 if test x$libnl_version = "xany" -o x$libnl_version = "x1"; then
 602                         PKG_CHECK_MODULES(LIBNL1, libnl-1 >= 1.0, [have_libnl1=yes], [have_libnl1=no])
 603                 fi
 604                 if (test "${have_libnl3}" = "yes"); then
 605                         CFLAGS="$CFLAGS $LIBNL3_CFLAGS"
 606                         LIBS="$LIBS $LIBNL3_LIBS"
 607                         AC_DEFINE(HAVE_LIBNL, 1, [Enable libnl support])
 608                         AC_DEFINE(HAVE_LIBNL3, 1, [libnl version 3])
 609                         libnl_message="yes (v3)"
 610                         enable_airpcap=no
 611                 elif (test "${have_libnl2}" = "yes"); then
 612                         CFLAGS="$CFLAGS $LIBNL2_CFLAGS"
 613                         LIBS="$LIBS $LIBNL2_LIBS"
 614                         AC_DEFINE(HAVE_LIBNL, 1, [Enable libnl support])
 615                         AC_DEFINE(HAVE_LIBNL2, 1, [libnl version 2])
 616                         libnl_message="yes (v2)"
 617                         enable_airpcap=no
 618                 elif (test "${have_libnl1}" = "yes"); then
 619                         CFLAGS="$CFLAGS $LIBNL1_CFLAGS"
 620                         LIBS="$LIBS $LIBNL1_LIBS"
 621                         AC_DEFINE(HAVE_LIBNL, 1, [Enable libnl support])
 622                         AC_DEFINE(HAVE_LIBNL1, 1, [libnl version 1])
 623                         libnl_message="yes (v1)"
 624                         enable_airpcap=no
 625                 else
 626                         if test x$want_libnl = "xyes"; then
 627                                 case "$libnl_version" in
 628
 629                                 any)
 630                                         AC_MSG_ERROR("I couldn't find libnl even though you manually enabled it.")
 631                                         ;;
 632
 633                                 *)
 634                                         AC_MSG_ERROR("I couldn't find libnl version $libnl_version even though you manually enabled it.")
 635                                         ;;
 636                                 esac
 637                         fi
 638                 fi
 639         fi
 640
 641         AC_MSG_CHECKING([if nl80211.h is new enough])
 642           AC_TRY_COMPILE([#include <linux/nl80211.h>],
 643             [int x = NL80211_FREQUENCY_ATTR_MAX_TX_POWER;
 644                 x = NL80211_ATTR_SUPPORTED_IFTYPES;
 645                 x = NL80211_ATTR_SUPPORTED_COMMANDS;
 646                 x = NL80211_ATTR_WIPHY_FREQ;
 647                 x = NL80211_CHAN_NO_HT;],
 648             [AC_MSG_RESULT(yes) AC_DEFINE(HAVE_NL80211, 1, [nl80211.h is new enough])],
 649             [AC_MSG_RESULT(no)])
 650
 651         AC_MSG_CHECKING([for NL80211_SET_CHANNEL])
 652           AC_TRY_COMPILE([#include <linux/nl80211.h>],
 653             [enum nl80211_commands x = NL80211_CMD_SET_CHANNEL;],
 654             [AC_MSG_RESULT(yes) AC_DEFINE(HAVE_NL80211_CMD_SET_CHANNEL, 1, [SET_CHANNEL is supported])],
 655             [AC_MSG_RESULT(no)])
 656         ;;
 657
 658 *)
 659         if test x$want_libnl != "xno" -a x$want_libnl != "xifavailable"; then
 660                 AC_MSG_WARN([libnl is Linux-specific, ignoring --with-libnl])
 661         fi
 662 esac
 663
 664 # libsmi
 665 # FIXME: currently the path argument to with-libsmi is being ignored
 666 AX_LIBSMI
 667
 668 #
 669 # Check for programs used when building DocBook documentation.
 670 #
 671
 672 # Check for a2x (convert asciidoc to another format)
 673 AC_PATH_PROG(A2X, a2x)
 674 AC_CHECK_PROG(HAVE_A2X, a2x, "yes", "no")
 675 AM_CONDITIONAL(HAVE_A2X, test x$HAVE_A2X = xyes)
 676
 677 # Want to control a tape drive? Use mt. Want to convert HTML to text?
 678 # Uhhhhh... elinks? lynx? w3m? pandoc? html2text?
 679 AC_PATH_PROG(ELINKS, elinks)
 680 AC_CHECK_PROG(HAVE_ELINKS, elinks, "yes", "no")
 681 AM_CONDITIONAL(HAVE_ELINKS, test x$HAVE_ELINKS = xyes)
 682
 683 # Check for fop (translate .fo to e.g. pdf)
 684 AC_PATH_PROG(FOP, fop)
 685 AC_CHECK_PROG(HAVE_FOP, fop, "yes", "no")
 686 AM_CONDITIONAL(HAVE_FOP, test x$HAVE_FOP = xyes)
 687
 688 # Check for lynx (html -> text)
 689 AC_PATH_PROG(LYNX, lynx)
 690 AC_CHECK_PROG(HAVE_LYNX, lynx, "yes", "no")
 691 AM_CONDITIONAL(HAVE_LYNX, test x$HAVE_LYNX = xyes)
 692
 693 # Check for w3m (html -> text)
 694 AC_PATH_PROG(W3M, w3m)
 695 AC_CHECK_PROG(HAVE_W3M, w3m, "yes", "no")
 696 AM_CONDITIONAL(HAVE_W3M, test x$HAVE_W3M = xyes)
 697
 698 # Check for xmllint
 699 AC_PATH_PROG(XMLLINT, xmllint)
 700 AC_CHECK_PROG(HAVE_XMLLINT, xmllint, "yes", "no")
 701 AM_CONDITIONAL(HAVE_XMLLINT, test x$HAVE_XMLLINT = xyes)
 702
 703 # Check for xsltproc
 704 AC_PATH_PROG(XSLTPROC, xsltproc)
 705 AC_CHECK_PROG(HAVE_XSLTPROC, xsltproc, "yes", "no")
 706 AM_CONDITIONAL(HAVE_XSLTPROC, test x$HAVE_XSLTPROC = xyes)
 707
 708
 709 # Check for packaging utilities
 710 # For now, we check to see if the various packaging utilites are in our
 711 # path.  I'm too lazy to write code to go hunt for them.  -  Gerald
 712
 713 #
 714 # Source packages.
 715 # (Lets you install the desktop files.)
 716 #
 717 AC_PATH_PROG(DESKTOP_FILE_INSTALL, desktop-file-install)
 718
 719 # SVR4/Solaris
 720 AC_CHECK_PROG(HAVE_PKGPROTO, pkgproto, "yes", "no")
 721 AC_CHECK_PROG(HAVE_PKGMK, pkgmk, "yes", "no")
 722 AC_CHECK_PROG(HAVE_PKGTRANS, pkgtrans, "yes", "no")
 723
 724 if test x$HAVE_PKGPROTO = xyes -a x$HAVE_PKGMK = xyes \
 725      -a x$HAVE_PKGTRANS = xyes ; then
 726   HAVE_SVR4_PACKAGING=yes
 727 else
 728   HAVE_SVR4_PACKAGING=no
 729 fi
 730 AC_SUBST(HAVE_SVR4_PACKAGING)
 731
 732 # RPM
 733 AC_WIRESHARK_RPM_CHECK
 734 AC_SUBST(HAVE_RPM)
 735
 736 # Debian
 737 AC_CHECK_PROG(HAVE_DPKG_BUILDPACKAGE, dpkg-buildpackage, "yes", "no")
 738
 739 # Mac OS X
 740 AC_CHECK_PROG(HAVE_XCODEBUILD, xcodebuild, "yes", "no")
 741 AC_CHECK_PROG(HAVE_HDIUTIL, hdiutil, "yes", "no")
 742 AC_CHECK_PROG(HAVE_BLESS, bless, "yes", "no")
 743
 744 if test x$HAVE_XCODEBUILD = xyes -a x$HAVE_HDIUTIL = xyes \
 745      -a x$HAVE_BLESS = xyes ; then
 746   HAVE_OSX_PACKAGING=yes
 747 else
 748   HAVE_OSX_PACKAGING=no
 749 fi
 750 AC_SUBST(HAVE_OSX_PACKAGING)
 751
 752 #
 753 # Some compilers have to be told to fail on unknown warning errors;
 754 # make sure we do that.
 755 #
 756 AC_WIRESHARK_CHECK_UNKNOWN_WARNING_OPTION_ERROR
 757
 758 #
 759 # Try to add some additional gcc checks to CFLAGS
 760 #
 761 AC_ARG_ENABLE(extra-gcc-checks,
 762   AC_HELP_STRING( [--enable-extra-gcc-checks],
 763                   [do additional -W checks in GCC @<:@default=no@:>@]),
 764 [
 765         wireshark_extra_gcc_flags=$enableval
 766         if test $enableval != no
 767         then
 768                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-pedantic)
 769                 #
 770                 # Various code blocks this one.
 771                 #
 772                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Woverflow)
 773                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-fstrict-overflow -Wstrict-overflow=4)
 774                 #
 775                 # Some memset() calls to clear out structures
 776                 # on the stack are getting flagged as "will never
 777                 # be executed" by this, at least by Apple's
 778                 # i686-apple-darwin11-llvm-gcc-4.2 (GCC) 4.2.1 (Based on
 779                 # Apple Inc. build 5658) (LLVM build 2336.11.00), for
 780                 # some unknown reason.
 781                 #
 782                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wunreachable-code)
 783                 #
 784                 # Due to various places where APIs we don't control
 785                 # require us to cast away constness, we can probably
 786                 # never enable these ones with -Werror.
 787                 #
 788                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wcast-qual)
 789                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wbad-function-cast, C)
 790                 #
 791                 # Some generated ASN.1 dissectors block this one;
 792                 # multiple function declarations for the same
 793                 # function are being generated.
 794                 #
 795                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wredundant-decls)
 796                 #
 797                 # Some loops are safe, but it's hard to convince the
 798                 # compiler of that.
 799                 #
 800                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wunsafe-loop-optimizations)
 801                 #
 802                 # All the registration functions block these for now.
 803                 #
 804                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wmissing-prototypes)
 805                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wmissing-declarations)
 806                 #
 807                 # A bunch of "that might not work on SPARC" code blocks
 808                 # this one for now.
 809                 #
 810                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wcast-align)
 811         fi
 812 ],)
 813 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wall -W) # -W is now known as -Wextra
 814 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wextra) # -W is now known as -Wextra
 815 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wdeclaration-after-statement, C)
 816 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wendif-labels)
 817 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wpointer-arith)
 818 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wno-pointer-sign, C)
 819 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Warray-bounds)
 820 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wformat-security)
 821 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-fwrapv)
 822 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-fno-strict-overflow)
 823 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-fno-delete-null-pointer-checks)
 824 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wold-style-definition, C)
 825 # The Qt headers generate a ton of shortening errors on 64-bit systems
 826 # so only enable this for C for now.
 827 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wshorten-64-to-32, C)
 828 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wstrict-prototypes, C)
 829 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wjump-misses-init, C)
 830 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wvla)
 831 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Waddress)
 832 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Warray-bounds)
 833 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wattributes)
 834 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wdiv-by-zero)
 835 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wignored-qualifiers)
 836 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wpragmas)
 837 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wno-overlength-strings)
 838 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wwrite-strings)
 839 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wno-long-long)
 840 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wc++-compat, C)
 841 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wheader-guard)
 842
 843 #
 844 # XXX - OK for C++?
 845 #
 846 # Make sure -Wshadow doesn't complain about variables in function and
 847 # function pointer declarations shadowing other variables; if not, don't
 848 # turn it on, as some versions of GCC (including the one in at least
 849 # some Xcode versions that came with Mac OS X 10.5) complain about
 850 # that.
 851 #
 852 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wshadow, C,
 853   [
 854 extern int bar(int a);
 855 extern int foo(int);
 856
 857 int
 858 foo(int a)
 859 {
 860         int (*fptr)(int a) = bar;
 861
 862         return fptr(a) * 2;
 863 }
 864   ],
 865   [warns about variables in function declarations shadowing other variables])
 866
 867 # Unfortunately some versions of gcc generate logical-op warnings when strchr()
 868 # is given a constant string.
 869 # gcc versions 4.3.2 and 4.4.5 are known to have the problem.
 870 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wlogical-op, C,
 871   [
 872 #include <string.h>
 873
 874 int foo(const char *, int);
 875 int bar(void);
 876
 877 int
 878 foo(const char *sep, int c)
 879 {
 880         if (strchr (sep, c) != NULL)
 881                 return 1;
 882         else
 883                 return 0;
 884 }
 885
 886 int
 887 bar(void)
 888 {
 889         return foo("<", 'a');
 890 }
 891   ],
 892   [generates warnings from strchr()])
 893
 894
 895 #
 896 # On OS X, suppress warnings about deprecated declarations, because
 897 # they apparently think everything on OS X is Shiny Happy Apple-
 898 # Framework-Based Apps and are deprecating some perfectly OK
 899 # multi-platform open-source libraries that we use in our multi-platform
 900 # open-source application in favor of various frameworks that are
 901 # OS X-only.
 902 #
 903 case "$host_os" in
 904 darwin*)
 905         AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wno-deprecated-declarations)
 906         ;;
 907 esac
 908
 909 #
 910 # Use the faster pre gcc 4.5 floating point precision if available.
 911 #
 912 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-fexcess-precision=fast)
 913
 914 CFLAGS_before_fvhidden=$CFLAGS
 915 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-fvisibility=hidden)
 916 if test "x$CLFAGS" = "x$CFLAGS_before_fvhidden"
 917 then
 918         # TODO add other ways of hiding symbols
 919         AC_MSG_WARN(Compiler will export all symbols from shared libraries)
 920 fi
 921
 922 AC_WIRESHARK_LDFLAGS_CHECK([-Wl,--as-needed])
 923 ###AC_WIRESHARK_LDFLAGS_CHECK([-Wl,-M])
 924 ###AC_WIRESHARK_LDFLAGS_CHECK([-Wl,--cref])
 925 # AC_WIRESHARK_LDFLAGS_CHECK([-flto])
 926 # AC_WIRESHARK_LDFLAGS_CHECK([-fwhopr])
 927 # AC_WIRESHARK_LDFLAGS_CHECK([-fwhole-program])
 928
 929 #
 930 # Put -fPIE in PIE_CFLAGS and -pie in PIE_LDFLAGS if we can use them,
 931 # so that we can build dumpcap PIE - it may run with elevated
 932 # privileges, and using PIE means the OS can run it at random locations
 933 # in the address space to make attacks more difficult.
 934 #
 935 CFLAGS_before_pie=$CFLAGS
 936 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-fPIE)
 937 if test "x$CLFAGS" != "x$CFLAGS_before_pie"
 938 then
 939         # Restore CFLAGS
 940         CFLAGS=$CFLAGS_before_pie
 941
 942         LDFLAGS_before_pie=$LDFLAGS
 943         AC_WIRESHARK_LDFLAGS_CHECK([-fPIE -pie])
 944         if test "x$LDFLAGS" != "x$LDFLAGS_before_pie"
 945         then
 946                 # We can use PIE
 947                 PIE_CFLAGS="-fPIE"
 948                 PIE_LDFLAGS="-pie"
 949
 950                 # Restore LDFLAGS
 951                 LDFLAGS=$LDFLAGS_before_pie
 952         fi
 953
 954 fi
 955 AC_SUBST(PIE_CFLAGS)
 956 AC_SUBST(PIE_LDFLAGS)
 957
 958 #
 959 # If we're running GCC or clang define _U_ to be "__attribute__((unused))"
 960 # so we can use _U_ to flag unused function parameters and not get warnings
 961 # about them. Otherwise, define _U_ to be an empty string so that _U_ used
 962 # to flag an unused function parameters will compile with other compilers.
 963 #
 964 # XXX - similar hints for other compilers?
 965 #
 966 if test "x$GCC" = "xyes" -o "x$CC" = "xclang" ; then
 967   AC_DEFINE(_U_, __attribute__((unused)), [Hint to the compiler that a function parameters is not used])
 968 else
 969   AC_DEFINE(_U_, , [Hint to the compiler that a function parameters is not used])
 970 fi
 971
 972 # If we're running GCC or CLang, use FORTIFY_SOURCE=2
 973 #  (only if the GCC 'optimization level' > 0).
 974 #
 975 # See: http://gcc.gnu.org/ml/gcc-patches/2004-09/msg02055.html
 976 # See: http://sourceware.org/bugzilla/show_bug.cgi?id=13979
 977 #
 978 # Note: FORTIFY_SOURCE is only effective for gcc optimization level > 0 (-O1, etc)
 979 AC_WIRESHARK_GCC_FORTIFY_SOURCE_CHECK
 980
 981 #
 982 # If the compiler supports GCC-style flags, enable a barrier "stop on
 983 # warning".
 984 # This barrier is set for a very large part of the code. However, it is
 985 # typically not set for "generated" code  (flex, ans2wrs, idl2wrs, ...)
 986 #
 987 warnings_as_errors_default="yes"
 988 AC_MSG_CHECKING(whether we should treat compiler warnings as errors)
 989 AC_ARG_ENABLE(warnings-as-errors,
 990   AC_HELP_STRING( [--enable-warnings-as-errors],
 991                   [treat warnings as errors (only for GCC or clang) @<:@default=yes, unless extra warnings are enabled@:>@]),
 992 [
 993   if test "x$ac_supports_gcc_flags" = "xyes" -a "x$enableval" = "xyes"; then
 994     with_warnings_as_errors="yes"
 995     AC_MSG_RESULT(yes)
 996   else
 997     with_warnings_as_errors="no"
 998     AC_MSG_RESULT(no)
 999   fi
1000 ],
1001 [
1002   if test "x$ac_supports_gcc_flags" = "xyes" -a "x$wireshark_extra_gcc_flags" = "x" -a "x$warnings_as_errors_default" = "xyes"; then
1003     with_warnings_as_errors="yes"
1004     AC_MSG_RESULT(yes)
1005   else
1006     with_warnings_as_errors="no"
1007     AC_MSG_RESULT(no)
1008   fi
1009 ]
1010 )
1011 AM_CONDITIONAL(HAVE_WARNINGS_AS_ERRORS, test "x$with_warnings_as_errors" = "xyes")
1012
1013 #
1014 # Add any platform-specific compiler flags needed.
1015 #
1016 AC_MSG_CHECKING(for platform-specific compiler flags)
1017 if test "x$GCC" = "xyes" ; then
1018         #
1019         # GCC - do any platform-specific tweaking necessary.
1020         #
1021         case "$host_os" in
1022         solaris*)
1023                 # the X11 headers don't automatically include prototype info
1024                 # and a lot don't include the return type
1025                 CPPFLAGS="$CPPFLAGS -DFUNCPROTO=15"
1026                 CFLAGS="$CFLAGS -Wno-return-type"
1027                 CXXFLAGS="$CXXFLAGS -Wno-return-type"
1028                 AC_MSG_RESULT(GCC on Solaris - added -Wno-return-type -DFUNCPROTO=15)
1029                 ;;
1030         *)
1031                 AC_MSG_RESULT(none needed)
1032                 ;;
1033         esac
1034 else
1035         #
1036         # Not GCC - assume it's the vendor's compiler.
1037         #
1038         case "$host_os" in
1039         hpux*)
1040                 #
1041                 # HP's ANSI C compiler; flags suggested by Jost Martin.
1042                 # "-Ae" for ANSI C plus extensions such as "long long".
1043                 # "+O2", for optimization.  XXX - works with "-g"?
1044                 #
1045                 # HP's ANSI C++ compiler doesn't support "-Ae", but
1046                 # does support "+O2", at least according to the
1047                 # documentation I can find online.
1048                 #
1049                 CFLAGS="-Ae +O2 $CFLAGS"
1050                 CFLAGS_FOR_BUILD="-Ae +O2 $CFLAGS"
1051                 CXXFLAGS="+O2 $CFLAGS"
1052                 AC_MSG_RESULT(HP ANSI C compiler - added -Ae +O2)
1053                 ;;
1054         *)
1055                 AC_MSG_RESULT(none needed)
1056                 ;;
1057         esac
1058 fi
1059
1060 #
1061 # Add any platform-specific linker flags needed.
1062 #
1063 AC_MSG_CHECKING(for platform-specific linker flags)
1064 case "$host_os" in
1065 darwin*)
1066         #
1067         # Add -Wl,-single_module to the LDFLAGS used with shared
1068         # libraries, to fix some error that show up in some cases;
1069         # some Apple documentation recommends it for most shared
1070         # libraries.
1071         #
1072         LDFLAGS_SHAREDLIB="-Wl,-single_module"
1073         #
1074         # Add -Wl,-search_paths_first to make sure that if we search
1075         # directories A and B, in that order, for a given library, a
1076         # non-shared version in directory A, rather than a shared
1077         # version in directory B, is chosen (so we can use
1078         # --with-pcap=/usr/local to force all programs to be linked
1079         # with a static version installed in /usr/local/lib rather than
1080         # the system version in /usr/lib).
1081         #
1082         # Also add -Wl,-rpath,@executable_path/../lib and
1083         # -Wl,-rpath,/usr/local/lib, so that, if we build an app
1084         # bundle, we can tweak all the executable images, shared
1085         # libraries, and plugins in the bundle to look for non-system
1086         # libraries in the rpath, rather than having a script tweak
1087         # DYLD_LIBRARY_PATH.
1088         #
1089         LDFLAGS="-Wl,-search_paths_first -Wl,-rpath,@executable_path/../lib -Wl,-rpath,@executable_path/../Frameworks -Wl,-rpath,/usr/local/lib $LDFLAGS"
1090         AC_MSG_RESULT([Apple linker - added -Wl,-single_module and -Wl,-search_paths_first, and rpaths])
1091         ;;
1092 cygwin*)
1093         #
1094         # Shared libraries in cygwin/Win32 must never contain
1095         # undefined symbols.
1096         #
1097         LDFLAGS="$LDFLAGS -no-undefined"
1098         AC_MSG_RESULT(CygWin GNU ld - added -no-undefined)
1099         ;;
1100 *)
1101         AC_MSG_RESULT(none needed)
1102         ;;
1103 esac
1104 AC_SUBST(LDFLAGS_SHAREDLIB)
1105
1106 # Enable silent builds by default
1107 # Verbose builds can be enabled with "./configure
1108 # --enable-silent-rules ..." or "make V=1 ..."
1109 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
1110   [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
1111
1112 #
1113 # On "Darwin", which we assume to mean "OS X" rather than "iOS" or
1114 # "just Darwin" (as we don't currently support iOS, and as I don't
1115 # think you can build and run "just Darwin" as an OS for PCs), we
1116 # arrange to build some programs with Application Services so they
1117 # can launch Web browsers and Finder windows, arrange to build some
1118 # programs with System Configuration so they can get "friendly names"
1119 # and other information about interfaces, and build any programs that
1120 # use either of those frameworks or that report version information
1121 # with Core Foundation as the frameworks in question use it and as we
1122 # get version information from plists and thus need Core Foundation
1123 # to process those plists.
1124 #
1125 case "$host_os" in
1126
1127 darwin*)
1128         AC_DEFINE(HAVE_OS_X_FRAMEWORKS, 1, [Define to 1 if you have OS X frameworks])
1129         APPLICATIONSERVICES_FRAMEWORKS="-framework ApplicationServices"
1130         SYSTEMCONFIGURATION_FRAMEWORKS="-framework SystemConfiguration"
1131         COREFOUNDATION_FRAMEWORKS="-framework CoreFoundation"
1132
1133         #
1134         # OK, so we have the OS X frameworks; do they include
1135         # CFPropertyListCreateWithStream, or do we have
1136         # to fall back on CFPropertyListCreateFromStream?
1137         # (They only differ in the error return, which we
1138         # don't care about.  And, no, we shouldn't just
1139         # use CFPropertyListCreateFromStream, because it's
1140         # deprecated in newer releases.)
1141         #
1142         ac_save_LIBS="$LIBS"
1143         LIBS="$LIBS $COREFOUNDATION_FRAMEWORKS"
1144         AC_CHECK_FUNCS(CFPropertyListCreateWithStream)
1145         LIBS="$ac_save_LIBS"
1146         ;;
1147 esac
1148 AC_SUBST(APPLICATIONSERVICES_FRAMEWORKS)
1149 AC_SUBST(SYSTEMCONFIGURATION_FRAMEWORKS)
1150 AC_SUBST(COREFOUNDATION_FRAMEWORKS)
1151
1152 #
1153 # On Solaris, check whether we have getexecname().
1154 #
1155 case "$host_os" in
1156 solaris*)
1157         AC_CHECK_FUNC(getexecname)
1158         ;;
1159 esac
1160
1161 dnl Look in /usr/local for header files and libraries ?
1162 dnl XXX FIXME don't include /usr/local if it is already in the system
1163 dnl search path as this causes gcc 3.2 on Linux to complain about a change
1164 dnl of the system search order for includes
1165 AC_ARG_ENABLE(usr-local,
1166   AC_HELP_STRING( [--enable-usr-local],
1167                   [look for headers and libs in /usr/local tree @<:@default=yes@:>@]),
1168     ac_cv_enable_usr_local=$enableval,ac_cv_enable_usr_local=yes)
1169
1170 AC_MSG_CHECKING(whether to use /usr/local for headers and libraries)
1171 if test "x$ac_cv_enable_usr_local" = "xyes" ; then
1172         if test -d "/usr/local"; then
1173                 AC_MSG_RESULT(yes)
1174                 #
1175                 # Arrange that we search for header files in the source directory
1176                 # and in its "wiretap" subdirectory, as well as in "/usr/local/include",
1177                 # as various packages we use ("libpcap", "zlib", "adns")
1178                 # may have been installed under "/usr/local/include".
1179                 #
1180                 CPPFLAGS="$CPPFLAGS -I/usr/local/include"
1181
1182                 #
1183                 # Arrange that we search for libraries in "/usr/local/lib".
1184                 #
1185                 AC_WIRESHARK_ADD_DASH_L(LDFLAGS, /usr/local/lib)
1186         else
1187                 AC_MSG_RESULT(no)
1188         fi
1189 else
1190         AC_MSG_RESULT(no)
1191 fi
1192
1193 #
1194 # If we're running Solaris, and LD_LIBRARY_PATH is defined, add it as a
1195 # link directory.
1196 #
1197 case "$host_os" in
1198   solaris*)
1199     AC_MSG_CHECKING(for LD_LIBRARY_PATH, since you appear to be running Solaris)
1200     if test x$LD_LIBRARY_PATH != x ; then
1201       LIBS="$LIBS -R$LD_LIBRARY_PATH"
1202       AC_MSG_RESULT(yes -- added LD_LIBRARY_PATH to run-time linker path)
1203     else
1204       AC_MSG_RESULT(no -- this may be a problem in a few seconds)
1205     fi
1206   ;;
1207 esac
1208
1209 #
1210 # Check for versions of "sed" inadequate to handle, in libtool, a list
1211 # of object files as large as the list in Wireshark.
1212 #
1213 # On Solaris, we check for "/bin/sed", "/usr/bin/sed", and "/usr/ucb/sed",
1214 # as both "/usr/bin/sed" (which is also "/bin/sed", as "/bin" is just a
1215 # symlink to "/usr/bin", but people may have "/bin" before "/usr/bin" in
1216 # their search path) and "/usr/ucb/sed" are inadequate; "/usr/xpg4/bin/sed"
1217 # is the only "sed" that comes with Solaris that can handle Wireshark.
1218 #
1219 # Add any checks here that are necessary for other OSes.
1220 #
1221 AC_PATH_PROG(SED, sed)
1222 if test "x$SED" = x
1223 then
1224         AC_MSG_ERROR(I couldn't find sed; make sure it's installed and in your path)
1225 fi
1226 AC_WIRESHARK_GNU_SED_CHECK
1227 if test "$HAVE_GNU_SED" = no ; then
1228         case "$host_os" in
1229         solaris*)
1230                 AC_MSG_CHECKING(whether one of /usr/bin/sed or /bin/sed or /usr/ucb/sed will be used)
1231                 case `which sed` in
1232                         /bin/sed|/usr/bin/sed|/usr/ucb/sed)
1233                         AC_MSG_RESULT(yes)
1234                         AC_MSG_ERROR([change your path to search /usr/xpg4/bin or directory containing GNU sed before /usr/bin (and /bin and /usr/ucb)])
1235                         ;;
1236
1237                         *)
1238                         AC_MSG_RESULT(no)
1239                         ;;
1240                 esac
1241                 ;;
1242
1243         *)
1244                 :
1245                 ;;
1246         esac
1247 fi
1248
1249 # Enable/disable wireshark
1250 AC_ARG_ENABLE(wireshark,
1251   AC_HELP_STRING( [--enable-wireshark],
1252                   [build the Wireshark GUI (with Gtk+, Qt, or both) @<:@default=yes@:>@]),
1253     enable_wireshark=$enableval,enable_wireshark=yes)
1254
1255 AC_ARG_ENABLE(packet-editor,
1256   AC_HELP_STRING( [--enable-packet-editor],
1257                   [add support for packet editor in Wireshark @<:@default=yes@:>@]),
1258     enable_packet_editor=$enableval,enable_packet_editor=yes)
1259 if test x$enable_packet_editor = xyes; then
1260         AC_DEFINE(WANT_PACKET_EDITOR, 1, [Support for packet editor])
1261 fi
1262
1263 AC_ARG_ENABLE(profile-build,
1264   AC_HELP_STRING( [--enable-profile-build],
1265                   [build profile-ready binaries @<:@default=no@:>@]),
1266     enable_profile_build=$enableval,enable_profile_build=no)
1267 AM_CONDITIONAL(USE_PROFILE_BUILD, test x$enable_profile_build = xyes)
1268 AC_MSG_CHECKING(if profile builds must be generated)
1269 if test "x$enable_profile_build" = "xyes" ; then
1270         if test "x$GCC" = "xyes" -o "x$CLANG" = "xyes" ; then
1271                 AC_MSG_RESULT(yes)
1272                 CFLAGS=" -pg $CFLAGS"
1273                 CXXFLAGS=" -pg $CXXFLAGS"
1274         else
1275                 AC_MSG_RESULT(no)
1276                 echo "Building profile binaries currently only supported for GCC and clang."
1277         fi
1278 else
1279         AC_MSG_RESULT(no)
1280 fi
1281
1282 # Create DATAFILE_DIR #define for config.h
1283 datafiledir=$datadir/wireshark
1284 datafiledir=`(
1285     test "x$prefix" = xNONE && prefix=$ac_default_prefix
1286     test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
1287     # Ugly hack, but I don't see how this problem can be solved
1288     # properly that DATAFILE_DIR had a value starting with
1289     # "${prefix}/" instead of e.g. "/usr/local/"
1290     eval eval echo "$datafiledir"
1291 )`
1292 AC_DEFINE_UNQUOTED(DATAFILE_DIR,"$datafiledir", [Directory for data])
1293
1294 # Create DOC_DIR #define for config.h
1295 docdir=`(
1296     test "x$prefix" = xNONE && prefix=$ac_default_prefix
1297     test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
1298     # Ugly hack, but I don't see how this problem can be solved
1299     # properly that DOC_DIR had a value starting with
1300     # "${prefix}/" instead of e.g. "/usr/local/"
1301     eval eval echo "$docdir"
1302 )`
1303 AC_DEFINE_UNQUOTED(DOC_DIR, "$docdir", [Directory for docs])
1304
1305 GTK2_MIN_VERSION=2.12.0
1306 AC_SUBST(GTK2_MIN_VERSION)
1307 GTK3_MIN_VERSION=3.0.0
1308 AC_SUBST(GTK3_MIN_VERSION)
1309 QT_MIN_VERSION=4.6.0
1310 AC_SUBST(QT_MIN_VERSION)
1311 # GTK+ and Qt checks; we require GTK+ $GTK2_MIN_VERSION or later or
1312 # GTK3_MIN_VERSION or later or Qt $QT_MIN_VERSION or later.
1313 #
1314 # We only do those if we're going to be building Wireshark;
1315 # otherwise, we don't have any GUI to build, so we don't use
1316 # GTK+ or Qt.
1317 #
1318 # We don't add $GTK_LIBS or $Qt_LIBS to LIBS, because we don't want to
1319 # force all programs to be built with GTK+ or Qt.
1320 #
1321 # Release dates for GTK+ versions:
1322 # 2.12.0: 14 Sep 2007
1323 # 2.14.0: 04 Sep 2008
1324 # 2.16.0: 13 Mar 2009
1325 # 2.18.0: 23 Sep 2009
1326 # 2.20.0: 23 Mar 2010
1327 # 2.22.0: 23 Sep 2010
1328 # 2.24.0: 30 Jan 2011
1329 # 3.0.0:  10 Feb 2011
1330 # 3.2.0:  25 Sep 2011
1331 # 3.4.0:  26 Mar 2012
1332 # 3.6.0:  24 Sep 2012
1333 # 3.8.0:  25 Mar 2013
1334
1335 have_qt=no
1336 have_gtk=no
1337 if test "x$enable_wireshark" = "xyes"; then
1338         if test "x$with_gtk2" = "xunspecified" -a \
1339                 "x$with_gtk3" = "xunspecified" -a \
1340                 "x$with_qt" = "xunspecified"; then
1341                 #
1342                 # No GUI toolkit was explicitly specified; pick Qt and GTK+ 3.
1343                 #
1344                 with_qt=yes
1345                 with_gtk3=yes
1346         fi
1347         if test "x$with_qt" = "xyes"; then
1348                 #
1349                 # Qt was specified; Make sure we have a C++ compiler.
1350                 #
1351                 if test -z "$CXX"; then
1352                         AC_MSG_ERROR(Need a working C++ compiler to build Wireshark with Qt)
1353                 fi
1354
1355                 #
1356                 # Now make sure we have Qt and, if so, add the flags
1357                 # for it to CFLAGS and CXXFLAGS.
1358                 #
1359                 AC_WIRESHARK_QT_CHECK($QT_MIN_VERSION,
1360                 [
1361                         CFLAGS="$CFLAGS $Qt_CFLAGS"
1362                         CXXFLAGS="$CXXFLAGS $Qt_CFLAGS"
1363                         have_qt=yes
1364                         GUI_CONFIGURE_FLAGS="$GUI_CONFIGURE_FLAGS --with-qt"
1365                         OSX_APP_FLAGS="$OSX_APP_FLAGS -qt"
1366                         OSX_DMG_FLAGS="-qt"
1367                 ],
1368                 [AC_MSG_ERROR([Qt is not available])])
1369
1370                 #
1371                 # XXX - greasy hack to make ui/gtk/recent.c
1372                 # compile.
1373                 #
1374                 CPPFLAGS="-DQT_GUI_LIB"
1375         fi
1376
1377         if test "x$with_gtk3" = "xyes"; then
1378                 #
1379                 # GTK+ 3 was specified; make sure they didn't also
1380                 # specify GTK+ 2, as we don't support building both
1381                 # GTK+ 2 and GTK+ 3 versions at the same time.
1382                 #
1383                 if test "x$with_gtk2" = "xyes"; then
1384                         AC_MSG_ERROR([Both GTK+ 2 and GTK+ 3 were specified; choose one but not both])
1385                 fi
1386
1387                 #
1388                 # Make sure we have GTK+ 3.
1389                 #
1390                 AM_PATH_GTK_3_0(3.0.0,
1391                 [
1392                         CFLAGS="$CFLAGS $GTK_CFLAGS"
1393                         CXXFLAGS="$CXXFLAGS $GTK_CFLAGS"
1394                         have_gtk=yes
1395                         GUI_CONFIGURE_FLAGS="$GUI_CONFIGURE_FLAGS --with-gtk3"
1396                 ],
1397                 [AC_MSG_ERROR([GTK+ 3 is not available])])
1398         elif test "x$with_gtk2" = "xyes"; then
1399                 #
1400                 # GTK+ 3 wasn't specified, and GTK+ 2 was specified;
1401                 # make sure we have GTK+ 2.
1402                 #
1403                 AM_PATH_GTK_2_0($GTK2_MIN_VERSION,
1404                 [
1405                         CFLAGS="$CFLAGS $GTK_CFLAGS"
1406                         CXXFLAGS="$CXXFLAGS $GTK_CFLAGS"
1407                         have_gtk=yes
1408                         GUI_CONFIGURE_FLAGS="$GUI_CONFIGURE_FLAGS --with-gtk2"
1409                 ],
1410                 [AC_MSG_ERROR([GTK+ 2 is not available])])
1411         fi
1412 fi
1413 AC_SUBST(GUI_CONFIGURE_FLAGS)
1414
1415 GLIB_MIN_VERSION=2.16.0
1416 AC_SUBST(GLIB_MIN_VERSION)
1417 # GLib checks; we require GLib $GLIB_MIN_VERSION or later, and require gmodule
1418 # support, as we need that for dynamically loading plugins.
1419 # If we found GTK+, this doesn't add GLIB_CFLAGS to CFLAGS, because
1420 # AM_PATH_GTK will add GTK_CFLAGS to CFLAGS, and GTK_CFLAGS is a
1421 # superset of GLIB_CFLAGS.  If we didn't find GTK+, it does add
1422 # GLIB_CFLAGS to CFLAGS.
1423 # However, this means that both @GLIB_LIBS@ and @GTK_LIBS@ will be
1424 # set when generating the Makefile, so we can make programs that require
1425 # only GLib link with @GLIB_LIBS@ and make programs that require GTK+
1426 # link with @GTK_LIBS@ (which includes @GLIB_LIBS@).
1427 # We don't add $GLIB_LIBS to LIBS, because we don't want to force all
1428 # programs to be built with GLib.
1429 #
1430 # Release dates for GLib versions:
1431 # 2.14.0: 03 Aug 2007
1432 # 2.16.0: 10 Mar 2008
1433 # 2.18.0: 02 Sep 2008
1434 # 2.20.0: 13 Mar 2009
1435 # 2.22.0: 22 Sep 2009
1436 # 2.24.0: 28 Mar 2010
1437 # 2.26.0: 27 Sep 2010
1438 # 2.28.0: 08 Feb 2011
1439 # 2.30.0: 27 Sep 2011
1440 # 2.32.0: 24 Mar 2012
1441 # 2.34.0: 24 Sep 2012
1442 # 2.36.0: 25 Mar 2013
1443
1444 use_glib_cflags="true"
1445 if test "$have_gtk" = "yes" -a "$have_qt" = "yes" ; then
1446         # We have both GTK and Qt and thus will be building both wireshark
1447         # and wireshark-qt.
1448
1449         wireshark_bin="wireshark\$(EXEEXT) wireshark-qt\$(EXEEXT)"
1450         wireshark_man="wireshark.1"
1451         wireshark_SUBDIRS="codecs ui/qt ui/gtk"
1452 fi
1453 if test "$have_gtk" = "no" -a "$have_qt" = "yes" ; then
1454         # We don't have GTK+ but we have Qt.
1455
1456         wireshark_bin="wireshark-qt\$(EXEEXT)"
1457         wireshark_man="wireshark.1"
1458         wireshark_SUBDIRS="codecs ui/qt"
1459 fi
1460 if test "$have_gtk" = "yes" -a "$have_qt" = "no" ; then
1461         # We have GTK+ but not Qt.
1462
1463         wireshark_bin="wireshark\$(EXEEXT)"
1464         wireshark_man="wireshark.1"
1465         wireshark_SUBDIRS="codecs ui/gtk"
1466         use_glib_cflags="false"
1467 fi
1468 if test "$have_gtk" = "no" -a "$have_qt" = "no" ; then
1469         # We have neither GTK+ nor Qt.
1470         #
1471         # If they didn't explicitly say "--disable-wireshark",
1472         # fail (so that, unless they explicitly indicated that
1473         # they don't want Wireshark, we stop so they know they
1474         # won't be getting Wireshark unless they fix the GTK+/Qt
1475         # problem).
1476         #
1477         if test "x$enable_wireshark" = "xyes"; then
1478                 if test "x$with_gtk3" = "xyes"; then
1479                         AC_MSG_ERROR([Neither Qt nor GTK+ $GTK3_MIN_VERSION or later are available, so Wireshark can't be compiled])
1480                 else
1481                         AC_MSG_ERROR([Neither Qt nor GTK+ $GTK2_MIN_VERSION or later are available, so Wireshark can't be compiled])
1482                 fi
1483         fi
1484         wireshark_bin=""
1485         wireshark_man=""
1486 fi
1487
1488 if test "$have_gtk" = "yes" ; then
1489         # If we have GTK then add flags for it.
1490
1491         CPPFLAGS="-DGDK_PIXBUF_DISABLE_DEPRECATED $CPPFLAGS"
1492         CPPFLAGS="-DGDK_DISABLE_DEPRECATED $CPPFLAGS"
1493         CPPFLAGS="-DGTK_DISABLE_DEPRECATED $CPPFLAGS"
1494         CPPFLAGS="-DGTK_DISABLE_SINGLE_INCLUDES $CPPFLAGS"
1495         if test ! \( $gtk_config_major_version -eq 2 -a $gtk_config_minor_version -lt 20 \) ; then
1496                 # Enable GSEAL when building with GTK > 2.20
1497                 # (Versions prior to 2.22 lacked some necessary accessors.)
1498                 CPPFLAGS="-DGSEAL_ENABLE $CPPFLAGS"
1499         fi
1500 fi
1501
1502 # XXX - Is this really necessary?  When we build with both Gtk+ and Qt it works...
1503 if test "$use_glib_cflags" = "true"; then
1504         # Use GLIB_CFLAGS
1505         AM_PATH_GLIB_2_0($GLIB_MIN_VERSION,
1506         [
1507                 CFLAGS="$CFLAGS $GLIB_CFLAGS"
1508                 CXXFLAGS="$CXXFLAGS $GLIB_CFLAGS"
1509         ], AC_MSG_ERROR(GLib $GLIB_MIN_VERSION or later distribution not found.), gthread gmodule)
1510 else
1511         # Don't use GLIB_CFLAGS
1512         AM_PATH_GLIB_2_0($GLIB_MIN_VERSION, , AC_MSG_ERROR(GLib $GLIB_MIN_VERSION or later distribution not found.), gthread gmodule)
1513 fi
1514
1515 #
1516 # "make dist" requires that we have the Qt build tools.
1517 #
1518 # Annoyingly, at least on Fedora 16, uic and moc are named XXX-qt4
1519 # rather than just XXX, perhaps to allow Qt 3 and Qt 4 tools to be
1520 # installed; if they're still doing that in current Fedora releases,
1521 # perhaps there will also be XXX-qt5 when they pick up Qt 5.
1522 #
1523 AC_PATH_PROG(UIC, uic)
1524 if test "x$UIC" = x
1525 then
1526         AC_PATH_PROG(UIC, uic-qt4)
1527         if test "x$UIC" = x
1528         then
1529                 if test "x$with_qt" = "xyes"; then
1530                         #
1531                         # If you want to build with Qt, you'd better
1532                         # have uic.
1533                         #
1534                         AC_MSG_ERROR(I couldn't find uic or uic-qt4; make sure it's installed and in your path)
1535                 else
1536                         #
1537                         # We shouldn't fail here, as the user's not
1538                         # building with Qt, and we shouldn't force them
1539                         # to have Qt installed if they're not doing so.
1540                         # "make dist" will fail if they do that, but
1541                         # we don't know whether they'll be doing that,
1542                         # so this is the best we can do.
1543                         #
1544                         UIC=uic
1545                 fi
1546         fi
1547 fi
1548 AC_SUBST(UIC)
1549 AC_PATH_PROG(MOC, moc)
1550 if test "x$MOC" = x
1551 then
1552         AC_PATH_PROG(MOC, moc-qt4)
1553         if test "x$MOC" = x
1554         then
1555                 if test "x$with_qt" = "xyes"; then
1556                         #
1557                         # If you want to build with Qt, you'd better
1558                         # have moc.
1559                         #
1560                         AC_MSG_ERROR(I couldn't find moc or moc-qt4; make sure it's installed and in your path)
1561                 else
1562                         #
1563                         # We shouldn't fail here, as the user's not
1564                         # building with Qt, and we shouldn't force them
1565                         # to have Qt installed if they're not doing so.
1566                         # "make dist" will fail if they do that, but
1567                         # we don't know whether they'll be doing that,
1568                         # so this is the best we can do.
1569                         #
1570                         MIC=moc
1571                 fi
1572         fi
1573 fi
1574 AC_SUBST(MOC)
1575
1576 # Error out if a glib header other than a "top level" header
1577 #  (glib.h, glib-object.h, gio.h) or certain other headers( e.g.,gmodule.h)
1578 #  is used.
1579 CPPFLAGS="-DG_DISABLE_SINGLE_INCLUDES $CPPFLAGS"
1580
1581 # Error out on the usage of deprecated glib functions
1582 CPPFLAGS="-DG_DISABLE_DEPRECATED $CPPFLAGS"
1583
1584 #
1585 # Check whether GLib modules are supported, to determine whether we
1586 # can support plugins.
1587 #
1588 AC_MSG_CHECKING(whether GLib supports loadable modules)
1589 ac_save_CFLAGS="$CFLAGS"
1590 ac_save_LIBS="$LIBS"
1591 CFLAGS="$CFLAGS $GLIB_CFLAGS"
1592 LIBS="$GLIB_LIBS $LIBS"
1593 AC_TRY_RUN([
1594 #include <glib.h>
1595 #include <gmodule.h>
1596 #include <stdio.h>
1597 #include <stdlib.h>
1598
1599 int
1600 main ()
1601 {
1602   if (g_module_supported())
1603     return 0;   /* success */
1604   else
1605     return 1;   /* failure */
1606 }
1607 ], ac_cv_glib_supports_modules=yes, ac_cv_glib_supports_modules=no,
1608    [echo $ac_n "cross compiling; assumed OK... $ac_c"
1609     ac_cv_glib_supports_modules=yes])
1610 CFLAGS="$ac_save_CFLAGS"
1611 LIBS="$ac_save_LIBS"
1612 if test "$ac_cv_glib_supports_modules" = yes ; then
1613   AC_MSG_RESULT(yes)
1614   have_plugins=yes
1615 else
1616   AC_MSG_RESULT(no)
1617   have_plugins=no
1618 fi
1619
1620 #
1621 # If we have <dlfcn.h>, check whether we have dladdr.
1622 #
1623 if test "$ac_cv_header_dlfcn_h" = "yes"
1624 then
1625         #
1626         # Use GLib compiler flags and linker flags; GLib's gmodule
1627         # stuff uses the dl APIs if available, so it might know
1628         # what flags are needed.
1629         #
1630         ac_save_CFLAGS="$CFLAGS"
1631         ac_save_LIBS="$LIBS"
1632         CFLAGS="$CFLAGS $GLIB_CFLAGS"
1633         LIBS="$GLIB_LIBS $LIBS"
1634         AC_CHECK_FUNCS(dladdr)
1635         if test x$ac_cv_func_dladdr = xno
1636         then
1637                 #
1638                 # OK, try it with -ldl, in case you need that to get
1639                 # dladdr().  For some reason, on Linux, that's not
1640                 # part of the GLib flags; perhaps GLib itself is
1641                 # linked with libdl, so that you can link with
1642                 # Glib and it'll pull libdl in itself.
1643                 #
1644                 LIBS="$LIBS -ldl"
1645                 AC_CHECK_FUNCS(dladdr)
1646         fi
1647         CFLAGS="$ac_save_CFLAGS"
1648         LIBS="$ac_save_LIBS"
1649 fi
1650
1651 #
1652 # Check whether GLib's printf supports thousands grouping. (This might
1653 # be different from the system's printf since GLib can optionally use
1654 # its own printf implementation.)
1655 #
1656 AC_MSG_CHECKING(whether GLib supports POSIX/XSI thousands grouping)
1657 ac_save_CFLAGS="$CFLAGS"
1658 ac_save_LIBS="$LIBS"
1659 CFLAGS="$CFLAGS $GLIB_CFLAGS"
1660 LIBS="$GLIB_LIBS $LIBS"
1661 AC_TRY_RUN([
1662 #include <glib.h>
1663 #include <locale.h>
1664 #include <stdio.h>
1665 #include <string.h>
1666
1667 int
1668 main ()
1669 {
1670   gchar *str;
1671   setlocale(LC_ALL, "en_US.UTF-8");
1672   str = g_strdup_printf("%'u", 123456);
1673   return (strcmp (str, "123,456") != 0);
1674 }
1675 ], ac_cv_glib_supports_printf_grouping=yes, ac_cv_glib_supports_printf_grouping=no,
1676    [echo $ac_n "cross compiling; playing it safe... $ac_c"
1677     ac_cv_glib_supports_printf_grouping=no])
1678 CFLAGS="$ac_save_CFLAGS"
1679 LIBS="$ac_save_LIBS"
1680 if test "$ac_cv_glib_supports_printf_grouping" = yes ; then
1681   AC_MSG_RESULT(yes)
1682   AC_DEFINE(HAVE_GLIB_PRINTF_GROUPING, 1, [Define if your printf() function supports thousands grouping.])
1683 else
1684   AC_MSG_RESULT(no)
1685 fi
1686
1687 if test "x$have_gtk" = "xyes"
1688 then
1689     #
1690     # We have GTK+; do we want the OS X integration functions and,
1691     # if so, do we have them and, if so, which versions do we have,
1692     # the old Carbon-based ones or the new Cocoa-based ones?
1693     #
1694     AC_MSG_CHECKING(whether to use OS X integration functions)
1695
1696     AC_ARG_WITH(osx-integration,
1697       AC_HELP_STRING( [--with-osx-integration],
1698                       [use OS X integration functions @<:@default=yes, if available@:>@]),
1699     [
1700         if test $withval = no
1701         then
1702             want_osx_integration=no
1703         else
1704             want_osx_integration=yes
1705         fi
1706     ],[
1707         want_osx_integration=yes
1708     ])
1709     if test "x$want_osx_integration" = "xno"; then
1710         AC_MSG_RESULT(no)
1711     else
1712         AC_MSG_RESULT(yes)
1713         AC_WIRESHARK_OSX_INTEGRATION_CHECK
1714     fi
1715 fi
1716
1717 AC_SUBST(wireshark_bin)
1718 AC_SUBST(wireshark_man)
1719 AM_CONDITIONAL(HAVE_Qt, test "$have_qt" = "yes")
1720 AM_CONDITIONAL(HAVE_GTK, test "$have_gtk" = "yes")
1721 AC_SUBST(OSX_APP_FLAGS)
1722 AC_SUBST(OSX_DMG_FLAGS)
1723
1724 # Enable/disable tshark
1725 AC_ARG_ENABLE(tshark,
1726   AC_HELP_STRING( [--enable-tshark],
1727                   [build TShark @<:@default=yes@:>@]),
1728     tshark=$enableval,enable_tshark=yes)
1729
1730 if test "x$enable_tshark" = "xyes" ; then
1731         tshark_bin="tshark\$(EXEEXT)"
1732         tshark_man="tshark.1"
1733         wiresharkfilter_man="wireshark-filter.4"
1734 else
1735         tshark_bin=""
1736         tshark_man=""
1737 fi
1738 AC_SUBST(tshark_bin)
1739 AC_SUBST(tshark_man)
1740 AC_SUBST(wiresharkfilter_man)
1741
1742
1743
1744 # Enable/disable editcap
1745
1746 AC_ARG_ENABLE(editcap,
1747   AC_HELP_STRING( [--enable-editcap],
1748                   [build editcap @<:@default=yes@:>@]),
1749     enable_editcap=$enableval,enable_editcap=yes)
1750
1751 if test "x$enable_editcap" = "xyes" ; then
1752         editcap_bin="editcap\$(EXEEXT)"
1753         editcap_man="editcap.1"
1754 else
1755         editcap_bin=""
1756         editcap_man=""
1757 fi
1758 AC_SUBST(editcap_bin)
1759 AC_SUBST(editcap_man)
1760
1761
1762
1763 # Enable/disable echld
1764
1765 AC_ARG_ENABLE(echld,
1766   AC_HELP_STRING( [--enable-echld],
1767                   [support echld]),
1768     have_echld=$enableval,have_echld=no)
1769
1770 AM_CONDITIONAL(HAVE_ECHLD, test "x$have_echld" = "xyes")
1771 if test "x$have_echld" = "xyes"
1772 then
1773   AC_DEFINE(HAVE_ECHLD, 1, [Define if echld is enabled])
1774   echld_test_bin="echld_test\$(EXEEXT)"
1775   echld_dir="echld"
1776 else
1777   have_echld="no"
1778   echld_test_bin=""
1779   echld_dir=""
1780 fi
1781 AC_SUBST(echld_test_bin)
1782 AC_SUBST(echld_dir)
1783
1784
1785 # Enabling/disabling of dumpcap is done later (after we know if we have PCAP
1786 # or not)
1787
1788 # Enable/disable capinfos
1789
1790 AC_ARG_ENABLE(capinfos,
1791   AC_HELP_STRING( [--enable-capinfos],
1792                   [build capinfos @<:@default=yes@:>@]),
1793     enable_capinfos=$enableval,enable_capinfos=yes)
1794
1795 if test "x$enable_capinfos" = "xyes" ; then
1796         capinfos_bin="capinfos\$(EXEEXT)"
1797         capinfos_man="capinfos.1"
1798 else
1799         capinfos_bin=""
1800         capinfos_man=""
1801 fi
1802 AC_SUBST(capinfos_bin)
1803 AC_SUBST(capinfos_man)
1804
1805
1806 # Enable/disable mergecap
1807
1808 AC_ARG_ENABLE(mergecap,
1809   AC_HELP_STRING( [--enable-mergecap],
1810                   [build mergecap @<:@default=yes@:>@]),
1811     enable_mergecap=$enableval,enable_mergecap=yes)
1812
1813 if test "x$enable_mergecap" = "xyes" ; then
1814         mergecap_bin="mergecap\$(EXEEXT)"
1815         mergecap_man="mergecap.1"
1816 else
1817         mergecap_bin=""
1818         mergecap_man=""
1819 fi
1820 AC_SUBST(mergecap_bin)
1821 AC_SUBST(mergecap_man)
1822
1823
1824 # Enable/disable reordercap
1825
1826 AC_ARG_ENABLE(reordercap,
1827   AC_HELP_STRING( [--enable-reordercap],
1828                   [build reordercap @<:@default=yes@:>@]),
1829     enable_reordercap=$enableval,enable_reordercap=yes)
1830
1831 if test "x$enable_reordercap" = "xyes" ; then
1832         reordercap_bin="reordercap\$(EXEEXT)"
1833         reordercap_man="reordercap.1"
1834 else
1835         reordercap_bin=""
1836         reordercap_man=""
1837 fi
1838 AC_SUBST(reordercap_bin)
1839 AC_SUBST(reordercap_man)
1840
1841
1842 # Enable/disable text2pcap
1843
1844 AC_ARG_ENABLE(text2pcap,
1845   AC_HELP_STRING( [--enable-text2pcap],
1846                   [build text2pcap @<:@default=yes@:>@]),
1847     text2pcap=$enableval,enable_text2pcap=yes)
1848
1849 if test "x$enable_text2pcap" = "xyes" ; then
1850         text2pcap_bin="text2pcap\$(EXEEXT)"
1851         text2pcap_man="text2pcap.1"
1852 else
1853         text2pcap_bin=""
1854         text2pcap_man=""
1855 fi
1856 AC_SUBST(text2pcap_bin)
1857 AC_SUBST(text2pcap_man)
1858
1859
1860 # Enable/disable dftest
1861
1862 AC_ARG_ENABLE(dftest,
1863   AC_HELP_STRING( [--enable-dftest],
1864                   [build dftest @<:@default=yes@:>@]),
1865     enable_dftest=$enableval,enable_dftest=yes)
1866
1867 if test "x$enable_dftest" = "xyes" ; then
1868         dftest_bin="dftest\$(EXEEXT)"
1869         dftest_man="dftest.1"
1870 else
1871         dftest_bin=""
1872         dftest_man=""
1873 fi
1874 AC_SUBST(dftest_bin)
1875 AC_SUBST(dftest_man)
1876
1877
1878 # Enable/disable randpkt
1879
1880 AC_ARG_ENABLE(randpkt,
1881   AC_HELP_STRING( [--enable-randpkt],
1882                   [build randpkt @<:@default=yes@:>@]),
1883     enable_randpkt=$enableval,enable_randpkt=yes)
1884
1885 if test "x$enable_randpkt" = "xyes" ; then
1886         randpkt_bin="randpkt\$(EXEEXT)"
1887         randpkt_man="randpkt.1"
1888 else
1889         randpkt_bin=""
1890         randpkt_man=""
1891 fi
1892 AC_SUBST(randpkt_bin)
1893 AC_SUBST(randpkt_man)
1894
1895
1896
1897 dnl Checks for "gethostbyname()" - and "-lnsl", if we need it to get
1898 dnl "gethostbyname()".
1899 AC_WIRESHARK_GETHOSTBY_LIB_CHECK
1900
1901 dnl Checks for "connect()", used as a proxy for "socket()" - and
1902 dnl "-lsocket", if we need it to get "connect()".
1903 AC_WIRESHARK_SOCKET_LIB_CHECK
1904
1905 dnl pcap check
1906 AC_MSG_CHECKING(whether to use libpcap for packet capture)
1907
1908 AC_ARG_WITH(pcap,
1909   AC_HELP_STRING( [--with-pcap@<:@=DIR@:>@],
1910                   [use libpcap for packet capturing @<:@default=yes@:>@]),
1911 [
1912         if test $withval = no
1913         then
1914                 want_pcap=no
1915         elif test $withval = yes
1916         then
1917                 want_pcap=yes
1918         else
1919                 want_pcap=yes
1920                 pcap_dir=$withval
1921         fi
1922 ],[
1923         want_pcap=yes
1924         pcap_dir=
1925 ])
1926 if test "x$want_pcap" = "xno" ; then
1927         AC_MSG_RESULT(no)
1928 else
1929         AC_MSG_RESULT(yes)
1930         AC_WIRESHARK_PCAP_CHECK
1931 fi
1932
1933
1934 dnl Check for airpcap
1935 AC_MSG_CHECKING(whether to include airpcap support)
1936 AC_ARG_ENABLE(airpcap,
1937   AC_HELP_STRING( [--enable-airpcap],
1938                   [use AirPcap in Wireshark @<:@default=yes@:>@]),
1939   enable_airpcap=$enableval, enable_airpcap=yes)
1940
1941 if test x$enable_airpcap = xyes; then
1942         if test "x$want_pcap" = "xno" ; then
1943                 enable_airpcap=no
1944                 AC_MSG_RESULT(pcap not available - disabling airpcap)
1945         else
1946                 AC_MSG_RESULT(yes)
1947                 AC_DEFINE(HAVE_AIRPCAP, 1, [Enable AirPcap])
1948         fi
1949 else
1950         AC_MSG_RESULT(no)
1951 fi
1952
1953
1954 dnl dumpcap check
1955 AC_MSG_CHECKING(whether to build dumpcap)
1956
1957 AC_ARG_ENABLE(dumpcap,
1958   AC_HELP_STRING( [--enable-dumpcap],
1959                   [build dumpcap @<:@default=yes@:>@]),
1960     enable_dumpcap=$enableval,enable_dumpcap=yes)
1961
1962 if test "x$enable_dumpcap" = "xyes" ; then
1963         if test "x$want_pcap" = "xno" ; then
1964                 enable_dumpcap=no
1965                 AC_MSG_RESULT(pcap not available - disabling dumpcap)
1966         else
1967                 AC_MSG_RESULT(yes)
1968         fi
1969 else
1970         AC_MSG_RESULT(no)
1971 fi
1972
1973 if test "x$enable_dumpcap" = "xyes" ; then
1974         dumpcap_bin="dumpcap\$(EXEEXT)"
1975         dumpcap_man="dumpcap.1"
1976 else
1977         dumpcap_bin=""
1978         dumpcap_man=""
1979 fi
1980 AC_SUBST(dumpcap_bin)
1981 AC_SUBST(dumpcap_man)
1982
1983 # Enable/disable rawshark
1984
1985 dnl rawshark check
1986 AC_MSG_CHECKING(whether to build rawshark)
1987
1988 AC_ARG_ENABLE(rawshark,
1989   AC_HELP_STRING( [--enable-rawshark],
1990                   [build rawshark @<:@default=yes@:>@]),
1991     rawshark=$enableval,enable_rawshark=yes)
1992
1993 if test "x$enable_rawshark" = "xyes" ; then
1994         if test "x$want_pcap" = "xno" ; then
1995                 enable_rawshark=no
1996                 AC_MSG_RESULT(pcap not available - disabling rawshark)
1997         else
1998                 AC_MSG_RESULT(yes)
1999         fi
2000 else
2001         AC_MSG_RESULT(no)
2002 fi
2003
2004 if test "x$enable_rawshark" = "xyes" ; then
2005         rawshark_bin="rawshark\$(EXEEXT)"
2006         rawshark_man="rawshark.1"
2007 else
2008         rawshark_bin=""
2009         rawshark_man=""
2010 fi
2011 AC_SUBST(rawshark_bin)
2012 AC_SUBST(rawshark_man)
2013
2014 dnl Use pcap-ng by default
2015 AC_ARG_ENABLE(pcap-ng-default,
2016   AC_HELP_STRING( [--enable-pcap-ng-default],
2017                   [use the pcap-ng file format by default instead of pcap @<:@default=yes@:>@]),
2018     enable_pcap_ng_default=$enableval,enable_pcap_ng_default=yes)
2019 if test x$enable_pcap_ng_default = xyes; then
2020         AC_DEFINE(PCAP_NG_DEFAULT, 1, [Support for pcap-ng])
2021 fi
2022
2023 dnl pcap remote check
2024 AC_MSG_CHECKING(whether to use libpcap remote capturing feature)
2025
2026 AC_ARG_WITH(pcap-remote,
2027     AC_HELP_STRING([--with-pcap-remote],
2028                    [use libpcap remote capturing (requires libpcap)]),
2029 [
2030     if test $withval = no
2031     then
2032         want_pcap_remote=no
2033     else
2034         want_pcap_remote=yes
2035     fi
2036 ],[
2037     want_pcap_remote=no
2038 ])
2039 if test "x$want_pcap_remote" = "xno" -o "x$want_pcap" = "xno" ; then
2040     AC_MSG_RESULT(no)
2041 else
2042     AC_MSG_RESULT(yes)
2043     AC_WIRESHARK_PCAP_REMOTE_CHECK
2044 fi
2045
2046 dnl zlib check
2047 AC_MSG_CHECKING(whether to use zlib for gzip compression and decompression)
2048
2049 AC_ARG_WITH(zlib,
2050   AC_HELP_STRING([--with-zlib@<:@=DIR@:>@],
2051                  [use zlib (located in directory DIR, if supplied) for gzip compression and decompression @<:@default=yes, if available@:>@]),
2052 [
2053         if test "x$withval" = "xno"
2054         then
2055                 want_zlib=no
2056         elif test "x$withval" = "xyes"
2057         then
2058                 want_zlib=yes
2059         else
2060                 want_zlib=yes
2061                 zlib_dir="$withval"
2062         fi
2063 ],[
2064         #
2065         # Use zlib if it's present, otherwise don't.
2066         #
2067         want_zlib=ifavailable
2068         zlib_dir=
2069 ])
2070 if test "x$want_zlib" = "xno" ; then
2071         AC_MSG_RESULT(no)
2072 else
2073         AC_MSG_RESULT(yes)
2074         AC_WIRESHARK_ZLIB_CHECK
2075         if test "x$want_zlib" = "xno" ; then
2076                 AC_MSG_RESULT(zlib not found - disabling gzip compression and decompression)
2077         else
2078                 if test "x$ac_cv_func_inflatePrime" = "xno" ; then
2079                         AC_MSG_RESULT(inflatePrime not found in zlib - disabling gzipped capture file support)
2080                 fi
2081         fi
2082 fi
2083
2084 dnl Lua check
2085 AC_MSG_CHECKING(whether to use liblua for the Lua scripting plugin)
2086
2087 AC_ARG_WITH(lua,
2088   AC_HELP_STRING( [--with-lua@<:@=DIR@:>@],
2089                   [use liblua (located in directory DIR, if supplied) for the Lua scripting plugin @<:@default=yes, if available@:>@]),
2090 [
2091         if test $withval = no
2092         then
2093                 want_lua=no
2094         elif test $withval = yes
2095         then
2096                 want_lua=yes
2097         else
2098                 want_lua=yes
2099                 lua_dir=$withval
2100         fi
2101 ],[
2102         #
2103         # Use liblua by default
2104         #
2105         want_lua=ifavailable
2106         lua_dir=
2107 ])
2108 if test "x$want_lua" = "xno" ; then
2109         AC_MSG_RESULT(no)
2110 else
2111         AC_MSG_RESULT(yes)
2112         AC_WIRESHARK_LIBLUA_CHECK
2113         if test "x$want_lua" = "xno" ; then
2114                 AC_MSG_RESULT(liblua not found - disabling support for the lua scripting plugin)
2115         fi
2116 fi
2117 AM_CONDITIONAL(HAVE_LIBLUA, test x$want_lua = xyes)
2118
2119
2120 dnl portaudio check
2121 AC_MSG_CHECKING(whether to use libportaudio for the rtp_player)
2122
2123 AC_ARG_WITH(portaudio,
2124   AC_HELP_STRING( [--with-portaudio@<:@=DIR@:>@],
2125                   [use libportaudio (located in directory DIR, if supplied) for the rtp_player @<:@default=yes, if available@:>@]),
2126 [
2127         if test $withval = no
2128         then
2129                 want_portaudio=no
2130         elif test $withval = yes
2131         then
2132                 want_portaudio=yes
2133         else
2134                 want_portaudio=yes
2135                 portaudio_dir=$withval
2136         fi
2137 ],[
2138         #
2139         # Use libportaudio by default
2140         #
2141         want_portaudio=ifavailable
2142         portaudio_dir=
2143 ])
2144 if test "x$want_portaudio" = "xno" ; then
2145         AC_MSG_RESULT(no)
2146 else
2147         AC_MSG_RESULT(yes)
2148         AC_WIRESHARK_LIBPORTAUDIO_CHECK
2149         if test "x$want_portaudio" = "xno" ; then
2150                 AC_MSG_RESULT(libportaudio not found - disabling support for the rtp_player)
2151         fi
2152 fi
2153 AM_CONDITIONAL(HAVE_LIBPORTAUDIO, test x$want_portaudio = xyes)
2154
2155
2156 dnl ipv6 check
2157 AC_ARG_ENABLE(ipv6,
2158   AC_HELP_STRING( [--enable-ipv6],
2159                   [use IPv6 name resolution, if available @<:@default=yes@:>@]),
2160     enable_ipv6=$enableval,enable_ipv6=yes)
2161
2162 AC_MSG_CHECKING(whether to enable ipv6 name resolution if available)
2163 if test "x$enable_ipv6" = "xno" ; then
2164         AC_MSG_RESULT(no)
2165 else
2166         AC_MSG_RESULT(yes)
2167         AC_WIRESHARK_IPV6_STACK
2168 fi
2169
2170
2171 dnl Check if dumpcap should be installed with filesystem capabilities
2172 AC_PATH_PROG(SETCAP, setcap)
2173 AC_ARG_ENABLE(setcap-install,
2174   AC_HELP_STRING( [--enable-setcap-install],
2175                   [install dumpcap with cap_net_admin and cap_net_raw @<:@default=no@:>@]),
2176     enable_setcap_install=$enableval,enable_setcap_install=no)
2177
2178 AC_MSG_CHECKING(whether to install dumpcap with cap_net_admin and cap_net_raw capabilities)
2179 if test "x$enable_setcap_install" = "xno" ; then
2180         AC_MSG_RESULT(no)
2181 else
2182         if test "x$SETCAP" = "x" ; then
2183                 AC_MSG_RESULT(no. Setcap not found)
2184         elif test "x$enable_dumpcap" = "xno" ; then
2185                 AC_MSG_ERROR(Setcap install works only with dumpcap but dumpcap is disabled)
2186         else
2187                 AC_MSG_RESULT(yes)
2188         fi
2189 fi
2190
2191 AM_CONDITIONAL(SETCAP_INSTALL, test x$enable_setcap_install = xyes)
2192
2193 dnl Check if dumpcap should be installed setuid
2194 AC_ARG_ENABLE(setuid-install,
2195   AC_HELP_STRING( [--enable-setuid-install],
2196                   [install dumpcap as setuid @<:@default=no@:>@]),
2197     enable_setuid_install=$enableval,enable_setuid_install=no)
2198
2199 AC_MSG_CHECKING(whether to install dumpcap setuid)
2200 if test "x$enable_setuid_install" = "xno" ; then
2201         AC_MSG_RESULT(no)
2202 else
2203         if test "x$enable_setcap_install" = "xyes" ; then
2204                 enable_setuid_install=no
2205                 AC_MSG_RESULT(no; using setcap instead)
2206         elif test "x$enable_dumpcap" = "xno" ; then
2207                 AC_MSG_ERROR(Setuid install works only with dumpcap but dumpcap is disabled)
2208         else
2209                 AC_MSG_RESULT(yes)
2210         fi
2211 fi
2212
2213 AM_CONDITIONAL(SETUID_INSTALL, test x$enable_setuid_install = xyes)
2214 AC_CHECK_FUNCS(setresuid setresgid)
2215
2216 dnl ...but our Network Operations group is named "no"!
2217 DUMPCAP_GROUP=''
2218 AC_ARG_WITH(dumpcap-group,
2219   AC_HELP_STRING( [--with-dumpcap-group=GROUP],
2220                   [restrict dumpcap to GROUP]),
2221 [
2222   if test "x$withval" = "xyes"; then
2223       AC_MSG_ERROR([No dumpcap group specified.])
2224   elif test "x$withval" != "xno"; then
2225       if test "x$enable_dumpcap" = "xno" ; then
2226           AC_MSG_ERROR(dumpcap group install works only with dumpcap but dumpcap is disabled)
2227       fi
2228       AC_MSG_RESULT($withval)
2229       DUMPCAP_GROUP="$withval"
2230   fi
2231 ])
2232 AC_SUBST(DUMPCAP_GROUP)
2233 AM_CONDITIONAL(HAVE_DUMPCAP_GROUP, test x$DUMPCAP_GROUP != x)
2234
2235 dnl libcap (not libpcap) check
2236 LIBCAP_LIBS=''
2237 AC_MSG_CHECKING(whether to use the libcap capabilities library)
2238
2239 AC_ARG_WITH(libcap,
2240   AC_HELP_STRING( [--with-libcap@<:@=DIR@:>@],
2241                   [use libcap (located in directory DIR, if supplied) for POSIX.1e capabilities management @<:@default=yes, if present@:>@]),
2242 [
2243 if   test "x$withval" = "xno";  then
2244         want_libcap=no
2245 elif test "x$withval" = "xyes"; then
2246         want_libcap=yes
2247 elif test -d "$withval"; then
2248         want_libcap=yes
2249         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
2250 fi
2251 ])
2252 if test "x$with_libcap" = "xno" ; then
2253         AC_MSG_RESULT(no)
2254 else
2255         AC_MSG_RESULT(yes)
2256         AC_WIRESHARK_LIBCAP_CHECK
2257 fi
2258 AC_SUBST(LIBCAP_LIBS)
2259
2260 dnl Checks for header files.
2261 dnl Some of these may not be needed: http://hacks.owlfolio.org/header-survey/
2262 AC_CHECK_HEADERS(direct.h dirent.h fcntl.h getopt.h grp.h inttypes.h netdb.h pwd.h stdarg.h stddef.h unistd.h)
2263 AC_CHECK_HEADERS(sys/ioctl.h sys/param.h sys/socket.h sys/sockio.h sys/stat.h sys/time.h sys/types.h sys/utsname.h sys/wait.h)
2264 AC_CHECK_HEADERS(netinet/in.h)
2265 AC_CHECK_HEADERS(arpa/inet.h arpa/nameser.h)
2266
2267 dnl SSL Check
2268 SSL_LIBS=''
2269 AC_MSG_CHECKING(whether to use SSL library)
2270
2271 AC_ARG_WITH(ssl,
2272   AC_HELP_STRING( [--with-ssl@<:@=DIR@:>@],
2273                   [use SSL crypto library (located in directory DIR, if supplied) @<:@default=no@:>@]),
2274 [
2275 if test "x$withval" = "xno";  then
2276         want_ssl=no
2277 elif test "x$withval" = "xyes"; then
2278         want_ssl=yes
2279 elif test -d "$withval"; then
2280         want_ssl=yes
2281         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
2282 fi
2283 ],[
2284         want_ssl=no
2285 ])
2286 if test "x$want_ssl" = "xyes"; then
2287         AC_MSG_RESULT(yes)
2288         AC_CHECK_LIB(crypto,EVP_md5,
2289             [
2290                 SSL_LIBS=-lcrypto
2291             ],
2292             [
2293                 AC_MSG_ERROR([SSL crypto library was requested, but is not available])
2294             ])
2295 else
2296         AC_MSG_RESULT(no)
2297 fi
2298 AC_SUBST(SSL_LIBS)
2299
2300 dnl kerberos check
2301 AC_MSG_CHECKING(whether to use Kerberos library)
2302
2303 AC_ARG_WITH(krb5,
2304   AC_HELP_STRING( [--with-krb5@<:@=DIR@:>@],
2305                   [use Kerberos library (located in directory DIR, if supplied) to use in Kerberos dissection @<:@default=yes@:>@]),
2306 [
2307         if test $withval = no
2308         then
2309                 want_krb5=no
2310         elif test $withval = yes
2311         then
2312                 want_krb5=yes
2313         else
2314                 want_krb5=yes
2315                 krb5_dir=$withval
2316         fi
2317 ],[
2318         #
2319         # Use Kerberos library if available, otherwise don't.
2320         #
2321         want_krb5=ifavailable
2322         krb5_dir=
2323 ])
2324 if test "x$want_krb5" = "xno" ; then
2325         AC_MSG_RESULT(no)
2326 else
2327         AC_MSG_RESULT(yes)
2328         AC_WIRESHARK_KRB5_CHECK
2329 fi
2330
2331
2332 dnl c-ares Check
2333 C_ARES_LIBS=''
2334 AC_MSG_CHECKING(whether to use the c-ares library if available)
2335
2336 AC_ARG_WITH(c-ares,
2337   AC_HELP_STRING( [--with-c-ares@<:@=DIR@:>@],
2338                   [use c-ares (located in directory DIR, if supplied) - supersedes --with-adns @<:@default=yes, if present@:>@]),
2339 [
2340 if   test "x$withval" = "xno";  then
2341         want_c_ares=no
2342 elif test "x$withval" = "xyes"; then
2343         want_c_ares=yes
2344 elif test -d "$withval"; then
2345         want_c_ares=yes
2346         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
2347 fi
2348 ])
2349 if test "x$want_c_ares" = "xno" ; then
2350         AC_MSG_RESULT(no)
2351 else
2352         AC_MSG_RESULT(yes)
2353         AC_WIRESHARK_C_ARES_CHECK
2354 fi
2355 AC_SUBST(C_ARES_LIBS)
2356
2357 dnl ADNS Check
2358 ADNS_LIBS=''
2359 AC_MSG_CHECKING(whether to use the GNU ADNS library if available)
2360
2361 AC_ARG_WITH(adns,
2362   AC_HELP_STRING( [--with-adns@<:@=DIR@:>@],
2363                   [use GNU ADNS (located in directory DIR, if supplied) @<:@default=yes, if present@:>@]),
2364 [
2365 if   test "x$withval" = "xno";  then
2366         want_adns=no
2367 elif test "x$withval" = "xyes"; then
2368         want_adns=yes
2369 elif test -d "$withval"; then
2370         want_adns=yes
2371         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
2372 fi
2373 ])
2374 if test "x$want_adns" = "xno" -o "x$have_good_c_ares" = "xyes" ; then
2375         AC_MSG_RESULT(no)
2376 else
2377         AC_MSG_RESULT(yes)
2378         AC_WIRESHARK_ADNS_CHECK
2379 fi
2380 AC_SUBST(ADNS_LIBS)
2381
2382 dnl GEOIP Check
2383 GEOIP_LIBS=''
2384 AC_MSG_CHECKING(whether to use the GeoIP IP address mapping library if available)
2385
2386 AC_ARG_WITH(geoip,
2387   AC_HELP_STRING( [--with-geoip@<:@=DIR@:>@],
2388                   [use GeoIP (located in directory DIR, if supplied) @<:@default=yes, if present@:>@]),
2389 [
2390 if   test "x$withval" = "xno";  then
2391         want_geoip=no
2392 elif test "x$withval" = "xyes"; then
2393         want_geoip=yes
2394 elif test -d "$withval"; then
2395         want_geoip=yes
2396         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
2397 fi
2398 ])
2399 if test "x$want_geoip" = "xno"; then
2400         AC_MSG_RESULT(no)
2401 else
2402         AC_MSG_RESULT(yes)
2403         AC_WIRESHARK_GEOIP_CHECK
2404 fi
2405 AC_SUBST(GEOIP_LIBS)
2406
2407 # Warning: this Python scripting appears to be broken (does not work at all).
2408 # Running it also causes Valgrind to complain about all sorts of memory errors.
2409 # Suggestion: do not enable it unless you are working on fixing it.
2410 #
2411 # An alternative might be https://code.google.com/p/pyreshark/
2412 #
2413 dnl Python devel Check
2414 AC_MSG_CHECKING(whether to use the Python interpreter for scripting)
2415
2416 AC_ARG_WITH(broken-python,
2417     AC_HELP_STRING( [--with-broken-python@<:@=DIR@:>@],
2418                     [use the (BROKEN) Python interpreter (installed in DIR, if supplied) @<:@default=no@:>@]),
2419 [
2420         pythondir='${libdir}/wireshark/python/${VERSION}'
2421         if test "x$withval" = "xno"
2422         then
2423                 want_python=no
2424         elif test "x$withval" = "xyes"
2425         then
2426                 want_python=yes
2427         else
2428                 want_python=yes
2429                 pythondir="$withval"
2430         fi
2431 ],[
2432         # By default (user didn't explicitly enable Python), don't enable
2433         # Python support.
2434         #
2435         want_python=no
2436         #pythondir='${libdir}/wireshark/python/${VERSION}'
2437 ])
2438 if test "x$want_python" = "xno" ; then
2439         AC_MSG_RESULT(no)
2440 else
2441         AC_MSG_RESULT(yes)
2442         AC_WIRESHARK_PYTHON_CHECK
2443 fi
2444 AM_CONDITIONAL(HAVE_LIBPY, test x$want_python != xno)
2445 AC_SUBST(pythondir)
2446
2447 #
2448 # Define WS_MSVC_NORETURN appropriately for declarations of routines that
2449 # never return (just like Charlie on the MTA).
2450 #
2451 # Note that MSVC++ expects __declspec(noreturn) to precede the function
2452 # name and GCC, as far as I know, expects __attribute__((noreturn)) to
2453 # follow the function name, so we need two different flavors of
2454 # noreturn tag.
2455 #
2456 AC_DEFINE(WS_MSVC_NORETURN,, [Define as the string to precede declarations of routines that never return])
2457
2458 dnl Checks for typedefs, structures, and compiler characteristics.
2459 # AC_C_CONST
2460
2461 # Check how we can get the time zone abbreviation
2462 AC_WIRESHARK_TIMEZONE_ABBREV
2463
2464 # We need to know whether "struct stat" has an "st_flags" member
2465 # for file_user_immutable().
2466
2467 AC_WIRESHARK_STRUCT_ST_FLAGS
2468
2469 # We need to know whether "struct sockaddr" has an "sa_len" member
2470 # for get_interface_list().
2471
2472 AC_WIRESHARK_STRUCT_SA_LEN
2473
2474 # We must know our byte order
2475 AC_C_BIGENDIAN
2476
2477 # Checks whether "-traditional" is needed when using "ioctl".
2478 # XXX - do we need this?
2479 AC_PROG_GCC_TRADITIONAL
2480
2481 GETOPT_LO=""
2482 AC_CHECK_FUNC(getopt,
2483   [GETOPT_LO=""
2484    AC_DEFINE(HAVE_GETOPT, 1, [Define to 1 if you have the getopt function.])
2485   ],
2486   GETOPT_LO="wsgetopt.lo"
2487 )
2488 if test "$ac_cv_func_getopt" = no ; then
2489   GETOPT_LO="wsgetopt.lo"
2490 fi
2491 AM_CONDITIONAL(NEED_GETOPT_LO, test "x$ac_cv_func_getopt" = "xno")
2492 AC_SUBST(GETOPT_LO)
2493
2494 AC_CHECK_FUNC(strncasecmp, STRNCASECMP_LO="",
2495   STRNCASECMP_LO="strncasecmp.lo")
2496 if test "$ac_cv_func_strncasecmp" = no ; then
2497   STRNCASECMP_LO="strncasecmp.lo"
2498 fi
2499 AM_CONDITIONAL(NEED_STRNCASECMP_LO, test "x$ac_cv_func_strncasecmp" = "xno")
2500 AC_SUBST(STRNCASECMP_LO)
2501
2502 AC_CHECK_FUNCS(mkstemp mkdtemp)
2503
2504 AC_SEARCH_LIBS(inet_aton, [socket nsl], have_inet_aton=yes,
2505     have_inet_aton=no)
2506 if test "$have_inet_aton" = no; then
2507   INET_ATON_LO="inet_aton.lo"
2508   AC_DEFINE(HAVE_INET_ATON_H, 0, [Define unless inet/aton.h needs to be included])
2509 else
2510   INET_ATON_LO=""
2511 fi
2512 AM_CONDITIONAL(NEED_INET_ATON_LO, test "x$have_inet_aton" = "xno")
2513 AC_SUBST(INET_ATON_LO)
2514
2515 AC_SEARCH_LIBS(inet_pton, [socket nsl], [
2516   dnl check for pre-BIND82 inet_pton() bug.
2517   AC_MSG_CHECKING(for broken inet_pton)
2518   AC_TRY_RUN([#include <sys/types.h>
2519 #include <sys/socket.h>
2520 #include <netinet/in.h>
2521 #include <arpa/inet.h>
2522 int main()
2523 {
2524 #ifdef AF_INET6
2525   char buf[16];
2526   /* this should return 0 (error) */
2527   return inet_pton(AF_INET6, "0:1:2:3:4:5:6:7:", buf);
2528 #else
2529   return 1;
2530 #endif
2531 }], [AC_MSG_RESULT(ok);
2532 have_inet_pton=yes], [AC_MSG_RESULT(broken);
2533 have_inet_pton=no], [AC_MSG_RESULT(cross compiling, assume it is broken);
2534 have_inet_pton=no])],
2535 have_inet_pton=no)
2536 if test "$have_inet_pton" = no; then
2537   INET_PTON_LO="inet_pton.lo"
2538 else
2539   INET_PTON_LO=""
2540 fi
2541 AM_CONDITIONAL(NEED_INET_PTON_LO, test "x$have_inet_pton" = "xno")
2542 AC_SUBST(INET_PTON_LO)
2543
2544 AC_SEARCH_LIBS(inet_ntop, [socket nsl], [
2545   AC_MSG_CHECKING([for inet_ntop prototype])
2546   AC_TRY_COMPILE([#include <stdio.h>
2547 #include <sys/types.h>
2548 #include <sys/socket.h>
2549 #include <netinet/in.h>
2550 #include <arpa/inet.h>
2551
2552 extern const char *inet_ntop(int, const void *, char *, size_t);],, [
2553     AC_MSG_RESULT(yes)
2554     AC_DEFINE(HAVE_INET_NTOP_PROTO, 1,
2555     [Define if inet_ntop() prototype exists])], [
2556     AC_TRY_COMPILE([#include <stdio.h>
2557 #include <sys/types.h>
2558 #include <sys/socket.h>
2559 #include <netinet/in.h>
2560 #include <arpa/inet.h>
2561
2562 extern const char *inet_ntop(int, const void *, char *, socklen_t);],, [
2563       AC_MSG_RESULT(yes)
2564       AC_DEFINE(HAVE_INET_NTOP_PROTO, 1,
2565       [Define if inet_ntop() prototype exists])], [
2566       AC_MSG_RESULT(no)])])
2567   INET_NTOP_LO=""], [
2568   INET_NTOP_LO="inet_ntop.lo"
2569   AC_DEFINE(NEED_INET_V6DEFS_H, 1,
2570   [Define if inet/v6defs.h needs to be included])])
2571 AM_CONDITIONAL(NEED_INET_NTOP_LO, test "x$INET_NTOP_LO" != "x")
2572 AC_SUBST(INET_NTOP_LO)
2573
2574 AC_CHECK_FUNC(strptime, STRPTIME_LO="",
2575   [STRPTIME_LO="strptime.lo"
2576    AC_DEFINE(NEED_STRPTIME_H, 1, [Define if strptime.h needs to be included])
2577 ])
2578 if test "$ac_cv_func_strptime" = no ; then
2579   STRPTIME_LO="strptime.lo"
2580 fi
2581 AC_SUBST(STRPTIME_C)
2582 AM_CONDITIONAL(NEED_STRPTIME_LO, test "x$ac_cv_func_strptime" = "no")
2583 AC_SUBST(STRPTIME_LO)
2584
2585 AC_CHECK_FUNCS(getprotobynumber gethostbyname2)
2586 AC_CHECK_FUNCS(issetugid)
2587 AC_CHECK_FUNCS(mmap mprotect sysconf)
2588
2589 dnl blank for now, but will be used in future
2590 AC_SUBST(wireshark_SUBDIRS)
2591
2592 dnl
2593 dnl check whether plugins should be enabled and, if they should be,
2594 dnl check for plugins directory - stolen from Amanda's configure.ac
2595 dnl
2596 dnl we don't wish to expand ${libdir} yet
2597 plugindir='${libdir}/wireshark/plugins/${VERSION}'
2598 AC_ARG_WITH(plugins,
2599   AC_HELP_STRING( [--with-plugins@<:@=DIR@:>@],
2600                   [support plugins (installed in DIR, if supplied) @<:@default=yes, if possible@:>@]),
2601 [
2602   if test "x$withval" = "xno"; then
2603     have_plugins=no
2604   elif test "x$have_plugins" = "xno"; then
2605       AC_MSG_ERROR([GLib on this platform doesn't support loadable modules, so you can't enable plugins.])
2606   elif test "x$withval" != "xyes"; then
2607       plugindir="$withval"
2608   fi
2609 ])
2610 AM_CONDITIONAL(HAVE_PLUGINS, test "x$have_plugins" = "xyes")
2611 if test x$have_plugins = xyes
2612 then
2613   AC_DEFINE(HAVE_PLUGINS, 1, [Define if plugins are enabled])
2614 fi
2615 AC_SUBST(plugindir)
2616 CPPFLAGS="$CPPFLAGS '-DPLUGIN_DIR=\"\$(plugindir)\"'"
2617
2618 #
2619 # The plugin dissectors reside in ./plugins/PROTO/
2620 #
2621 PLUGIN_LIBS=""
2622 AC_SUBST(PLUGIN_LIBS)
2623
2624 #
2625 # Check if (emem) memory allocations must be 8-byte aligned.
2626 # I haven't been able to write C code that reliably makes that determination
2627 # (different versions of GCC with or without optimization give different
2628 # results) so just assume everything except (32-bit) x86 needs 8-byte
2629 # alignment (64-bit platforms either require 8-byte alignment for pointers
2630 # and 64-bit integral data types or may get better performance from that;
2631 # 64-bit x86 will get 8-byte alignment from G_MEM_ALIGN anyway.  32-bit
2632 # platforms would only require it, or get better performance from it,
2633 # for 64-bit floating-point values.).
2634 #
2635 AC_MSG_CHECKING(whether we need memory allocations to be 8-byte aligned)
2636 case $host_cpu in
2637         i386|i486|i586|i686)
2638                 AC_MSG_RESULT(no)
2639                 ;;
2640         *)
2641                 AC_MSG_RESULT(yes)
2642                 AC_DEFINE(NEED_8_BYTE_ALIGNMENT, 1, [Define if we need memory allocations to be 8-byte aligned])
2643                 ;;
2644 esac
2645
2646 # Gather only the "--with*" arguments and also a list of --with arguments for rpmbuild
2647 for f in $CONFIG_ARGS
2648 do
2649         case $f in
2650         --with-gtk2*)
2651                 CONFIG_WITH_ARGS="$CONFIG_WITH_ARGS $f"
2652                 RPMBUILD_WITH_ARGS="$RPMBUILD_WITH_ARGS --with gtk2"
2653                 ;;
2654         --without-gtk2*)
2655                 CONFIG_WITH_ARGS="$CONFIG_WITH_ARGS $f"
2656                 RPMBUILD_WITH_ARGS="$RPMBUILD_WITH_ARGS --without gtk2"
2657                 ;;
2658         --with-gtk3*)
2659                 CONFIG_WITH_ARGS="$CONFIG_WITH_ARGS $f"
2660                 RPMBUILD_WITH_ARGS="$RPMBUILD_WITH_ARGS --with gtk3"
2661                 ;;
2662         --without-gtk3*)
2663                 CONFIG_WITH_ARGS="$CONFIG_WITH_ARGS $f"
2664                 RPMBUILD_WITH_ARGS="$RPMBUILD_WITH_ARGS --without gtk3"
2665                 ;;
2666         --with-qt*)
2667                 CONFIG_WITH_ARGS="$CONFIG_WITH_ARGS $f"
2668                 RPMBUILD_WITH_ARGS="$RPMBUILD_WITH_ARGS --with qt"
2669                 ;;
2670         --without-qt*)
2671                 CONFIG_WITH_ARGS="$CONFIG_WITH_ARGS $f"
2672                 RPMBUILD_WITH_ARGS="$RPMBUILD_WITH_ARGS --without qt"
2673                 ;;
2674         --with*)
2675                 CONFIG_WITH_ARGS="$CONFIG_WITH_ARGS $f"
2676                 ;;
2677         esac
2678
2679 done
2680 AC_SUBST(CONFIG_WITH_ARGS)
2681 AC_SUBST(RPMBUILD_WITH_ARGS)
2682
2683 dnl libtool defs
2684 #
2685 # Yes, AM_PROG_LIBTOOL is redundant with newer version(s) of some tool(s)
2686 # (autoconf?  automake?  libtool?) - with the newer version(s), it's
2687 # just an alias for AC_PROG_LIBTOOL, which is called earlier.
2688 #
2689 # With older version(s) of those tool(s), however, it's not just an
2690 # alias, and the configure scripts don't work without it.
2691 #
2692 AM_PROG_LIBTOOL
2693 AC_SUBST(LIBTOOL_DEPS)
2694
2695 AM_CONDITIONAL(ENABLE_STATIC, test x$enable_static = xyes)
2696 if test x$enable_static = xyes -a x$have_plugins = xyes
2697 then
2698   AC_DEFINE(ENABLE_STATIC, 1, [Link plugins statically into Wireshark])
2699 fi
2700 AC_SUBST(ENABLE_STATIC)
2701
2702 dnl Save the cacheable configure results to config.cache before recursing
2703 AC_CACHE_SAVE
2704
2705 sinclude(plugins/Custom.m4) dnl
2706 ifdef(_CUSTOM_AC_OUTPUT_,, define(_CUSTOM_AC_OUTPUT_, )) dnl
2707
2708 sinclude(asn1/Custom.m4) dnl
2709 ifdef(_CUSTOM_ASN1_AC_OUTPUT_,, define(_CUSTOM_ASN1_AC_OUTPUT_, )) dnl
2710
2711 AC_CONFIG_HEADERS(config.h)
2712 AC_OUTPUT(
2713   Makefile
2714   doxygen.cfg
2715   asn1/Makefile
2716   _CUSTOM_ASN1_AC_OUTPUT_
2717   asn1/acp133/Makefile
2718   asn1/acse/Makefile
2719   asn1/ansi_map/Makefile
2720   asn1/ansi_tcap/Makefile
2721   asn1/atn-cm/Makefile
2722   asn1/atn-cpdlc/Makefile
2723   asn1/atn-ulcs/Makefile
2724   asn1/c1222/Makefile
2725   asn1/camel/Makefile
2726   asn1/cdt/Makefile
2727   asn1/charging_ase/Makefile
2728   asn1/cmip/Makefile
2729   asn1/cmp/Makefile
2730   asn1/crmf/Makefile
2731   asn1/cms/Makefile
2732   asn1/credssp/Makefile
2733   asn1/dap/Makefile
2734   asn1/disp/Makefile
2735   asn1/dop/Makefile
2736   asn1/dsp/Makefile
2737   asn1/ess/Makefile
2738   asn1/ftam/Makefile
2739   asn1/gnm/Makefile
2740   asn1/goose/Makefile
2741   asn1/gprscdr/Makefile
2742   asn1/gsm_map/Makefile
2743   asn1/h225/Makefile
2744   asn1/h235/Makefile
2745   asn1/h245/Makefile
2746   asn1/h248/Makefile
2747   asn1/h282/Makefile
2748   asn1/h283/Makefile
2749   asn1/h323/Makefile
2750   asn1/h450/Makefile
2751   asn1/h450-ros/Makefile
2752   asn1/h460/Makefile
2753   asn1/h501/Makefile
2754   asn1/HI2Operations/Makefile
2755   asn1/hnbap/Makefile
2756   asn1/idmp/Makefile
2757   asn1/ilp/Makefile
2758   asn1/inap/Makefile
2759   asn1/isdn-sup/Makefile
2760   asn1/kerberos/Makefile
2761   asn1/lcsap/Makefile
2762   asn1/ldap/Makefile
2763   asn1/logotypecertextn/Makefile
2764   asn1/lpp/Makefile
2765   asn1/lppa/Makefile
2766   asn1/lppe/Makefile
2767   asn1/lte-rrc/Makefile
2768   asn1/m3ap/Makefile
2769   asn1/mms/Makefile
2770   asn1/mpeg-audio/Makefile
2771   asn1/mpeg-pes/Makefile
2772   asn1/nbap/Makefile
2773   asn1/ns_cert_exts/Makefile
2774   asn1/ocsp/Makefile
2775   asn1/p1/Makefile
2776   asn1/p22/Makefile
2777   asn1/p7/Makefile
2778   asn1/p772/Makefile
2779   asn1/pcap/Makefile
2780   asn1/pkcs1/Makefile
2781   asn1/pkcs12/Makefile
2782   asn1/pkinit/Makefile
2783   asn1/pkixac/Makefile
2784   asn1/pkix1explicit/Makefile
2785   asn1/pkix1implicit/Makefile
2786   asn1/pkixproxy/Makefile
2787   asn1/pkixqualified/Makefile
2788   asn1/pkixtsp/Makefile
2789   asn1/pres/Makefile
2790   asn1/q932/Makefile
2791   asn1/q932-ros/Makefile
2792   asn1/qsig/Makefile
2793   asn1/ranap/Makefile
2794   asn1/rnsap/Makefile
2795   asn1/ros/Makefile
2796   asn1/rrc/Makefile
2797   asn1/rrlp/Makefile
2798   asn1/rtse/Makefile
2799   asn1/rua/Makefile
2800   asn1/s1ap/Makefile
2801   asn1/sabp/Makefile
2802   asn1/sbc-ap/Makefile
2803   asn1/smrse/Makefile
2804   asn1/snmp/Makefile
2805   asn1/spnego/Makefile
2806   asn1/sv/Makefile
2807   asn1/t124/Makefile
2808   asn1/t125/Makefile
2809   asn1/t38/Makefile
2810   asn1/tcap/Makefile
2811   asn1/tetra/Makefile
2812   asn1/ulp/Makefile
2813   asn1/wlancertextn/Makefile
2814   asn1/x2ap/Makefile
2815   asn1/x509af/Makefile
2816   asn1/x509ce/Makefile
2817   asn1/x509if/Makefile
2818   asn1/x509sat/Makefile
2819   asn1/x721/Makefile
2820   doc/Makefile
2821   docbook/Makefile
2822   epan/Makefile
2823   epan/crypt/Makefile
2824   epan/doxygen.cfg
2825   epan/dfilter/Makefile
2826   epan/dissectors/Makefile
2827   epan/dissectors/dcerpc/Makefile
2828   epan/dissectors/pidl/Makefile
2829   epan/ftypes/Makefile
2830   epan/wmem/Makefile
2831   epan/wslua/Makefile
2832   epan/wspython/Makefile
2833   codecs/Makefile
2834   ui/Makefile
2835   ui/doxygen.cfg
2836   ui/gtk/Makefile
2837   ui/gtk/doxygen.cfg
2838   ui/cli/Makefile
2839   ui/qt/Makefile
2840   ui/qt/doxygen.cfg
2841   help/Makefile
2842   packaging/Makefile
2843   packaging/macosx/Info.plist
2844   packaging/macosx/Makefile
2845   packaging/macosx/osx-dmg.sh
2846   packaging/macosx/Wireshark_package.pmdoc/index.xml
2847   packaging/nsis/Makefile
2848   packaging/rpm/Makefile
2849   packaging/rpm/SPECS/Makefile
2850   packaging/rpm/SPECS/wireshark.spec
2851   packaging/svr4/Makefile
2852   packaging/svr4/checkinstall
2853   packaging/svr4/pkginfo
2854   plugins/Makefile
2855   plugins/asn1/Makefile
2856   plugins/docsis/Makefile
2857   plugins/ethercat/Makefile
2858   plugins/gryphon/Makefile
2859   plugins/irda/Makefile
2860   plugins/m2m/Makefile
2861   plugins/mate/Makefile
2862   plugins/opcua/Makefile
2863   plugins/profinet/Makefile
2864   plugins/stats_tree/Makefile
2865   plugins/unistim/Makefile
2866   plugins/wimax/Makefile
2867   plugins/wimaxasncp/Makefile
2868   plugins/wimaxmacphy/Makefile
2869   tools/Makefile
2870   tools/lemon/Makefile
2871   wiretap/Makefile
2872   wsutil/Makefile
2873   echld/Makefile
2874   _CUSTOM_AC_OUTPUT_
2875   ,)
2876 dnl AC_CONFIG_FILES([tools/setuid-root.pl], [chmod +x tools/setuid-root.pl])
2877
2878
2879 # Pretty messages
2880
2881 if test "x$have_gtk" = "xyes"; then
2882         if test "x$with_gtk3" = "xyes"; then
2883                 gtk_lib_message=" (with GTK+ 3"
2884         else
2885                 gtk_lib_message=" (with GTK+ 2"
2886         fi
2887         if test "x$have_ige_mac" = "xyes"; then
2888                 gtk_lib_message="$gtk_lib_message and Mac OS X integration)"
2889         else
2890                 gtk_lib_message="$gtk_lib_message)"
2891         fi
2892 fi
2893
2894 if test "x$have_qt" = "xyes" ; then
2895         enable_qtshark="yes"
2896 else
2897         enable_qtshark="no"
2898 fi
2899
2900 if test "x$enable_setcap_install" = "xyes" ; then
2901         setcap_message="yes"
2902 else
2903         setcap_message="no"
2904 fi
2905
2906 if test "x$enable_setuid_install" = "xyes" ; then
2907         setuid_message="yes"
2908 else
2909         setuid_message="no"
2910 fi
2911
2912 if test "x$DUMPCAP_GROUP" = "x" ; then
2913         dumpcap_group_message="(none)"
2914 else
2915         dumpcap_group_message="$DUMPCAP_GROUP"
2916 fi
2917
2918 if test "x$want_zlib" = "xno" ; then
2919         zlib_message="no"
2920 else
2921         zlib_message="yes"
2922 fi
2923
2924 if test "x$want_lua" = "xyes" ; then
2925         lua_message="yes"
2926 else
2927         lua_message="no"
2928 fi
2929
2930 if test "x$want_python" = "xno"; then
2931         python_message="no"
2932 else
2933         python_message="yes"
2934 fi
2935
2936 if test "x$want_portaudio" = "xyes" ; then
2937         portaudio_message="yes"
2938 else
2939         portaudio_message="no"
2940 fi
2941
2942 if test "x$want_ssl" = "xno" ; then
2943         ssl_message="no"
2944 else
2945         ssl_message="yes"
2946 fi
2947
2948 if test "x$want_krb5" = "xno" ; then
2949         krb5_message="no"
2950 else
2951         krb5_message="yes ($ac_krb5_version)"
2952 fi
2953
2954 if test "x$have_good_c_ares" = "xyes" ; then
2955         c_ares_message="yes"
2956 else
2957         c_ares_message="no"
2958 fi
2959
2960 if test "x$have_good_adns" = "xyes" ; then
2961         adns_message="yes"
2962 else
2963         if test "x$have_good_c_ares" = "xyes" ; then
2964                 adns_message="no (using c-ares instead)"
2965         else
2966                 adns_message="no"
2967         fi
2968 fi
2969
2970 if test "x$have_good_libcap" = "xyes" ; then
2971         libcap_message="yes"
2972 else
2973         libcap_message="no"
2974 fi
2975
2976 if test "x$have_good_geoip" = "xyes" ; then
2977         geoip_message="yes"
2978 else
2979         geoip_message="no"
2980 fi
2981
2982 echo ""
2983 echo "The Wireshark package has been configured with the following options."
2984 echo "             Build wireshark (Gtk+) : $have_gtk""$gtk_lib_message"
2985 echo "                 Build wireshark-qt : $enable_qtshark"
2986 echo "                       Build tshark : $enable_tshark"
2987 echo "                     Build capinfos : $enable_capinfos"
2988 echo "                      Build editcap : $enable_editcap"
2989 echo "                      Build dumpcap : $enable_dumpcap"
2990 echo "                     Build mergecap : $enable_mergecap"
2991 echo "                   Build reordercap : $enable_reordercap"
2992 echo "                    Build text2pcap : $enable_text2pcap"
2993 echo "                      Build randpkt : $enable_randpkt"
2994 echo "                       Build dftest : $enable_dftest"
2995 echo "                     Build rawshark : $enable_rawshark"
2996 echo "                        Build echld : $have_echld"
2997 echo ""
2998 echo "   Save files as pcap-ng by default : $enable_pcap_ng_default"
2999 echo "  Install dumpcap with capabilities : $setcap_message"
3000 echo "             Install dumpcap setuid : $setuid_message"
3001 echo "                  Use dumpcap group : $dumpcap_group_message"
3002 echo "                        Use plugins : $have_plugins"
3003 echo "                    Use Lua library : $lua_message"
3004 echo "                 Use Python binding : $python_message"
3005 echo "                   Build rtp_player : $portaudio_message"
3006 echo "             Build profile binaries : $enable_profile_build"
3007 echo "                   Use pcap library : $want_pcap"
3008 echo "                   Use zlib library : $zlib_message"
3009 echo "               Use kerberos library : $krb5_message"
3010 echo "                 Use c-ares library : $c_ares_message"
3011 echo "               Use GNU ADNS library : $adns_message"
3012 echo "                Use SMI MIB library : $libsmi_message"
3013 echo "             Use GNU crypto library : $gcrypt_message"
3014 echo "             Use SSL crypto library : $ssl_message"
3015 echo "           Use IPv6 name resolution : $enable_ipv6"
3016 echo "                 Use gnutls library : $tls_message"
3017 echo "     Use POSIX capabilities library : $libcap_message"
3018 echo "                  Use GeoIP library : $geoip_message"
3019 echo "                     Use nl library : $libnl_message"