configure.ac

   1 # $Id$
   2 #
   3
   4 m4_define([version_major], [1])
   5 m4_define([version_minor], [11])
   6 m4_define([version_micro], [0])
   7 m4_define([version_micro_extra], version_micro)
   8 m4_append([version_micro_extra], [])
   9
  10 AC_INIT(wireshark, [version_major.version_minor.version_micro_extra], http://bugs.wireshark.org/, , http://www.wireshark.org/)
  11
  12 # Minimum autoconf version we require.
  13 AC_PREREQ(2.60)
  14 # Variable expansion doesn't work in AC_PREREQ()
  15 AC_MIN_VERSION=2.60
  16 AC_SUBST(AC_MIN_VERSION)
  17
  18 dnl Check for CPU / vendor / OS
  19 dnl The user is encouraged to use either `AC_CANONICAL_BUILD', or
  20 dnl `AC_CANONICAL_HOST', or `AC_CANONICAL_TARGET', depending on the
  21 dnl needs.  Using `AC_CANONICAL_TARGET' is enough to run the two other
  22 dnl macros.
  23 dnl
  24 dnl As nothing in the Wireshark is itself a build tool (we are not,
  25 dnl for example, a compiler that generates machine code), we probably
  26 dnl don't need AC_CANONICAL_TARGET, so, in theory, we should be able
  27 dnl to use AC_CANONICAL_BUILD and AC_CANONICAL_HOST - or perhaps just
  28 dnl AC_CANONICAL_HOST - instead.  Note that we do have tools, such as
  29 dnl lemon, that need to be built for the build machine, not for the
  30 dnl host machine, so we might need both.
  31 dnl
  32 dnl This has to be done *after* AC_INIT, otherwise autogen.sh fails.
  33
  34 dnl AC_CANONICAL_BUILD
  35 dnl AC_CANONICAL_HOST
  36 AC_CANONICAL_TARGET
  37
  38 AM_INIT_AUTOMAKE([1.9 tar-ustar dist-bzip2 no-dist-gzip])
  39
  40 # Make Wireshark's version available in config.h
  41 AC_DEFINE(VERSION_MAJOR, version_major, [Wireshark's major version])
  42 AC_DEFINE(VERSION_MINOR, version_minor, [Wireshark's minor version])
  43 AC_DEFINE(VERSION_MICRO, version_micro, [Wireshark's micro version])
  44
  45 AM_DISABLE_STATIC
  46
  47 #
  48 # Checks for programs used in the main build process.
  49 #
  50 AC_PROG_CC
  51 AM_PROG_CC_C_O
  52 AC_PROG_CXX
  53 AC_PROG_CPP
  54 dnl Work around libtool bug (fixed in the version 1.5a?)
  55 AC_DEFUN([AC_PROVIDE_AC_LIBTOOL_DLOPEN], )
  56 AC_LIBTOOL_DLOPEN
  57 AC_PROG_LIBTOOL
  58 AC_PATH_PROG(PERL, perl)
  59
  60 # Check for Python.
  61 AC_PATH_PROG(PYTHON, python)
  62 if test ! -z "$PYTHON"; then
  63         #
  64         # OK, we found Python; is it Python 2.x?
  65         # Note: we don't use named components for sys.version_info to get
  66         # the major version number, as named components for version_info
  67         # were apparently introduced in Python 2.7.
  68         #
  69         AC_MSG_CHECKING([whether $PYTHON is Python 2])
  70         python_major_version=`$PYTHON -c 'import sys; print sys.version_info[[0]]'`
  71         if test "$python_major_version" = 2; then
  72                 AC_MSG_RESULT([yes])
  73         else
  74                 #
  75                 # It's not 2.x.
  76                 #
  77                 AC_MSG_RESULT([no])
  78
  79                 #
  80                 # Try looking for python2; if we find it, we assume it's
  81                 # Python 2
  82                 #
  83                 AC_PATH_PROG(PYTHON, python2)
  84         fi
  85 fi
  86
  87 #
  88 # XXX - should autogen.sh check for YACC/Bison and Flex?  A user building
  89 # from a distribution tarball shouldn't have to have YACC/Bison or Flex,
  90 # as the tarball should contain the results of running YACC/Bison on .y
  91 # files and running Flex on .l files, but a user building from SVN
  92 # will have to run YACC/Bison and Flex to process those files.
  93 #
  94 # On the other hand, what about users who use a distribution tarball to
  95 # do development?  They *shouldn't* - that's what the SVN repository is
  96 # for - but they might.  They'd get errors if they modify a .y or .l
  97 # file and try to do a build - but the error should tell them that they
  98 # need to get YACC/Bison and/or Flex.
  99 #
 100 # Then again, getting them shouldn't be too big of a burden.
 101 #
 102 # XXX - is the same true of pod2man and pod2html, or are they needed
 103 # even when building from a distribution tarball?
 104 #
 105 #
 106 AC_PROG_YACC
 107 AC_PATH_PROG(YACCDUMMY, $YACC)
 108 if test "x$YACCDUMMY" = x
 109 then
 110         AC_MSG_ERROR(I couldn't find yacc (or bison or ...); make sure it's installed and in your path)
 111 fi
 112 AM_PROG_LEX
 113 AC_PATH_PROG(LEX, flex)
 114 if test "x$LEX" = x
 115 then
 116         AC_MSG_ERROR(I couldn't find flex; make sure it's installed and in your path)
 117 fi
 118 AC_PATH_PROG(POD2MAN, pod2man)
 119 if test "x$POD2MAN" = x
 120 then
 121         #
 122         # The alternative is not to build the man pages....
 123         #
 124         AC_MSG_ERROR(I couldn't find pod2man; make sure it's installed and in your path)
 125 fi
 126 AC_PATH_PROG(POD2HTML, pod2html)
 127 if test "x$POD2HTML" = x
 128 then
 129         #
 130         # The alternative is not to build the HTML man pages....
 131         #
 132         AC_MSG_ERROR(I couldn't find pod2html; make sure it's installed and in your path)
 133 fi
 134
 135 #
 136 # Checks for programs used by Wireshark/TShark/etc.
 137 #
 138
 139 #
 140 # XXX - this looks for various HTML viewers on the host, not the target;
 141 # we really want to know what's available on the target, for cross-builds.
 142 # That would probably require us to, at run time, look for xdg-open and,
 143 # if we don't find it, look for mozilla, htmlview, etc.
 144 #
 145 AC_PATH_PROG(HTML_VIEWER, xdg-open)
 146 if test "x$HTML_VIEWER" != x
 147 then
 148         #
 149         # XXX - the HTML_VIEWER shell variable is the full path of xdg-open.
 150         # Define some variable to be that, so we just run that?
 151         #
 152         AC_DEFINE(HAVE_XDG_OPEN, 1, [Define if we have xdg-open])
 153
 154         #
 155         # XXX - we have to define HTML_VIEWER for the prefs.c code that
 156         # sets the default value of the Web browser preference, even
 157         # though that preference won't be offered.
 158         #
 159         AC_DEFINE_UNQUOTED(HTML_VIEWER, "xdg-open", [HTML viewer, e.g. mozilla])
 160 else
 161         AC_PATH_PROG(HTML_VIEWER, htmlview)
 162         if test "x$HTML_VIEWER" = x
 163         then
 164                 AC_DEFINE_UNQUOTED(HTML_VIEWER, "mozilla", [HTML viewer, e.g. mozilla])
 165         else
 166                 AC_DEFINE_UNQUOTED(HTML_VIEWER, "htmlview", [HTML viewer, e.g. mozilla])
 167         fi
 168 fi
 169
 170 #
 171 # Set "ac_supports_gcc_flags" if the compiler is known to support GCC-style
 172 # flags such as -pedantic, -W warning flags and -f feature flags.  Currently,
 173 # we assume GCC and clang do; other compilers should be added here.
 174 #
 175 # This is done to avoid getting tripped up by compilers that support
 176 # those flags but give them a different meaning.
 177 #
 178 if test "x$GCC" = "xyes" -o "x$CC" = "xclang" ; then
 179         ac_supports_gcc_flags=yes
 180 fi
 181
 182 #
 183 # Set "ac_supports_W_linker_passthrough" if the compiler is known to
 184 # support "-Wl,{options}" to pass options through to the linker.
 185 # Currently, we assume GCC, xlc, and clang do; other compilers should
 186 # be added here.
 187 #
 188 if test "x$GCC" = "xyes" -o "x$CC" = "xxlc" -o "x$CC" = "xclang" ; then
 189         ac_supports_W_linker_passthrough=yes
 190 fi
 191
 192 #
 193 # Set "ac_supports_attribute_unused" if the compiler is known to
 194 # support "__attribute__(unused)".
 195 # Currently, we assume GCC and clang do; other compilers should
 196 # be added here.
 197 #
 198 # XXX - do this with a compiler test?
 199 #
 200 if test "x$GCC" = "xyes" -o "x$CC" = "xclang" ; then
 201         ac_supports_W_linker_passthrough=yes
 202 fi
 203
 204 if test "x$CC_FOR_BUILD" = x
 205 then
 206        CC_FOR_BUILD=$CC
 207 fi
 208 AC_SUBST(CC_FOR_BUILD)
 209 AC_SUBST(CFLAGS_FOR_BUILD)
 210
 211 # Check for doxygen
 212 AC_PATH_PROG(DOXYGEN, doxygen)
 213 AC_CHECK_PROG(HAVE_DOXYGEN, doxygen, "yes", "no")
 214 AM_CONDITIONAL(HAVE_DOXYGEN, test x$HAVE_DOXYGEN = xyes)
 215
 216 #
 217 # Check for pkg-config and set PKG_CONFIG accordingly.
 218 #
 219 # This is referenced via AC_REQUIRE([PKG_PROG_PKG_CONFIG] in some macros
 220 # like PKG_CHECK_MODULES. If the first call to such a macro is under an
 221 # "if" statement, it's safer to call PKG_PROG_PKG_CONFIG directly, see
 222 # the comments in acolocal.m4
 223 #
 224 PKG_PROG_PKG_CONFIG
 225
 226 #
 227 # Try to arrange for large file support.
 228 #
 229 AC_SYS_LARGEFILE
 230
 231 #
 232 # GUI toolkit options
 233 #
 234 AC_ARG_WITH([qt],
 235   AC_HELP_STRING( [--with-qt=@<:@yes/no@:>@],
 236                   [use Qt @<:@default=no@:>@]),
 237   with_qt="$withval", with_qt="no")
 238
 239 AC_ARG_WITH([gtk2],
 240   AC_HELP_STRING( [--with-gtk2=@<:@yes/no@:>@],
 241                   [use GTK+ 2.0 @<:@default=yes@:>@]),
 242   with_gtk2="$withval", with_gtk2="yes")
 243
 244 AC_ARG_WITH([gtk3],
 245   AC_HELP_STRING( [--with-gtk3=@<:@yes/no@:>@],
 246                   [use GTK+ 3.0 instead of 2.0 @<:@default=no@:>@]),
 247   with_gtk3="$withval", with_gtk3="no")
 248
 249 # GnuTLS
 250 # Version 3.0 switched from LGPLv2.1+ to LGPLv3+, then switched back to
 251 # LGPLv2.1+ in version 3.1.10
 252 tls_message="no"
 253 AC_ARG_WITH([gnutls],
 254   AC_HELP_STRING( [--with-gnutls=@<:@yes/no@:>@],
 255                   [use GnuTLS library @<:@default=yes@:>@]),
 256   with_gnutls="$withval", with_gnutls="yes")
 257 if test "x$with_gnutls" = "xyes"; then
 258   have_license_compatible_gnutls="no"
 259   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 3.1.10 ],
 260     [ have_license_compatible_gnutls="yes" ], [ echo "GnuTLS >= 3.1.10 not found " ]
 261   )
 262
 263   if test "x$have_license_compatible_gnutls" != "xyes"; then
 264     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 1.2.0 gnutls < 3],
 265       [ have_license_compatible_gnutls="yes" ] , [ echo "GnuTLS >= 1.2.0, < 3.0 not found " ]
 266     )
 267   fi
 268
 269   if test "x$have_license_compatible_gnutls" = "xyes"; then
 270     echo "GnuTLS found, enabling SSL decryption"
 271     AC_DEFINE(HAVE_LIBGNUTLS, 1, [Define to use GnuTLS library])
 272     tls_message="yes"
 273   else
 274     echo "GnuTLS with compatible license not found, disabling SSL decryption"
 275     tls_message="no"
 276   fi
 277 fi
 278
 279 # libgrypt
 280 gcrypt_message="no"
 281 AC_ARG_WITH([gcrypt],
 282   AC_HELP_STRING( [--with-gcrypt=@<:@yes/no@:>@],
 283                   [use gcrypt library @<:@default=yes@:>@]),
 284   with_gcrypt="$withval", with_gcrypt="yes")
 285 if test "x$with_gcrypt" = "xyes"; then
 286   AM_PATH_LIBGCRYPT(1.1.92,
 287         [
 288                 echo "libgcrypt found, enabling ipsec decryption"
 289                 AC_DEFINE(HAVE_LIBGCRYPT, 1, [Define to use libgcrypt])
 290                 gcrypt_message="yes"
 291         ]
 292         , [
 293                 if test x$libgcrypt_config_prefix != x ; then
 294                         AC_MSG_ERROR([[libgcrypt not found; install libgcrypt-devel package for your system]])
 295                 else
 296                         echo "libgcrypt not found, disabling ipsec decryption"
 297                         gcrypt_message="no"
 298                 fi
 299         ]
 300   )
 301 fi
 302
 303 AC_ARG_WITH(libnl,
 304   AC_HELP_STRING([--with-libnl@<:@=VERSION@:>@],
 305                  [use libnl (force version VERSION, if supplied) @<:@default: yes, if available@:>@]),
 306 [
 307         if test "x$withval" = "xno"
 308         then
 309                 want_libnl=no
 310         elif test "x$withval" = "xyes"
 311         then
 312                 want_libnl=yes
 313                 libnl_version=any
 314         elif test "x$withval" = "x1"
 315         then
 316                 want_libnl=yes
 317                 libnl_version=1
 318         elif test "x$withval" = "x2"
 319         then
 320                 want_libnl=yes
 321                 libnl_version=2
 322         elif test "x$withval" = "x3"
 323         then
 324                 want_libnl=yes
 325                 libnl_version=3
 326         else
 327                 AC_MSG_ERROR(["$withval" is not a valid argument to --with-libnl])
 328         fi
 329 ],[
 330         #
 331         # Use libnl if it's present, otherwise don't.
 332         #
 333         want_libnl=ifavailable
 334         libnl_version=any
 335 ])
 336 #
 337 # Libnl is Linux-specific.
 338 #
 339 libnl_message="no"
 340 case "$host_os" in
 341 linux*)
 342         AC_MSG_CHECKING(whether to use libnl for various network interface purposes)
 343
 344         if test x$want_libnl = "xno"; then
 345                 AC_MSG_RESULT(no)
 346         else
 347                 AC_MSG_RESULT(yes)
 348                 #
 349                 # Test for specific libnl versions only if no version
 350                 # was specified by the user or if the version in question
 351                 # was requested by the user.
 352                 #
 353                 if test x$libnl_version = "xany" -o x$libnl_version = "x3"; then
 354                         PKG_CHECK_MODULES(LIBNL3, [libnl-route-3.0 >= 3.0 libnl-genl-3.0] >= 3.0, [have_libnl3=yes], [have_libnl3=no])
 355                 fi
 356                 if test x$libnl_version = "xany" -o x$libnl_version = "x2"; then
 357                         PKG_CHECK_MODULES(LIBNL2, libnl-2.0 >= 2.0, [have_libnl2=yes], [have_libnl2=no])
 358                 fi
 359                 if test x$libnl_version = "xany" -o x$libnl_version = "x1"; then
 360                         PKG_CHECK_MODULES(LIBNL1, libnl-1 >= 1.0, [have_libnl1=yes], [have_libnl1=no])
 361                 fi
 362                 if (test "${have_libnl3}" = "yes"); then
 363                         CFLAGS="$CFLAGS $LIBNL3_CFLAGS"
 364                         LIBS="$LIBS $LIBNL3_LIBS"
 365                         AC_DEFINE(HAVE_LIBNL, 1, [Enable libnl support])
 366                         AC_DEFINE(HAVE_LIBNL3, 1, [libnl version 3])
 367                         libnl_message="yes (v3)"
 368                         enable_airpcap=no
 369                 elif (test "${have_libnl2}" = "yes"); then
 370                         CFLAGS="$CFLAGS $LIBNL2_CFLAGS"
 371                         LIBS="$LIBS $LIBNL2_LIBS"
 372                         AC_DEFINE(HAVE_LIBNL, 1, [Enable libnl support])
 373                         AC_DEFINE(HAVE_LIBNL2, 1, [libnl version 2])
 374                         libnl_message="yes (v2)"
 375                         enable_airpcap=no
 376                 elif (test "${have_libnl1}" = "yes"); then
 377                         CFLAGS="$CFLAGS $LIBNL1_CFLAGS"
 378                         LIBS="$LIBS $LIBNL1_LIBS"
 379                         AC_DEFINE(HAVE_LIBNL, 1, [Enable libnl support])
 380                         AC_DEFINE(HAVE_LIBNL1, 1, [libnl version 1])
 381                         libnl_message="yes (v1)"
 382                         enable_airpcap=no
 383                 else
 384                         if test x$want_libnl = "xyes"; then
 385                                 case "$libnl_version" in
 386
 387                                 any)
 388                                         AC_MSG_ERROR("I couldn't find libnl even though you manually enabled it.")
 389                                         ;;
 390
 391                                 *)
 392                                         AC_MSG_ERROR("I couldn't find libnl version $libnl_version even though you manually enabled it.")
 393                                         ;;
 394                                 esac
 395                         fi
 396                 fi
 397         fi
 398
 399         AC_MSG_CHECKING([if nl80211.h is new enough])
 400           AC_TRY_COMPILE([#include <linux/nl80211.h>],
 401             [int x = NL80211_FREQUENCY_ATTR_MAX_TX_POWER;
 402                 x = NL80211_ATTR_SUPPORTED_IFTYPES;
 403                 x = NL80211_ATTR_SUPPORTED_COMMANDS;
 404                 x = NL80211_ATTR_WIPHY_FREQ;
 405                 x = NL80211_CHAN_NO_HT;],
 406             [AC_MSG_RESULT(yes) AC_DEFINE(HAVE_NL80211, 1, [nl80211.h is new enough])],
 407             [AC_MSG_RESULT(no)])
 408
 409         AC_MSG_CHECKING([for NL80211_SET_CHANNEL])
 410           AC_TRY_COMPILE([#include <linux/nl80211.h>],
 411             [enum nl80211_commands x = NL80211_CMD_SET_CHANNEL;],
 412             [AC_MSG_RESULT(yes) AC_DEFINE(HAVE_NL80211_CMD_SET_CHANNEL, 1, [SET_CHANNEL is supported])],
 413             [AC_MSG_RESULT(no)])
 414         ;;
 415
 416 *)
 417         if test x$want_libnl != "xno" -a x$want_libnl != "xifavailable"; then
 418                 AC_MSG_WARN([libnl is Linux-specific, ignoring --with-libnl])
 419         fi
 420 esac
 421
 422 # libsmi
 423 # FIXME: currently the path argument to with-libsmi is being ignored
 424 AX_LIBSMI
 425
 426 #
 427 # Check for programs used when building DocBook documentation.
 428 #
 429
 430 # Check for a2x (convert asciidoc to another format)
 431 AC_PATH_PROG(A2X, a2x)
 432 AC_CHECK_PROG(HAVE_A2X, a2x, "yes", "no")
 433 AM_CONDITIONAL(HAVE_A2X, test x$HAVE_A2X = xyes)
 434
 435 # Want to control a tape drive? Use mt. Want to convert HTML to text?
 436 # Uhhhhh... elinks? lynx? w3m? pandoc? html2text?
 437 AC_PATH_PROG(ELINKS, elinks)
 438 AC_CHECK_PROG(HAVE_ELINKS, elinks, "yes", "no")
 439 AM_CONDITIONAL(HAVE_ELINKS, test x$HAVE_ELINKS = xyes)
 440
 441 # Check for fop (translate .fo to e.g. pdf)
 442 AC_PATH_PROG(FOP, fop)
 443 AC_CHECK_PROG(HAVE_FOP, fop, "yes", "no")
 444 AM_CONDITIONAL(HAVE_FOP, test x$HAVE_FOP = xyes)
 445
 446 # Check for lynx (html -> text)
 447 AC_PATH_PROG(LYNX, lynx)
 448 AC_CHECK_PROG(HAVE_LYNX, lynx, "yes", "no")
 449 AM_CONDITIONAL(HAVE_LYNX, test x$HAVE_LYNX = xyes)
 450
 451 # Check for w3m (html -> text)
 452 AC_PATH_PROG(W3M, w3m)
 453 AC_CHECK_PROG(HAVE_W3M, w3m, "yes", "no")
 454 AM_CONDITIONAL(HAVE_W3M, test x$HAVE_W3M = xyes)
 455
 456 # Check for xmllint
 457 AC_PATH_PROG(XMLLINT, xmllint)
 458 AC_CHECK_PROG(HAVE_XMLLINT, xmllint, "yes", "no")
 459 AM_CONDITIONAL(HAVE_XMLLINT, test x$HAVE_XMLLINT = xyes)
 460
 461 # Check for xsltproc
 462 AC_PATH_PROG(XSLTPROC, xsltproc)
 463 AC_CHECK_PROG(HAVE_XSLTPROC, xsltproc, "yes", "no")
 464 AM_CONDITIONAL(HAVE_XSLTPROC, test x$HAVE_XSLTPROC = xyes)
 465
 466
 467 # Check for packaging utilities
 468 # For now, we check to see if the various packaging utilites are in our
 469 # path.  I'm too lazy to write code to go hunt for them.  -  Gerald
 470
 471 #
 472 # Source packages.
 473 # (Lets you install the desktop files.)
 474 #
 475 AC_PATH_PROG(DESKTOP_FILE_INSTALL, desktop-file-install)
 476
 477 # SVR4/Solaris
 478 AC_CHECK_PROG(HAVE_PKGPROTO, pkgproto, "yes", "no")
 479 AC_CHECK_PROG(HAVE_PKGMK, pkgmk, "yes", "no")
 480 AC_CHECK_PROG(HAVE_PKGTRANS, pkgtrans, "yes", "no")
 481
 482 if test x$HAVE_PKGPROTO = xyes -a x$HAVE_PKGMK = xyes \
 483      -a x$HAVE_PKGTRANS = xyes ; then
 484   HAVE_SVR4_PACKAGING=yes
 485 else
 486   HAVE_SVR4_PACKAGING=no
 487 fi
 488 AC_SUBST(HAVE_SVR4_PACKAGING)
 489
 490 # RPM
 491 AC_WIRESHARK_RPM_CHECK
 492 AC_SUBST(HAVE_RPM)
 493
 494 # Debian
 495 AC_CHECK_PROG(HAVE_DPKG_BUILDPACKAGE, dpkg-buildpackage, "yes", "no")
 496
 497 # Mac OS X
 498 AC_CHECK_PROG(HAVE_XCODEBUILD, xcodebuild, "yes", "no")
 499 AC_CHECK_PROG(HAVE_HDIUTIL, hdiutil, "yes", "no")
 500 AC_CHECK_PROG(HAVE_BLESS, bless, "yes", "no")
 501
 502 if test x$HAVE_XCODEBUILD = xyes -a x$HAVE_HDIUTIL = xyes \
 503      -a x$HAVE_BLESS = xyes ; then
 504   HAVE_OSX_PACKAGING=yes
 505 else
 506   HAVE_OSX_PACKAGING=no
 507 fi
 508 AC_SUBST(HAVE_OSX_PACKAGING)
 509
 510 #
 511 # Try to add some additional gcc checks to CFLAGS
 512 #
 513 AC_ARG_ENABLE(extra-gcc-checks,
 514   AC_HELP_STRING( [--enable-extra-gcc-checks],
 515                   [do additional -W checks in GCC @<:@default=no@:>@]),
 516 [
 517         wireshark_extra_gcc_flags=$enableval
 518         if test $enableval != no
 519         then
 520                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-pedantic)
 521                 #
 522                 # Various code blocks this one.
 523                 #
 524                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Woverflow)
 525                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-fstrict-overflow -Wstrict-overflow=4)
 526                 #
 527                 # Some memset() calls to clear out structures
 528                 # on the stack are getting flagged as "will never
 529                 # be executed" by this, at least by Apple's
 530                 # i686-apple-darwin11-llvm-gcc-4.2 (GCC) 4.2.1 (Based on
 531                 # Apple Inc. build 5658) (LLVM build 2336.11.00), for
 532                 # some unknown reason.
 533                 #
 534                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wunreachable-code)
 535                 #
 536                 # Due to various places where APIs we don't control
 537                 # require us to cast away constness, we can probably
 538                 # never enable these ones with -Werror.
 539                 #
 540                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wcast-qual)
 541                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wbad-function-cast, C)
 542                 #
 543                 # Some generated ASN.1 dissectors block this one;
 544                 # multiple function declarations for the same
 545                 # function are being generated.
 546                 #
 547                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wredundant-decls)
 548                 #
 549                 # Some loops are safe, but it's hard to convince the
 550                 # compiler of that.
 551                 #
 552                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wunsafe-loop-optimizations)
 553                 #
 554                 # All the registration functions block these for now.
 555                 #
 556                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wmissing-prototypes)
 557                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wmissing-declarations)
 558         fi
 559 ],)
 560 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wall -W) # -W is now known as -Wextra
 561 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wextra) # -W is now known as -Wextra
 562 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wdeclaration-after-statement, C)
 563 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wendif-labels)
 564 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wpointer-arith)
 565 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wno-pointer-sign, C)
 566 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Warray-bounds)
 567 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wcast-align)
 568 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wformat-security)
 569 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wold-style-definition, C)
 570 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wshorten-64-to-32)
 571 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wstrict-prototypes, C)
 572 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wjump-misses-init, C)
 573 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wvla)
 574 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Waddress)
 575 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Warray-bounds)
 576 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wattributes)
 577 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wdiv-by-zero)
 578 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wignored-qualifiers)
 579 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wpragmas)
 580 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wno-overlength-strings)
 581 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wwrite-strings)
 582 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wno-long-long)
 583 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wc++-compat, C)
 584
 585 #
 586 # XXX - OK for C++?
 587 #
 588 # Make sure -Wshadow doesn't complain about variables in function and
 589 # function pointer declarations shadowing other variables; if not, don't
 590 # turn it on, as some versions of GCC (including the one in at least
 591 # some Xcode versions that came with Mac OS X 10.5) complain about
 592 # that.
 593 #
 594 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wshadow, C,
 595   [
 596 extern int bar(int a);
 597 extern int foo(int);
 598
 599 int
 600 foo(int a)
 601 {
 602         int (*fptr)(int a) = bar;
 603
 604         return fptr(a) * 2;
 605 }
 606   ],
 607   [warns about variables in function declarations shadowing other variables])
 608
 609 # Unfortunately some versions of gcc generate logical-op warnings when strchr()
 610 # is given a constant string.
 611 # gcc versions 4.3.2 and 4.4.5 are known to have the problem.
 612 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wlogical-op, C,
 613   [
 614 #include <string.h>
 615
 616 int foo(const char *, int);
 617 int bar(void);
 618
 619 int
 620 foo(const char *sep, int c)
 621 {
 622         if (strchr (sep, c) != NULL)
 623                 return 1;
 624         else
 625                 return 0;
 626 }
 627
 628 int
 629 bar(void)
 630 {
 631         return foo("<", 'a');
 632 }
 633   ],
 634   [generates warnings from strchr()])
 635
 636
 637 ## AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wno-error=unused-but-set-variable)
 638
 639 #
 640 # Use the faster pre gcc 4.5 floating point precision if available;
 641 # clang doesn't error out on -f options that it doesn't know about,
 642 # it just warns and ignores them, so this check doesn't cause us
 643 # to omit -fexcess-precision=fast, which produces a pile of
 644 # annoying warnings.
 645 #
 646 if test "x$CC" != "xclang" ; then
 647   AC_WIRESHARK_GCC_CFLAGS_CHECK(-fexcess-precision=fast)
 648 fi
 649
 650 CFLAGS_before_fvhidden=$CFLAGS
 651 AC_WIRESHARK_GCC_CFLAGS_CHECK(-fvisibility=hidden)
 652 if test "x$CLFAGS" = "x$CFLAGS_before_fvhidden"
 653 then
 654         # TODO add other ways of hiding symbols
 655         AC_MSG_WARN(Compiler will export all symbols from shared libraries)
 656 fi
 657
 658 AC_WIRESHARK_LDFLAGS_CHECK([-Wl,--as-needed])
 659 ###AC_WIRESHARK_LDFLAGS_CHECK([-Wl,-M])
 660 ###AC_WIRESHARK_LDFLAGS_CHECK([-Wl,--cref])
 661 # AC_WIRESHARK_LDFLAGS_CHECK([-flto])
 662 # AC_WIRESHARK_LDFLAGS_CHECK([-fwhopr])
 663 # AC_WIRESHARK_LDFLAGS_CHECK([-fwhole-program])
 664
 665 #
 666 # Put -fPIE in PIE_CFLAGS and -pie in PIE_LDFLAGS if we can use them,
 667 # so that we can build dumpcap PIE - it may run with elevated
 668 # privileges, and using PIE means the OS can run it at random locations
 669 # in the address space to make attacks more difficult.
 670 #
 671 CFLAGS_before_pie=$CFLAGS
 672 AC_WIRESHARK_GCC_CFLAGS_CHECK(-fPIE, C)
 673 if test "x$CLFAGS" != "x$CFLAGS_before_pie"
 674 then
 675         # Restore CFLAGS
 676         CFLAGS=$CFLAGS_before_pie
 677
 678         LDFLAGS_before_pie=$LDFLAGS
 679         AC_WIRESHARK_LDFLAGS_CHECK([-fPIE -pie])
 680         if test "x$LDFLAGS" != "x$LDFLAGS_before_pie"
 681         then
 682                 # We can use PIE
 683                 PIE_CFLAGS="-fPIE"
 684                 PIE_LDFLAGS="-pie"
 685
 686                 # Restore LDFLAGS
 687                 LDFLAGS=$LDFLAGS_before_pie
 688         fi
 689
 690 fi
 691 AC_SUBST(PIE_CFLAGS)
 692 AC_SUBST(PIE_LDFLAGS)
 693
 694 #
 695 # If we're running GCC or clang define _U_ to be "__attribute__((unused))"
 696 # so we can use _U_ to flag unused function parameters and not get warnings
 697 # about them. Otherwise, define _U_ to be an empty string so that _U_ used
 698 # to flag an unused function parameters will compile with other compilers.
 699 #
 700 # XXX - similar hints for other compilers?
 701 #
 702 if test "x$GCC" = "xyes" -o "x$CC" = "xclang" ; then
 703   AC_DEFINE(_U_, __attribute__((unused)), [Hint to the compiler that a function parameters is not used])
 704 else
 705   AC_DEFINE(_U_, , [Hint to the compiler that a function parameters is not used])
 706 fi
 707
 708 # If we're running GCC or CLang, use FORTIFY_SOURCE=2
 709 #  (only if the GCC 'optimization level' > 0).
 710 #
 711 # See: http://gcc.gnu.org/ml/gcc-patches/2004-09/msg02055.html
 712 # See: http://sourceware.org/bugzilla/show_bug.cgi?id=13979
 713 #
 714 # Note: FORTIFY_SOURCE is only effective for gcc optimization level > 0 (-O1, etc)
 715 AC_WIRESHARK_GCC_FORTIFY_SOURCE_CHECK
 716
 717 #
 718 # If the compiler supports GCC-style flags, enable a barrier "stop on
 719 # warning".
 720 # This barrier is set for a very large part of the code. However, it is
 721 # typically not set for "generated" code  (flex, ans2wrs, idl2wrs, ...)
 722 #
 723 warnings_as_errors_default="yes"
 724 AC_MSG_CHECKING(whether we should treat compiler warnings as errors)
 725 AC_ARG_ENABLE(warnings-as-errors,
 726   AC_HELP_STRING( [--enable-warnings-as-errors],
 727                   [treat warnings as errors (only for GCC or clang) @<:@default=yes, unless extra warnings are enabled@:>@]),
 728 [
 729   if test "x$ac_supports_gcc_flags" = "xyes" -a "x$enableval" = "xyes"; then
 730     with_warnings_as_errors="yes"
 731     AC_MSG_RESULT(yes)
 732   else
 733     with_warnings_as_errors="no"
 734     AC_MSG_RESULT(no)
 735   fi
 736 ],
 737 [
 738   if test "x$ac_supports_gcc_flags" = "xyes" -a "x$wireshark_extra_gcc_flags" = "x" -a "x$warnings_as_errors_default" = "xyes"; then
 739     with_warnings_as_errors="yes"
 740     AC_MSG_RESULT(yes)
 741   else
 742     with_warnings_as_errors="no"
 743     AC_MSG_RESULT(no)
 744   fi
 745 ]
 746 )
 747 AM_CONDITIONAL(HAVE_WARNINGS_AS_ERRORS, test "x$with_warnings_as_errors" = "xyes")
 748
 749 #
 750 # Add any platform-specific compiler flags needed.
 751 #
 752 AC_MSG_CHECKING(for platform-specific compiler flags)
 753 if test "x$GCC" = "xyes" ; then
 754         #
 755         # GCC - do any platform-specific tweaking necessary.
 756         #
 757         case "$host_os" in
 758         solaris*)
 759                 # the X11 headers don't automatically include prototype info
 760                 # and a lot don't include the return type
 761                 CPPFLAGS="$CPPFLAGS -DFUNCPROTO=15"
 762                 CFLAGS="$CFLAGS -Wno-return-type"
 763                 CXXFLAGS="$CXXFLAGS -Wno-return-type"
 764                 AC_MSG_RESULT(GCC on Solaris - added -Wno-return-type -DFUNCPROTO=15)
 765                 ;;
 766         *)
 767                 AC_MSG_RESULT(none needed)
 768                 ;;
 769         esac
 770 else
 771         #
 772         # Not GCC - assume it's the vendor's compiler.
 773         #
 774         case "$host_os" in
 775         hpux*)
 776                 #
 777                 # HP's ANSI C compiler; flags suggested by Jost Martin.
 778                 # "-Ae" for ANSI C plus extensions such as "long long".
 779                 # "+O2", for optimization.  XXX - works with "-g"?
 780                 #
 781                 # HP's ANSI C++ compiler doesn't support "-Ae", but
 782                 # does support "+O2", at least according to the
 783                 # documentation I can find online.
 784                 #
 785                 CFLAGS="-Ae +O2 $CFLAGS"
 786                 CFLAGS_FOR_BUILD="-Ae +O2 $CFLAGS"
 787                 CXXFLAGS="+O2 $CFLAGS"
 788                 AC_MSG_RESULT(HP ANSI C compiler - added -Ae +O2)
 789                 ;;
 790         *)
 791                 AC_MSG_RESULT(none needed)
 792                 ;;
 793         esac
 794 fi
 795
 796 #
 797 # Add any platform-specific linker flags needed.
 798 #
 799 AC_MSG_CHECKING(for platform-specific linker flags)
 800 case "$host_os" in
 801 darwin*)
 802         #
 803         # Add -Wl,-single_module to the LDFLAGS used with shared
 804         # libraries, to fix some error that show up in some cases;
 805         # some Apple documentation recommends it for most shared
 806         # libraries.
 807         #
 808         LDFLAGS_SHAREDLIB="-Wl,-single_module"
 809         #
 810         # Add -Wl,-search_paths_first to make sure that if we search
 811         # directories A and B, in that order, for a given library, a
 812         # non-shared version in directory A, rather than a shared
 813         # version in directory B, is chosen (so we can use
 814         # --with-pcap=/usr/local to force all programs to be linked
 815         # with a static version installed in /usr/local/lib rather than
 816         # the system version in /usr/lib).
 817         #
 818         LDFLAGS="-Wl,-search_paths_first $LDFLAGS"
 819         AC_MSG_RESULT([Apple linker - added -Wl,-single_module and -Wl,-search_paths_first])
 820         ;;
 821 cygwin*)
 822         #
 823         # Shared libraries in cygwin/Win32 must never contain
 824         # undefined symbols.
 825         #
 826         LDFLAGS="$LDFLAGS -no-undefined"
 827         AC_MSG_RESULT(CygWin GNU ld - added -no-undefined)
 828         ;;
 829 *)
 830         AC_MSG_RESULT(none needed)
 831         ;;
 832 esac
 833 AC_SUBST(LDFLAGS_SHAREDLIB)
 834
 835 # Enable silent builds by default
 836 # Verbose builds can be enabled with "./configure
 837 # --enable-silent-rules ..." or "make V=1 ..."
 838 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
 839   [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
 840
 841 #
 842 # On "Darwin", which we assume to mean "OS X" rather than "iOS" or
 843 # "just Darwin" (as we don't currently support iOS, and as I don't
 844 # think you can build and run "just Darwin" as an OS for PCs), we
 845 # arrange to build some programs with Application Services so they
 846 # can launch Web browsers and Finder windows, arrange to build some
 847 # programs with System Configuration so they can get "friendly names"
 848 # and other information about interfaces, and build any programs that
 849 # use either of those frameworks or that report version information
 850 # with Core Foundation as the frameworks in question use it and as we
 851 # get version information from plists and thus need Core Foundation
 852 # to process those plists.
 853 #
 854 case "$host_os" in
 855
 856 darwin*)
 857         AC_DEFINE(HAVE_OS_X_FRAMEWORKS, 1, [Define to 1 if you have OS X frameworks])
 858         APPLICATIONSERVICES_FRAMEWORKS="-framework ApplicationServices"
 859         SYSTEMCONFIGURATION_FRAMEWORKS="-framework SystemConfiguration"
 860         COREFOUNDATION_FRAMEWORKS="-framework CoreFoundation"
 861
 862         #
 863         # OK, so we have the OS X frameworks; do they include
 864         # CFPropertyListCreateWithStream, or do we have
 865         # to fall back on CFPropertyListCreateFromStream?
 866         # (They only differ in the error return, which we
 867         # don't care about.  And, no, we shouldn't just
 868         # use CFPropertyListCreateFromStream, because it's
 869         # deprecated in newer releases.)
 870         #
 871         ac_save_LIBS="$LIBS"
 872         LIBS="$LIBS $COREFOUNDATION_FRAMEWORKS"
 873         AC_CHECK_FUNCS(CFPropertyListCreateWithStream)
 874         LIBS="$ac_save_LIBS"
 875         ;;
 876 esac
 877 AC_SUBST(APPLICATIONSERVICES_FRAMEWORKS)
 878 AC_SUBST(SYSTEMCONFIGURATION_FRAMEWORKS)
 879 AC_SUBST(COREFOUNDATION_FRAMEWORKS)
 880
 881 dnl Look in /usr/local for header files and libraries ?
 882 dnl XXX FIXME don't include /usr/local if it is already in the system
 883 dnl search path as this causes gcc 3.2 on Linux to complain about a change
 884 dnl of the system search order for includes
 885 AC_ARG_ENABLE(usr-local,
 886   AC_HELP_STRING( [--enable-usr-local],
 887                   [look for headers and libs in /usr/local tree @<:@default=yes@:>@]),
 888     ac_cv_enable_usr_local=$enableval,ac_cv_enable_usr_local=yes)
 889
 890 AC_MSG_CHECKING(whether to use /usr/local for headers and libraries)
 891 if test "x$ac_cv_enable_usr_local" = "xyes" ; then
 892         if test -d "/usr/local"; then
 893                 AC_MSG_RESULT(yes)
 894                 #
 895                 # Arrange that we search for header files in the source directory
 896                 # and in its "wiretap" subdirectory, as well as in "/usr/local/include",
 897                 # as various packages we use ("libpcap", "zlib", "adns")
 898                 # may have been installed under "/usr/local/include".
 899                 #
 900                 CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 901
 902                 #
 903                 # Arrange that we search for libraries in "/usr/local/lib".
 904                 #
 905                 AC_WIRESHARK_ADD_DASH_L(LDFLAGS, /usr/local/lib)
 906         else
 907                 AC_MSG_RESULT(no)
 908         fi
 909 else
 910         AC_MSG_RESULT(no)
 911 fi
 912
 913 #
 914 # If we're running Solaris, and LD_LIBRARY_PATH is defined, add it as a
 915 # link directory.
 916 #
 917 case "$host_os" in
 918   solaris*)
 919     AC_MSG_CHECKING(for LD_LIBRARY_PATH, since you appear to be running Solaris)
 920     if test x$LD_LIBRARY_PATH != x ; then
 921       LIBS="$LIBS -R$LD_LIBRARY_PATH"
 922       AC_MSG_RESULT(yes -- added LD_LIBRARY_PATH to run-time linker path)
 923     else
 924       AC_MSG_RESULT(no -- this may be a problem in a few seconds)
 925     fi
 926   ;;
 927 esac
 928
 929 #
 930 # Check for versions of "sed" inadequate to handle, in libtool, a list
 931 # of object files as large as the list in Wireshark.
 932 #
 933 # On Solaris, we check for "/bin/sed", "/usr/bin/sed", and "/usr/ucb/sed",
 934 # as both "/usr/bin/sed" (which is also "/bin/sed", as "/bin" is just a
 935 # symlink to "/usr/bin", but people may have "/bin" before "/usr/bin" in
 936 # their search path) and "/usr/ucb/sed" are inadequate; "/usr/xpg4/bin/sed"
 937 # is the only "sed" that comes with Solaris that can handle Wireshark.
 938 #
 939 # Add any checks here that are necessary for other OSes.
 940 #
 941 AC_WIRESHARK_GNU_SED_CHECK
 942 if test "$HAVE_GNU_SED" = no ; then
 943         case "$host_os" in
 944         solaris*)
 945                 AC_MSG_CHECKING(whether one of /usr/bin/sed or /bin/sed or /usr/ucb/sed will be used)
 946                 case `which sed` in
 947                         /bin/sed|/usr/bin/sed|/usr/ucb/sed)
 948                         AC_MSG_RESULT(yes)
 949                         AC_MSG_ERROR([change your path to search /usr/xpg4/bin or directory containing GNU sed before /usr/bin (and /bin and /usr/ucb)])
 950                         ;;
 951
 952                         *)
 953                         AC_MSG_RESULT(no)
 954                         ;;
 955                 esac
 956                 ;;
 957
 958         *)
 959                 :
 960                 ;;
 961         esac
 962 fi
 963
 964 # Enable/disable wireshark
 965 AC_ARG_ENABLE(wireshark,
 966   AC_HELP_STRING( [--enable-wireshark],
 967                   [build the Wireshark GUI (with Gtk+, Qt, or both) @<:@default=yes@:>@]),
 968     enable_wireshark=$enableval,enable_wireshark=yes)
 969
 970 AC_ARG_ENABLE(packet-editor,
 971   AC_HELP_STRING( [--enable-packet-editor],
 972                   [add support for packet editor in Wireshark @<:@default=no@:>@]),
 973     enable_packet_editor=$enableval,enable_packet_editor=no)
 974 if test x$enable_packet_editor = xyes; then
 975         AC_DEFINE(WANT_PACKET_EDITOR, 1, [Support for packet editor])
 976 fi
 977
 978 AC_ARG_ENABLE(profile-build,
 979   AC_HELP_STRING( [--enable-profile-build],
 980                   [build profile-ready binaries @<:@default=no@:>@]),
 981     enable_profile_build=$enableval,enable_profile_build=no)
 982 AM_CONDITIONAL(USE_PROFILE_BUILD, test x$enable_profile_build = xyes)
 983 AC_MSG_CHECKING(if profile builds must be generated)
 984 if test "x$enable_profile_build" = "xyes" ; then
 985         if test "x$GCC" = "xyes" -o "x$CLANG" = "xyes" ; then
 986                 AC_MSG_RESULT(yes)
 987                 CFLAGS=" -pg $CFLAGS"
 988                 CXXFLAGS=" -pg $CXXFLAGS"
 989         else
 990                 AC_MSG_RESULT(no)
 991                 echo "Building profile binaries currently only supported for GCC and clang."
 992         fi
 993 else
 994         AC_MSG_RESULT(no)
 995 fi
 996
 997 # Create DATAFILE_DIR #define for config.h
 998 datafiledir=$datadir/wireshark
 999 datafiledir=`(
1000     test "x$prefix" = xNONE && prefix=$ac_default_prefix
1001     test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
1002     # Ugly hack, but I don't see how this problem can be solved
1003     # properly that DATAFILE_DIR had a value starting with
1004     # "${prefix}/" instead of e.g. "/usr/local/"
1005     eval eval echo "$datafiledir"
1006 )`
1007 AC_DEFINE_UNQUOTED(DATAFILE_DIR,"$datafiledir", [Directory for data])
1008
1009 # Create DOC_DIR #define for config.h
1010 docdir=`(
1011     test "x$prefix" = xNONE && prefix=$ac_default_prefix
1012     test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
1013     # Ugly hack, but I don't see how this problem can be solved
1014     # properly that DOC_DIR had a value starting with
1015     # "${prefix}/" instead of e.g. "/usr/local/"
1016     eval eval echo "$docdir"
1017 )`
1018 AC_DEFINE_UNQUOTED(DOC_DIR, "$docdir", [Directory for docs])
1019
1020 GTK2_MIN_VERSION=2.12.0
1021 AC_SUBST(GTK2_MIN_VERSION)
1022 GTK3_MIN_VERSION=3.0.0
1023 AC_SUBST(GTK3_MIN_VERSION)
1024 QT_MIN_VERSION=4.6.0
1025 AC_SUBST(QT_MIN_VERSION)
1026 # GTK+ and Qt checks; we require GTK+ $GTK2_MIN_VERSION or later or
1027 # GTK3_MIN_VERSION or later or Qt $QT_MIN_VERSION or later.
1028 #
1029 # We only do those if we're going to be building Wireshark;
1030 # otherwise, we don't have any GUI to build, so we don't use
1031 # GTK+ or Qt.
1032 #
1033 # We don't add $GTK_LIBS or $Qt_LIBS to LIBS, because we don't want to
1034 # force all programs to be built with GTK+ or Qt.
1035 #
1036 # Release dates for GTK+ versions:
1037 # 2.12.0: 14 Sep 2007
1038 # 2.14.0: 04 Sep 2008
1039 # 2.16.0: 13 Mar 2009
1040 # 2.18.0: 23 Sep 2009
1041 # 2.20.0: 23 Mar 2010
1042 # 2.22.0: 23 Sep 2010
1043 # 2.24.0: 30 Jan 2011
1044 # 3.0.0:  10 Feb 2011
1045 # 3.2.0:  25 Sep 2011
1046 # 3.4.0:  26 Mar 2012
1047 # 3.6.0:  24 Sep 2012
1048 # 3.8.0:  25 Mar 2013
1049
1050 have_qt=no
1051 have_gtk=no
1052 if test "x$enable_wireshark" = "xyes"; then
1053         if test "x$with_qt" = "xyes"; then
1054
1055                 AC_MSG_CHECKING(whether we have a working C++ compiler)
1056                 AC_LANG_PUSH([C++])
1057                 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1058                         [AC_MSG_RESULT(yes)],
1059                         [
1060                          AC_MSG_RESULT(no)
1061                          AC_MSG_ERROR(Need a working C++ compiler to build Wireshark with Qt)
1062                         ])
1063                 AC_LANG_POP([C++])
1064
1065                 AM_PATH_QT($QT_MIN_VERSION,
1066                 [
1067                         CFLAGS="$CFLAGS $Qt_CFLAGS"
1068                         CXXFLAGS="$CXXFLAGS $Qt_CFLAGS"
1069                         have_qt=yes
1070                 ]
1071                 , [AC_MSG_ERROR([Qt is not available])])
1072
1073                 #
1074                 # XXX - greasy hack to make ui/gtk/recent.c
1075                 # compile.
1076                 #
1077                 CPPFLAGS="-DQT_GUI_LIB"
1078         fi
1079
1080         if test "x$with_gtk3" = "xyes" -a "x$with_gtk2" = "xyes" ; then
1081                 # If the user gave us --with-gtk3, use gtk3 rather than gtk2
1082                 with_gtk2="no"
1083         fi
1084
1085         if test "x$with_gtk3" = "xyes"; then
1086                 AM_PATH_GTK_3_0(3.0.0,
1087                 [
1088                         CFLAGS="$CFLAGS $GTK_CFLAGS"
1089                         CXXFLAGS="$CXXFLAGS $GTK_CFLAGS"
1090                         have_gtk=yes
1091                 ], have_gtk=no)
1092         fi
1093
1094         if test "x$with_gtk2" = "xyes"; then
1095                 AM_PATH_GTK_2_0($GTK2_MIN_VERSION,
1096                 [
1097                         CFLAGS="$CFLAGS $GTK_CFLAGS"
1098                         CXXFLAGS="$CXXFLAGS $GTK_CFLAGS"
1099                         have_gtk=yes
1100                 ], have_gtk=no)
1101         fi
1102 fi
1103
1104 GLIB_MIN_VERSION=2.16.0
1105 AC_SUBST(GLIB_MIN_VERSION)
1106 # GLib checks; we require GLib $GLIB_MIN_VERSION or later, and require gmodule
1107 # support, as we need that for dynamically loading plugins.
1108 # If we found GTK+, this doesn't add GLIB_CFLAGS to CFLAGS, because
1109 # AM_PATH_GTK will add GTK_CFLAGS to CFLAGS, and GTK_CFLAGS is a
1110 # superset of GLIB_CFLAGS.  If we didn't find GTK+, it does add
1111 # GLIB_CFLAGS to CFLAGS.
1112 # However, this means that both @GLIB_LIBS@ and @GTK_LIBS@ will be
1113 # set when generating the Makefile, so we can make programs that require
1114 # only GLib link with @GLIB_LIBS@ and make programs that require GTK+
1115 # link with @GTK_LIBS@ (which includes @GLIB_LIBS@).
1116 # We don't add $GLIB_LIBS to LIBS, because we don't want to force all
1117 # programs to be built with GLib.
1118 #
1119 # Release dates for GLib versions:
1120 # 2.14.0: 03 Aug 2007
1121 # 2.16.0: 10 Mar 2008
1122 # 2.18.0: 02 Sep 2008
1123 # 2.20.0: 13 Mar 2009
1124 # 2.22.0: 22 Sep 2009
1125 # 2.24.0: 28 Mar 2010
1126 # 2.26.0: 27 Sep 2010
1127 # 2.28.0: 08 Feb 2011
1128 # 2.30.0: 27 Sep 2011
1129 # 2.32.0: 24 Mar 2012
1130 # 2.34.0: 24 Sep 2012
1131 # 2.36.0: 25 Mar 2013
1132
1133 use_glib_cflags="true"
1134 if test "$have_gtk" = "yes" -a "$have_qt" = "yes" ; then
1135         # We have both GTK and Qt and thus will be building both wireshark
1136         # and wireshark-qt.
1137
1138         wireshark_bin="wireshark\$(EXEEXT) wireshark-qt\$(EXEEXT)"
1139         wireshark_man="wireshark.1"
1140         wireshark_SUBDIRS="codecs ui/qt ui/gtk"
1141 fi
1142 if test "$have_gtk" = "no" -a "$have_qt" = "yes" ; then
1143         # We don't have GTK+ but we have Qt.
1144
1145         wireshark_bin="wireshark-qt\$(EXEEXT)"
1146         wireshark_man="wireshark.1"
1147         wireshark_SUBDIRS="codecs ui/qt"
1148 fi
1149 if test "$have_gtk" = "yes" -a "$have_qt" = "no" ; then
1150         # We have GTK+ but not Qt.
1151
1152         wireshark_bin="wireshark\$(EXEEXT)"
1153         wireshark_man="wireshark.1"
1154         wireshark_SUBDIRS="codecs ui/gtk"
1155         use_glib_cflags="false"
1156 fi
1157 if test "$have_gtk" = "no" -a "$have_qt" = "no" ; then
1158         # We have neither GTK+ nor Qt.
1159         #
1160         # If they didn't explicitly say "--disable-wireshark",
1161         # fail (so that, unless they explicitly indicated that
1162         # they don't want Wireshark, we stop so they know they
1163         # won't be getting Wireshark unless they fix the GTK+/Qt
1164         # problem).
1165         #
1166         if test "x$enable_wireshark" = "xyes"; then
1167                 if test "x$with_gtk3" = "xyes"; then
1168                         AC_MSG_ERROR([Neither Qt nor GTK+ $GTK3_MIN_VERSION or later are available, so Wireshark can't be compiled])
1169                 else
1170                         AC_MSG_ERROR([Neither Qt nor GTK+ $GTK2_MIN_VERSION or later are available, so Wireshark can't be compiled])
1171                 fi
1172         fi
1173         wireshark_bin=""
1174         wireshark_man=""
1175 fi
1176
1177 if test "$have_gtk" = "yes" ; then
1178         # If we have GTK then add flags for it.
1179
1180         CPPFLAGS="-DGDK_PIXBUF_DISABLE_DEPRECATED $CPPFLAGS"
1181         CPPFLAGS="-DGDK_DISABLE_DEPRECATED $CPPFLAGS"
1182         CPPFLAGS="-DGTK_DISABLE_DEPRECATED $CPPFLAGS"
1183         CPPFLAGS="-DGTK_DISABLE_SINGLE_INCLUDES $CPPFLAGS"
1184         if test ! \( $gtk_config_major_version -eq 2 -a $gtk_config_minor_version -lt 20 \) ; then
1185                 # Enable GSEAL when building with GTK > 2.20
1186                 # (Versions prior to 2.22 lacked some necessary accessors.)
1187                 CPPFLAGS="-DGSEAL_ENABLE $CPPFLAGS"
1188         fi
1189 fi
1190
1191 # XXX - Is this really necessary?  When we build with both Gtk+ and Qt it works...
1192 if test "$use_glib_cflags" = "true"; then
1193         # Use GLIB_CFLAGS
1194         AM_PATH_GLIB_2_0($GLIB_MIN_VERSION,
1195         [
1196                 CFLAGS="$CFLAGS $GLIB_CFLAGS"
1197                 CXXFLAGS="$CXXFLAGS $GLIB_CFLAGS"
1198         ], AC_MSG_ERROR(GLib $GLIB_MIN_VERSION or later distribution not found.), gthread gmodule)
1199 else
1200         # Don't use GLIB_CFLAGS
1201         AM_PATH_GLIB_2_0($GLIB_MIN_VERSION, , AC_MSG_ERROR(GLib $GLIB_MIN_VERSION or later distribution not found.), gthread gmodule)
1202 fi
1203
1204 #
1205 # "make dist" requires that we have the Qt build tools.
1206 #
1207 # Annoyingly, at least on Fedora 16, uic and moc are named XXX-qt4
1208 # rather than just XXX, perhaps to allow Qt 3 and Qt 4 tools to be
1209 # installed; if they're still doing that in current Fedora releases,
1210 # perhaps there will also be XXX-qt5 when they pick up Qt 5.
1211 #
1212 AC_PATH_PROG(UIC, uic-qt4)
1213 if test "x$UIC" = x
1214 then
1215         AC_PATH_PROG(UIC, uic)
1216         if test "x$UIC" = x
1217         then
1218                 if test "x$with_qt" = "xyes"; then
1219                         #
1220                         # If you want to build with Qt, you'd better
1221                         # have uic.
1222                         #
1223                         AC_MSG_ERROR(I couldn't find uic or uic-qt4; make sure it's installed and in your path)
1224                 else
1225                         #
1226                         # We shouldn't fail here, as the user's not
1227                         # building with Qt, and we shouldn't force them
1228                         # to have Qt installed if they're not doing so.
1229                         # "make dist" will fail if they do that, but
1230                         # we don't know whether they'll be doing that,
1231                         # so this is the best we can do.
1232                         #
1233                         UIC=uic
1234                 fi
1235         fi
1236 fi
1237 AC_SUBST(UIC)
1238 AC_PATH_PROG(MOC, moc-qt4)
1239 if test "x$MOC" = x
1240 then
1241         AC_PATH_PROG(MOC, moc)
1242         if test "x$MOC" = x
1243         then
1244                 if test "x$with_qt" = "xyes"; then
1245                         #
1246                         # If you want to build with Qt, you'd better
1247                         # have moc.
1248                         #
1249                         AC_MSG_ERROR(I couldn't find moc or moc-qt4; make sure it's installed and in your path)
1250                 else
1251                         #
1252                         # We shouldn't fail here, as the user's not
1253                         # building with Qt, and we shouldn't force them
1254                         # to have Qt installed if they're not doing so.
1255                         # "make dist" will fail if they do that, but
1256                         # we don't know whether they'll be doing that,
1257                         # so this is the best we can do.
1258                         #
1259                         MIC=moc
1260                 fi
1261         fi
1262 fi
1263 AC_SUBST(MOC)
1264
1265 # Error out if a glib header other than a "top level" header
1266 #  (glib.h, glib-object.h, gio.h) or certain other headers( e.g.,gmodule.h)
1267 #  is used.
1268 CPPFLAGS="-DG_DISABLE_SINGLE_INCLUDES $CPPFLAGS"
1269
1270 # Error out on the usage of deprecated glib functions
1271 CPPFLAGS="-DG_DISABLE_DEPRECATED $CPPFLAGS"
1272
1273 #
1274 # Check whether GLib modules are supported, to determine whether we
1275 # can support plugins.
1276 #
1277 AC_MSG_CHECKING(whether GLib supports loadable modules)
1278 ac_save_CFLAGS="$CFLAGS"
1279 ac_save_LIBS="$LIBS"
1280 CFLAGS="$CFLAGS $GLIB_CFLAGS"
1281 LIBS="$GLIB_LIBS $LIBS"
1282 AC_TRY_RUN([
1283 #include <glib.h>
1284 #include <gmodule.h>
1285 #include <stdio.h>
1286 #include <stdlib.h>
1287
1288 int
1289 main ()
1290 {
1291   if (g_module_supported())
1292     return 0;   /* success */
1293   else
1294     return 1;   /* failure */
1295 }
1296 ], ac_cv_glib_supports_modules=yes, ac_cv_glib_supports_modules=no,
1297    [echo $ac_n "cross compiling; assumed OK... $ac_c"
1298     ac_cv_glib_supports_modules=yes])
1299 CFLAGS="$ac_save_CFLAGS"
1300 LIBS="$ac_save_LIBS"
1301 if test "$ac_cv_glib_supports_modules" = yes ; then
1302   AC_MSG_RESULT(yes)
1303   have_plugins=yes
1304 else
1305   AC_MSG_RESULT(no)
1306   have_plugins=no
1307 fi
1308
1309 #
1310 # If we have <dlfcn.h>, check whether we can use dladdr to find a
1311 # filename (hopefully, a full pathname, but no guarantees) for
1312 # the executable.
1313 #
1314 if test "$ac_cv_header_dlfcn_h" = "yes"
1315 then
1316         AC_MSG_CHECKING(whether dladdr can be used to find the pathname of an executable)
1317         ac_save_CFLAGS="$CFLAGS"
1318         ac_save_LIBS="$LIBS"
1319         CFLAGS="$CFLAGS $GLIB_CFLAGS"
1320         LIBS="$GLIB_LIBS $LIBS"
1321         AC_TRY_RUN([
1322 #define _GNU_SOURCE     /* required on Linux, sigh */
1323 #include <dlfcn.h>
1324
1325 int
1326 main(void)
1327 {
1328         Dl_info info;
1329
1330         if (!dladdr((void *)main, &info))
1331                 return 1;       /* failure */
1332         return 0;               /* assume success */
1333 }
1334 ], ac_cv_dladdr_finds_executable_path=yes, ac_cv_dladdr_finds_executable_path=no,
1335    [echo $ac_n "cross compiling; assumed OK... $ac_c"
1336     ac_cv_dladdr_finds_executable_path=yes])
1337         CFLAGS="$ac_save_CFLAGS"
1338         LIBS="$ac_save_LIBS"
1339         if test x$ac_cv_dladdr_finds_executable_path = xyes
1340         then
1341                 AC_DEFINE(DLADDR_FINDS_EXECUTABLE_PATH, 1, [Define if dladdr can be used to find the path of the executable])
1342         fi
1343         AC_MSG_RESULT($ac_cv_dladdr_finds_executable_path)
1344 fi
1345
1346 #
1347 # Check whether GLib's printf supports thousands grouping. (This might
1348 # be different from the system's printf since GLib can optionally use
1349 # its own printf implementation.)
1350 #
1351 AC_MSG_CHECKING(whether GLib supports POSIX/XSI thousands grouping)
1352 ac_save_CFLAGS="$CFLAGS"
1353 ac_save_LIBS="$LIBS"
1354 CFLAGS="$CFLAGS $GLIB_CFLAGS"
1355 LIBS="$GLIB_LIBS $LIBS"
1356 AC_TRY_RUN([
1357 #include <glib.h>
1358 #include <locale.h>
1359 #include <stdio.h>
1360 #include <string.h>
1361
1362 int
1363 main ()
1364 {
1365   gchar *str;
1366   setlocale(LC_ALL, "en_US.UTF-8");
1367   str = g_strdup_printf("%'u", 123456);
1368   return (strcmp (str, "123,456") != 0);
1369 }
1370 ], ac_cv_glib_supports_printf_grouping=yes, ac_cv_glib_supports_printf_grouping=no,
1371    [echo $ac_n "cross compiling; playing it safe... $ac_c"
1372     ac_cv_glib_supports_printf_grouping=no])
1373 CFLAGS="$ac_save_CFLAGS"
1374 LIBS="$ac_save_LIBS"
1375 if test "$ac_cv_glib_supports_printf_grouping" = yes ; then
1376   AC_MSG_RESULT(yes)
1377   AC_DEFINE(HAVE_GLIB_PRINTF_GROUPING, 1, [Define if your printf() function supports thousands grouping.])
1378 else
1379   AC_MSG_RESULT(no)
1380 fi
1381
1382 if test "x$have_gtk" = "xyes"
1383 then
1384     #
1385     # We have GTK+; do we want the OS X integration functions and,
1386     # if so, do we have them and, if so, which versions do we have,
1387     # the old Carbon-based ones or the new Cocoa-based ones?
1388     #
1389     AC_MSG_CHECKING(whether to use OS X integration functions)
1390
1391     AC_ARG_WITH(osx-integration,
1392       AC_HELP_STRING( [--with-osx-integration],
1393                       [use OS X integration functions @<:@default=yes, if available@:>@]),
1394     [
1395         if test $withval = no
1396         then
1397             want_osx_integration=no
1398         else
1399             want_osx_integration=yes
1400         fi
1401     ],[
1402         want_osx_integration=yes
1403     ])
1404     if test "x$want_osx_integration" = "xno"; then
1405         AC_MSG_RESULT(no)
1406     else
1407         AC_MSG_RESULT(yes)
1408         AC_WIRESHARK_OSX_INTEGRATION_CHECK
1409     fi
1410 fi
1411
1412 AC_SUBST(wireshark_bin)
1413 AC_SUBST(wireshark_man)
1414 AM_CONDITIONAL(HAVE_Qt, test "$have_qt" = "yes")
1415 AM_CONDITIONAL(HAVE_GTK, test "$have_gtk" = "yes")
1416
1417
1418 # Enable/disable tshark
1419
1420 AC_ARG_ENABLE(tshark,
1421   AC_HELP_STRING( [--enable-tshark],
1422                   [build TShark @<:@default=yes@:>@]),
1423     tshark=$enableval,enable_tshark=yes)
1424
1425 if test "x$enable_tshark" = "xyes" ; then
1426         tshark_bin="tshark\$(EXEEXT)"
1427         tshark_man="tshark.1"
1428         wiresharkfilter_man="wireshark-filter.4"
1429 else
1430         tshark_bin=""
1431         tshark_man=""
1432 fi
1433 AC_SUBST(tshark_bin)
1434 AC_SUBST(tshark_man)
1435 AC_SUBST(wiresharkfilter_man)
1436
1437
1438
1439 # Enable/disable editcap
1440
1441 AC_ARG_ENABLE(editcap,
1442   AC_HELP_STRING( [--enable-editcap],
1443                   [build editcap @<:@default=yes@:>@]),
1444     enable_editcap=$enableval,enable_editcap=yes)
1445
1446 if test "x$enable_editcap" = "xyes" ; then
1447         editcap_bin="editcap\$(EXEEXT)"
1448         editcap_man="editcap.1"
1449 else
1450         editcap_bin=""
1451         editcap_man=""
1452 fi
1453 AC_SUBST(editcap_bin)
1454 AC_SUBST(editcap_man)
1455
1456
1457
1458 # Enable/disable echld
1459
1460 AC_ARG_ENABLE(echld,
1461   AC_HELP_STRING( [--enable-echld],
1462                   [support echld]),
1463     have_echld=$enableval,have_echld=no)
1464
1465 AM_CONDITIONAL(HAVE_ECHLD, test "x$have_echld" = "xyes")
1466 if test "x$have_echld" = "xyes"
1467 then
1468   AC_DEFINE(HAVE_ECHLD, 1, [Define if echld is enabled])
1469   echld_test_bin="echld_test\$(EXEEXT)"
1470   echld_dir="echld"
1471 else
1472   have_echld="no"
1473   echld_test_bin=""
1474   echld_dir=""
1475 fi
1476 AC_SUBST(echld_test_bin)
1477 AC_SUBST(echld_dir)
1478
1479
1480 # Enabling/disabling of dumpcap is done later (after we know if we have PCAP
1481 # or not)
1482
1483 # Enable/disable capinfos
1484
1485 AC_ARG_ENABLE(capinfos,
1486   AC_HELP_STRING( [--enable-capinfos],
1487                   [build capinfos @<:@default=yes@:>@]),
1488     enable_capinfos=$enableval,enable_capinfos=yes)
1489
1490 if test "x$enable_capinfos" = "xyes" ; then
1491         capinfos_bin="capinfos\$(EXEEXT)"
1492         capinfos_man="capinfos.1"
1493 else
1494         capinfos_bin=""
1495         capinfos_man=""
1496 fi
1497 AC_SUBST(capinfos_bin)
1498 AC_SUBST(capinfos_man)
1499
1500
1501 # Enable/disable mergecap
1502
1503 AC_ARG_ENABLE(mergecap,
1504   AC_HELP_STRING( [--enable-mergecap],
1505                   [build mergecap @<:@default=yes@:>@]),
1506     enable_mergecap=$enableval,enable_mergecap=yes)
1507
1508 if test "x$enable_mergecap" = "xyes" ; then
1509         mergecap_bin="mergecap\$(EXEEXT)"
1510         mergecap_man="mergecap.1"
1511 else
1512         mergecap_bin=""
1513         mergecap_man=""
1514 fi
1515 AC_SUBST(mergecap_bin)
1516 AC_SUBST(mergecap_man)
1517
1518
1519 # Enable/disable reordercap
1520
1521 AC_ARG_ENABLE(reordercap,
1522   AC_HELP_STRING( [--enable-reordercap],
1523                   [build reordercap @<:@default=yes@:>@]),
1524     enable_reordercap=$enableval,enable_reordercap=yes)
1525
1526 if test "x$enable_reordercap" = "xyes" ; then
1527         reordercap_bin="reordercap\$(EXEEXT)"
1528         reordercap_man="reordercap.1"
1529 else
1530         reordercap_bin=""
1531         reordercap_man=""
1532 fi
1533 AC_SUBST(reordercap_bin)
1534 AC_SUBST(reordercap_man)
1535
1536
1537 # Enable/disable text2pcap
1538
1539 AC_ARG_ENABLE(text2pcap,
1540   AC_HELP_STRING( [--enable-text2pcap],
1541                   [build text2pcap @<:@default=yes@:>@]),
1542     text2pcap=$enableval,enable_text2pcap=yes)
1543
1544 if test "x$enable_text2pcap" = "xyes" ; then
1545         text2pcap_bin="text2pcap\$(EXEEXT)"
1546         text2pcap_man="text2pcap.1"
1547 else
1548         text2pcap_bin=""
1549         text2pcap_man=""
1550 fi
1551 AC_SUBST(text2pcap_bin)
1552 AC_SUBST(text2pcap_man)
1553
1554
1555 # Enable/disable dftest
1556
1557 AC_ARG_ENABLE(dftest,
1558   AC_HELP_STRING( [--enable-dftest],
1559                   [build dftest @<:@default=yes@:>@]),
1560     enable_dftest=$enableval,enable_dftest=yes)
1561
1562 if test "x$enable_dftest" = "xyes" ; then
1563         dftest_bin="dftest\$(EXEEXT)"
1564         dftest_man="dftest.1"
1565 else
1566         dftest_bin=""
1567         dftest_man=""
1568 fi
1569 AC_SUBST(dftest_bin)
1570 AC_SUBST(dftest_man)
1571
1572
1573 # Enable/disable randpkt
1574
1575 AC_ARG_ENABLE(randpkt,
1576   AC_HELP_STRING( [--enable-randpkt],
1577                   [build randpkt @<:@default=yes@:>@]),
1578     enable_randpkt=$enableval,enable_randpkt=yes)
1579
1580 if test "x$enable_randpkt" = "xyes" ; then
1581         randpkt_bin="randpkt\$(EXEEXT)"
1582         randpkt_man="randpkt.1"
1583 else
1584         randpkt_bin=""
1585         randpkt_man=""
1586 fi
1587 AC_SUBST(randpkt_bin)
1588 AC_SUBST(randpkt_man)
1589
1590
1591
1592 dnl Checks for "gethostbyname()" - and "-lnsl", if we need it to get
1593 dnl "gethostbyname()".
1594 AC_WIRESHARK_GETHOSTBY_LIB_CHECK
1595
1596 dnl Checks for "connect()", used as a proxy for "socket()" - and
1597 dnl "-lsocket", if we need it to get "connect()".
1598 AC_WIRESHARK_SOCKET_LIB_CHECK
1599
1600 dnl pcap check
1601 AC_MSG_CHECKING(whether to use libpcap for packet capture)
1602
1603 AC_ARG_WITH(pcap,
1604   AC_HELP_STRING( [--with-pcap@<:@=DIR@:>@],
1605                   [use libpcap for packet capturing @<:@default=yes@:>@]),
1606 [
1607         if test $withval = no
1608         then
1609                 want_pcap=no
1610         elif test $withval = yes
1611         then
1612                 want_pcap=yes
1613         else
1614                 want_pcap=yes
1615                 pcap_dir=$withval
1616         fi
1617 ],[
1618         want_pcap=yes
1619         pcap_dir=
1620 ])
1621 if test "x$want_pcap" = "xno" ; then
1622         AC_MSG_RESULT(no)
1623 else
1624         AC_MSG_RESULT(yes)
1625         AC_WIRESHARK_PCAP_CHECK
1626 fi
1627
1628
1629 dnl Check for airpcap
1630 AC_MSG_CHECKING(whether to include airpcap support)
1631 AC_ARG_ENABLE(airpcap,
1632   AC_HELP_STRING( [--enable-airpcap],
1633                   [use AirPcap in Wireshark @<:@default=yes@:>@]),
1634   enable_airpcap=$enableval, enable_airpcap=yes)
1635
1636 if test x$enable_airpcap = xyes; then
1637         if test "x$want_pcap" = "xno" ; then
1638                 enable_airpcap=no
1639                 AC_MSG_RESULT(pcap not available - disabling airpcap)
1640         else
1641                 AC_MSG_RESULT(yes)
1642                 AC_DEFINE(HAVE_AIRPCAP, 1, [Enable AirPcap])
1643         fi
1644 else
1645         AC_MSG_RESULT(no)
1646 fi
1647
1648
1649 dnl dumpcap check
1650 AC_MSG_CHECKING(whether to build dumpcap)
1651
1652 AC_ARG_ENABLE(dumpcap,
1653   AC_HELP_STRING( [--enable-dumpcap],
1654                   [build dumpcap @<:@default=yes@:>@]),
1655     enable_dumpcap=$enableval,enable_dumpcap=yes)
1656
1657 if test "x$enable_dumpcap" = "xyes" ; then
1658         if test "x$want_pcap" = "xno" ; then
1659                 enable_dumpcap=no
1660                 AC_MSG_RESULT(pcap not available - disabling dumpcap)
1661         else
1662                 AC_MSG_RESULT(yes)
1663         fi
1664 else
1665         AC_MSG_RESULT(no)
1666 fi
1667
1668 if test "x$enable_dumpcap" = "xyes" ; then
1669         dumpcap_bin="dumpcap\$(EXEEXT)"
1670         dumpcap_man="dumpcap.1"
1671 else
1672         dumpcap_bin=""
1673         dumpcap_man=""
1674 fi
1675 AC_SUBST(dumpcap_bin)
1676 AC_SUBST(dumpcap_man)
1677
1678 # Enable/disable rawshark
1679
1680 dnl rawshark check
1681 AC_MSG_CHECKING(whether to build rawshark)
1682
1683 AC_ARG_ENABLE(rawshark,
1684   AC_HELP_STRING( [--enable-rawshark],
1685                   [build rawshark @<:@default=yes@:>@]),
1686     rawshark=$enableval,enable_rawshark=yes)
1687
1688 if test "x$enable_rawshark" = "xyes" ; then
1689         if test "x$want_pcap" = "xno" ; then
1690                 enable_rawshark=no
1691                 AC_MSG_RESULT(pcap not available - disabling rawshark)
1692         else
1693                 AC_MSG_RESULT(yes)
1694         fi
1695 else
1696         AC_MSG_RESULT(no)
1697 fi
1698
1699 if test "x$enable_rawshark" = "xyes" ; then
1700         rawshark_bin="rawshark\$(EXEEXT)"
1701         rawshark_man="rawshark.1"
1702 else
1703         rawshark_bin=""
1704         rawshark_man=""
1705 fi
1706 AC_SUBST(rawshark_bin)
1707 AC_SUBST(rawshark_man)
1708
1709 dnl Use pcap-ng by default
1710 AC_ARG_ENABLE(pcap-ng-default,
1711   AC_HELP_STRING( [--enable-pcap-ng-default],
1712                   [use the pcap-ng file format by default instead of pcap @<:@default=yes@:>@]),
1713     enable_pcap_ng_default=$enableval,enable_pcap_ng_default=yes)
1714 if test x$enable_pcap_ng_default = xyes; then
1715         AC_DEFINE(PCAP_NG_DEFAULT, 1, [Support for pcap-ng])
1716 fi
1717
1718 dnl pcap remote check
1719 AC_MSG_CHECKING(whether to use libpcap remote capturing feature)
1720
1721 AC_ARG_WITH(pcap-remote,
1722     AC_HELP_STRING([--with-pcap-remote],
1723                    [use libpcap remote capturing (requires libpcap)]),
1724 [
1725     if test $withval = no
1726     then
1727         want_pcap_remote=no
1728     else
1729         want_pcap_remote=yes
1730     fi
1731 ],[
1732     want_pcap_remote=no
1733 ])
1734 if test "x$want_pcap_remote" = "xno" -o "x$want_pcap" = "xno" ; then
1735     AC_MSG_RESULT(no)
1736 else
1737     AC_MSG_RESULT(yes)
1738     AC_WIRESHARK_PCAP_REMOTE_CHECK
1739 fi
1740
1741 dnl zlib check
1742 AC_MSG_CHECKING(whether to use zlib for gzip compression and decompression)
1743
1744 AC_ARG_WITH(zlib,
1745   AC_HELP_STRING([--with-zlib@<:@=DIR@:>@],
1746                  [use zlib (located in directory DIR, if supplied) for gzip compression and decompression @<:@default=yes, if available@:>@]),
1747 [
1748         if test "x$withval" = "xno"
1749         then
1750                 want_zlib=no
1751         elif test "x$withval" = "xyes"
1752         then
1753                 want_zlib=yes
1754         else
1755                 want_zlib=yes
1756                 zlib_dir="$withval"
1757         fi
1758 ],[
1759         #
1760         # Use zlib if it's present, otherwise don't.
1761         #
1762         want_zlib=ifavailable
1763         zlib_dir=
1764 ])
1765 if test "x$want_zlib" = "xno" ; then
1766         AC_MSG_RESULT(no)
1767 else
1768         AC_MSG_RESULT(yes)
1769         AC_WIRESHARK_ZLIB_CHECK
1770         if test "x$want_zlib" = "xno" ; then
1771                 AC_MSG_RESULT(zlib not found - disabling gzip compression and decompression)
1772         else
1773                 if test "x$ac_cv_func_inflatePrime" = "xno" ; then
1774                         AC_MSG_RESULT(inflatePrime not found in zlib - disabling gzipped capture file support)
1775                 fi
1776         fi
1777 fi
1778
1779 dnl Lua check
1780 AC_MSG_CHECKING(whether to use liblua for the Lua scripting plugin)
1781
1782 AC_ARG_WITH(lua,
1783   AC_HELP_STRING( [--with-lua@<:@=DIR@:>@],
1784                   [use liblua (located in directory DIR, if supplied) for the Lua scripting plugin @<:@default=yes, if available@:>@]),
1785 [
1786         if test $withval = no
1787         then
1788                 want_lua=no
1789         elif test $withval = yes
1790         then
1791                 want_lua=yes
1792         else
1793                 want_lua=yes
1794                 lua_dir=$withval
1795         fi
1796 ],[
1797         #
1798         # Use liblua by default
1799         #
1800         want_lua=ifavailable
1801         lua_dir=
1802 ])
1803 if test "x$want_lua" = "xno" ; then
1804         AC_MSG_RESULT(no)
1805 else
1806         AC_MSG_RESULT(yes)
1807         AC_WIRESHARK_LIBLUA_CHECK
1808         if test "x$want_lua" = "xno" ; then
1809                 AC_MSG_RESULT(liblua not found - disabling support for the lua scripting plugin)
1810         fi
1811 fi
1812 AM_CONDITIONAL(HAVE_LIBLUA, test x$want_lua = xyes)
1813
1814
1815 dnl portaudio check
1816 AC_MSG_CHECKING(whether to use libportaudio for the rtp_player)
1817
1818 AC_ARG_WITH(portaudio,
1819   AC_HELP_STRING( [--with-portaudio@<:@=DIR@:>@],
1820                   [use libportaudio (located in directory DIR, if supplied) for the rtp_player @<:@default=yes, if available@:>@]),
1821 [
1822         if test $withval = no
1823         then
1824                 want_portaudio=no
1825         elif test $withval = yes
1826         then
1827                 want_portaudio=yes
1828         else
1829                 want_portaudio=yes
1830                 portaudio_dir=$withval
1831         fi
1832 ],[
1833         #
1834         # Use libportaudio by default
1835         #
1836         want_portaudio=ifavailable
1837         portaudio_dir=
1838 ])
1839 if test "x$want_portaudio" = "xno" ; then
1840         AC_MSG_RESULT(no)
1841 else
1842         AC_MSG_RESULT(yes)
1843         AC_WIRESHARK_LIBPORTAUDIO_CHECK
1844         if test "x$want_portaudio" = "xno" ; then
1845                 AC_MSG_RESULT(libportaudio not found - disabling support for the rtp_player)
1846         fi
1847 fi
1848 AM_CONDITIONAL(HAVE_LIBPORTAUDIO, test x$want_portaudio = xyes)
1849
1850
1851 dnl ipv6 check
1852 AC_ARG_ENABLE(ipv6,
1853   AC_HELP_STRING( [--enable-ipv6],
1854                   [use IPv6 name resolution, if available @<:@default=yes@:>@]),
1855     enable_ipv6=$enableval,enable_ipv6=yes)
1856
1857 AC_MSG_CHECKING(whether to enable ipv6 name resolution if available)
1858 if test "x$enable_ipv6" = "xno" ; then
1859         AC_MSG_RESULT(no)
1860 else
1861         AC_MSG_RESULT(yes)
1862         AC_WIRESHARK_IPV6_STACK
1863 fi
1864
1865
1866 dnl Check if dumpcap should be installed with filesystem capabilities
1867 AC_PATH_PROG(SETCAP, setcap)
1868 AC_ARG_ENABLE(setcap-install,
1869   AC_HELP_STRING( [--enable-setcap-install],
1870                   [install dumpcap with cap_net_admin and cap_net_raw @<:@default=no@:>@]),
1871     enable_setcap_install=$enableval,enable_setcap_install=no)
1872
1873 AC_MSG_CHECKING(whether to install dumpcap with cap_net_admin and cap_net_raw capabilities)
1874 if test "x$enable_setcap_install" = "xno" ; then
1875         AC_MSG_RESULT(no)
1876 else
1877         if test "x$SETCAP" = "x" ; then
1878                 AC_MSG_RESULT(no. Setcap not found)
1879         elif test "x$enable_dumpcap" = "xno" ; then
1880                 AC_MSG_ERROR(Setcap install works only with dumpcap but dumpcap is disabled)
1881         else
1882                 AC_MSG_RESULT(yes)
1883         fi
1884 fi
1885
1886 AM_CONDITIONAL(SETCAP_INSTALL, test x$enable_setcap_install = xyes)
1887
1888 dnl Check if dumpcap should be installed setuid
1889 AC_ARG_ENABLE(setuid-install,
1890   AC_HELP_STRING( [--enable-setuid-install],
1891                   [install dumpcap as setuid @<:@default=no@:>@]),
1892     enable_setuid_install=$enableval,enable_setuid_install=no)
1893
1894 AC_MSG_CHECKING(whether to install dumpcap setuid)
1895 if test "x$enable_setuid_install" = "xno" ; then
1896         AC_MSG_RESULT(no)
1897 else
1898         if test "x$enable_setcap_install" = "xyes" ; then
1899                 enable_setuid_install=no
1900                 AC_MSG_RESULT(no; using setcap instead)
1901         elif test "x$enable_dumpcap" = "xno" ; then
1902                 AC_MSG_ERROR(Setuid install works only with dumpcap but dumpcap is disabled)
1903         else
1904                 AC_MSG_RESULT(yes)
1905         fi
1906 fi
1907
1908 AM_CONDITIONAL(SETUID_INSTALL, test x$enable_setuid_install = xyes)
1909 AC_CHECK_FUNCS(setresuid setresgid)
1910
1911 dnl ...but our Network Operations group is named "no"!
1912 DUMPCAP_GROUP=''
1913 AC_ARG_WITH(dumpcap-group,
1914   AC_HELP_STRING( [--with-dumpcap-group=GROUP],
1915                   [restrict dumpcap to GROUP]),
1916 [
1917   if test "x$withval" = "xyes"; then
1918       AC_MSG_ERROR([No dumpcap group specified.])
1919   elif test "x$withval" != "xno"; then
1920       if test "x$enable_dumpcap" = "xno" ; then
1921           AC_MSG_ERROR(dumpcap group install works only with dumpcap but dumpcap is disabled)
1922       fi
1923       AC_MSG_RESULT($withval)
1924       DUMPCAP_GROUP="$withval"
1925   fi
1926 ])
1927 AC_SUBST(DUMPCAP_GROUP)
1928 AM_CONDITIONAL(HAVE_DUMPCAP_GROUP, test x$DUMPCAP_GROUP != x)
1929
1930 dnl libcap (not libpcap) check
1931 LIBCAP_LIBS=''
1932 AC_MSG_CHECKING(whether to use the libcap capabilities library)
1933
1934 AC_ARG_WITH(libcap,
1935   AC_HELP_STRING( [--with-libcap@<:@=DIR@:>@],
1936                   [use libcap (located in directory DIR, if supplied) for POSIX.1e capabilities management @<:@default=yes, if present@:>@]),
1937 [
1938 if   test "x$withval" = "xno";  then
1939         want_libcap=no
1940 elif test "x$withval" = "xyes"; then
1941         want_libcap=yes
1942 elif test -d "$withval"; then
1943         want_libcap=yes
1944         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
1945 fi
1946 ])
1947 if test "x$with_libcap" = "xno" ; then
1948         AC_MSG_RESULT(no)
1949 else
1950         AC_MSG_RESULT(yes)
1951         AC_WIRESHARK_LIBCAP_CHECK
1952 fi
1953 AC_SUBST(LIBCAP_LIBS)
1954
1955 dnl Checks for header files.
1956 dnl Some of these may not be needed: http://hacks.owlfolio.org/header-survey/
1957 AC_CHECK_HEADERS(direct.h dirent.h fcntl.h grp.h inttypes.h netdb.h pwd.h stdarg.h stddef.h unistd.h)
1958 AC_CHECK_HEADERS(sys/ioctl.h sys/param.h sys/socket.h sys/sockio.h sys/stat.h sys/time.h sys/types.h sys/utsname.h sys/wait.h)
1959 AC_CHECK_HEADERS(netinet/in.h)
1960 AC_CHECK_HEADERS(arpa/inet.h arpa/nameser.h)
1961
1962 dnl SSL Check
1963 SSL_LIBS=''
1964 AC_MSG_CHECKING(whether to use SSL library)
1965
1966 AC_ARG_WITH(ssl,
1967   AC_HELP_STRING( [--with-ssl@<:@=DIR@:>@],
1968                   [use SSL crypto library (located in directory DIR, if supplied) @<:@default=no@:>@]),
1969 [
1970 if test "x$withval" = "xno";  then
1971         want_ssl=no
1972 elif test "x$withval" = "xyes"; then
1973         want_ssl=yes
1974 elif test -d "$withval"; then
1975         want_ssl=yes
1976         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
1977 fi
1978 ],[
1979         want_ssl=no
1980 ])
1981 if test "x$want_ssl" = "xyes"; then
1982         AC_MSG_RESULT(yes)
1983         AC_CHECK_LIB(crypto,EVP_md5,
1984             [
1985                 SSL_LIBS=-lcrypto
1986             ],
1987             [
1988                 AC_MSG_ERROR([SSL crypto library was requested, but is not available])
1989             ])
1990 else
1991         AC_MSG_RESULT(no)
1992 fi
1993 AC_SUBST(SSL_LIBS)
1994
1995 dnl kerberos check
1996 AC_MSG_CHECKING(whether to use Kerberos library)
1997
1998 AC_ARG_WITH(krb5,
1999   AC_HELP_STRING( [--with-krb5@<:@=DIR@:>@],
2000                   [use Kerberos library (located in directory DIR, if supplied) to use in Kerberos dissection @<:@default=yes@:>@]),
2001 [
2002         if test $withval = no
2003         then
2004                 want_krb5=no
2005         elif test $withval = yes
2006         then
2007                 want_krb5=yes
2008         else
2009                 want_krb5=yes
2010                 krb5_dir=$withval
2011         fi
2012 ],[
2013         #
2014         # Use Kerberos library if available, otherwise don't.
2015         #
2016         want_krb5=ifavailable
2017         krb5_dir=
2018 ])
2019 if test "x$want_krb5" = "xno" ; then
2020         AC_MSG_RESULT(no)
2021 else
2022         AC_MSG_RESULT(yes)
2023         AC_WIRESHARK_KRB5_CHECK
2024 fi
2025
2026
2027 dnl c-ares Check
2028 C_ARES_LIBS=''
2029 AC_MSG_CHECKING(whether to use the c-ares library if available)
2030
2031 AC_ARG_WITH(c-ares,
2032   AC_HELP_STRING( [--with-c-ares@<:@=DIR@:>@],
2033                   [use c-ares (located in directory DIR, if supplied) - supersedes --with-adns @<:@default=yes, if present@:>@]),
2034 [
2035 if   test "x$withval" = "xno";  then
2036         want_c_ares=no
2037 elif test "x$withval" = "xyes"; then
2038         want_c_ares=yes
2039 elif test -d "$withval"; then
2040         want_c_ares=yes
2041         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
2042 fi
2043 ])
2044 if test "x$want_c_ares" = "xno" ; then
2045         AC_MSG_RESULT(no)
2046 else
2047         AC_MSG_RESULT(yes)
2048         AC_WIRESHARK_C_ARES_CHECK
2049 fi
2050 AC_SUBST(C_ARES_LIBS)
2051
2052 dnl ADNS Check
2053 ADNS_LIBS=''
2054 AC_MSG_CHECKING(whether to use the GNU ADNS library if available)
2055
2056 AC_ARG_WITH(adns,
2057   AC_HELP_STRING( [--with-adns@<:@=DIR@:>@],
2058                   [use GNU ADNS (located in directory DIR, if supplied) @<:@default=yes, if present@:>@]),
2059 [
2060 if   test "x$withval" = "xno";  then
2061         want_adns=no
2062 elif test "x$withval" = "xyes"; then
2063         want_adns=yes
2064 elif test -d "$withval"; then
2065         want_adns=yes
2066         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
2067 fi
2068 ])
2069 if test "x$want_adns" = "xno" -o "x$have_good_c_ares" = "xyes" ; then
2070         AC_MSG_RESULT(no)
2071 else
2072         AC_MSG_RESULT(yes)
2073         AC_WIRESHARK_ADNS_CHECK
2074 fi
2075 AC_SUBST(ADNS_LIBS)
2076
2077 dnl GEOIP Check
2078 GEOIP_LIBS=''
2079 AC_MSG_CHECKING(whether to use the GeoIP IP address mapping library if available)
2080
2081 AC_ARG_WITH(geoip,
2082   AC_HELP_STRING( [--with-geoip@<:@=DIR@:>@],
2083                   [use GeoIP (located in directory DIR, if supplied) @<:@default=yes, if present@:>@]),
2084 [
2085 if   test "x$withval" = "xno";  then
2086         want_geoip=no
2087 elif test "x$withval" = "xyes"; then
2088         want_geoip=yes
2089 elif test -d "$withval"; then
2090         want_geoip=yes
2091         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
2092 fi
2093 ])
2094 if test "x$want_geoip" = "xno"; then
2095         AC_MSG_RESULT(no)
2096 else
2097         AC_MSG_RESULT(yes)
2098         AC_WIRESHARK_GEOIP_CHECK
2099 fi
2100 AC_SUBST(GEOIP_LIBS)
2101
2102 # Warning: this Python scripting appears to be broken (does not work at all).
2103 # Running it also causes Valgrind to complain about all sorts of memory errors.
2104 # Suggestion: do not enable it unless you are working on fixing it.
2105 #
2106 # An alternative might be https://code.google.com/p/pyreshark/
2107 #
2108 dnl Python devel Check
2109 AC_MSG_CHECKING(whether to use the Python interpreter for scripting)
2110
2111 AC_ARG_WITH(broken-python,
2112     AC_HELP_STRING( [--with-broken-python@<:@=DIR@:>@],
2113                     [use the (BROKEN) Python interpreter (installed in DIR, if supplied) @<:@default=no@:>@]),
2114 [
2115         pythondir='${libdir}/wireshark/python/${VERSION}'
2116         if test "x$withval" = "xno"
2117         then
2118                 want_python=no
2119         elif test "x$withval" = "xyes"
2120         then
2121                 want_python=yes
2122         else
2123                 want_python=yes
2124                 pythondir="$withval"
2125         fi
2126 ],[
2127         # By default (user didn't explicitly enable Python), don't enable
2128         # Python support.
2129         #
2130         want_python=no
2131         #pythondir='${libdir}/wireshark/python/${VERSION}'
2132 ])
2133 if test "x$want_python" = "xno" ; then
2134         AC_MSG_RESULT(no)
2135 else
2136         AC_MSG_RESULT(yes)
2137         AC_WIRESHARK_PYTHON_CHECK
2138 fi
2139 AM_CONDITIONAL(HAVE_LIBPY, test x$want_python != xno)
2140 AC_SUBST(pythondir)
2141
2142 #
2143 # Define WS_MSVC_NORETURN appropriately for declarations of routines that
2144 # never return (just like Charlie on the MTA).
2145 #
2146 # Note that MSVC++ expects __declspec(noreturn) to precede the function
2147 # name and GCC, as far as I know, expects __attribute__((noreturn)) to
2148 # follow the function name, so we need two different flavors of
2149 # noreturn tag.
2150 #
2151 AC_DEFINE(WS_MSVC_NORETURN,, [Define as the string to precede declarations of routines that never return])
2152
2153 dnl Checks for typedefs, structures, and compiler characteristics.
2154 # AC_C_CONST
2155
2156 # Check how we can get the time zone abbreviation
2157 AC_WIRESHARK_TIMEZONE_ABBREV
2158
2159 # We need to know whether "struct stat" has an "st_flags" member
2160 # for file_user_immutable().
2161
2162 AC_WIRESHARK_STRUCT_ST_FLAGS
2163
2164 # We need to know whether "struct sockaddr" has an "sa_len" member
2165 # for get_interface_list().
2166
2167 AC_WIRESHARK_STRUCT_SA_LEN
2168
2169 # We must know our byte order
2170 AC_C_BIGENDIAN
2171
2172 # Checks whether "-traditional" is needed when using "ioctl".
2173 # XXX - do we need this?
2174 AC_PROG_GCC_TRADITIONAL
2175
2176 GETOPT_LO=""
2177 AC_CHECK_FUNC(getopt,
2178   [GETOPT_LO=""
2179    AC_DEFINE(HAVE_GETOPT, 1, [Define to 1 if you have the getopt function.])
2180   ],
2181   GETOPT_LO="wsgetopt.lo"
2182 )
2183 if test "$ac_cv_func_getopt" = no ; then
2184   GETOPT_LO="wsgetopt.lo"
2185 fi
2186 AM_CONDITIONAL(NEED_GETOPT_LO, test "x$ac_cv_func_getopt" = "xno")
2187 AC_SUBST(GETOPT_LO)
2188
2189 AC_CHECK_FUNC(strncasecmp, STRNCASECMP_LO="",
2190   STRNCASECMP_LO="strncasecmp.lo")
2191 if test "$ac_cv_func_strncasecmp" = no ; then
2192   STRNCASECMP_LO="strncasecmp.lo"
2193 fi
2194 AM_CONDITIONAL(NEED_STRNCASECMP_LO, test "x$ac_cv_func_strncasecmp" = "xno")
2195 AC_SUBST(STRNCASECMP_LO)
2196
2197 AC_CHECK_FUNCS(mkstemp mkdtemp)
2198
2199 AC_SEARCH_LIBS(inet_aton, [socket nsl], have_inet_aton=yes,
2200     have_inet_aton=no)
2201 if test "$have_inet_aton" = no; then
2202   INET_ATON_LO="inet_aton.lo"
2203   AC_DEFINE(NEED_INET_ATON_H, 1, [Define if inet/aton.h needs to be included])
2204 else
2205   INET_ATON_LO=""
2206 fi
2207 AM_CONDITIONAL(NEED_INET_ATON_LO, test "x$have_inet_aton" = "xno")
2208 AC_SUBST(INET_ATON_LO)
2209
2210 AC_SEARCH_LIBS(inet_pton, [socket nsl], [
2211   dnl check for pre-BIND82 inet_pton() bug.
2212   AC_MSG_CHECKING(for broken inet_pton)
2213   AC_TRY_RUN([#include <sys/types.h>
2214 #include <sys/socket.h>
2215 #include <netinet/in.h>
2216 #include <arpa/inet.h>
2217 int main()
2218 {
2219 #ifdef AF_INET6
2220   char buf[16];
2221   /* this should return 0 (error) */
2222   return inet_pton(AF_INET6, "0:1:2:3:4:5:6:7:", buf);
2223 #else
2224   return 1;
2225 #endif
2226 }], [AC_MSG_RESULT(ok);
2227 have_inet_pton=yes], [AC_MSG_RESULT(broken);
2228 have_inet_pton=no], [AC_MSG_RESULT(cross compiling, assume it is broken);
2229 have_inet_pton=no])],
2230 have_inet_pton=no)
2231 if test "$have_inet_pton" = no; then
2232   INET_PTON_LO="inet_pton.lo"
2233 else
2234   INET_PTON_LO=""
2235 fi
2236 AM_CONDITIONAL(NEED_INET_PTON_LO, test "x$have_inet_pton" = "xno")
2237 AC_SUBST(INET_PTON_LO)
2238
2239 AC_SEARCH_LIBS(inet_ntop, [socket nsl], [
2240   AC_MSG_CHECKING([for inet_ntop prototype])
2241   AC_TRY_COMPILE([#include <stdio.h>
2242 #include <sys/types.h>
2243 #include <sys/socket.h>
2244 #include <netinet/in.h>
2245 #include <arpa/inet.h>
2246
2247 extern const char *inet_ntop(int, const void *, char *, size_t);],, [
2248     AC_MSG_RESULT(yes)
2249     AC_DEFINE(HAVE_INET_NTOP_PROTO, 1,
2250     [Define if inet_ntop() prototype exists])], [
2251     AC_TRY_COMPILE([#include <stdio.h>
2252 #include <sys/types.h>
2253 #include <sys/socket.h>
2254 #include <netinet/in.h>
2255 #include <arpa/inet.h>
2256
2257 extern const char *inet_ntop(int, const void *, char *, socklen_t);],, [
2258       AC_MSG_RESULT(yes)
2259       AC_DEFINE(HAVE_INET_NTOP_PROTO, 1,
2260       [Define if inet_ntop() prototype exists])], [
2261       AC_MSG_RESULT(no)])])
2262   INET_NTOP_LO=""], [
2263   INET_NTOP_LO="inet_ntop.lo"
2264   AC_DEFINE(NEED_INET_V6DEFS_H, 1,
2265   [Define if inet/v6defs.h needs to be included])])
2266 AM_CONDITIONAL(NEED_INET_NTOP_LO, test "x$INET_NTOP_LO" != "x")
2267 AC_SUBST(INET_NTOP_LO)
2268
2269 AC_CHECK_FUNC(strptime, STRPTIME_LO="",
2270   [STRPTIME_LO="strptime.lo"
2271    AC_DEFINE(NEED_STRPTIME_H, 1, [Define if strptime.h needs to be included])
2272 ])
2273 if test "$ac_cv_func_strptime" = no ; then
2274   STRPTIME_LO="strptime.lo"
2275 fi
2276 AC_SUBST(STRPTIME_C)
2277 AM_CONDITIONAL(NEED_STRPTIME_LO, test "x$ac_cv_func_strptime" = "no")
2278 AC_SUBST(STRPTIME_LO)
2279
2280 AC_CHECK_FUNCS(getprotobynumber gethostbyname2)
2281 AC_CHECK_FUNCS(issetugid)
2282 AC_CHECK_FUNCS(mmap mprotect sysconf)
2283 AC_CHECK_FUNCS(strtoll)
2284
2285 dnl blank for now, but will be used in future
2286 AC_SUBST(wireshark_SUBDIRS)
2287
2288 dnl
2289 dnl check whether plugins should be enabled and, if they should be,
2290 dnl check for plugins directory - stolen from Amanda's configure.ac
2291 dnl
2292 dnl we don't wish to expand ${libdir} yet
2293 plugindir='${libdir}/wireshark/plugins/${VERSION}'
2294 AC_ARG_WITH(plugins,
2295   AC_HELP_STRING( [--with-plugins@<:@=DIR@:>@],
2296                   [support plugins (installed in DIR, if supplied) @<:@default=yes, if possible@:>@]),
2297 [
2298   if test "x$withval" = "xno"; then
2299     have_plugins=no
2300   elif test "x$have_plugins" = "xno"; then
2301       AC_MSG_ERROR([GLib on this platform doesn't support loadable modules, so you can't enable plugins.])
2302   elif test "x$withval" != "xyes"; then
2303       plugindir="$withval"
2304   fi
2305 ])
2306 AM_CONDITIONAL(HAVE_PLUGINS, test "x$have_plugins" = "xyes")
2307 if test x$have_plugins = xyes
2308 then
2309   AC_DEFINE(HAVE_PLUGINS, 1, [Define if plugins are enabled])
2310 fi
2311 AC_SUBST(plugindir)
2312 CPPFLAGS="$CPPFLAGS '-DPLUGIN_DIR=\"\$(plugindir)\"'"
2313
2314 #
2315 # The plugin dissectors reside in ./plugins/PROTO/
2316 #
2317 PLUGIN_LIBS=""
2318 AC_SUBST(PLUGIN_LIBS)
2319
2320 #
2321 # Check if (emem) memory allocations must be 8-byte aligned.
2322 # I haven't been able to write C code that reliably makes that determination
2323 # (different versions of GCC with or without optimization give different
2324 # results) so just assume everything except (32-bit) x86 needs 8-byte
2325 # alignment (64-bit platforms either require 8-byte alignment for pointers
2326 # and 64-bit integral data types or may get better performance from that;
2327 # 64-bit x86 will get 8-byte alignment from G_MEM_ALIGN anyway.  32-bit
2328 # platforms would only require it, or get better performance from it,
2329 # for 64-bit floating-point values.).
2330 #
2331 AC_MSG_CHECKING(whether we need memory allocations to be 8-byte aligned)
2332 case $host_cpu in
2333         i386|i486|i586|i686)
2334                 AC_MSG_RESULT(no)
2335                 ;;
2336         *)
2337                 AC_MSG_RESULT(yes)
2338                 AC_DEFINE(NEED_8_BYTE_ALIGNMENT, 1, [Define if we need memory allocations to be 8-byte aligned])
2339                 ;;
2340 esac
2341
2342 dnl libtool defs
2343 #
2344 # Yes, AM_PROG_LIBTOOL is redundant with newer version(s) of some tool(s)
2345 # (autoconf?  automake?  libtool?) - with the newer version(s), it's
2346 # just an alias for AC_PROG_LIBTOOL, which is called earlier.
2347 #
2348 # With older version(s) of those tool(s), however, it's not just an
2349 # alias, and the configure scripts don't work without it.
2350 #
2351 AM_PROG_LIBTOOL
2352 AC_SUBST(LIBTOOL_DEPS)
2353
2354 AM_CONDITIONAL(ENABLE_STATIC, test x$enable_static = xyes)
2355 if test x$enable_static = xyes -a x$have_plugins = xyes
2356 then
2357   AC_DEFINE(ENABLE_STATIC, 1, [Link plugins statically into Wireshark])
2358 fi
2359 AC_SUBST(ENABLE_STATIC)
2360
2361 dnl Save the cacheable configure results to config.cache before recursing
2362 AC_CACHE_SAVE
2363
2364 sinclude(plugins/Custom.m4) dnl
2365 ifdef(_CUSTOM_AC_OUTPUT_,, define(_CUSTOM_AC_OUTPUT_, )) dnl
2366
2367 sinclude(asn1/Custom.m4) dnl
2368 ifdef(_CUSTOM_ASN1_AC_OUTPUT_,, define(_CUSTOM_ASN1_AC_OUTPUT_, )) dnl
2369
2370 AC_CONFIG_HEADERS(config.h)
2371 AC_OUTPUT(
2372   Makefile
2373   doxygen.cfg
2374   asn1/Makefile
2375   _CUSTOM_ASN1_AC_OUTPUT_
2376   asn1/acp133/Makefile
2377   asn1/acse/Makefile
2378   asn1/ansi_map/Makefile
2379   asn1/ansi_tcap/Makefile
2380   asn1/c1222/Makefile
2381   asn1/camel/Makefile
2382   asn1/cdt/Makefile
2383   asn1/charging_ase/Makefile
2384   asn1/cmip/Makefile
2385   asn1/cmp/Makefile
2386   asn1/crmf/Makefile
2387   asn1/cms/Makefile
2388   asn1/credssp/Makefile
2389   asn1/dap/Makefile
2390   asn1/disp/Makefile
2391   asn1/dop/Makefile
2392   asn1/dsp/Makefile
2393   asn1/ess/Makefile
2394   asn1/ftam/Makefile
2395   asn1/gnm/Makefile
2396   asn1/goose/Makefile
2397   asn1/gprscdr/Makefile
2398   asn1/gsm_map/Makefile
2399   asn1/h225/Makefile
2400   asn1/h235/Makefile
2401   asn1/h245/Makefile
2402   asn1/h248/Makefile
2403   asn1/h282/Makefile
2404   asn1/h283/Makefile
2405   asn1/h323/Makefile
2406   asn1/h450/Makefile
2407   asn1/h450-ros/Makefile
2408   asn1/h460/Makefile
2409   asn1/h501/Makefile
2410   asn1/HI2Operations/Makefile
2411   asn1/hnbap/Makefile
2412   asn1/idmp/Makefile
2413   asn1/inap/Makefile
2414   asn1/isdn-sup/Makefile
2415   asn1/kerberos/Makefile
2416   asn1/lcsap/Makefile
2417   asn1/ldap/Makefile
2418   asn1/logotypecertextn/Makefile
2419   asn1/lpp/Makefile
2420   asn1/lppa/Makefile
2421   asn1/lppe/Makefile
2422   asn1/lte-rrc/Makefile
2423   asn1/m3ap/Makefile
2424   asn1/mms/Makefile
2425   asn1/mpeg-audio/Makefile
2426   asn1/mpeg-pes/Makefile
2427   asn1/nbap/Makefile
2428   asn1/ns_cert_exts/Makefile
2429   asn1/ocsp/Makefile
2430   asn1/p1/Makefile
2431   asn1/p22/Makefile
2432   asn1/p7/Makefile
2433   asn1/p772/Makefile
2434   asn1/pcap/Makefile
2435   asn1/pkcs1/Makefile
2436   asn1/pkcs12/Makefile
2437   asn1/pkinit/Makefile
2438   asn1/pkixac/Makefile
2439   asn1/pkix1explicit/Makefile
2440   asn1/pkix1implicit/Makefile
2441   asn1/pkixproxy/Makefile
2442   asn1/pkixqualified/Makefile
2443   asn1/pkixtsp/Makefile
2444   asn1/pres/Makefile
2445   asn1/q932/Makefile
2446   asn1/q932-ros/Makefile
2447   asn1/qsig/Makefile
2448   asn1/ranap/Makefile
2449   asn1/rnsap/Makefile
2450   asn1/ros/Makefile
2451   asn1/rrc/Makefile
2452   asn1/rrlp/Makefile
2453   asn1/rtse/Makefile
2454   asn1/rua/Makefile
2455   asn1/s1ap/Makefile
2456   asn1/sabp/Makefile
2457   asn1/sbc-ap/Makefile
2458   asn1/smrse/Makefile
2459   asn1/snmp/Makefile
2460   asn1/spnego/Makefile
2461   asn1/sv/Makefile
2462   asn1/t124/Makefile
2463   asn1/t125/Makefile
2464   asn1/t38/Makefile
2465   asn1/tcap/Makefile
2466   asn1/tetra/Makefile
2467   asn1/ulp/Makefile
2468   asn1/wlancertextn/Makefile
2469   asn1/x2ap/Makefile
2470   asn1/x509af/Makefile
2471   asn1/x509ce/Makefile
2472   asn1/x509if/Makefile
2473   asn1/x509sat/Makefile
2474   asn1/x721/Makefile
2475   doc/Makefile
2476   docbook/Makefile
2477   epan/Makefile
2478   epan/crypt/Makefile
2479   epan/doxygen.cfg
2480   epan/dfilter/Makefile
2481   epan/dissectors/Makefile
2482   epan/dissectors/dcerpc/Makefile
2483   epan/dissectors/pidl/Makefile
2484   epan/ftypes/Makefile
2485   epan/wmem/Makefile
2486   epan/wslua/Makefile
2487   epan/wspython/Makefile
2488   codecs/Makefile
2489   ui/Makefile
2490   ui/doxygen.cfg
2491   ui/gtk/Makefile
2492   ui/gtk/doxygen.cfg
2493   ui/cli/Makefile
2494   ui/qt/Makefile
2495   ui/qt/doxygen.cfg
2496   help/Makefile
2497   packaging/Makefile
2498   packaging/macosx/Info.plist
2499   packaging/macosx/Makefile
2500   packaging/macosx/osx-dmg.sh
2501   packaging/nsis/Makefile
2502   packaging/rpm/Makefile
2503   packaging/rpm/SPECS/Makefile
2504   packaging/rpm/SPECS/wireshark.spec
2505   packaging/svr4/Makefile
2506   packaging/svr4/checkinstall
2507   packaging/svr4/pkginfo
2508   plugins/Makefile
2509   plugins/asn1/Makefile
2510   plugins/docsis/Makefile
2511   plugins/ethercat/Makefile
2512   plugins/gryphon/Makefile
2513   plugins/irda/Makefile
2514   plugins/m2m/Makefile
2515   plugins/mate/Makefile
2516   plugins/opcua/Makefile
2517   plugins/profinet/Makefile
2518   plugins/stats_tree/Makefile
2519   plugins/unistim/Makefile
2520   plugins/wimax/Makefile
2521   plugins/wimaxasncp/Makefile
2522   plugins/wimaxmacphy/Makefile
2523   tools/Makefile
2524   tools/lemon/Makefile
2525   wiretap/Makefile
2526   wsutil/Makefile
2527   echld/Makefile
2528   _CUSTOM_AC_OUTPUT_
2529   ,)
2530 dnl AC_CONFIG_FILES([tools/setuid-root.pl], [chmod +x tools/setuid-root.pl])
2531
2532
2533 # Pretty messages
2534
2535 if test "x$have_gtk" = "xyes"; then
2536         if test "x$with_gtk3" = "xyes"; then
2537                 gtk_lib_message=" (with GTK+ 3"
2538         else
2539                 gtk_lib_message=" (with GTK+ 2"
2540         fi
2541         if test "x$have_ige_mac" = "xyes"; then
2542                 gtk_lib_message="$gtk_lib_message and Mac OS X integration)"
2543         else
2544                 gtk_lib_message="$gtk_lib_message)"
2545         fi
2546 fi
2547
2548 if test "x$have_qt" = "xyes" ; then
2549         enable_qtshark="yes"
2550 else
2551         enable_qtshark="no"
2552 fi
2553
2554 if test "x$enable_setcap_install" = "xyes" ; then
2555         setcap_message="yes"
2556 else
2557         setcap_message="no"
2558 fi
2559
2560 if test "x$enable_setuid_install" = "xyes" ; then
2561         setuid_message="yes"
2562 else
2563         setuid_message="no"
2564 fi
2565
2566 if test "x$DUMPCAP_GROUP" = "x" ; then
2567         dumpcap_group_message="(none)"
2568 else
2569         dumpcap_group_message="$DUMPCAP_GROUP"
2570 fi
2571
2572 if test "x$want_zlib" = "xno" ; then
2573         zlib_message="no"
2574 else
2575         zlib_message="yes"
2576 fi
2577
2578 if test "x$want_lua" = "xyes" ; then
2579         lua_message="yes"
2580 else
2581         lua_message="no"
2582 fi
2583
2584 if test "x$want_python" = "xno"; then
2585         python_message="no"
2586 else
2587         python_message="yes"
2588 fi
2589
2590 if test "x$want_portaudio" = "xyes" ; then
2591         portaudio_message="yes"
2592 else
2593         portaudio_message="no"
2594 fi
2595
2596 if test "x$want_ssl" = "xno" ; then
2597         ssl_message="no"
2598 else
2599         ssl_message="yes"
2600 fi
2601
2602 if test "x$want_krb5" = "xno" ; then
2603         krb5_message="no"
2604 else
2605         krb5_message="yes ($ac_krb5_version)"
2606 fi
2607
2608 if test "x$have_good_c_ares" = "xyes" ; then
2609         c_ares_message="yes"
2610 else
2611         c_ares_message="no"
2612 fi
2613
2614 if test "x$have_good_adns" = "xyes" ; then
2615         adns_message="yes"
2616 else
2617         if test "x$have_good_c_ares" = "xyes" ; then
2618                 adns_message="no (using c-ares instead)"
2619         else
2620                 adns_message="no"
2621         fi
2622 fi
2623
2624 if test "x$have_good_libcap" = "xyes" ; then
2625         libcap_message="yes"
2626 else
2627         libcap_message="no"
2628 fi
2629
2630 if test "x$have_good_geoip" = "xyes" ; then
2631         geoip_message="yes"
2632 else
2633         geoip_message="no"
2634 fi
2635
2636 echo ""
2637 echo "The Wireshark package has been configured with the following options."
2638 echo "             Build wireshark (Gtk+) : $have_gtk""$gtk_lib_message"
2639 echo "                 Build wireshark-qt : $enable_qtshark"
2640 echo "                       Build tshark : $enable_tshark"
2641 echo "                     Build capinfos : $enable_capinfos"
2642 echo "                      Build editcap : $enable_editcap"
2643 echo "                      Build dumpcap : $enable_dumpcap"
2644 echo "                     Build mergecap : $enable_mergecap"
2645 echo "                   Build reordercap : $enable_reordercap"
2646 echo "                    Build text2pcap : $enable_text2pcap"
2647 echo "                      Build randpkt : $enable_randpkt"
2648 echo "                       Build dftest : $enable_dftest"
2649 echo "                     Build rawshark : $enable_rawshark"
2650 echo "                        Build echld : $have_echld"
2651 echo ""
2652 echo "   Save files as pcap-ng by default : $enable_pcap_ng_default"
2653 echo "  Install dumpcap with capabilities : $setcap_message"
2654 echo "             Install dumpcap setuid : $setuid_message"
2655 echo "                  Use dumpcap group : $dumpcap_group_message"
2656 echo "                        Use plugins : $have_plugins"
2657 echo "                    Use Lua library : $lua_message"
2658 echo "                 Use Python binding : $python_message"
2659 echo "                   Build rtp_player : $portaudio_message"
2660 echo "             Build profile binaries : $enable_profile_build"
2661 echo "                   Use pcap library : $want_pcap"
2662 echo "                   Use zlib library : $zlib_message"
2663 echo "               Use kerberos library : $krb5_message"
2664 echo "                 Use c-ares library : $c_ares_message"
2665 echo "               Use GNU ADNS library : $adns_message"
2666 echo "                Use SMI MIB library : $libsmi_message"
2667 echo "             Use GNU crypto library : $gcrypt_message"
2668 echo "             Use SSL crypto library : $ssl_message"
2669 echo "           Use IPv6 name resolution : $enable_ipv6"
2670 echo "                 Use gnutls library : $tls_message"
2671 echo "     Use POSIX capabilities library : $libcap_message"
2672 echo "                  Use GeoIP library : $geoip_message"
2673 echo "                     Use nl library : $libnl_message"