configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([rsync],[3.2.0pre3],[http://rsync.samba.org/bugzilla.html])
   4
   5 AC_CONFIG_MACRO_DIR([m4])
   6 AC_CONFIG_SRCDIR([byteorder.h])
   7 AC_CONFIG_HEADER(config.h)
   8 AC_PREREQ([2.69])
   9
  10 AC_SUBST(RSYNC_VERSION, $PACKAGE_VERSION)
  11 AC_MSG_NOTICE([Configuring rsync $PACKAGE_VERSION])
  12
  13 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$PACKAGE_VERSION"], [rsync release version])
  14
  15 LDFLAGS=${LDFLAGS-""}
  16
  17 AC_CANONICAL_HOST
  18
  19 dnl define the directory for replacement function since AC_LIBOBJ does not
  20 dnl officially support subdirs and fails with automake
  21 AC_CONFIG_LIBOBJ_DIR([lib])
  22
  23 # We must decide this before testing the compiler.
  24
  25 # Please allow this to default to yes, so that your users have more
  26 # chance of getting a useful stack trace if problems occur.
  27
  28 AC_MSG_CHECKING([whether to include debugging symbols])
  29 AC_ARG_ENABLE(debug,
  30         AS_HELP_STRING([--disable-debug],[disable debugging symbols and features]))
  31
  32 if test x"$enable_debug" = x"no"; then
  33     AC_MSG_RESULT(no)
  34     ac_cv_prog_cc_g=no
  35 else
  36     AC_MSG_RESULT([yes])
  37     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  38     # leave ac_cv_prog_cc_g alone; AC_PROG_CC will try to include -g if it can
  39 fi
  40
  41 dnl Checks for programs.
  42 AC_PROG_CC
  43 AC_PROG_CPP
  44 AC_PROG_CXX
  45 AC_PROG_EGREP
  46 AC_PROG_INSTALL
  47 AC_PROG_MKDIR_P
  48 AC_PROG_CC_STDC
  49 AC_SUBST(SHELL)
  50 AC_PATH_PROG([PERL], [perl])
  51 AC_PATH_PROG([PYTHON3], [python3])
  52
  53 AC_DEFINE([_GNU_SOURCE], 1,
  54           [Define _GNU_SOURCE so that we get all necessary prototypes])
  55
  56 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  57         AC_MSG_WARN([rsync requires an ANSI C compiler and you do not seem to have one])
  58 fi
  59
  60 AC_ARG_ENABLE(profile,
  61         AS_HELP_STRING([--enable-profile],[turn on CPU profiling]))
  62 if test x"$enable_profile" = x"yes"; then
  63         CFLAGS="$CFLAGS -pg"
  64 fi
  65
  66 AC_MSG_CHECKING([if md2man can create man pages])
  67 if test x"$ac_cv_path_PYTHON3" = x; then
  68     AC_MSG_RESULT(no - python3 not found)
  69     md2man_works=no
  70 else
  71     md2man_out=`"$srcdir/md2man" --test "$srcdir/rsync.1.md" 2>&1`
  72     if test $? = 0; then
  73         AC_MSG_RESULT(yes)
  74         md2man_works=yes
  75     else
  76         AC_MSG_RESULT(no)
  77         md2man_works=no
  78         echo "$md2man_out"
  79     fi
  80 fi
  81
  82 AC_MSG_CHECKING([if we require man-page building])
  83 AC_ARG_ENABLE([md2man],
  84         AS_HELP_STRING([--disable-md2man],[disable md2man for man page creation]))
  85 if test x"$enable_md2man" != x"no"; then
  86     if test -f "$srcdir/rsync.1"; then
  87         AC_MSG_RESULT(optional)
  88     else
  89         AC_MSG_RESULT(required)
  90         if test x"$md2man_works" = x"no"; then
  91             AC_MSG_ERROR(You need python3 and the cmarkgfm OR commonmark python3 lib in order to build man pages.
  92 You can specify --disable-md2man if you want to skip building them.)
  93         fi
  94     fi
  95     MAKE_MAN=man
  96 else
  97     AC_MSG_RESULT(no)
  98     MAKE_MAN=''
  99 fi
 100
 101 # Specifically, this turns on panic_action handling.
 102 AC_ARG_ENABLE(maintainer-mode,
 103         AS_HELP_STRING([--enable-maintainer-mode],[turn on extra debug features]))
 104 if test x"$enable_maintainer_mode" = x"yes"; then
 105         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
 106 fi
 107
 108 # This is needed for our included version of popt.  Kind of silly, but
 109 # I don't want our version too far out of sync.
 110 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
 111
 112 # If GCC, turn on warnings.
 113 if test x"$GCC" = x"yes"; then
 114         CFLAGS="$CFLAGS -Wall -W"
 115 fi
 116
 117 AC_ARG_WITH(included-popt,
 118         AS_HELP_STRING([--with-included-popt],[use bundled popt library, not from system]))
 119
 120 AC_ARG_WITH(included-zlib,
 121         AS_HELP_STRING([--with-included-zlib],[use bundled zlib library, not from system]))
 122
 123 AC_ARG_WITH(protected-args,
 124         AS_HELP_STRING([--with-protected-args],[make --protected-args option the default]))
 125 if test x"$with_protected_args" = x"yes"; then
 126         AC_DEFINE_UNQUOTED(RSYNC_USE_PROTECTED_ARGS, 1, [Define to 1 if --protected-args should be the default])
 127 fi
 128
 129 AC_ARG_WITH(rsync-path,
 130         AS_HELP_STRING([--with-rsync-path=PATH],[set default --rsync-path to PATH (default: rsync)]),
 131         [ RSYNC_PATH="$with_rsync_path" ],
 132         [ RSYNC_PATH="rsync" ])
 133
 134 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
 135
 136 AC_ARG_WITH(rsyncd-conf,
 137         AS_HELP_STRING([--with-rsyncd-conf=PATH],[set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
 138         [ if test ! -z "$with_rsyncd_conf" ; then
 139                 case $with_rsyncd_conf in
 140                         yes|no)
 141                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 142                                 ;;
 143                         /*)
 144                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
 145                                 ;;
 146                         *)
 147                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 148                                 ;;
 149                 esac
 150         else
 151                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 152         fi ],
 153         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 154
 155 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 156
 157 AC_ARG_WITH(rsh,
 158         AS_HELP_STRING([--with-rsh=CMD],[set remote shell command to CMD (default: ssh)]))
 159
 160 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 161 if test x$HAVE_REMSH = x1; then
 162         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 163 fi
 164
 165 if test x"$with_rsh" != x; then
 166         RSYNC_RSH="$with_rsh"
 167 else
 168         RSYNC_RSH="ssh"
 169 fi
 170 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 171
 172 # Some programs on solaris are only found in /usr/xpg4/bin (or work better than others versions).
 173 AC_PATH_PROG(SHELL_PATH, sh, /bin/sh, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 174 AC_PATH_PROG(FAKEROOT_PATH, fakeroot, /usr/bin/fakeroot, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 175
 176 AC_ARG_WITH(nobody-group,
 177     AS_HELP_STRING([--with-nobody-group=GROUP],[set the default unprivileged group (default nobody or nogroup)]),
 178     [ NOBODY_GROUP="$with_nobody_group" ])
 179
 180 if test x"$with_nobody_group" = x; then
 181     AC_MSG_CHECKING([the group for user "nobody"])
 182     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 183         NOBODY_GROUP=nobody
 184     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 185         NOBODY_GROUP=nogroup
 186     else
 187         NOBODY_GROUP=nobody # test for others?
 188     fi
 189     AC_MSG_RESULT($NOBODY_GROUP)
 190 fi
 191
 192 AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody])
 193 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 194
 195 # SIMD optimizations
 196 SIMD=
 197
 198 AC_MSG_CHECKING([whether to enable SIMD optimizations])
 199 AC_ARG_ENABLE(simd,
 200     AS_HELP_STRING([--enable-simd],[enable SIMD optimizations (requires g++)]))
 201
 202 if test x"$enable_simd" = x"yes"; then
 203     # For x86-64 SIMD, g++ is also required
 204     if test x"$build_cpu" = x"x86_64"; then
 205         if test x"$CXX" = x"g++"; then
 206             # AC_MSG_RESULT() called below
 207             SIMD="$SIMD x86_64"
 208         else
 209             AC_MSG_RESULT(no)
 210             AC_MSG_ERROR(Failed to find g++ for SIMD speedups.
 211 Omit --enable-simd to continue without it.)
 212         fi
 213     fi
 214 fi
 215
 216 if test x"$SIMD" != x""; then
 217     SIMD=`echo "$SIMD" | sed -e 's/^ *//'`
 218     AC_MSG_RESULT([yes ($SIMD)])
 219     AC_DEFINE(HAVE_SIMD, 1, [Define to 1 to enable SIMD optimizations])
 220     SIMD=`echo "$SIMD" | sed -e 's/[[^ ]]\+/$(SIMD_&)/g'`
 221     # We only use g++ for its target attribute dispatching, disable unneeded bulky features
 222     CXXFLAGS="$CXXFLAGS -fno-exceptions -fno-rtti"
 223 else
 224     AC_MSG_RESULT(no)
 225 fi
 226
 227 AC_SUBST(SIMD)
 228
 229 # arrgh. libc in some old debian version screwed up the largefile
 230 # stuff, getting byte range locking wrong
 231 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 232 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 233 #define _FILE_OFFSET_BITS 64
 234 #include <stdio.h>
 235 #include <fcntl.h>
 236 #include <sys/types.h>
 237 #include <sys/wait.h>
 238 #if HAVE_UNISTD_H
 239 #include <unistd.h>
 240 #endif
 241
 242 int main(void)
 243 {
 244         struct flock lock;
 245         int status;
 246         char tpl[32] = "/tmp/locktest.XXXXXX";
 247         int fd = mkstemp(tpl);
 248         if (fd < 0) {
 249                 strcpy(tpl, "conftest.dat");
 250                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 251         }
 252
 253         lock.l_type = F_WRLCK;
 254         lock.l_whence = SEEK_SET;
 255         lock.l_start = 0;
 256         lock.l_len = 1;
 257         lock.l_pid = 0;
 258         fcntl(fd,F_SETLK,&lock);
 259         if (fork() == 0) {
 260                 lock.l_start = 1;
 261                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 262         }
 263         wait(&status);
 264         unlink(tpl);
 265         return WEXITSTATUS(status);
 266 }
 267 ]])],[rsync_cv_HAVE_BROKEN_LARGEFILE=yes],[rsync_cv_HAVE_BROKEN_LARGEFILE=no],[rsync_cv_HAVE_BROKEN_LARGEFILE=cross])])
 268 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 269    AC_SYS_LARGEFILE
 270 fi
 271
 272 ipv6type=unknown
 273 ipv6lib=none
 274 ipv6trylibc=yes
 275
 276 AC_ARG_ENABLE(ipv6,
 277         AS_HELP_STRING([--disable-ipv6],[turn off IPv6 support]))
 278 if test x"$enable_ipv6" != x"no"; then
 279         AC_MSG_CHECKING([ipv6 stack type])
 280         for i in inria kame linux-glibc linux-inet6 solaris toshiba v6d zeta cygwin; do
 281                 case $i in
 282                 inria)
 283                         # http://www.kame.net/
 284                         AC_EGREP_CPP(yes, [
 285 #include <netinet/in.h>
 286 #ifdef IPV6_INRIA_VERSION
 287 yes
 288 #endif],
 289                                 [ipv6type=$i;
 290                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 291                                 ])
 292                         ;;
 293                 kame)
 294                         # http://www.kame.net/
 295                         AC_EGREP_CPP(yes, [
 296 #include <netinet/in.h>
 297 #ifdef __KAME__
 298 yes
 299 #endif],
 300                                 [ipv6type=$i;
 301                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 302                         ;;
 303                 linux-glibc)
 304                         # http://www.v6.linux.or.jp/
 305                         AC_EGREP_CPP(yes, [
 306 #include <features.h>
 307 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 308 yes
 309 #endif],
 310                                 [ipv6type=$i;
 311 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 312                         ;;
 313                 linux-inet6)
 314                         # http://www.v6.linux.or.jp/
 315                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 316                                 ipv6type=$i
 317                                 ipv6lib=inet6
 318                                 ipv6libdir=/usr/inet6/lib
 319                                 ipv6trylibc=yes;
 320                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 321                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 322                         fi
 323                         ;;
 324                 solaris)
 325                         # http://www.sun.com
 326                         AC_EGREP_CPP(yes, [
 327 #include <netinet/ip6.h>
 328 #ifdef __sun
 329 yes
 330 #endif],
 331                                 [ipv6type=$i;
 332                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 333                         ;;
 334                 toshiba)
 335                         AC_EGREP_CPP(yes, [
 336 #include <sys/param.h>
 337 #ifdef _TOSHIBA_INET6
 338 yes
 339 #endif],
 340                                 [ipv6type=$i;
 341                                 ipv6lib=inet6;
 342                                 ipv6libdir=/usr/local/v6/lib;
 343                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 344                         ;;
 345                 v6d)
 346                         AC_EGREP_CPP(yes, [
 347 #include </usr/local/v6/include/sys/v6config.h>
 348 #ifdef __V6D__
 349 yes
 350 #endif],
 351                                 [ipv6type=$i;
 352                                 ipv6lib=v6;
 353                                 ipv6libdir=/usr/local/v6/lib;
 354                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 355                         ;;
 356                 zeta)
 357                         AC_EGREP_CPP(yes, [
 358 #include <sys/param.h>
 359 #ifdef _ZETA_MINAMI_INET6
 360 yes
 361 #endif],
 362                                 [ipv6type=$i;
 363                                 ipv6lib=inet6;
 364                                 ipv6libdir=/usr/local/v6/lib;
 365                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 366                         ;;
 367                 cygwin)
 368                         AC_EGREP_CPP(yes, [
 369 #include <netinet/in.h>
 370 #ifdef _CYGWIN_IN6_H
 371 yes
 372 #endif],
 373                                 [ipv6type=$i;
 374                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 375                         ;;
 376                 esac
 377                 if test "$ipv6type" != "unknown"; then
 378                         break
 379                 fi
 380         done
 381         AC_MSG_RESULT($ipv6type)
 382
 383         AC_SEARCH_LIBS(getaddrinfo, inet6)
 384 fi
 385
 386 dnl Do you want to disable use of locale functions
 387 AC_ARG_ENABLE([locale],
 388         AS_HELP_STRING([--disable-locale],[disable locale features]))
 389 AH_TEMPLATE([CONFIG_LOCALE],
 390 [Undefine if you do not want locale features.  By default this is defined.])
 391 if test x"$enable_locale" != x"no"; then
 392         AC_DEFINE(CONFIG_LOCALE)
 393 fi
 394
 395 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 396 case $host_os in
 397         *cygwin* ) AC_MSG_RESULT(yes)
 398                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 399                             [Define to 1 if sockets need to be shutdown])
 400                    ;;
 401                * ) AC_MSG_RESULT(no);;
 402 esac
 403
 404 AC_C_BIGENDIAN
 405 AC_HEADER_DIRENT
 406 AC_HEADER_TIME
 407 AC_HEADER_SYS_WAIT
 408 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
 409     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
 410     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
 411     sys/un.h sys/attr.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
 412     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h \
 413     sys/acl.h acl/libacl.h attr/xattr.h sys/xattr.h sys/extattr.h \
 414     popt.h popt/popt.h linux/falloc.h netinet/in_systm.h netinet/ip.h \
 415     zlib.h xxhash.h openssl/md4.h openssl/md5.h zstd.h lz4.h)
 416 AC_HEADER_MAJOR_FIXED
 417
 418 AC_MSG_CHECKING([whether to enable use of openssl crypto library])
 419 AC_ARG_ENABLE([openssl],
 420         AS_HELP_STRING([--disable-openssl],[disable openssl crypto library]))
 421 AH_TEMPLATE([USE_OPENSSL],
 422 [Undefine if you do not want to use openssl crypto library.  By default this is defined.])
 423 if test x"$enable_openssl" != x"no"; then
 424     if test x"$ac_cv_header_openssl_md4_h" = x"yes" && test x"$ac_cv_header_openssl_md5_h" = x"yes"; then
 425       AC_MSG_RESULT(yes)
 426       AC_SEARCH_LIBS(MD5_Init, crypto,
 427           [AC_DEFINE(USE_OPENSSL)],
 428           [AC_MSG_ERROR(Failed to find MD5_Init function in openssl crypto lib.
 429 Use --disable-openssl to continue without openssl crypto lib support.)])
 430     else
 431         AC_MSG_RESULT(no)
 432         AC_MSG_ERROR(Failed to find openssl/md4.h and openssl/md5.h for openssl crypto lib support.
 433 Use --disable-openssl to continue without it.)
 434     fi
 435 else
 436     AC_MSG_RESULT(no)
 437 fi
 438
 439 AC_MSG_CHECKING([whether to enable xxhash checksum support])
 440 AC_ARG_ENABLE([xxhash],
 441         AS_HELP_STRING([--disable-xxhash],[disable xxhash checksums]))
 442 AH_TEMPLATE([SUPPORT_XXHASH],
 443 [Undefine if you do not want xxhash checksums.  By default this is defined.])
 444 if test x"$enable_xxhash" != x"no"; then
 445     if test x"$ac_cv_header_xxhash_h" = x"yes"; then
 446         AC_MSG_RESULT(yes)
 447         AC_SEARCH_LIBS(XXH64_createState, xxhash,
 448             [AC_DEFINE(SUPPORT_XXHASH)],
 449             [AC_MSG_ERROR(Failed to find XXH64_createState function in xxhash lib.
 450 Use --disable-xxhash to continue without xxhash checksums.)])
 451     else
 452         AC_MSG_RESULT(no)
 453         AC_MSG_ERROR(Failed to find xxhash.h for xxhash checksum support.
 454 Use --disable-xxhash to continue without it.)
 455     fi
 456 else
 457     AC_MSG_RESULT(no)
 458 fi
 459
 460 AC_MSG_CHECKING([whether to enable zstd compression])
 461 AC_ARG_ENABLE([zstd],
 462         AC_HELP_STRING([--disable-zstd], [disable zstd compression]))
 463 AH_TEMPLATE([SUPPORT_ZSTD],
 464 [Undefine if you do not want zstd compression.  By default this is defined.])
 465 if test x"$enable_zstd" != x"no"; then
 466     if test x"$ac_cv_header_zstd_h" = x"yes"; then
 467         AC_MSG_RESULT(yes)
 468         AC_SEARCH_LIBS(ZSTD_minCLevel, zstd,
 469             [AC_DEFINE(SUPPORT_ZSTD)],
 470             [AC_MSG_ERROR(Failed to find ZSTD_minCLevel function in zstd lib.
 471 Use --disable-zstd to continue without zstd compression.)])
 472     else
 473         AC_MSG_RESULT(no)
 474         AC_MSG_ERROR(Failed to find zstd.h for zstd compression support.
 475 Use --disable-zstd to continue without it.)
 476     fi
 477 else
 478     AC_MSG_RESULT(no)
 479 fi
 480
 481 AC_MSG_CHECKING([whether to enable LZ4 compression])
 482 AC_ARG_ENABLE([lz4],
 483         AC_HELP_STRING([--disable-lz4], [disable LZ4 compression]))
 484 AH_TEMPLATE([SUPPORT_LZ4],
 485 [Undefine if you do not want LZ4 compression.  By default this is defined.])
 486 if test x"$enable_lz4" != x"no"; then
 487     if test x"$ac_cv_header_lz4_h" = x"yes"; then
 488         AC_MSG_RESULT(yes)
 489         AC_SEARCH_LIBS(LZ4_compress_default, lz4,
 490             [AC_DEFINE(SUPPORT_LZ4)],
 491             [AC_MSG_ERROR(Failed to find LZ4_compress_default function in lz4 lib.
 492 Use --disable-lz4 to continue without lz4 compression.)])
 493     else
 494         AC_MSG_RESULT(no)
 495         AC_MSG_ERROR(Failed to find lz4.h for lz4 compression support.
 496 Use --disable-lz4 to continue without it.)
 497     fi
 498 else
 499     AC_MSG_RESULT(no)
 500 fi
 501
 502 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
 503 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 504 #include <sys/types.h>
 505 #ifdef MAJOR_IN_MKDEV
 506 #include <sys/mkdev.h>
 507 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
 508 #  define makedev mkdev
 509 # endif
 510 #elif defined MAJOR_IN_SYSMACROS
 511 #include <sys/sysmacros.h>
 512 #endif
 513
 514 int main(void)
 515 {
 516         dev_t dev = makedev(0, 5, 7);
 517         if (major(dev) != 5 || minor(dev) != 7)
 518                 return 1;
 519         return 0;
 520 }
 521 ]])],[rsync_cv_MAKEDEV_TAKES_3_ARGS=yes],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no])])
 522 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
 523    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
 524 fi
 525
 526 AC_CHECK_SIZEOF(int)
 527 AC_CHECK_SIZEOF(long)
 528 AC_CHECK_SIZEOF(long long)
 529 AC_CHECK_SIZEOF(short)
 530 AC_CHECK_SIZEOF(int16_t)
 531 AC_CHECK_SIZEOF(uint16_t)
 532 AC_CHECK_SIZEOF(int32_t)
 533 AC_CHECK_SIZEOF(uint32_t)
 534 AC_CHECK_SIZEOF(int64_t)
 535 AC_CHECK_SIZEOF(off_t)
 536 AC_CHECK_SIZEOF(off64_t)
 537 AC_CHECK_SIZEOF(time_t)
 538 AC_CHECK_SIZEOF(char*)
 539
 540 AC_C_INLINE
 541
 542 AC_TYPE_LONG_DOUBLE_WIDER
 543 ac_cv_c_long_double=$ac_cv_type_long_double_wider
 544 if test $ac_cv_c_long_double = yes; then
 545   AC_DEFINE([HAVE_LONG_DOUBLE],[1],[Define to 1 if the type `long double' works and has more range or precision than `double'.])
 546 fi
 547
 548 AC_TYPE_UID_T
 549 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
 550 AC_TYPE_GETGROUPS
 551 AC_CHECK_MEMBERS([struct stat.st_rdev,
 552                   struct stat.st_mtimensec,
 553                   struct stat.st_mtimespec.tv_nsec,
 554                   struct stat.st_mtim.tv_nsec],,,[
 555 #ifdef HAVE_SYS_TYPES_H
 556 #include <sys/types.h>
 557 #endif
 558 #ifdef HAVE_SYS_STAT_H
 559 #include <sys/stat.h>
 560 #endif
 561 #ifdef HAVE_UNISTD_H
 562 #include <unistd.h>
 563 #endif])
 564
 565 TYPE_SOCKLEN_T
 566
 567 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 568     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]], [[int i = errno]])],[rsync_cv_errno=yes],[rsync_cv_have_errno_decl=no])])
 569 if test x"$rsync_cv_errno" = x"yes"; then
 570    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 571 fi
 572
 573 # The following test taken from the cvs sources
 574 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 575 # These need checks to be before checks for any other functions that
 576 #    might be in the same libraries.
 577 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 578 # libsocket.so which has a bad implementation of gethostbyname (it
 579 # only looks in /etc/hosts), so we only look for -lsocket if we need
 580 # it.
 581 AC_CHECK_FUNCS(connect)
 582 if test x"$ac_cv_func_connect" = x"no"; then
 583     case "$LIBS" in
 584     *-lnsl*) ;;
 585     *) AC_CHECK_LIB(nsl_s, printf) ;;
 586     esac
 587     case "$LIBS" in
 588     *-lnsl*) ;;
 589     *) AC_CHECK_LIB(nsl, printf) ;;
 590     esac
 591     case "$LIBS" in
 592     *-lsocket*) ;;
 593     *) AC_CHECK_LIB(socket, connect) ;;
 594     esac
 595     case "$LIBS" in
 596     *-linet*) ;;
 597     *) AC_CHECK_LIB(inet, connect) ;;
 598     esac
 599     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 600     dnl has been cached.
 601     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 602        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 603         # ac_cv_func_connect=yes
 604         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 605         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 606     fi
 607 fi
 608
 609 AC_SEARCH_LIBS(inet_ntop, resolv)
 610
 611 # For OS X, Solaris, HP-UX, etc.: figure out if -liconv is needed.  We'll
 612 # accept either iconv_open or libiconv_open, since some include files map
 613 # the former to the latter.
 614 AC_SEARCH_LIBS(iconv_open, iconv)
 615 AC_SEARCH_LIBS(libiconv_open, iconv)
 616
 617 AC_MSG_CHECKING([for iconv declaration])
 618 AC_CACHE_VAL(am_cv_proto_iconv, [
 619     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 620 #include <stdlib.h>
 621 #include <iconv.h>
 622 extern
 623 #ifdef __cplusplus
 624 "C"
 625 #endif
 626 #if defined(__STDC__) || defined(__cplusplus)
 627 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 628 #else
 629 size_t iconv();
 630 #endif
 631 ]], [[]])],[am_cv_proto_iconv_arg1=""],[am_cv_proto_iconv_arg1="const"])
 632       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 633     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed -e 's/( /(/'`
 634 AC_MSG_RESULT([$]{ac_t:-
 635          }[$]am_cv_proto_iconv)
 636 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 637                    [Define as const if the declaration of iconv() needs const.])
 638
 639 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 640
 641 AC_REPLACE_FUNCS([inet_ntop inet_pton])
 642
 643 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
 644 AC_HAVE_TYPE([struct sockaddr_storage], [#include <sys/types.h>
 645 #include <sys/socket.h>])
 646
 647 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 648 #   builtin getaddrinfo if one of the defines don't exist
 649 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 650                rsync_cv_HAVE_GETADDR_DEFINES,[
 651                         AC_EGREP_CPP(yes, [
 652                         #include <sys/types.h>
 653                         #include <sys/socket.h>
 654                         #include <netdb.h>
 655                         #ifdef AI_PASSIVE
 656                         yes
 657                         #endif],
 658                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 659                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 660 AS_IF([test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" -a x"$ac_cv_type_struct_addrinfo" = x"yes"],[
 661         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 662         # something else so we must include <netdb.h> to get the
 663         # redefinition.
 664         AC_CHECK_FUNCS(getaddrinfo, ,
 665                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 666                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 667                 #include <sys/socket.h>
 668                 #include <netdb.h>]], [[getaddrinfo(NULL, NULL, NULL, NULL);]])],[AC_MSG_RESULT([yes])
 669                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 670                                 [Define to 1 if you have the "getaddrinfo" function and required types.])],[AC_MSG_RESULT([no])
 671                         AC_LIBOBJ([getaddrinfo])])])
 672     ],[AC_LIBOBJ([getaddrinfo])])
 673
 674 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 675                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 676                 [],
 677                 [
 678 #include <sys/types.h>
 679 #include <sys/socket.h>
 680 ])
 681
 682 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 683                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 684                 [],
 685                 [
 686 #include <sys/types.h>
 687 #include <sys/socket.h>
 688 #include <netinet/in.h>
 689 ])
 690
 691 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 692                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 693                 [],
 694                 [
 695 #include <sys/types.h>
 696 #include <sys/socket.h>
 697 #include <netinet/in.h>
 698 ])
 699
 700 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 701                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 702                 [],
 703                 [
 704 #include <sys/types.h>
 705 #include <sys/socket.h>
 706 #include <netinet/in.h>
 707 ])
 708
 709 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
 710 #if HAVE_SYS_TYPES_H
 711 # include <sys/types.h>
 712 #endif
 713 #if HAVE_SYS_STAT_H
 714 # include <sys/stat.h>
 715 #endif
 716 #if STDC_HEADERS
 717 # include <stdlib.h>
 718 # include <stddef.h>
 719 #else
 720 # if HAVE_STDLIB_H
 721 #  include <stdlib.h>
 722 # endif
 723 #endif
 724 ])
 725
 726 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 727 #
 728 AC_CHECK_FUNCS(strcasecmp)
 729 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 730     AC_CHECK_LIB(resolv, strcasecmp)
 731 fi
 732
 733 AC_CHECK_FUNCS(aclsort)
 734 if test x"$ac_cv_func_aclsort" = x"no"; then
 735     AC_CHECK_LIB(sec, aclsort)
 736 fi
 737
 738 dnl At the moment we don't test for a broken memcmp(), because all we
 739 dnl need to do is test for equality, not comparison, and it seems that
 740 dnl every platform has a memcmp that can do at least that.
 741 dnl AC_FUNC_MEMCMP
 742
 743 AC_FUNC_UTIME_NULL
 744 AC_FUNC_ALLOCA
 745 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup chown chmod lchmod mknod mkfifo \
 746     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 747     chflags getattrlist \
 748     memmove lchown vsnprintf snprintf vasprintf asprintf setsid strpbrk \
 749     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
 750     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 751     seteuid strerror putenv iconv_open locale_charset nl_langinfo getxattr \
 752     extattr_get_link sigaction sigprocmask setattrlist getgrouplist \
 753     initgroups utimensat posix_fallocate attropen setvbuf nanosleep usleep)
 754
 755 dnl cygwin iconv.h defines iconv_open as libiconv_open
 756 if test x"$ac_cv_func_iconv_open" != x"yes"; then
 757     AC_CHECK_FUNC(libiconv_open, [ac_cv_func_iconv_open=yes; AC_DEFINE(HAVE_ICONV_OPEN, 1)])
 758 fi
 759
 760 dnl Preallocation stuff (also fallocate, posix_fallocate function tests above):
 761
 762 AC_CACHE_CHECK([for useable fallocate],rsync_cv_have_fallocate,[
 763 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <fcntl.h>
 764 #include <sys/types.h>]], [[fallocate(0, 0, 0, 0);]])],[rsync_cv_have_fallocate=yes],[rsync_cv_have_fallocate=no])])
 765 if test x"$rsync_cv_have_fallocate" = x"yes"; then
 766     AC_DEFINE(HAVE_FALLOCATE, 1, [Define to 1 if you have the fallocate function and it compiles and links without error])
 767 fi
 768
 769 AC_MSG_CHECKING([for FALLOC_FL_PUNCH_HOLE])
 770 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 771         #define _GNU_SOURCE 1
 772         #include <linux/falloc.h>
 773         #ifndef FALLOC_FL_PUNCH_HOLE
 774         #error FALLOC_FL_PUNCH_HOLE is missing
 775         #endif
 776     ]])], [
 777         AC_MSG_RESULT([yes])
 778         AC_DEFINE([HAVE_FALLOC_FL_PUNCH_HOLE], [1], [Define if FALLOC_FL_PUNCH_HOLE is available.])
 779     ], [
 780         AC_MSG_RESULT([no])
 781     ]
 782 )
 783
 784 AC_MSG_CHECKING([for FALLOC_FL_ZERO_RANGE])
 785 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 786         #define _GNU_SOURCE 1
 787         #include <linux/falloc.h>
 788         #ifndef FALLOC_FL_ZERO_RANGE
 789         #error FALLOC_FL_ZERO_RANGE is missing
 790         #endif
 791     ]])], [
 792         AC_MSG_RESULT([yes])
 793         AC_DEFINE([HAVE_FALLOC_FL_ZERO_RANGE], [1], [Define if FALLOC_FL_ZERO_RANGE is available.])
 794     ], [
 795         AC_MSG_RESULT([no])
 796     ]
 797 )
 798
 799 AC_CACHE_CHECK([for SYS_fallocate],rsync_cv_have_sys_fallocate,[
 800 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/syscall.h>
 801 #include <unistd.h>
 802 #include <sys/types.h>]], [[syscall(SYS_fallocate, 0, 0, (loff_t)0, (loff_t)0);]])],[rsync_cv_have_sys_fallocate=yes],[rsync_cv_have_sys_fallocate=no])])
 803 if test x"$rsync_cv_have_sys_fallocate" = x"yes"; then
 804     AC_DEFINE(HAVE_SYS_FALLOCATE, 1, [Define to 1 if you have the SYS_fallocate syscall number])
 805 fi
 806
 807 if test x"$ac_cv_func_posix_fallocate" = x"yes"; then
 808     AC_MSG_CHECKING([whether posix_fallocate is efficient])
 809     case $host_os in
 810     *cygwin*)
 811         AC_MSG_RESULT(yes)
 812         AC_DEFINE(HAVE_EFFICIENT_POSIX_FALLOCATE, 1,
 813                   [Define if posix_fallocate is efficient (Cygwin)])
 814         ;;
 815     *)
 816         AC_MSG_RESULT(no)
 817         ;;
 818     esac
 819 fi
 820
 821 dnl End of preallocation stuff
 822
 823 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 824 if test $ac_cv_func_getpgrp = yes; then
 825     AC_FUNC_GETPGRP
 826 fi
 827
 828 AC_ARG_ENABLE(iconv-open,
 829     AS_HELP_STRING([--disable-iconv-open],[disable all use of iconv_open() function]),
 830     [], [enable_iconv_open=$ac_cv_func_iconv_open])
 831
 832 if test x"$enable_iconv_open" != x"no"; then
 833     AC_DEFINE(USE_ICONV_OPEN, 1, [Define to 1 if you want rsync to make use of iconv_open()])
 834 fi
 835
 836 AC_ARG_ENABLE(iconv,
 837     AS_HELP_STRING([--disable-iconv],[disable rsync's --iconv option]),
 838     [], [enable_iconv=$enable_iconv_open])
 839 AH_TEMPLATE([ICONV_OPTION],
 840 [Define if you want the --iconv option.  Specifying a value will set the
 841 default iconv setting (a NULL means no --iconv processing by default).])
 842 if test x"$enable_iconv" != x"no"; then
 843         if test x"$enable_iconv" = x"yes"; then
 844                 AC_DEFINE(ICONV_OPTION, NULL)
 845         else
 846                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
 847         fi
 848         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
 849 fi
 850
 851 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
 852   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 853 #if HAVE_UNISTD_H
 854 # include <unistd.h>
 855 #endif
 856 #include <stdlib.h>
 857 #include <errno.h>
 858 int main(void) {
 859         char const *dangling_symlink = "conftest.dangle";
 860         unlink(dangling_symlink);
 861         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 862         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) return 1;
 863         return 0;
 864     }]])],[rsync_cv_chown_modifies_symlink=yes],[rsync_cv_chown_modifies_symlink=no],[rsync_cv_chown_modifies_symlink=no])])
 865 if test $rsync_cv_chown_modifies_symlink = yes; then
 866   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 867 fi
 868
 869 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
 870   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 871 #if HAVE_UNISTD_H
 872 # include <unistd.h>
 873 #endif
 874 #include <stdlib.h>
 875 #include <errno.h>
 876 #define FILENAME "conftest.dangle"
 877 int main(void) {
 878         unlink(FILENAME);
 879         if (symlink("conftest.no-such", FILENAME) < 0) abort();
 880         unlink(FILENAME "2");
 881         if (link(FILENAME, FILENAME "2") < 0) return 1;
 882         return 0;
 883     }]])],[rsync_cv_can_hardlink_symlink=yes],[rsync_cv_can_hardlink_symlink=no],[rsync_cv_can_hardlink_symlink=no])])
 884 if test $rsync_cv_can_hardlink_symlink = yes; then
 885   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
 886 fi
 887
 888 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
 889   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 890 #if HAVE_UNISTD_H
 891 # include <unistd.h>
 892 #endif
 893 #ifdef HAVE_SYS_STAT_H
 894 #include <sys/stat.h>
 895 #endif
 896 #include <stdlib.h>
 897 #include <errno.h>
 898 #define FILENAME "conftest.fifi"
 899 int main(void) {
 900         unlink(FILENAME);
 901         if (mkfifo(FILENAME, 0777) < 0) abort();
 902         unlink(FILENAME "2");
 903         if (link(FILENAME, FILENAME "2") < 0) return 1;
 904         return 0;
 905     }]])],[rsync_cv_can_hardlink_special=yes],[rsync_cv_can_hardlink_special=no],[rsync_cv_can_hardlink_special=no])])
 906 if test $rsync_cv_can_hardlink_special = yes; then
 907     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
 908 fi
 909
 910 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 911 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 912 #include <sys/types.h>
 913 #include <sys/socket.h>
 914
 915 int main(void) {
 916        int fd[2];
 917        return (socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1;
 918 }]])],[rsync_cv_HAVE_SOCKETPAIR=yes],[rsync_cv_HAVE_SOCKETPAIR=no],[rsync_cv_HAVE_SOCKETPAIR=cross])])
 919 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 920     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
 921 fi
 922
 923 AC_REPLACE_FUNCS([getpass])
 924
 925 if test x"$with_included_popt" != x"yes"; then
 926     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 927 fi
 928 if test x"$ac_cv_header_popt_popt_h" = x"yes"; then
 929     # If the system has /usr/include/popt/popt.h, we enable the
 930     # included popt because an attempt to "#include <popt/popt.h>"
 931     # would use our included header file anyway (due to -I.), and
 932     # might conflict with the system popt.
 933     with_included_popt=yes
 934 elif test x"$ac_cv_header_popt_h" != x"yes"; then
 935     with_included_popt=yes
 936 fi
 937
 938 AC_MSG_CHECKING([whether to use included libpopt])
 939 if test x"$with_included_popt" = x"yes"; then
 940     AC_MSG_RESULT($srcdir/popt)
 941     BUILD_POPT='$(popt_OBJS)'
 942     CFLAGS="-I$srcdir/popt $CFLAGS"
 943     if test x"$ALLOCA" != x
 944     then
 945         # this can be removed when/if we add an included alloca.c;
 946         #  see autoconf documentation on AC_FUNC_ALLOCA
 947         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
 948     fi
 949 else
 950     AC_MSG_RESULT(no)
 951 fi
 952
 953 # We default to using our zlib unless --with-included-zlib=no is given.
 954 if test x"$with_included_zlib" != x"no"; then
 955     with_included_zlib=yes
 956 elif test x"$ac_cv_header_zlib_h" != x"yes"; then
 957     with_included_zlib=yes
 958 fi
 959 if test x"$with_included_zlib" != x"yes"; then
 960     AC_CHECK_LIB(z, deflateParams, , [with_included_zlib=yes])
 961 fi
 962
 963 AC_MSG_CHECKING([whether to use included zlib])
 964 if test x"$with_included_zlib" = x"yes"; then
 965     AC_MSG_RESULT($srcdir/zlib)
 966     BUILD_ZLIB='$(zlib_OBJS)'
 967     CFLAGS="-I$srcdir/zlib $CFLAGS"
 968 else
 969     AC_DEFINE(EXTERNAL_ZLIB, 1, [Define to 1 if using external zlib])
 970     AC_MSG_RESULT(no)
 971 fi
 972
 973 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
 974 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[signed char *s = ""]])],[rsync_cv_SIGNED_CHAR_OK=yes],[rsync_cv_SIGNED_CHAR_OK=no])])
 975 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
 976     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
 977 fi
 978
 979 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
 980 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <sys/types.h>
 981 #include <dirent.h>
 982 int main(void) { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 983 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 984 di->d_name[0] == 0) return 0; return 1;} ]])],[rsync_cv_HAVE_BROKEN_READDIR=yes],[rsync_cv_HAVE_BROKEN_READDIR=no],[rsync_cv_HAVE_BROKEN_READDIR=cross])])
 985 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 986     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
 987 fi
 988
 989 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
 990 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 991 #include <utime.h>]], [[struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; return utime("foo.c",&tbuf);]])],[rsync_cv_HAVE_STRUCT_UTIMBUF=yes],[rsync_cv_HAVE_STRUCT_UTIMBUF=no])])
 992 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
 993     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
 994 fi
 995
 996 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
 997 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/time.h>
 998 #include <unistd.h>]], [[struct timeval tv; return gettimeofday(&tv, NULL);]])],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=no])])
 999 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
1000     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
1001 fi
1002
1003 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
1004 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1005 #include <sys/types.h>
1006 #include <stdarg.h>
1007 #include <stdio.h>
1008 #include <stdlib.h>
1009 #include <string.h>
1010 void foo(const char *format, ...) {
1011        va_list ap;
1012        int len;
1013        static char buf[] = "12345678901234567890";
1014
1015        va_start(ap, format);
1016        len = vsnprintf(0, 0, format, ap);
1017        va_end(ap);
1018        if (len != 5) exit(1);
1019
1020        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
1021 }
1022 int main(void) { foo("hello"); return 0; }
1023 ]])],[rsync_cv_HAVE_C99_VSNPRINTF=yes],[rsync_cv_HAVE_C99_VSNPRINTF=no],[rsync_cv_HAVE_C99_VSNPRINTF=cross])])
1024 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
1025     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
1026 fi
1027
1028
1029 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
1030 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1031 #include <sys/types.h>
1032 #include <sys/stat.h>
1033 #include <unistd.h>
1034 int main(void) {
1035   struct stat st;
1036   char tpl[20]="/tmp/test.XXXXXX";
1037   int fd = mkstemp(tpl);
1038   if (fd == -1) return 1;
1039   unlink(tpl);
1040   if (fstat(fd, &st) != 0) return 1;
1041   if ((st.st_mode & 0777) != 0600) return 1;
1042   return 0;
1043 }]])],[rsync_cv_HAVE_SECURE_MKSTEMP=yes],[rsync_cv_HAVE_SECURE_MKSTEMP=no],[rsync_cv_HAVE_SECURE_MKSTEMP=cross])])
1044 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
1045     case $host_os in
1046     hpux*)
1047         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
1048         dnl so we noisily skip using it.  See HP change request JAGaf34426
1049         dnl for details. (sbonds)
1050         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
1051         ;;
1052     *)
1053         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
1054         ;;
1055     esac
1056 fi
1057
1058
1059 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
1060 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1061 #include <stdio.h>
1062 #include <sys/stat.h>
1063 #include <errno.h>
1064 #if HAVE_UNISTD_H
1065 # include <unistd.h>
1066 #endif
1067 int main(void) { int rc, ec; char *fn = "fifo-test";
1068 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
1069 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1070 return 0;}]])],[rsync_cv_MKNOD_CREATES_FIFOS=yes],[rsync_cv_MKNOD_CREATES_FIFOS=no],[rsync_cv_MKNOD_CREATES_FIFOS=cross])])
1071 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
1072     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
1073 fi
1074
1075 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
1076 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1077 #include <stdio.h>
1078 #include <sys/stat.h>
1079 #include <errno.h>
1080 #if HAVE_UNISTD_H
1081 # include <unistd.h>
1082 #endif
1083 int main(void) { int rc, ec; char *fn = "sock-test";
1084 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
1085 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1086 return 0;}]])],[rsync_cv_MKNOD_CREATES_SOCKETS=yes],[rsync_cv_MKNOD_CREATES_SOCKETS=no],[rsync_cv_MKNOD_CREATES_SOCKETS=cross])])
1087 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
1088     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
1089 fi
1090
1091 #
1092 # The following test was mostly taken from the tcl/tk plus patches
1093 #
1094 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
1095 rm -rf conftest*
1096 cat > conftest.$ac_ext <<EOF
1097 int main(void) { return 0; }
1098 EOF
1099 ${CC-cc} -c -o conftest..o conftest.$ac_ext
1100 if test -f conftest..o; then
1101     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
1102 else
1103     rsync_cv_DASHC_WORKS_WITH_DASHO=no
1104 fi
1105 rm -rf conftest*
1106 ])
1107 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
1108     OBJ_SAVE="#"
1109     OBJ_RESTORE="#"
1110     CC_SHOBJ_FLAG='-o $@'
1111 else
1112     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
1113     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
1114     CC_SHOBJ_FLAG=""
1115 fi
1116
1117 AC_SUBST(OBJ_SAVE)
1118 AC_SUBST(OBJ_RESTORE)
1119 AC_SUBST(CC_SHOBJ_FLAG)
1120 AC_SUBST(BUILD_POPT)
1121 AC_SUBST(BUILD_ZLIB)
1122 AC_SUBST(MAKE_MAN)
1123
1124 AC_CHECK_FUNCS(_acl __acl _facl __facl)
1125 #################################################
1126 # check for ACL support
1127
1128 AC_MSG_CHECKING([whether to support ACLs])
1129 AC_ARG_ENABLE(acl-support,
1130         AS_HELP_STRING([--disable-acl-support],[disable ACL support]))
1131
1132 if test x"$enable_acl_support" = x"no"; then
1133     AC_MSG_RESULT(no)
1134 else
1135     case "$host_os" in
1136     *sysv5*)
1137         AC_MSG_RESULT(Using UnixWare ACLs)
1138         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
1139         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
1140         ;;
1141     solaris*)
1142         AC_MSG_RESULT(Using solaris ACLs)
1143         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
1144         AC_DEFINE(SUPPORT_ACLS, 1)
1145         ;;
1146     *hpux*)
1147         AC_MSG_RESULT(Using HPUX ACLs)
1148         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
1149         AC_DEFINE(SUPPORT_ACLS, 1)
1150         ;;
1151     *irix*)
1152         AC_MSG_RESULT(Using IRIX ACLs)
1153         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
1154         AC_DEFINE(SUPPORT_ACLS, 1)
1155         ;;
1156     *aix*)
1157         AC_MSG_RESULT(Using AIX ACLs)
1158         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
1159         AC_DEFINE(SUPPORT_ACLS, 1)
1160         ;;
1161     *osf*)
1162         AC_MSG_RESULT(Using Tru64 ACLs)
1163         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
1164         AC_DEFINE(SUPPORT_ACLS, 1)
1165         LIBS="$LIBS -lpacl"
1166         ;;
1167     darwin*)
1168         AC_MSG_RESULT(Using OS X ACLs)
1169         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
1170         AC_DEFINE(SUPPORT_ACLS, 1)
1171         ;;
1172     *)
1173         AC_MSG_RESULT(running tests:)
1174         AC_CHECK_LIB(acl,acl_get_file)
1175         AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
1176             AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1177 #include <sys/acl.h>]], [[ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);]])],[samba_cv_HAVE_POSIX_ACLS=yes],[samba_cv_HAVE_POSIX_ACLS=no])])
1178         AC_MSG_CHECKING(ACL test results)
1179         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
1180             AC_MSG_RESULT(Using posix ACLs)
1181             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
1182             AC_DEFINE(SUPPORT_ACLS, 1)
1183             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
1184                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1185 #include <sys/acl.h>]], [[ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);]])],[samba_cv_HAVE_ACL_GET_PERM_NP=yes],[samba_cv_HAVE_ACL_GET_PERM_NP=no])])
1186             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
1187                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
1188             fi
1189         else
1190             if test x"$enable_acl_support" = x"yes"; then
1191                 AC_MSG_ERROR(Failed to find ACL support)
1192             else
1193                 AC_MSG_RESULT(No ACL support found)
1194             fi
1195         fi
1196         ;;
1197     esac
1198 fi
1199
1200 #################################################
1201 # check for extended attribute support
1202 AC_MSG_CHECKING(whether to support extended attributes)
1203 AC_ARG_ENABLE(xattr-support,
1204     AS_HELP_STRING([--disable-xattr-support],[disable extended attributes]),
1205     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link$ac_cv_func_attropen" in
1206         *yes*) enable_xattr_support=maybe ;;
1207         *) enable_xattr_support=no ;;
1208         esac])
1209 AH_TEMPLATE([SUPPORT_XATTRS],
1210 [Define to 1 to add support for extended attributes])
1211 if test x"$enable_xattr_support" = x"no"; then
1212     AC_MSG_RESULT(no)
1213 else
1214     case "$host_os" in
1215     *linux*|*netbsd*)
1216         AC_MSG_RESULT(Using Linux xattrs)
1217         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs (or equivalent)])
1218         AC_DEFINE(SUPPORT_XATTRS, 1)
1219         AC_DEFINE(NO_SYMLINK_USER_XATTRS, 1, [True if symlinks do not support user xattrs])
1220         AC_CHECK_LIB(attr,getxattr)
1221         ;;
1222     darwin*)
1223         AC_MSG_RESULT(Using OS X xattrs)
1224         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
1225         AC_DEFINE(SUPPORT_XATTRS, 1)
1226         AC_DEFINE(NO_DEVICE_XATTRS, 1, [True if device files do not support xattrs])
1227         AC_DEFINE(NO_SPECIAL_XATTRS, 1, [True if special files do not support xattrs])
1228         ;;
1229     freebsd*)
1230         AC_MSG_RESULT(Using FreeBSD extattrs)
1231         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
1232         AC_DEFINE(SUPPORT_XATTRS, 1)
1233         ;;
1234     solaris*)
1235         AC_MSG_RESULT(Using Solaris xattrs)
1236         AC_DEFINE(HAVE_SOLARIS_XATTRS, 1, [True if you have Solaris xattrs])
1237         AC_DEFINE(SUPPORT_XATTRS, 1)
1238         AC_DEFINE(NO_SYMLINK_XATTRS, 1, [True if symlinks do not support xattrs])
1239         ;;
1240     *)
1241         if test x"$enable_xattr_support" = x"yes"; then
1242             AC_MSG_ERROR(Failed to find extended attribute support)
1243         else
1244             AC_MSG_RESULT(No extended attribute support found)
1245         fi
1246         ;;
1247     esac
1248 fi
1249
1250 if test x"$enable_acl_support" = x"no" -o x"$enable_xattr_support" = x"no" -o x"$enable_iconv" = x"no"; then
1251     AC_MSG_CHECKING([whether $CC supports -Wno-unused-parameter])
1252     OLD_CFLAGS="$CFLAGS"
1253     CFLAGS="$CFLAGS -Wno-unused-parameter"
1254     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]], [[printf("hello\n");]])],[rsync_warn_flag=yes],[rsync_warn_flag=no])
1255     AC_MSG_RESULT([$rsync_warn_flag])
1256     if test x"$rsync_warn_flag" = x"no"; then
1257         CFLAGS="$OLD_CFLAGS"
1258     fi
1259 fi
1260
1261 case "$CC" in
1262 ' checker'*|checker*)
1263     AC_DEFINE(FORCE_FD_ZERO_MEMSET, 1, [Used to make "checker" understand that FD_ZERO() clears memory.])
1264     ;;
1265 esac
1266
1267 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
1268 AC_OUTPUT
1269
1270 AC_MSG_RESULT()
1271 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
1272 AC_MSG_RESULT()