configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([rsync],[3.2.1pre1],[https://rsync.samba.org/bugtracking.html])
   4
   5 AC_CONFIG_MACRO_DIR([m4])
   6 AC_CONFIG_SRCDIR([byteorder.h])
   7 AC_CONFIG_HEADER(config.h)
   8 AC_PREREQ([2.69])
   9
  10 AC_SUBST(RSYNC_VERSION, $PACKAGE_VERSION)
  11 AC_MSG_NOTICE([Configuring rsync $PACKAGE_VERSION])
  12
  13 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$PACKAGE_VERSION"], [rsync release version])
  14
  15 LDFLAGS=${LDFLAGS-""}
  16
  17 AC_CANONICAL_HOST
  18
  19 dnl define the directory for replacement function since AC_LIBOBJ does not
  20 dnl officially support subdirs and fails with automake
  21 AC_CONFIG_LIBOBJ_DIR([lib])
  22
  23 # We must decide this before testing the compiler.
  24
  25 # Please allow this to default to yes, so that your users have more
  26 # chance of getting a useful stack trace if problems occur.
  27
  28 AC_MSG_CHECKING([whether to include debugging symbols])
  29 AC_ARG_ENABLE(debug,
  30         AS_HELP_STRING([--disable-debug],[disable debugging symbols and features]))
  31
  32 if test x"$enable_debug" = x"no"; then
  33     AC_MSG_RESULT(no)
  34     ac_cv_prog_cc_g=no
  35 else
  36     AC_MSG_RESULT([yes])
  37     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  38     # leave ac_cv_prog_cc_g alone; AC_PROG_CC will try to include -g if it can
  39 fi
  40
  41 dnl Checks for programs.
  42 AC_PROG_CC
  43 AC_PROG_CPP
  44 AC_PROG_CXX
  45 AC_PROG_AWK
  46 AC_PROG_EGREP
  47 AC_PROG_INSTALL
  48 AC_PROG_MKDIR_P
  49 AC_PROG_CC_STDC
  50 AC_SUBST(SHELL)
  51 AC_PATH_PROG([PERL], [perl])
  52 AC_PATH_PROG([PYTHON3], [python3])
  53
  54 AC_DEFINE([_GNU_SOURCE], 1,
  55           [Define _GNU_SOURCE so that we get all necessary prototypes])
  56
  57 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  58         AC_MSG_WARN([rsync requires an ANSI C compiler and you do not seem to have one])
  59 fi
  60
  61 AC_ARG_ENABLE(profile,
  62         AS_HELP_STRING([--enable-profile],[turn on CPU profiling]))
  63 if test x"$enable_profile" = x"yes"; then
  64         CFLAGS="$CFLAGS -pg"
  65 fi
  66
  67 AC_MSG_CHECKING([if md2man can create man pages])
  68 if test x"$ac_cv_path_PYTHON3" = x; then
  69     AC_MSG_RESULT(no - python3 not found)
  70     md2man_works=no
  71 else
  72     md2man_out=`"$srcdir/md2man" --test "$srcdir/rsync-ssl.1.md" 2>&1`
  73     if test $? = 0; then
  74         AC_MSG_RESULT(yes)
  75         md2man_works=yes
  76     else
  77         AC_MSG_RESULT(no)
  78         md2man_works=no
  79         echo "$md2man_out"
  80     fi
  81 fi
  82
  83 AC_MSG_CHECKING([if we require man-page building])
  84 AC_ARG_ENABLE([md2man],
  85         AS_HELP_STRING([--disable-md2man],[disable md2man for man page creation]))
  86 if test x"$enable_md2man" != x"no"; then
  87     if test -f "$srcdir/rsync.1"; then
  88         AC_MSG_RESULT(optional)
  89     else
  90         AC_MSG_RESULT(required)
  91         if test x"$md2man_works" = x"no"; then
  92             AC_MSG_ERROR(You need python3 and the cmarkgfm OR commonmark python3 lib in order to build man pages.
  93 You can specify --disable-md2man if you want to skip building them.)
  94         fi
  95     fi
  96     MAKE_MAN=man
  97 else
  98     AC_MSG_RESULT(no)
  99     MAKE_MAN=''
 100 fi
 101
 102 # Specifically, this turns on panic_action handling.
 103 AC_ARG_ENABLE(maintainer-mode,
 104         AS_HELP_STRING([--enable-maintainer-mode],[turn on extra debug features]))
 105 if test x"$enable_maintainer_mode" = x"yes"; then
 106         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
 107 fi
 108
 109 # This is needed for our included version of popt.  Kind of silly, but
 110 # I don't want our version too far out of sync.
 111 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
 112
 113 # If GCC, turn on warnings.
 114 if test x"$GCC" = x"yes"; then
 115         CFLAGS="$CFLAGS -Wall -W"
 116 fi
 117
 118 AC_ARG_WITH(included-popt,
 119         AS_HELP_STRING([--with-included-popt],[use bundled popt library, not from system]))
 120
 121 AC_ARG_WITH(included-zlib,
 122         AS_HELP_STRING([--with-included-zlib],[use bundled zlib library, not from system]))
 123
 124 AC_ARG_WITH(protected-args,
 125         AS_HELP_STRING([--with-protected-args],[make --protected-args option the default]))
 126 if test x"$with_protected_args" = x"yes"; then
 127         AC_DEFINE_UNQUOTED(RSYNC_USE_PROTECTED_ARGS, 1, [Define to 1 if --protected-args should be the default])
 128 fi
 129
 130 AC_ARG_WITH(rsync-path,
 131         AS_HELP_STRING([--with-rsync-path=PATH],[set default --rsync-path to PATH (default: rsync)]),
 132         [ RSYNC_PATH="$with_rsync_path" ],
 133         [ RSYNC_PATH="rsync" ])
 134
 135 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
 136
 137 AC_ARG_WITH(rsyncd-conf,
 138         AS_HELP_STRING([--with-rsyncd-conf=PATH],[set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
 139         [ if test ! -z "$with_rsyncd_conf" ; then
 140                 case $with_rsyncd_conf in
 141                         yes|no)
 142                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 143                                 ;;
 144                         /*)
 145                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
 146                                 ;;
 147                         *)
 148                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 149                                 ;;
 150                 esac
 151         else
 152                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 153         fi ],
 154         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 155
 156 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 157
 158 AC_ARG_WITH(rsh,
 159         AS_HELP_STRING([--with-rsh=CMD],[set remote shell command to CMD (default: ssh)]))
 160
 161 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 162 if test x$HAVE_REMSH = x1; then
 163         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 164 fi
 165
 166 if test x"$with_rsh" != x; then
 167         RSYNC_RSH="$with_rsh"
 168 else
 169         RSYNC_RSH="ssh"
 170 fi
 171 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 172
 173 # Some programs on solaris are only found in /usr/xpg4/bin (or work better than others versions).
 174 AC_PATH_PROG(SHELL_PATH, sh, /bin/sh, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 175 AC_PATH_PROG(FAKEROOT_PATH, fakeroot, /usr/bin/fakeroot, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 176
 177 AC_ARG_WITH(nobody-group,
 178     AS_HELP_STRING([--with-nobody-group=GROUP],[set the default unprivileged group (default nobody or nogroup)]),
 179     [ NOBODY_GROUP="$with_nobody_group" ])
 180
 181 if test x"$with_nobody_group" = x; then
 182     AC_MSG_CHECKING([the group for user "nobody"])
 183     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 184         NOBODY_GROUP=nobody
 185     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 186         NOBODY_GROUP=nogroup
 187     else
 188         NOBODY_GROUP=nobody # test for others?
 189     fi
 190     AC_MSG_RESULT($NOBODY_GROUP)
 191 fi
 192
 193 AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody])
 194 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 195
 196 # SIMD optimizations
 197 SIMD=
 198
 199 AC_MSG_CHECKING([whether to enable SIMD optimizations])
 200 AC_ARG_ENABLE(simd,
 201     AS_HELP_STRING([--disable-simd],[disable SIMD optimizations (requires c++)]))
 202
 203 # Clag is crashing with -g -O2, so we'll get rid of -g for now.
 204 CXXFLAGS=`echo "$CXXFLAGS" | sed 's/-g //'`
 205
 206 if test x"$enable_simd" != x"no"; then
 207     # For x86-64 SIMD, g++ >=5 or clang++ >=7 is required
 208     if test x"$build_cpu" = x"x86_64"; then
 209         AC_LANG(C++)
 210         AC_RUN_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
 211 #include <immintrin.h>
 212 __attribute__ ((target("default"))) int test_ssse3(int x) { return x; }
 213 __attribute__ ((target("default"))) int test_sse2(int x) { return x; }
 214 __attribute__ ((target("default"))) int test_avx2(int x) { return x; }
 215 __attribute__ ((target("ssse3"))) int test_ssse3(int x) { return x; }
 216 __attribute__ ((target("sse2"))) int test_sse2(int x) { return x; }
 217 __attribute__ ((target("avx2"))) int test_avx2(int x) { return x; }
 218 typedef long long __m128i_u __attribute__((__vector_size__(16), __may_alias__, __aligned__(1)));
 219 typedef long long __m256i_u __attribute__((__vector_size__(32), __may_alias__, __aligned__(1)));
 220 __attribute__ ((target("default"))) void more_testing(char* buf, int len) { }
 221 __attribute__ ((target("ssse3"))) void more_testing(char* buf, int len)
 222 {
 223     int i;
 224     for (i = 0; i < (len-32); i+=32) {
 225         __m128i in8_1, in8_2;
 226         in8_1 = _mm_lddqu_si128((__m128i_u*)&buf[i]);
 227         in8_2 = _mm_lddqu_si128((__m128i_u*)&buf[i + 16]);
 228     }
 229 }
 230 ]], [[if (test_ssse3(42) != 42 || test_sse2(42) != 42 || test_avx2(42) != 42) exit(1);]])],[CXX_OK=yes],[CXX_OK=no])
 231         AC_LANG(C)
 232         if test x"$CXX_OK" = x"yes"; then
 233             # AC_MSG_RESULT() is called below.
 234             SIMD="x86_64"
 235         elif test x"$enable_simd" = x"yes"; then
 236             AC_MSG_RESULT(error)
 237             AC_MSG_ERROR(The SIMD compilation test failed.
 238 Omit --enable-simd to continue without it.)
 239         fi
 240     elif test x"$enable_simd" = x"yes"; then
 241         AC_MSG_RESULT(unavailable)
 242         AC_MSG_ERROR(The SIMD optimizations are currently x86_64 only.
 243 Omit --enable-simd to continue without it.)
 244     fi
 245 fi
 246
 247 if test x"$SIMD" != x""; then
 248     AC_MSG_RESULT([yes ($SIMD)])
 249     AC_DEFINE(HAVE_SIMD, 1, [Define to 1 to enable SIMD optimizations])
 250     SIMD='$(SIMD_'"$SIMD)"
 251     # We only use c++ for its target attribute dispatching, disable unneeded bulky features
 252     CXXFLAGS="$CXXFLAGS -fno-exceptions -fno-rtti"
 253     case "$CXX" in
 254     *clang*) CXXFLAGS="$CXXFLAGS -fno-slp-vectorize" ;; # avoid a performance hit
 255     esac
 256 else
 257     AC_MSG_RESULT(no)
 258 fi
 259
 260 AC_SUBST(SIMD)
 261
 262 AC_MSG_CHECKING([if assembler accepts noexecstack])
 263 OLD_CFLAGS="$CFLAGS"
 264 CFLAGS="$CFLAGS -Wa,--noexecstack"
 265 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ ]], [[return 0;]])],
 266 [ NOEXECSTACK='-Wa,--noexecstack' ; AC_MSG_RESULT(yes) ],
 267 [ NOEXECSTACK='' ; AC_MSG_RESULT(no) ])
 268 CFLAGS="$OLD_CFLAGS"
 269 AC_SUBST(NOEXECSTACK)
 270
 271 ASM=
 272
 273 AC_MSG_CHECKING([whether to enable ASM optimizations])
 274 AC_ARG_ENABLE(asm,
 275     AS_HELP_STRING([--disable-asm],[disable ASM optimizations]))
 276
 277 if test x"$enable_asm" != x"no"; then
 278     if test x"$build_cpu" = x"x86_64"; then
 279         ASM="$build_cpu"
 280     elif test x"$enable_asm" = x"yes"; then
 281         AC_MSG_RESULT(unavailable)
 282         AC_MSG_ERROR(The ASM optimizations are currently x86_64 only.
 283 Omit --enable-asm to continue without it.)
 284     fi
 285 fi
 286
 287 if test x"$ASM" != x""; then
 288     AC_MSG_RESULT([yes ($ASM)])
 289     AC_DEFINE(HAVE_ASM, 1, [Define to 1 to enable ASM optimizations])
 290     ASM='$(ASM_'"$ASM)"
 291 else
 292     AC_MSG_RESULT(no)
 293 fi
 294
 295 AC_SUBST(ASM)
 296
 297 # arrgh. libc in some old debian version screwed up the largefile
 298 # stuff, getting byte range locking wrong
 299 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 300 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 301 #define _FILE_OFFSET_BITS 64
 302 #include <stdio.h>
 303 #include <fcntl.h>
 304 #include <sys/types.h>
 305 #include <sys/wait.h>
 306 #if HAVE_UNISTD_H
 307 #include <unistd.h>
 308 #endif
 309
 310 int main(void)
 311 {
 312         struct flock lock;
 313         int status;
 314         char tpl[32] = "/tmp/locktest.XXXXXX";
 315         int fd = mkstemp(tpl);
 316         if (fd < 0) {
 317                 strcpy(tpl, "conftest.dat");
 318                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 319         }
 320
 321         lock.l_type = F_WRLCK;
 322         lock.l_whence = SEEK_SET;
 323         lock.l_start = 0;
 324         lock.l_len = 1;
 325         lock.l_pid = 0;
 326         fcntl(fd,F_SETLK,&lock);
 327         if (fork() == 0) {
 328                 lock.l_start = 1;
 329                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 330         }
 331         wait(&status);
 332         unlink(tpl);
 333         return WEXITSTATUS(status);
 334 }
 335 ]])],[rsync_cv_HAVE_BROKEN_LARGEFILE=yes],[rsync_cv_HAVE_BROKEN_LARGEFILE=no],[rsync_cv_HAVE_BROKEN_LARGEFILE=cross])])
 336 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 337    AC_SYS_LARGEFILE
 338 fi
 339
 340 ipv6type=unknown
 341 ipv6lib=none
 342 ipv6trylibc=yes
 343
 344 AC_ARG_ENABLE(ipv6,
 345         AS_HELP_STRING([--disable-ipv6],[turn off IPv6 support]))
 346 if test x"$enable_ipv6" != x"no"; then
 347         AC_MSG_CHECKING([ipv6 stack type])
 348         for i in inria kame linux-glibc linux-inet6 solaris toshiba v6d zeta cygwin; do
 349                 case $i in
 350                 inria)
 351                         # http://www.kame.net/
 352                         AC_EGREP_CPP(yes, [
 353 #include <netinet/in.h>
 354 #ifdef IPV6_INRIA_VERSION
 355 yes
 356 #endif],
 357                                 [ipv6type=$i;
 358                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 359                                 ])
 360                         ;;
 361                 kame)
 362                         # http://www.kame.net/
 363                         AC_EGREP_CPP(yes, [
 364 #include <netinet/in.h>
 365 #ifdef __KAME__
 366 yes
 367 #endif],
 368                                 [ipv6type=$i;
 369                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 370                         ;;
 371                 linux-glibc)
 372                         # http://www.v6.linux.or.jp/
 373                         AC_EGREP_CPP(yes, [
 374 #include <features.h>
 375 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 376 yes
 377 #endif],
 378                                 [ipv6type=$i;
 379 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 380                         ;;
 381                 linux-inet6)
 382                         # http://www.v6.linux.or.jp/
 383                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 384                                 ipv6type=$i
 385                                 ipv6lib=inet6
 386                                 ipv6libdir=/usr/inet6/lib
 387                                 ipv6trylibc=yes;
 388                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 389                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 390                         fi
 391                         ;;
 392                 solaris)
 393                         # http://www.sun.com
 394                         AC_EGREP_CPP(yes, [
 395 #include <netinet/ip6.h>
 396 #ifdef __sun
 397 yes
 398 #endif],
 399                                 [ipv6type=$i;
 400                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 401                         ;;
 402                 toshiba)
 403                         AC_EGREP_CPP(yes, [
 404 #include <sys/param.h>
 405 #ifdef _TOSHIBA_INET6
 406 yes
 407 #endif],
 408                                 [ipv6type=$i;
 409                                 ipv6lib=inet6;
 410                                 ipv6libdir=/usr/local/v6/lib;
 411                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 412                         ;;
 413                 v6d)
 414                         AC_EGREP_CPP(yes, [
 415 #include </usr/local/v6/include/sys/v6config.h>
 416 #ifdef __V6D__
 417 yes
 418 #endif],
 419                                 [ipv6type=$i;
 420                                 ipv6lib=v6;
 421                                 ipv6libdir=/usr/local/v6/lib;
 422                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 423                         ;;
 424                 zeta)
 425                         AC_EGREP_CPP(yes, [
 426 #include <sys/param.h>
 427 #ifdef _ZETA_MINAMI_INET6
 428 yes
 429 #endif],
 430                                 [ipv6type=$i;
 431                                 ipv6lib=inet6;
 432                                 ipv6libdir=/usr/local/v6/lib;
 433                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 434                         ;;
 435                 cygwin)
 436                         AC_EGREP_CPP(yes, [
 437 #include <netinet/in.h>
 438 #ifdef _CYGWIN_IN6_H
 439 yes
 440 #endif],
 441                                 [ipv6type=$i;
 442                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 443                         ;;
 444                 esac
 445                 if test "$ipv6type" != "unknown"; then
 446                         break
 447                 fi
 448         done
 449         AC_MSG_RESULT($ipv6type)
 450
 451         AC_SEARCH_LIBS(getaddrinfo, inet6)
 452 fi
 453
 454 dnl Do you want to disable use of locale functions
 455 AC_ARG_ENABLE([locale],
 456         AS_HELP_STRING([--disable-locale],[disable locale features]))
 457 AH_TEMPLATE([CONFIG_LOCALE],
 458 [Undefine if you do not want locale features.  By default this is defined.])
 459 if test x"$enable_locale" != x"no"; then
 460         AC_DEFINE(CONFIG_LOCALE)
 461 fi
 462
 463 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 464 case $host_os in
 465         *cygwin* ) AC_MSG_RESULT(yes)
 466                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 467                             [Define to 1 if sockets need to be shutdown])
 468                    ;;
 469                * ) AC_MSG_RESULT(no);;
 470 esac
 471
 472 AC_C_BIGENDIAN
 473 AC_HEADER_DIRENT
 474 AC_HEADER_TIME
 475 AC_HEADER_SYS_WAIT
 476 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
 477     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
 478     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
 479     sys/un.h sys/attr.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
 480     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h \
 481     sys/acl.h acl/libacl.h attr/xattr.h sys/xattr.h sys/extattr.h \
 482     popt.h popt/popt.h linux/falloc.h netinet/in_systm.h netinet/ip.h \
 483     zlib.h xxhash.h openssl/md4.h openssl/md5.h zstd.h lz4.h)
 484 AC_HEADER_MAJOR_FIXED
 485
 486 AC_MSG_CHECKING([whether to enable use of openssl crypto library])
 487 AC_ARG_ENABLE([openssl],
 488         AS_HELP_STRING([--disable-openssl],[disable openssl crypto library]))
 489 AH_TEMPLATE([USE_OPENSSL],
 490 [Undefine if you do not want to use openssl crypto library.  By default this is defined.])
 491 if test x"$enable_openssl" != x"no"; then
 492     if test x"$ac_cv_header_openssl_md4_h" = x"yes" && test x"$ac_cv_header_openssl_md5_h" = x"yes"; then
 493       AC_MSG_RESULT(yes)
 494       AC_SEARCH_LIBS(MD5_Init, crypto,
 495           [AC_DEFINE(USE_OPENSSL)],
 496           [AC_MSG_ERROR(Failed to find MD5_Init function in openssl crypto lib.
 497 Use --disable-openssl to continue without openssl crypto lib support.)])
 498     else
 499         AC_MSG_RESULT(no)
 500         AC_MSG_ERROR(Failed to find openssl/md4.h and openssl/md5.h for openssl crypto lib support.
 501 Use --disable-openssl to continue without it.)
 502     fi
 503 else
 504     AC_MSG_RESULT(no)
 505 fi
 506
 507 AC_MSG_CHECKING([whether to enable xxhash checksum support])
 508 AC_ARG_ENABLE([xxhash],
 509         AS_HELP_STRING([--disable-xxhash],[disable xxhash checksums]))
 510 AH_TEMPLATE([SUPPORT_XXHASH],
 511 [Undefine if you do not want xxhash checksums.  By default this is defined.])
 512 if test x"$enable_xxhash" != x"no"; then
 513     if test x"$ac_cv_header_xxhash_h" = x"yes"; then
 514         AC_MSG_RESULT(yes)
 515         AC_SEARCH_LIBS(XXH64_createState, xxhash,
 516             [AC_DEFINE(SUPPORT_XXHASH)],
 517             [AC_MSG_ERROR(Failed to find XXH64_createState function in xxhash lib.
 518 Use --disable-xxhash to continue without xxhash checksums.)])
 519     else
 520         AC_MSG_RESULT(no)
 521         AC_MSG_ERROR(Failed to find xxhash.h for xxhash checksum support.
 522 Use --disable-xxhash to continue without it.)
 523     fi
 524 else
 525     AC_MSG_RESULT(no)
 526 fi
 527
 528 AC_MSG_CHECKING([whether to enable zstd compression])
 529 AC_ARG_ENABLE([zstd],
 530         AC_HELP_STRING([--disable-zstd], [disable zstd compression]))
 531 AH_TEMPLATE([SUPPORT_ZSTD],
 532 [Undefine if you do not want zstd compression.  By default this is defined.])
 533 if test x"$enable_zstd" != x"no"; then
 534     if test x"$ac_cv_header_zstd_h" = x"yes"; then
 535         AC_MSG_RESULT(yes)
 536         AC_SEARCH_LIBS(ZSTD_minCLevel, zstd,
 537             [AC_DEFINE(SUPPORT_ZSTD)],
 538             [AC_MSG_ERROR(Failed to find ZSTD_minCLevel function in zstd lib.
 539 Use --disable-zstd to continue without zstd compression.)])
 540     else
 541         AC_MSG_RESULT(no)
 542         AC_MSG_ERROR(Failed to find zstd.h for zstd compression support.
 543 Use --disable-zstd to continue without it.)
 544     fi
 545 else
 546     AC_MSG_RESULT(no)
 547 fi
 548
 549 AC_MSG_CHECKING([whether to enable LZ4 compression])
 550 AC_ARG_ENABLE([lz4],
 551         AC_HELP_STRING([--disable-lz4], [disable LZ4 compression]))
 552 AH_TEMPLATE([SUPPORT_LZ4],
 553 [Undefine if you do not want LZ4 compression.  By default this is defined.])
 554 if test x"$enable_lz4" != x"no"; then
 555     if test x"$ac_cv_header_lz4_h" = x"yes"; then
 556         AC_MSG_RESULT(yes)
 557         AC_SEARCH_LIBS(LZ4_compress_default, lz4,
 558             [AC_DEFINE(SUPPORT_LZ4)],
 559             [AC_MSG_ERROR(Failed to find LZ4_compress_default function in lz4 lib.
 560 Use --disable-lz4 to continue without lz4 compression.)])
 561     else
 562         AC_MSG_RESULT(no)
 563         AC_MSG_ERROR(Failed to find lz4.h for lz4 compression support.
 564 Use --disable-lz4 to continue without it.)
 565     fi
 566 else
 567     AC_MSG_RESULT(no)
 568 fi
 569
 570 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
 571 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 572 #include <sys/types.h>
 573 #ifdef MAJOR_IN_MKDEV
 574 #include <sys/mkdev.h>
 575 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
 576 #  define makedev mkdev
 577 # endif
 578 #elif defined MAJOR_IN_SYSMACROS
 579 #include <sys/sysmacros.h>
 580 #endif
 581
 582 int main(void)
 583 {
 584         dev_t dev = makedev(0, 5, 7);
 585         if (major(dev) != 5 || minor(dev) != 7)
 586                 return 1;
 587         return 0;
 588 }
 589 ]])],[rsync_cv_MAKEDEV_TAKES_3_ARGS=yes],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no])])
 590 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
 591    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
 592 fi
 593
 594 AC_CHECK_SIZEOF(int)
 595 AC_CHECK_SIZEOF(long)
 596 AC_CHECK_SIZEOF(long long)
 597 AC_CHECK_SIZEOF(short)
 598 AC_CHECK_SIZEOF(int16_t)
 599 AC_CHECK_SIZEOF(uint16_t)
 600 AC_CHECK_SIZEOF(int32_t)
 601 AC_CHECK_SIZEOF(uint32_t)
 602 AC_CHECK_SIZEOF(int64_t)
 603 AC_CHECK_SIZEOF(off_t)
 604 AC_CHECK_SIZEOF(off64_t)
 605 AC_CHECK_SIZEOF(time_t)
 606 AC_CHECK_SIZEOF(char*)
 607
 608 AC_C_INLINE
 609
 610 AC_TYPE_LONG_DOUBLE_WIDER
 611 ac_cv_c_long_double=$ac_cv_type_long_double_wider
 612 if test $ac_cv_c_long_double = yes; then
 613   AC_DEFINE([HAVE_LONG_DOUBLE],[1],[Define to 1 if the type `long double' works and has more range or precision than `double'.])
 614 fi
 615
 616 AC_TYPE_UID_T
 617 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
 618 AC_TYPE_GETGROUPS
 619 AC_CHECK_MEMBERS([struct stat.st_rdev,
 620                   struct stat.st_mtimensec,
 621                   struct stat.st_mtimespec.tv_nsec,
 622                   struct stat.st_mtim.tv_nsec],,,[
 623 #ifdef HAVE_SYS_TYPES_H
 624 #include <sys/types.h>
 625 #endif
 626 #ifdef HAVE_SYS_STAT_H
 627 #include <sys/stat.h>
 628 #endif
 629 #ifdef HAVE_UNISTD_H
 630 #include <unistd.h>
 631 #endif])
 632
 633 TYPE_SOCKLEN_T
 634
 635 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 636     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]], [[int i = errno]])],[rsync_cv_errno=yes],[rsync_cv_have_errno_decl=no])])
 637 if test x"$rsync_cv_errno" = x"yes"; then
 638    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 639 fi
 640
 641 # The following test taken from the cvs sources
 642 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 643 # These need checks to be before checks for any other functions that
 644 #    might be in the same libraries.
 645 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 646 # libsocket.so which has a bad implementation of gethostbyname (it
 647 # only looks in /etc/hosts), so we only look for -lsocket if we need
 648 # it.
 649 AC_CHECK_FUNCS(connect)
 650 if test x"$ac_cv_func_connect" = x"no"; then
 651     case "$LIBS" in
 652     *-lnsl*) ;;
 653     *) AC_CHECK_LIB(nsl_s, printf) ;;
 654     esac
 655     case "$LIBS" in
 656     *-lnsl*) ;;
 657     *) AC_CHECK_LIB(nsl, printf) ;;
 658     esac
 659     case "$LIBS" in
 660     *-lsocket*) ;;
 661     *) AC_CHECK_LIB(socket, connect) ;;
 662     esac
 663     case "$LIBS" in
 664     *-linet*) ;;
 665     *) AC_CHECK_LIB(inet, connect) ;;
 666     esac
 667     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 668     dnl has been cached.
 669     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 670        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 671         # ac_cv_func_connect=yes
 672         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 673         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 674     fi
 675 fi
 676
 677 AC_SEARCH_LIBS(inet_ntop, resolv)
 678
 679 # For OS X, Solaris, HP-UX, etc.: figure out if -liconv is needed.  We'll
 680 # accept either iconv_open or libiconv_open, since some include files map
 681 # the former to the latter.
 682 AC_SEARCH_LIBS(iconv_open, iconv)
 683 AC_SEARCH_LIBS(libiconv_open, iconv)
 684
 685 AC_MSG_CHECKING([for iconv declaration])
 686 AC_CACHE_VAL(am_cv_proto_iconv, [
 687     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 688 #include <stdlib.h>
 689 #include <iconv.h>
 690 extern
 691 #ifdef __cplusplus
 692 "C"
 693 #endif
 694 #if defined(__STDC__) || defined(__cplusplus)
 695 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 696 #else
 697 size_t iconv();
 698 #endif
 699 ]], [[]])],[am_cv_proto_iconv_arg1=""],[am_cv_proto_iconv_arg1="const"])
 700       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 701     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed 's/( /(/'`
 702 AC_MSG_RESULT([$]{ac_t:-
 703          }[$]am_cv_proto_iconv)
 704 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 705                    [Define as const if the declaration of iconv() needs const.])
 706
 707 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 708
 709 AC_REPLACE_FUNCS([inet_ntop inet_pton])
 710
 711 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
 712 AC_HAVE_TYPE([struct sockaddr_storage], [#include <sys/types.h>
 713 #include <sys/socket.h>])
 714
 715 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 716 #   builtin getaddrinfo if one of the defines don't exist
 717 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 718                rsync_cv_HAVE_GETADDR_DEFINES,[
 719                         AC_EGREP_CPP(yes, [
 720                         #include <sys/types.h>
 721                         #include <sys/socket.h>
 722                         #include <netdb.h>
 723                         #ifdef AI_PASSIVE
 724                         yes
 725                         #endif],
 726                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 727                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 728 AS_IF([test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" -a x"$ac_cv_type_struct_addrinfo" = x"yes"],[
 729         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 730         # something else so we must include <netdb.h> to get the
 731         # redefinition.
 732         AC_CHECK_FUNCS(getaddrinfo, ,
 733                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 734                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 735                 #include <sys/socket.h>
 736                 #include <netdb.h>]], [[getaddrinfo(NULL, NULL, NULL, NULL);]])],[AC_MSG_RESULT([yes])
 737                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 738                                 [Define to 1 if you have the "getaddrinfo" function and required types.])],[AC_MSG_RESULT([no])
 739                         AC_LIBOBJ([getaddrinfo])])])
 740     ],[AC_LIBOBJ([getaddrinfo])])
 741
 742 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 743                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 744                 [],
 745                 [
 746 #include <sys/types.h>
 747 #include <sys/socket.h>
 748 ])
 749
 750 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 751                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 752                 [],
 753                 [
 754 #include <sys/types.h>
 755 #include <sys/socket.h>
 756 #include <netinet/in.h>
 757 ])
 758
 759 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 760                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 761                 [],
 762                 [
 763 #include <sys/types.h>
 764 #include <sys/socket.h>
 765 #include <netinet/in.h>
 766 ])
 767
 768 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 769                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 770                 [],
 771                 [
 772 #include <sys/types.h>
 773 #include <sys/socket.h>
 774 #include <netinet/in.h>
 775 ])
 776
 777 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
 778 #if HAVE_SYS_TYPES_H
 779 # include <sys/types.h>
 780 #endif
 781 #if HAVE_SYS_STAT_H
 782 # include <sys/stat.h>
 783 #endif
 784 #if STDC_HEADERS
 785 # include <stdlib.h>
 786 # include <stddef.h>
 787 #else
 788 # if HAVE_STDLIB_H
 789 #  include <stdlib.h>
 790 # endif
 791 #endif
 792 ])
 793
 794 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 795 #
 796 AC_CHECK_FUNCS(strcasecmp)
 797 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 798     AC_CHECK_LIB(resolv, strcasecmp)
 799 fi
 800
 801 AC_CHECK_FUNCS(aclsort)
 802 if test x"$ac_cv_func_aclsort" = x"no"; then
 803     AC_CHECK_LIB(sec, aclsort)
 804 fi
 805
 806 dnl At the moment we don't test for a broken memcmp(), because all we
 807 dnl need to do is test for equality, not comparison, and it seems that
 808 dnl every platform has a memcmp that can do at least that.
 809 dnl AC_FUNC_MEMCMP
 810
 811 AC_FUNC_UTIME_NULL
 812 AC_FUNC_ALLOCA
 813 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup chown chmod lchmod mknod mkfifo \
 814     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 815     chflags getattrlist \
 816     memmove lchown vsnprintf snprintf vasprintf asprintf setsid strpbrk \
 817     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
 818     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 819     seteuid strerror putenv iconv_open locale_charset nl_langinfo getxattr \
 820     extattr_get_link sigaction sigprocmask setattrlist getgrouplist \
 821     initgroups utimensat posix_fallocate attropen setvbuf nanosleep usleep)
 822
 823 dnl cygwin iconv.h defines iconv_open as libiconv_open
 824 if test x"$ac_cv_func_iconv_open" != x"yes"; then
 825     AC_CHECK_FUNC(libiconv_open, [ac_cv_func_iconv_open=yes; AC_DEFINE(HAVE_ICONV_OPEN, 1)])
 826 fi
 827
 828 dnl Preallocation stuff (also fallocate, posix_fallocate function tests above):
 829
 830 AC_CACHE_CHECK([for useable fallocate],rsync_cv_have_fallocate,[
 831 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <fcntl.h>
 832 #include <sys/types.h>]], [[fallocate(0, 0, 0, 0);]])],[rsync_cv_have_fallocate=yes],[rsync_cv_have_fallocate=no])])
 833 if test x"$rsync_cv_have_fallocate" = x"yes"; then
 834     AC_DEFINE(HAVE_FALLOCATE, 1, [Define to 1 if you have the fallocate function and it compiles and links without error])
 835 fi
 836
 837 AC_MSG_CHECKING([for FALLOC_FL_PUNCH_HOLE])
 838 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 839         #define _GNU_SOURCE 1
 840         #include <linux/falloc.h>
 841         #ifndef FALLOC_FL_PUNCH_HOLE
 842         #error FALLOC_FL_PUNCH_HOLE is missing
 843         #endif
 844     ]])], [
 845         AC_MSG_RESULT([yes])
 846         AC_DEFINE([HAVE_FALLOC_FL_PUNCH_HOLE], [1], [Define if FALLOC_FL_PUNCH_HOLE is available.])
 847     ], [
 848         AC_MSG_RESULT([no])
 849     ]
 850 )
 851
 852 AC_MSG_CHECKING([for FALLOC_FL_ZERO_RANGE])
 853 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 854         #define _GNU_SOURCE 1
 855         #include <linux/falloc.h>
 856         #ifndef FALLOC_FL_ZERO_RANGE
 857         #error FALLOC_FL_ZERO_RANGE is missing
 858         #endif
 859     ]])], [
 860         AC_MSG_RESULT([yes])
 861         AC_DEFINE([HAVE_FALLOC_FL_ZERO_RANGE], [1], [Define if FALLOC_FL_ZERO_RANGE is available.])
 862     ], [
 863         AC_MSG_RESULT([no])
 864     ]
 865 )
 866
 867 AC_CACHE_CHECK([for SYS_fallocate],rsync_cv_have_sys_fallocate,[
 868 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/syscall.h>
 869 #include <unistd.h>
 870 #include <sys/types.h>]], [[syscall(SYS_fallocate, 0, 0, (loff_t)0, (loff_t)0);]])],[rsync_cv_have_sys_fallocate=yes],[rsync_cv_have_sys_fallocate=no])])
 871 if test x"$rsync_cv_have_sys_fallocate" = x"yes"; then
 872     AC_DEFINE(HAVE_SYS_FALLOCATE, 1, [Define to 1 if you have the SYS_fallocate syscall number])
 873 fi
 874
 875 if test x"$ac_cv_func_posix_fallocate" = x"yes"; then
 876     AC_MSG_CHECKING([whether posix_fallocate is efficient])
 877     case $host_os in
 878     *cygwin*)
 879         AC_MSG_RESULT(yes)
 880         AC_DEFINE(HAVE_EFFICIENT_POSIX_FALLOCATE, 1,
 881                   [Define if posix_fallocate is efficient (Cygwin)])
 882         ;;
 883     *)
 884         AC_MSG_RESULT(no)
 885         ;;
 886     esac
 887 fi
 888
 889 dnl End of preallocation stuff
 890
 891 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 892 if test $ac_cv_func_getpgrp = yes; then
 893     AC_FUNC_GETPGRP
 894 fi
 895
 896 AC_ARG_ENABLE(iconv-open,
 897     AS_HELP_STRING([--disable-iconv-open],[disable all use of iconv_open() function]),
 898     [], [enable_iconv_open=$ac_cv_func_iconv_open])
 899
 900 if test x"$enable_iconv_open" != x"no"; then
 901     AC_DEFINE(USE_ICONV_OPEN, 1, [Define to 1 if you want rsync to make use of iconv_open()])
 902 fi
 903
 904 AC_ARG_ENABLE(iconv,
 905     AS_HELP_STRING([--disable-iconv],[disable rsync's --iconv option]),
 906     [], [enable_iconv=$enable_iconv_open])
 907 AH_TEMPLATE([ICONV_OPTION],
 908 [Define if you want the --iconv option.  Specifying a value will set the
 909 default iconv setting (a NULL means no --iconv processing by default).])
 910 if test x"$enable_iconv" != x"no"; then
 911         if test x"$enable_iconv" = x"yes"; then
 912                 AC_DEFINE(ICONV_OPTION, NULL)
 913         else
 914                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
 915         fi
 916         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
 917 fi
 918
 919 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
 920   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 921 #if HAVE_UNISTD_H
 922 # include <unistd.h>
 923 #endif
 924 #include <stdlib.h>
 925 #include <errno.h>
 926 int main(void) {
 927         char const *dangling_symlink = "conftest.dangle";
 928         unlink(dangling_symlink);
 929         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 930         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) return 1;
 931         return 0;
 932     }]])],[rsync_cv_chown_modifies_symlink=yes],[rsync_cv_chown_modifies_symlink=no],[rsync_cv_chown_modifies_symlink=no])])
 933 if test $rsync_cv_chown_modifies_symlink = yes; then
 934   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 935 fi
 936
 937 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
 938   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 939 #if HAVE_UNISTD_H
 940 # include <unistd.h>
 941 #endif
 942 #include <stdlib.h>
 943 #include <errno.h>
 944 #define FILENAME "conftest.dangle"
 945 int main(void) {
 946         unlink(FILENAME);
 947         if (symlink("conftest.no-such", FILENAME) < 0) abort();
 948         unlink(FILENAME "2");
 949         if (link(FILENAME, FILENAME "2") < 0) return 1;
 950         return 0;
 951     }]])],[rsync_cv_can_hardlink_symlink=yes],[rsync_cv_can_hardlink_symlink=no],[rsync_cv_can_hardlink_symlink=no])])
 952 if test $rsync_cv_can_hardlink_symlink = yes; then
 953   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
 954 fi
 955
 956 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
 957   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 958 #if HAVE_UNISTD_H
 959 # include <unistd.h>
 960 #endif
 961 #ifdef HAVE_SYS_STAT_H
 962 #include <sys/stat.h>
 963 #endif
 964 #include <stdlib.h>
 965 #include <errno.h>
 966 #define FILENAME "conftest.fifi"
 967 int main(void) {
 968         unlink(FILENAME);
 969         if (mkfifo(FILENAME, 0777) < 0) abort();
 970         unlink(FILENAME "2");
 971         if (link(FILENAME, FILENAME "2") < 0) return 1;
 972         return 0;
 973     }]])],[rsync_cv_can_hardlink_special=yes],[rsync_cv_can_hardlink_special=no],[rsync_cv_can_hardlink_special=no])])
 974 if test $rsync_cv_can_hardlink_special = yes; then
 975     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
 976 fi
 977
 978 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 979 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 980 #include <sys/types.h>
 981 #include <sys/socket.h>
 982
 983 int main(void) {
 984        int fd[2];
 985        return (socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1;
 986 }]])],[rsync_cv_HAVE_SOCKETPAIR=yes],[rsync_cv_HAVE_SOCKETPAIR=no],[rsync_cv_HAVE_SOCKETPAIR=cross])])
 987 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 988     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
 989 fi
 990
 991 AC_REPLACE_FUNCS([getpass])
 992
 993 if test x"$with_included_popt" != x"yes"; then
 994     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 995 fi
 996 if test x"$ac_cv_header_popt_popt_h" = x"yes"; then
 997     # If the system has /usr/include/popt/popt.h, we enable the
 998     # included popt because an attempt to "#include <popt/popt.h>"
 999     # would use our included header file anyway (due to -I.), and
1000     # might conflict with the system popt.
1001     with_included_popt=yes
1002 elif test x"$ac_cv_header_popt_h" != x"yes"; then
1003     with_included_popt=yes
1004 fi
1005
1006 AC_MSG_CHECKING([whether to use included libpopt])
1007 if test x"$with_included_popt" = x"yes"; then
1008     AC_MSG_RESULT($srcdir/popt)
1009     BUILD_POPT='$(popt_OBJS)'
1010     CFLAGS="-I$srcdir/popt $CFLAGS"
1011     if test x"$ALLOCA" != x
1012     then
1013         # this can be removed when/if we add an included alloca.c;
1014         #  see autoconf documentation on AC_FUNC_ALLOCA
1015         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
1016     fi
1017 else
1018     AC_MSG_RESULT(no)
1019 fi
1020
1021 # We default to using our zlib unless --with-included-zlib=no is given.
1022 if test x"$with_included_zlib" != x"no"; then
1023     with_included_zlib=yes
1024 elif test x"$ac_cv_header_zlib_h" != x"yes"; then
1025     with_included_zlib=yes
1026 fi
1027 if test x"$with_included_zlib" != x"yes"; then
1028     AC_CHECK_LIB(z, deflateParams, , [with_included_zlib=yes])
1029 fi
1030
1031 AC_MSG_CHECKING([whether to use included zlib])
1032 if test x"$with_included_zlib" = x"yes"; then
1033     AC_MSG_RESULT($srcdir/zlib)
1034     BUILD_ZLIB='$(zlib_OBJS)'
1035     CFLAGS="-I$srcdir/zlib $CFLAGS"
1036 else
1037     AC_DEFINE(EXTERNAL_ZLIB, 1, [Define to 1 if using external zlib])
1038     AC_MSG_RESULT(no)
1039 fi
1040
1041 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
1042 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[signed char *s = ""]])],[rsync_cv_SIGNED_CHAR_OK=yes],[rsync_cv_SIGNED_CHAR_OK=no])])
1043 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
1044     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
1045 fi
1046
1047 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
1048 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <sys/types.h>
1049 #include <dirent.h>
1050 int main(void) { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
1051 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
1052 di->d_name[0] == 0) return 0; return 1;} ]])],[rsync_cv_HAVE_BROKEN_READDIR=yes],[rsync_cv_HAVE_BROKEN_READDIR=no],[rsync_cv_HAVE_BROKEN_READDIR=cross])])
1053 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
1054     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
1055 fi
1056
1057 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
1058 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1059 #include <utime.h>]], [[struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; return utime("foo.c",&tbuf);]])],[rsync_cv_HAVE_STRUCT_UTIMBUF=yes],[rsync_cv_HAVE_STRUCT_UTIMBUF=no])])
1060 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
1061     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
1062 fi
1063
1064 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
1065 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/time.h>
1066 #include <unistd.h>]], [[struct timeval tv; return gettimeofday(&tv, NULL);]])],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=no])])
1067 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
1068     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
1069 fi
1070
1071 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
1072 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1073 #include <sys/types.h>
1074 #include <stdarg.h>
1075 #include <stdio.h>
1076 #include <stdlib.h>
1077 #include <string.h>
1078 void foo(const char *format, ...) {
1079        va_list ap;
1080        int len;
1081        static char buf[] = "12345678901234567890";
1082
1083        va_start(ap, format);
1084        len = vsnprintf(0, 0, format, ap);
1085        va_end(ap);
1086        if (len != 5) exit(1);
1087
1088        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
1089 }
1090 int main(void) { foo("hello"); return 0; }
1091 ]])],[rsync_cv_HAVE_C99_VSNPRINTF=yes],[rsync_cv_HAVE_C99_VSNPRINTF=no],[rsync_cv_HAVE_C99_VSNPRINTF=cross])])
1092 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
1093     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
1094 fi
1095
1096
1097 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
1098 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1099 #include <sys/types.h>
1100 #include <sys/stat.h>
1101 #include <unistd.h>
1102 int main(void) {
1103   struct stat st;
1104   char tpl[20]="/tmp/test.XXXXXX";
1105   int fd = mkstemp(tpl);
1106   if (fd == -1) return 1;
1107   unlink(tpl);
1108   if (fstat(fd, &st) != 0) return 1;
1109   if ((st.st_mode & 0777) != 0600) return 1;
1110   return 0;
1111 }]])],[rsync_cv_HAVE_SECURE_MKSTEMP=yes],[rsync_cv_HAVE_SECURE_MKSTEMP=no],[rsync_cv_HAVE_SECURE_MKSTEMP=cross])])
1112 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
1113     case $host_os in
1114     hpux*)
1115         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
1116         dnl so we noisily skip using it.  See HP change request JAGaf34426
1117         dnl for details. (sbonds)
1118         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
1119         ;;
1120     *)
1121         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
1122         ;;
1123     esac
1124 fi
1125
1126
1127 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
1128 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1129 #include <stdio.h>
1130 #include <sys/stat.h>
1131 #include <errno.h>
1132 #if HAVE_UNISTD_H
1133 # include <unistd.h>
1134 #endif
1135 int main(void) { int rc, ec; char *fn = "fifo-test";
1136 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
1137 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1138 return 0;}]])],[rsync_cv_MKNOD_CREATES_FIFOS=yes],[rsync_cv_MKNOD_CREATES_FIFOS=no],[rsync_cv_MKNOD_CREATES_FIFOS=cross])])
1139 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
1140     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
1141 fi
1142
1143 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
1144 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1145 #include <stdio.h>
1146 #include <sys/stat.h>
1147 #include <errno.h>
1148 #if HAVE_UNISTD_H
1149 # include <unistd.h>
1150 #endif
1151 int main(void) { int rc, ec; char *fn = "sock-test";
1152 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
1153 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1154 return 0;}]])],[rsync_cv_MKNOD_CREATES_SOCKETS=yes],[rsync_cv_MKNOD_CREATES_SOCKETS=no],[rsync_cv_MKNOD_CREATES_SOCKETS=cross])])
1155 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
1156     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
1157 fi
1158
1159 #
1160 # The following test was mostly taken from the tcl/tk plus patches
1161 #
1162 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
1163 rm -rf conftest*
1164 cat > conftest.$ac_ext <<EOF
1165 int main(void) { return 0; }
1166 EOF
1167 ${CC-cc} -c -o conftest..o conftest.$ac_ext
1168 if test -f conftest..o; then
1169     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
1170 else
1171     rsync_cv_DASHC_WORKS_WITH_DASHO=no
1172 fi
1173 rm -rf conftest*
1174 ])
1175 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
1176     OBJ_SAVE="#"
1177     OBJ_RESTORE="#"
1178     CC_SHOBJ_FLAG='-o $@'
1179 else
1180     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
1181     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
1182     CC_SHOBJ_FLAG=""
1183 fi
1184
1185 AC_SUBST(OBJ_SAVE)
1186 AC_SUBST(OBJ_RESTORE)
1187 AC_SUBST(CC_SHOBJ_FLAG)
1188 AC_SUBST(BUILD_POPT)
1189 AC_SUBST(BUILD_ZLIB)
1190 AC_SUBST(MAKE_MAN)
1191
1192 AC_CHECK_FUNCS(_acl __acl _facl __facl)
1193 #################################################
1194 # check for ACL support
1195
1196 AC_MSG_CHECKING([whether to support ACLs])
1197 AC_ARG_ENABLE(acl-support,
1198         AS_HELP_STRING([--disable-acl-support],[disable ACL support]))
1199
1200 if test x"$enable_acl_support" = x"no"; then
1201     AC_MSG_RESULT(no)
1202 else
1203     case "$host_os" in
1204     *sysv5*)
1205         AC_MSG_RESULT(Using UnixWare ACLs)
1206         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
1207         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
1208         ;;
1209     solaris*)
1210         AC_MSG_RESULT(Using solaris ACLs)
1211         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
1212         AC_DEFINE(SUPPORT_ACLS, 1)
1213         ;;
1214     *hpux*)
1215         AC_MSG_RESULT(Using HPUX ACLs)
1216         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
1217         AC_DEFINE(SUPPORT_ACLS, 1)
1218         ;;
1219     *irix*)
1220         AC_MSG_RESULT(Using IRIX ACLs)
1221         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
1222         AC_DEFINE(SUPPORT_ACLS, 1)
1223         ;;
1224     *aix*)
1225         AC_MSG_RESULT(Using AIX ACLs)
1226         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
1227         AC_DEFINE(SUPPORT_ACLS, 1)
1228         ;;
1229     *osf*)
1230         AC_MSG_RESULT(Using Tru64 ACLs)
1231         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
1232         AC_DEFINE(SUPPORT_ACLS, 1)
1233         LIBS="$LIBS -lpacl"
1234         ;;
1235     darwin*)
1236         AC_MSG_RESULT(Using OS X ACLs)
1237         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
1238         AC_DEFINE(SUPPORT_ACLS, 1)
1239         ;;
1240     *)
1241         AC_MSG_RESULT(running tests:)
1242         AC_CHECK_LIB(acl,acl_get_file)
1243         AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
1244             AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1245 #include <sys/acl.h>]], [[ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);]])],[samba_cv_HAVE_POSIX_ACLS=yes],[samba_cv_HAVE_POSIX_ACLS=no])])
1246         AC_MSG_CHECKING(ACL test results)
1247         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
1248             AC_MSG_RESULT(Using posix ACLs)
1249             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
1250             AC_DEFINE(SUPPORT_ACLS, 1)
1251             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
1252                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1253 #include <sys/acl.h>]], [[ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);]])],[samba_cv_HAVE_ACL_GET_PERM_NP=yes],[samba_cv_HAVE_ACL_GET_PERM_NP=no])])
1254             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
1255                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
1256             fi
1257         else
1258             if test x"$enable_acl_support" = x"yes"; then
1259                 AC_MSG_ERROR(Failed to find ACL support)
1260             else
1261                 AC_MSG_RESULT(No ACL support found)
1262             fi
1263         fi
1264         ;;
1265     esac
1266 fi
1267
1268 #################################################
1269 # check for extended attribute support
1270 AC_MSG_CHECKING(whether to support extended attributes)
1271 AC_ARG_ENABLE(xattr-support,
1272     AS_HELP_STRING([--disable-xattr-support],[disable extended attributes]),
1273     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link$ac_cv_func_attropen" in
1274         *yes*) enable_xattr_support=maybe ;;
1275         *) enable_xattr_support=no ;;
1276         esac])
1277 AH_TEMPLATE([SUPPORT_XATTRS],
1278 [Define to 1 to add support for extended attributes])
1279 if test x"$enable_xattr_support" = x"no"; then
1280     AC_MSG_RESULT(no)
1281 else
1282     case "$host_os" in
1283     *linux*|*netbsd*)
1284         AC_MSG_RESULT(Using Linux xattrs)
1285         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs (or equivalent)])
1286         AC_DEFINE(SUPPORT_XATTRS, 1)
1287         AC_DEFINE(NO_SYMLINK_USER_XATTRS, 1, [True if symlinks do not support user xattrs])
1288         AC_CHECK_LIB(attr,getxattr)
1289         ;;
1290     darwin*)
1291         AC_MSG_RESULT(Using OS X xattrs)
1292         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
1293         AC_DEFINE(SUPPORT_XATTRS, 1)
1294         AC_DEFINE(NO_DEVICE_XATTRS, 1, [True if device files do not support xattrs])
1295         AC_DEFINE(NO_SPECIAL_XATTRS, 1, [True if special files do not support xattrs])
1296         ;;
1297     freebsd*)
1298         AC_MSG_RESULT(Using FreeBSD extattrs)
1299         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
1300         AC_DEFINE(SUPPORT_XATTRS, 1)
1301         ;;
1302     solaris*)
1303         AC_MSG_RESULT(Using Solaris xattrs)
1304         AC_DEFINE(HAVE_SOLARIS_XATTRS, 1, [True if you have Solaris xattrs])
1305         AC_DEFINE(SUPPORT_XATTRS, 1)
1306         AC_DEFINE(NO_SYMLINK_XATTRS, 1, [True if symlinks do not support xattrs])
1307         ;;
1308     *)
1309         if test x"$enable_xattr_support" = x"yes"; then
1310             AC_MSG_ERROR(Failed to find extended attribute support)
1311         else
1312             AC_MSG_RESULT(No extended attribute support found)
1313         fi
1314         ;;
1315     esac
1316 fi
1317
1318 if test x"$enable_acl_support" = x"no" -o x"$enable_xattr_support" = x"no" -o x"$enable_iconv" = x"no"; then
1319     AC_MSG_CHECKING([whether $CC supports -Wno-unused-parameter])
1320     OLD_CFLAGS="$CFLAGS"
1321     CFLAGS="$CFLAGS -Wno-unused-parameter"
1322     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]], [[printf("hello\n");]])],[rsync_warn_flag=yes],[rsync_warn_flag=no])
1323     AC_MSG_RESULT([$rsync_warn_flag])
1324     if test x"$rsync_warn_flag" = x"no"; then
1325         CFLAGS="$OLD_CFLAGS"
1326     fi
1327 fi
1328
1329 case "$CC" in
1330 ' checker'*|checker*)
1331     AC_DEFINE(FORCE_FD_ZERO_MEMSET, 1, [Used to make "checker" understand that FD_ZERO() clears memory.])
1332     ;;
1333 esac
1334
1335 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
1336 AC_OUTPUT
1337
1338 AC_MSG_RESULT()
1339 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
1340 AC_MSG_RESULT()