configure.ac

   1 # $Id$
   2 #
   3
   4 m4_define([version_major], [1])
   5 m4_define([version_minor], [11])
   6 m4_define([version_micro], [0])
   7 m4_define([version_micro_extra], version_micro)
   8 m4_append([version_micro_extra], [])
   9
  10 AC_INIT(wireshark, [version_major.version_minor.version_micro_extra], http://bugs.wireshark.org/, , http://www.wireshark.org/)
  11
  12 # Minimum autoconf version we require.
  13 AC_PREREQ(2.60)
  14 # Variable expansion doesn't work in AC_PREREQ()
  15 AC_MIN_VERSION=2.60
  16 AC_SUBST(AC_MIN_VERSION)
  17
  18 dnl Check for CPU / vendor / OS
  19 dnl The user is encouraged to use either `AC_CANONICAL_BUILD', or
  20 dnl `AC_CANONICAL_HOST', or `AC_CANONICAL_TARGET', depending on the
  21 dnl needs.  Using `AC_CANONICAL_TARGET' is enough to run the two other
  22 dnl macros.
  23 dnl
  24 dnl As nothing in the Wireshark is itself a build tool (we are not,
  25 dnl for example, a compiler that generates machine code), we probably
  26 dnl don't need AC_CANONICAL_TARGET, so, in theory, we should be able
  27 dnl to use AC_CANONICAL_BUILD and AC_CANONICAL_HOST - or perhaps just
  28 dnl AC_CANONICAL_HOST - instead.  Note that we do have tools, such as
  29 dnl lemon, that need to be built for the build machine, not for the
  30 dnl host machine, so we might need both.
  31 dnl
  32 dnl This has to be done *after* AC_INIT, otherwise autogen.sh fails.
  33
  34 dnl AC_CANONICAL_BUILD
  35 dnl AC_CANONICAL_HOST
  36 AC_CANONICAL_TARGET
  37
  38 AM_INIT_AUTOMAKE([1.9 tar-ustar dist-bzip2 no-dist-gzip])
  39
  40 # Make Wireshark's version available in config.h
  41 AC_DEFINE(VERSION_MAJOR, version_major, [Wireshark's major version])
  42 AC_DEFINE(VERSION_MINOR, version_minor, [Wireshark's minor version])
  43 AC_DEFINE(VERSION_MICRO, version_micro, [Wireshark's micro version])
  44
  45 AM_DISABLE_STATIC
  46
  47 #
  48 # Checks for programs used in the main build process.
  49 #
  50 AC_PROG_CC
  51 AM_PROG_CC_C_O
  52 AC_PROG_CXX
  53 AC_PROG_CPP
  54 dnl Work around libtool bug (fixed in the version 1.5a?)
  55 AC_DEFUN([AC_PROVIDE_AC_LIBTOOL_DLOPEN], )
  56 AC_LIBTOOL_DLOPEN
  57 AC_PROG_LIBTOOL
  58 AC_PATH_PROG(PERL, perl)
  59
  60 # Check for Python.
  61 AC_PATH_PROG(PYTHON, python)
  62 if test ! -z "$PYTHON"; then
  63         #
  64         # OK, we found Python; is it Python 2.x?
  65         # Note: we don't use named components for sys.version_info to get
  66         # the major version number, as named components for version_info
  67         # were apparently introduced in Python 2.7.
  68         #
  69         AC_MSG_CHECKING([whether $PYTHON is Python 2])
  70         python_major_version=`$PYTHON -c 'import sys; print sys.version_info[[0]]'`
  71         if test "$python_major_version" = 2; then
  72                 AC_MSG_RESULT([yes])
  73         else
  74                 #
  75                 # It's not 2.x.
  76                 #
  77                 AC_MSG_RESULT([no])
  78
  79                 #
  80                 # Try looking for python2; if we find it, we assume it's
  81                 # Python 2
  82                 #
  83                 AC_PATH_PROG(PYTHON, python2)
  84         fi
  85 fi
  86
  87 #
  88 # XXX - should autogen.sh check for YACC/Bison and Flex?  A user building
  89 # from a distribution tarball shouldn't have to have YACC/Bison or Flex,
  90 # as the tarball should contain the results of running YACC/Bison on .y
  91 # files and running Flex on .l files, but a user building from SVN
  92 # will have to run YACC/Bison and Flex to process those files.
  93 #
  94 # On the other hand, what about users who use a distribution tarball to
  95 # do development?  They *shouldn't* - that's what the SVN repository is
  96 # for - but they might.  They'd get errors if they modify a .y or .l
  97 # file and try to do a build - but the error should tell them that they
  98 # need to get YACC/Bison and/or Flex.
  99 #
 100 # Then again, getting them shouldn't be too big of a burden.
 101 #
 102 # XXX - is the same true of pod2man and pod2html, or are they needed
 103 # even when building from a distribution tarball?
 104 #
 105 #
 106 AC_PROG_YACC
 107 AC_PATH_PROG(YACCDUMMY, $YACC)
 108 if test "x$YACCDUMMY" = x
 109 then
 110         AC_MSG_ERROR(I couldn't find yacc (or bison or ...); make sure it's installed and in your path)
 111 fi
 112 AM_PROG_LEX
 113 AC_PATH_PROG(LEX, flex)
 114 if test "x$LEX" = x
 115 then
 116         AC_MSG_ERROR(I couldn't find flex; make sure it's installed and in your path)
 117 fi
 118 AC_PATH_PROG(POD2MAN, pod2man)
 119 if test "x$POD2MAN" = x
 120 then
 121         #
 122         # The alternative is not to build the man pages....
 123         #
 124         AC_MSG_ERROR(I couldn't find pod2man; make sure it's installed and in your path)
 125 fi
 126 AC_PATH_PROG(POD2HTML, pod2html)
 127 if test "x$POD2HTML" = x
 128 then
 129         #
 130         # The alternative is not to build the HTML man pages....
 131         #
 132         AC_MSG_ERROR(I couldn't find pod2html; make sure it's installed and in your path)
 133 fi
 134
 135 #
 136 # Checks for programs used by Wireshark/TShark/etc.
 137 #
 138
 139 #
 140 # XXX - this looks for various HTML viewers on the host, not the target;
 141 # we really want to know what's available on the target, for cross-builds.
 142 # That would probably require us to, at run time, look for xdg-open and,
 143 # if we don't find it, look for mozilla, htmlview, etc.
 144 #
 145 AC_PATH_PROG(HTML_VIEWER, xdg-open)
 146 if test "x$HTML_VIEWER" != x
 147 then
 148         #
 149         # XXX - the HTML_VIEWER shell variable is the full path of xdg-open.
 150         # Define some variable to be that, so we just run that?
 151         #
 152         AC_DEFINE(HAVE_XDG_OPEN, 1, [Define if we have xdg-open])
 153
 154         #
 155         # XXX - we have to define HTML_VIEWER for the prefs.c code that
 156         # sets the default value of the Web browser preference, even
 157         # though that preference won't be offered.
 158         #
 159         AC_DEFINE_UNQUOTED(HTML_VIEWER, "xdg-open", [HTML viewer, e.g. mozilla])
 160 else
 161         AC_PATH_PROG(HTML_VIEWER, htmlview)
 162         if test "x$HTML_VIEWER" = x
 163         then
 164                 AC_DEFINE_UNQUOTED(HTML_VIEWER, "mozilla", [HTML viewer, e.g. mozilla])
 165         else
 166                 AC_DEFINE_UNQUOTED(HTML_VIEWER, "htmlview", [HTML viewer, e.g. mozilla])
 167         fi
 168 fi
 169
 170 #
 171 # Set "ac_supports_gcc_flags" if the compiler is known to support GCC-style
 172 # flags such as -pedantic, -W warning flags and -f feature flags.  Currently,
 173 # we assume GCC and clang do; other compilers should be added here.
 174 #
 175 # This is done to avoid getting tripped up by compilers that support
 176 # those flags but give them a different meaning.
 177 #
 178 if test "x$GCC" = "xyes" -o "x$CC" = "xclang" ; then
 179         ac_supports_gcc_flags=yes
 180 fi
 181
 182 #
 183 # Set "ac_supports_W_linker_passthrough" if the compiler is known to
 184 # support "-Wl,{options}" to pass options through to the linker.
 185 # Currently, we assume GCC, xlc, and clang do; other compilers should
 186 # be added here.
 187 #
 188 if test "x$GCC" = "xyes" -o "x$CC" = "xxlc" -o "x$CC" = "xclang" ; then
 189         ac_supports_W_linker_passthrough=yes
 190 fi
 191
 192 #
 193 # Set "ac_supports_attribute_unused" if the compiler is known to
 194 # support "__attribute__(unused)".
 195 # Currently, we assume GCC and clang do; other compilers should
 196 # be added here.
 197 #
 198 # XXX - do this with a compiler test?
 199 #
 200 if test "x$GCC" = "xyes" -o "x$CC" = "xclang" ; then
 201         ac_supports_W_linker_passthrough=yes
 202 fi
 203
 204 if test "x$CC_FOR_BUILD" = x
 205 then
 206        CC_FOR_BUILD=$CC
 207 fi
 208 AC_SUBST(CC_FOR_BUILD)
 209 AC_SUBST(CFLAGS_FOR_BUILD)
 210
 211 # Check for doxygen
 212 AC_PATH_PROG(DOXYGEN, doxygen)
 213 AC_CHECK_PROG(HAVE_DOXYGEN, doxygen, "yes", "no")
 214 AM_CONDITIONAL(HAVE_DOXYGEN, test x$HAVE_DOXYGEN = xyes)
 215
 216 #
 217 # Check for pkg-config and set PKG_CONFIG accordingly.
 218 #
 219 # This is referenced via AC_REQUIRE([PKG_PROG_PKG_CONFIG] in some macros
 220 # like PKG_CHECK_MODULES. If the first call to such a macro is under an
 221 # "if" statement, it's safer to call PKG_PROG_PKG_CONFIG directly, see
 222 # the comments in acolocal.m4
 223 #
 224 PKG_PROG_PKG_CONFIG
 225
 226 #
 227 # Try to arrange for large file support.
 228 #
 229 AC_SYS_LARGEFILE
 230
 231 # GnuTLS
 232 # Version 3.0 switched from LGPLv2.1+ to LGPLv3+, then switched back to
 233 # LGPLv2.1+ in version 3.1.10
 234 tls_message="no"
 235 AC_ARG_WITH([gnutls],
 236   AC_HELP_STRING( [--with-gnutls=@<:@yes/no@:>@],
 237                   [use GnuTLS library @<:@default=yes@:>@]),
 238   with_gnutls="$withval", with_gnutls="yes")
 239 if test "x$with_gnutls" = "xyes"; then
 240   have_license_compatible_gnutls="no"
 241   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 3.1.10 ],
 242     [ have_license_compatible_gnutls="yes" ], [ echo "GnuTLS >= 3.1.10 not found " ]
 243   )
 244
 245   if test "x$have_license_compatible_gnutls" != "xyes"; then
 246     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 1.2.0 gnutls < 3],
 247       [ have_license_compatible_gnutls="yes" ] , [ echo "GnuTLS >= 1.2.0, < 3.0 not found " ]
 248     )
 249   fi
 250
 251   if test "x$have_license_compatible_gnutls" = "xyes"; then
 252     echo "GnuTLS found, enabling SSL decryption"
 253     AC_DEFINE(HAVE_LIBGNUTLS, 1, [Define to use GnuTLS library])
 254     tls_message="yes"
 255   else
 256     echo "GnuTLS with compatible license not found, disabling SSL decryption"
 257     tls_message="no"
 258   fi
 259 fi
 260
 261 # libgrypt
 262 gcrypt_message="no"
 263 AC_ARG_WITH([gcrypt],
 264   AC_HELP_STRING( [--with-gcrypt=@<:@yes/no@:>@],
 265                   [use gcrypt library @<:@default=yes@:>@]),
 266   with_gcrypt="$withval", with_gcrypt="yes")
 267 if test "x$with_gcrypt" = "xyes"; then
 268   AM_PATH_LIBGCRYPT(1.1.92,
 269         [
 270                 echo "libgcrypt found, enabling ipsec decryption"
 271                 AC_DEFINE(HAVE_LIBGCRYPT, 1, [Define to use libgcrypt])
 272                 gcrypt_message="yes"
 273         ]
 274         , [
 275                 if test x$libgcrypt_config_prefix != x ; then
 276                         AC_MSG_ERROR([[libgcrypt not found; install libgcrypt-devel package for your system]])
 277                 else
 278                         echo "libgcrypt not found, disabling ipsec decryption"
 279                         gcrypt_message="no"
 280                 fi
 281         ]
 282   )
 283 fi
 284
 285 AC_ARG_WITH([qt],
 286   AC_HELP_STRING( [--with-qt=@<:@yes/no@:>@],
 287                   [use Qt instead of GTK+ @<:@default=no@:>@]),
 288   with_qt="$withval", with_qt="no")
 289
 290 AC_ARG_WITH(libnl,
 291   AC_HELP_STRING([--with-libnl@<:@=VERSION@:>@],
 292                  [use libnl (force version VERSION, if supplied) @<:@default: yes, if available@:>@]),
 293 [
 294         if test "x$withval" = "xno"
 295         then
 296                 want_libnl=no
 297         elif test "x$withval" = "xyes"
 298         then
 299                 want_libnl=yes
 300                 libnl_version=any
 301         elif test "x$withval" = "x1"
 302         then
 303                 want_libnl=yes
 304                 libnl_version=1
 305         elif test "x$withval" = "x2"
 306         then
 307                 want_libnl=yes
 308                 libnl_version=2
 309         elif test "x$withval" = "x3"
 310         then
 311                 want_libnl=yes
 312                 libnl_version=3
 313         else
 314                 AC_MSG_ERROR(["$withval" is not a valid argument to --with-libnl])
 315         fi
 316 ],[
 317         #
 318         # Use libnl if it's present, otherwise don't.
 319         #
 320         want_libnl=ifavailable
 321         libnl_version=any
 322 ])
 323 #
 324 # Libnl is Linux-specific.
 325 #
 326 libnl_message="no"
 327 case "$host_os" in
 328 linux*)
 329         AC_MSG_CHECKING(whether to use libnl for various network interface purposes)
 330
 331         if test x$want_libnl = "xno"; then
 332                 AC_MSG_RESULT(no)
 333         else
 334                 AC_MSG_RESULT(yes)
 335                 #
 336                 # Test for specific libnl versions only if no version
 337                 # was specified by the user or if the version in question
 338                 # was requested by the user.
 339                 #
 340                 if test x$libnl_version = "xany" -o x$libnl_version = "x3"; then
 341                         PKG_CHECK_MODULES(LIBNL3, [libnl-route-3.0 >= 3.0 libnl-genl-3.0] >= 3.0, [have_libnl3=yes], [have_libnl3=no])
 342                 fi
 343                 if test x$libnl_version = "xany" -o x$libnl_version = "x2"; then
 344                         PKG_CHECK_MODULES(LIBNL2, libnl-2.0 >= 2.0, [have_libnl2=yes], [have_libnl2=no])
 345                 fi
 346                 if test x$libnl_version = "xany" -o x$libnl_version = "x1"; then
 347                         PKG_CHECK_MODULES(LIBNL1, libnl-1 >= 1.0, [have_libnl1=yes], [have_libnl1=no])
 348                 fi
 349                 if (test "${have_libnl3}" = "yes"); then
 350                         CFLAGS="$CFLAGS $LIBNL3_CFLAGS"
 351                         LIBS="$LIBS $LIBNL3_LIBS"
 352                         AC_DEFINE(HAVE_LIBNL, 1, [Enable libnl support])
 353                         AC_DEFINE(HAVE_LIBNL3, 1, [libnl version 3])
 354                         libnl_message="yes (v3)"
 355                         enable_airpcap=no
 356                 elif (test "${have_libnl2}" = "yes"); then
 357                         CFLAGS="$CFLAGS $LIBNL2_CFLAGS"
 358                         LIBS="$LIBS $LIBNL2_LIBS"
 359                         AC_DEFINE(HAVE_LIBNL, 1, [Enable libnl support])
 360                         AC_DEFINE(HAVE_LIBNL2, 1, [libnl version 2])
 361                         libnl_message="yes (v2)"
 362                         enable_airpcap=no
 363                 elif (test "${have_libnl1}" = "yes"); then
 364                         CFLAGS="$CFLAGS $LIBNL1_CFLAGS"
 365                         LIBS="$LIBS $LIBNL1_LIBS"
 366                         AC_DEFINE(HAVE_LIBNL, 1, [Enable libnl support])
 367                         AC_DEFINE(HAVE_LIBNL1, 1, [libnl version 1])
 368                         libnl_message="yes (v1)"
 369                         enable_airpcap=no
 370                 else
 371                         if test x$want_libnl = "xyes"; then
 372                                 case "$libnl_version" in
 373
 374                                 any)
 375                                         AC_MSG_ERROR("I couldn't find libnl even though you manually enabled it.")
 376                                         ;;
 377
 378                                 *)
 379                                         AC_MSG_ERROR("I couldn't find libnl version $libnl_version even though you manually enabled it.")
 380                                         ;;
 381                                 esac
 382                         fi
 383                 fi
 384         fi
 385
 386         AC_MSG_CHECKING([if nl80211.h is new enough])
 387           AC_TRY_COMPILE([#include <linux/nl80211.h>],
 388             [int x = NL80211_FREQUENCY_ATTR_MAX_TX_POWER;
 389                 x = NL80211_ATTR_SUPPORTED_IFTYPES;
 390                 x = NL80211_ATTR_SUPPORTED_COMMANDS;
 391                 x = NL80211_ATTR_WIPHY_FREQ;
 392                 x = NL80211_CHAN_NO_HT;],
 393             [AC_MSG_RESULT(yes) AC_DEFINE(HAVE_NL80211, 1, [nl80211.h is new enough])],
 394             [AC_MSG_RESULT(no)])
 395
 396         AC_MSG_CHECKING([for NL80211_SET_CHANNEL])
 397           AC_TRY_COMPILE([#include <linux/nl80211.h>],
 398             [enum nl80211_commands x = NL80211_CMD_SET_CHANNEL;],
 399             [AC_MSG_RESULT(yes) AC_DEFINE(HAVE_NL80211_CMD_SET_CHANNEL, 1, [SET_CHANNEL is supported])],
 400             [AC_MSG_RESULT(no)])
 401         ;;
 402
 403 *)
 404         if test x$want_libnl != "xno" -a x$want_libnl != "xifavailable"; then
 405                 AC_MSG_WARN([libnl is Linux-specific, ignoring --with-libnl])
 406         fi
 407 esac
 408
 409 AC_ARG_WITH([gtk3],
 410   AC_HELP_STRING( [--with-gtk3=@<:@yes/no@:>@],
 411                   [use GTK+ 3.0 instead of 2.0 @<:@default=no@:>@]),
 412   with_gtk3="$withval", with_gtk3="no")
 413
 414 # libsmi
 415 # FIXME: currently the path argument to with-libsmi is being ignored
 416 AX_LIBSMI
 417
 418 #
 419 # Check for programs used when building DocBook documentation.
 420 #
 421
 422 # Check for a2x (convert asciidoc to another format)
 423 AC_PATH_PROG(A2X, a2x)
 424 AC_CHECK_PROG(HAVE_A2X, a2x, "yes", "no")
 425 AM_CONDITIONAL(HAVE_A2X, test x$HAVE_A2X = xyes)
 426
 427 # Want to control a tape drive? Use mt. Want to convert HTML to text?
 428 # Uhhhhh... elinks? lynx? w3m? pandoc? html2text?
 429 AC_PATH_PROG(ELINKS, elinks)
 430 AC_CHECK_PROG(HAVE_ELINKS, elinks, "yes", "no")
 431 AM_CONDITIONAL(HAVE_ELINKS, test x$HAVE_ELINKS = xyes)
 432
 433 # Check for fop (translate .fo to e.g. pdf)
 434 AC_PATH_PROG(FOP, fop)
 435 AC_CHECK_PROG(HAVE_FOP, fop, "yes", "no")
 436 AM_CONDITIONAL(HAVE_FOP, test x$HAVE_FOP = xyes)
 437
 438 # Check for lynx (html -> text)
 439 AC_PATH_PROG(LYNX, lynx)
 440 AC_CHECK_PROG(HAVE_LYNX, lynx, "yes", "no")
 441 AM_CONDITIONAL(HAVE_LYNX, test x$HAVE_LYNX = xyes)
 442
 443 # Check for w3m (html -> text)
 444 AC_PATH_PROG(W3M, w3m)
 445 AC_CHECK_PROG(HAVE_W3M, w3m, "yes", "no")
 446 AM_CONDITIONAL(HAVE_W3M, test x$HAVE_W3M = xyes)
 447
 448 # Check for xmllint
 449 AC_PATH_PROG(XMLLINT, xmllint)
 450 AC_CHECK_PROG(HAVE_XMLLINT, xmllint, "yes", "no")
 451 AM_CONDITIONAL(HAVE_XMLLINT, test x$HAVE_XMLLINT = xyes)
 452
 453 # Check for xsltproc
 454 AC_PATH_PROG(XSLTPROC, xsltproc)
 455 AC_CHECK_PROG(HAVE_XSLTPROC, xsltproc, "yes", "no")
 456 AM_CONDITIONAL(HAVE_XSLTPROC, test x$HAVE_XSLTPROC = xyes)
 457
 458
 459 # Check for packaging utilities
 460 # For now, we check to see if the various packaging utilites are in our
 461 # path.  I'm too lazy to write code to go hunt for them.  -  Gerald
 462
 463 #
 464 # Source packages.
 465 # (Lets you install the desktop files.)
 466 #
 467 AC_PATH_PROG(DESKTOP_FILE_INSTALL, desktop-file-install)
 468
 469 # SVR4/Solaris
 470 AC_CHECK_PROG(HAVE_PKGPROTO, pkgproto, "yes", "no")
 471 AC_CHECK_PROG(HAVE_PKGMK, pkgmk, "yes", "no")
 472 AC_CHECK_PROG(HAVE_PKGTRANS, pkgtrans, "yes", "no")
 473
 474 if test x$HAVE_PKGPROTO = xyes -a x$HAVE_PKGMK = xyes \
 475      -a x$HAVE_PKGTRANS = xyes ; then
 476   HAVE_SVR4_PACKAGING=yes
 477 else
 478   HAVE_SVR4_PACKAGING=no
 479 fi
 480 AC_SUBST(HAVE_SVR4_PACKAGING)
 481
 482 # RPM
 483 AC_WIRESHARK_RPM_CHECK
 484 AC_SUBST(HAVE_RPM)
 485
 486 # Debian
 487 AC_CHECK_PROG(HAVE_DPKG_BUILDPACKAGE, dpkg-buildpackage, "yes", "no")
 488
 489 # Mac OS X
 490 AC_CHECK_PROG(HAVE_XCODEBUILD, xcodebuild, "yes", "no")
 491 AC_CHECK_PROG(HAVE_HDIUTIL, hdiutil, "yes", "no")
 492 AC_CHECK_PROG(HAVE_BLESS, bless, "yes", "no")
 493
 494 if test x$HAVE_XCODEBUILD = xyes -a x$HAVE_HDIUTIL = xyes \
 495      -a x$HAVE_BLESS = xyes ; then
 496   HAVE_OSX_PACKAGING=yes
 497 else
 498   HAVE_OSX_PACKAGING=no
 499 fi
 500 AC_SUBST(HAVE_OSX_PACKAGING)
 501
 502 #
 503 # Try to add some additional gcc checks to CFLAGS
 504 #
 505 AC_ARG_ENABLE(extra-gcc-checks,
 506   AC_HELP_STRING( [--enable-extra-gcc-checks],
 507                   [do additional -W checks in GCC @<:@default=no@:>@]),
 508 [
 509         wireshark_extra_gcc_flags=$enableval
 510         if test $enableval != no
 511         then
 512                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-pedantic)
 513                 #
 514                 # Various code blocks this one.
 515                 #
 516                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Woverflow)
 517                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-fstrict-overflow -Wstrict-overflow=4)
 518                 #
 519                 # Some memset() calls to clear out structures
 520                 # on the stack are getting flagged as "will never
 521                 # be executed" by this, at least by Apple's
 522                 # i686-apple-darwin11-llvm-gcc-4.2 (GCC) 4.2.1 (Based on
 523                 # Apple Inc. build 5658) (LLVM build 2336.11.00), for
 524                 # some unknown reason.
 525                 #
 526                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wunreachable-code)
 527                 #
 528                 # Due to various places where APIs we don't control
 529                 # require us to cast away constness, we can probably
 530                 # never enable these ones with -Werror.
 531                 #
 532                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wcast-qual)
 533                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wbad-function-cast, C)
 534                 #
 535                 # Some generated ASN.1 dissectors block this one;
 536                 # multiple function declarations for the same
 537                 # function are being generated.
 538                 #
 539                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wredundant-decls)
 540                 #
 541                 # Some loops are safe, but it's hard to convince the
 542                 # compiler of that.
 543                 #
 544                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wunsafe-loop-optimizations)
 545                 #
 546                 # All the registration functions block these for now.
 547                 #
 548                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wmissing-prototypes)
 549                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wmissing-declarations)
 550         fi
 551 ],)
 552 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wall -W) # -W is now known as -Wextra
 553 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wextra) # -W is now known as -Wextra
 554 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wdeclaration-after-statement, C)
 555 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wendif-labels)
 556 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wpointer-arith)
 557 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wno-pointer-sign, C)
 558 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Warray-bounds)
 559 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wcast-align)
 560 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wformat-security)
 561 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wold-style-definition, C)
 562 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wshorten-64-to-32)
 563 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wstrict-prototypes, C)
 564 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wjump-misses-init, C)
 565 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wvla)
 566 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Waddress)
 567 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Warray-bounds)
 568 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wattributes)
 569 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wdiv-by-zero)
 570 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wignored-qualifiers)
 571 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wpragmas)
 572 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wno-overlength-strings)
 573 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wwrite-strings)
 574 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wno-long-long)
 575 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wc++-compat, C)
 576
 577 #
 578 # XXX - OK for C++?
 579 #
 580 # Make sure -Wshadow doesn't complain about variables in function and
 581 # function pointer declarations shadowing other variables; if not, don't
 582 # turn it on, as some versions of GCC (including the one in at least
 583 # some Xcode versions that came with Mac OS X 10.5) complain about
 584 # that.
 585 #
 586 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wshadow, C,
 587   [
 588 extern int bar(int a);
 589 extern int foo(int);
 590
 591 int
 592 foo(int a)
 593 {
 594         int (*fptr)(int a) = bar;
 595
 596         return fptr(a) * 2;
 597 }
 598   ],
 599   [warns about variables in function declarations shadowing other variables])
 600
 601 # Unfortunately some versions of gcc generate logical-op warnings when strchr()
 602 # is given a constant string.
 603 # gcc versions 4.3.2 and 4.4.5 are known to have the problem.
 604 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wlogical-op, C,
 605   [
 606 #include <string.h>
 607
 608 int foo(const char *, int);
 609 int bar(void);
 610
 611 int
 612 foo(const char *sep, int c)
 613 {
 614         if (strchr (sep, c) != NULL)
 615                 return 1;
 616         else
 617                 return 0;
 618 }
 619
 620 int
 621 bar(void)
 622 {
 623         return foo("<", 'a');
 624 }
 625   ],
 626   [generates warnings from strchr()])
 627
 628
 629 ## AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wno-error=unused-but-set-variable)
 630
 631 #
 632 # Use the faster pre gcc 4.5 floating point precision if available;
 633 # clang doesn't error out on -f options that it doesn't know about,
 634 # it just warns and ignores them, so this check doesn't cause us
 635 # to omit -fexcess-precision=fast, which produces a pile of
 636 # annoying warnings.
 637 #
 638 if test "x$CC" != "xclang" ; then
 639   AC_WIRESHARK_GCC_CFLAGS_CHECK(-fexcess-precision=fast)
 640 fi
 641
 642 CFLAGS_before_fvhidden=$CFLAGS
 643 AC_WIRESHARK_GCC_CFLAGS_CHECK(-fvisibility=hidden)
 644 if test "x$CLFAGS" = "x$CFLAGS_before_fvhidden"
 645 then
 646         # TODO add other ways of hiding symbols
 647         AC_MSG_WARN(Compiler will export all symbols from shared libraries)
 648 fi
 649
 650 AC_WIRESHARK_LDFLAGS_CHECK([-Wl,--as-needed])
 651 ###AC_WIRESHARK_LDFLAGS_CHECK([-Wl,-M])
 652 ###AC_WIRESHARK_LDFLAGS_CHECK([-Wl,--cref])
 653 # AC_WIRESHARK_LDFLAGS_CHECK([-flto])
 654 # AC_WIRESHARK_LDFLAGS_CHECK([-fwhopr])
 655 # AC_WIRESHARK_LDFLAGS_CHECK([-fwhole-program])
 656
 657 #
 658 # Put -fPIE in PIE_CFLAGS and -pie in PIE_LDFLAGS if we can use them,
 659 # so that we can build dumpcap PIE - it may run with elevated
 660 # privileges, and using PIE means the OS can run it at random locations
 661 # in the address space to make attacks more difficult.
 662 #
 663 CFLAGS_before_pie=$CFLAGS
 664 AC_WIRESHARK_GCC_CFLAGS_CHECK(-fPIE, C)
 665 if test "x$CLFAGS" != "x$CFLAGS_before_pie"
 666 then
 667         # Restore CFLAGS
 668         CFLAGS=$CFLAGS_before_pie
 669
 670         LDFLAGS_before_pie=$LDFLAGS
 671         AC_WIRESHARK_LDFLAGS_CHECK([-fPIE -pie])
 672         if test "x$LDFLAGS" != "x$LDFLAGS_before_pie"
 673         then
 674                 # We can use PIE
 675                 PIE_CFLAGS="-fPIE"
 676                 PIE_LDFLAGS="-pie"
 677
 678                 # Restore LDFLAGS
 679                 LDFLAGS=$LDFLAGS_before_pie
 680         fi
 681
 682 fi
 683 AC_SUBST(PIE_CFLAGS)
 684 AC_SUBST(PIE_LDFLAGS)
 685
 686 #
 687 # If we're running GCC or clang define _U_ to be "__attribute__((unused))"
 688 # so we can use _U_ to flag unused function parameters and not get warnings
 689 # about them. Otherwise, define _U_ to be an empty string so that _U_ used
 690 # to flag an unused function parameters will compile with other compilers.
 691 #
 692 # XXX - similar hints for other compilers?
 693 #
 694 if test "x$GCC" = "xyes" -o "x$CC" = "xclang" ; then
 695   AC_DEFINE(_U_, __attribute__((unused)), [Hint to the compiler that a function parameters is not used])
 696 else
 697   AC_DEFINE(_U_, , [Hint to the compiler that a function parameters is not used])
 698 fi
 699
 700 # If we're running GCC or CLang, use FORTIFY_SOURCE=2
 701 #  (only if the GCC 'optimization level' > 0).
 702 #
 703 # See: http://gcc.gnu.org/ml/gcc-patches/2004-09/msg02055.html
 704 # See: http://sourceware.org/bugzilla/show_bug.cgi?id=13979
 705 #
 706 # Note: FORTIFY_SOURCE is only effective for gcc optimization level > 0 (-O1, etc)
 707 AC_WIRESHARK_GCC_FORTIFY_SOURCE_CHECK
 708
 709 #
 710 # If the compiler supports GCC-style flags, enable a barrier "stop on
 711 # warning".
 712 # This barrier is set for a very large part of the code. However, it is
 713 # typically not set for "generated" code  (flex, ans2wrs, idl2wrs, ...)
 714 #
 715 warnings_as_errors_default="yes"
 716 AC_MSG_CHECKING(whether we should treat compiler warnings as errors)
 717 AC_ARG_ENABLE(warnings-as-errors,
 718   AC_HELP_STRING( [--enable-warnings-as-errors],
 719                   [treat warnings as errors (only for GCC or clang) @<:@default=yes, unless extra warnings are enabled@:>@]),
 720 [
 721   if test "x$ac_supports_gcc_flags" = "xyes" -a "x$enableval" = "xyes"; then
 722     with_warnings_as_errors="yes"
 723     AC_MSG_RESULT(yes)
 724   else
 725     with_warnings_as_errors="no"
 726     AC_MSG_RESULT(no)
 727   fi
 728 ],
 729 [
 730   if test "x$ac_supports_gcc_flags" = "xyes" -a "x$wireshark_extra_gcc_flags" = "x" -a "x$warnings_as_errors_default" = "xyes"; then
 731     with_warnings_as_errors="yes"
 732     AC_MSG_RESULT(yes)
 733   else
 734     with_warnings_as_errors="no"
 735     AC_MSG_RESULT(no)
 736   fi
 737 ]
 738 )
 739 AM_CONDITIONAL(HAVE_WARNINGS_AS_ERRORS, test "x$with_warnings_as_errors" = "xyes")
 740
 741 #
 742 # Add any platform-specific compiler flags needed.
 743 #
 744 AC_MSG_CHECKING(for platform-specific compiler flags)
 745 if test "x$GCC" = "xyes" ; then
 746         #
 747         # GCC - do any platform-specific tweaking necessary.
 748         #
 749         case "$host_os" in
 750         solaris*)
 751                 # the X11 headers don't automatically include prototype info
 752                 # and a lot don't include the return type
 753                 CPPFLAGS="$CPPFLAGS -DFUNCPROTO=15"
 754                 CFLAGS="$CFLAGS -Wno-return-type"
 755                 CXXFLAGS="$CXXFLAGS -Wno-return-type"
 756                 AC_MSG_RESULT(GCC on Solaris - added -Wno-return-type -DFUNCPROTO=15)
 757                 ;;
 758         *)
 759                 AC_MSG_RESULT(none needed)
 760                 ;;
 761         esac
 762 else
 763         #
 764         # Not GCC - assume it's the vendor's compiler.
 765         #
 766         case "$host_os" in
 767         hpux*)
 768                 #
 769                 # HP's ANSI C compiler; flags suggested by Jost Martin.
 770                 # "-Ae" for ANSI C plus extensions such as "long long".
 771                 # "+O2", for optimization.  XXX - works with "-g"?
 772                 #
 773                 # HP's ANSI C++ compiler doesn't support "-Ae", but
 774                 # does support "+O2", at least according to the
 775                 # documentation I can find online.
 776                 #
 777                 CFLAGS="-Ae +O2 $CFLAGS"
 778                 CFLAGS_FOR_BUILD="-Ae +O2 $CFLAGS"
 779                 CXXFLAGS="+O2 $CFLAGS"
 780                 AC_MSG_RESULT(HP ANSI C compiler - added -Ae +O2)
 781                 ;;
 782         *)
 783                 AC_MSG_RESULT(none needed)
 784                 ;;
 785         esac
 786 fi
 787
 788 #
 789 # Add any platform-specific linker flags needed.
 790 #
 791 AC_MSG_CHECKING(for platform-specific linker flags)
 792 case "$host_os" in
 793 darwin*)
 794         #
 795         # Add -Wl,-single_module to the LDFLAGS used with shared
 796         # libraries, to fix some error that show up in some cases;
 797         # some Apple documentation recommends it for most shared
 798         # libraries.
 799         #
 800         LDFLAGS_SHAREDLIB="-Wl,-single_module"
 801         #
 802         # Add -Wl,-search_paths_first to make sure that if we search
 803         # directories A and B, in that order, for a given library, a
 804         # non-shared version in directory A, rather than a shared
 805         # version in directory B, is chosen (so we can use
 806         # --with-pcap=/usr/local to force all programs to be linked
 807         # with a static version installed in /usr/local/lib rather than
 808         # the system version in /usr/lib).
 809         #
 810         LDFLAGS="-Wl,-search_paths_first $LDFLAGS"
 811         AC_MSG_RESULT([Apple linker - added -Wl,-single_module and -Wl,-search_paths_first])
 812         ;;
 813 cygwin*)
 814         #
 815         # Shared libraries in cygwin/Win32 must never contain
 816         # undefined symbols.
 817         #
 818         LDFLAGS="$LDFLAGS -no-undefined"
 819         AC_MSG_RESULT(CygWin GNU ld - added -no-undefined)
 820         ;;
 821 *)
 822         AC_MSG_RESULT(none needed)
 823         ;;
 824 esac
 825 AC_SUBST(LDFLAGS_SHAREDLIB)
 826
 827 # Enable silent builds by default
 828 # Verbose builds can be enabled with "./configure
 829 # --enable-silent-rules ..." or "make V=1 ..."
 830 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
 831   [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
 832
 833 #
 834 # On "Darwin", which we assume to mean "OS X" rather than "iOS" or
 835 # "just Darwin" (as we don't currently support iOS, and as I don't
 836 # think you can build and run "just Darwin" as an OS for PCs), we
 837 # arrange to build some programs with Application Services so they
 838 # can launch Web browsers and Finder windows, arrange to build some
 839 # programs with System Configuration so they can get "friendly names"
 840 # and other information about interfaces, and build any programs that
 841 # use either of those frameworks or that report version information
 842 # with Core Foundation as the frameworks in question use it and as we
 843 # get version information from plists and thus need Core Foundation
 844 # to process those plists.
 845 #
 846 case "$host_os" in
 847
 848 darwin*)
 849         AC_DEFINE(HAVE_OS_X_FRAMEWORKS, 1, [Define to 1 if you have OS X frameworks])
 850         APPLICATIONSERVICES_FRAMEWORKS="-framework ApplicationServices"
 851         SYSTEMCONFIGURATION_FRAMEWORKS="-framework SystemConfiguration"
 852         COREFOUNDATION_FRAMEWORKS="-framework CoreFoundation"
 853
 854         #
 855         # OK, so we have the OS X frameworks; do they include
 856         # CFPropertyListCreateWithStream, or do we have
 857         # to fall back on CFPropertyListCreateFromStream?
 858         # (They only differ in the error return, which we
 859         # don't care about.  And, no, we shouldn't just
 860         # use CFPropertyListCreateFromStream, because it's
 861         # deprecated in newer releases.)
 862         #
 863         ac_save_LIBS="$LIBS"
 864         LIBS="$LIBS $COREFOUNDATION_FRAMEWORKS"
 865         AC_CHECK_FUNCS(CFPropertyListCreateWithStream)
 866         LIBS="$ac_save_LIBS"
 867         ;;
 868 esac
 869 AC_SUBST(APPLICATIONSERVICES_FRAMEWORKS)
 870 AC_SUBST(SYSTEMCONFIGURATION_FRAMEWORKS)
 871 AC_SUBST(COREFOUNDATION_FRAMEWORKS)
 872
 873 dnl Look in /usr/local for header files and libraries ?
 874 dnl XXX FIXME don't include /usr/local if it is already in the system
 875 dnl search path as this causes gcc 3.2 on Linux to complain about a change
 876 dnl of the system search order for includes
 877 AC_ARG_ENABLE(usr-local,
 878   AC_HELP_STRING( [--enable-usr-local],
 879                   [look for headers and libs in /usr/local tree @<:@default=yes@:>@]),
 880     ac_cv_enable_usr_local=$enableval,ac_cv_enable_usr_local=yes)
 881
 882 AC_MSG_CHECKING(whether to use /usr/local for headers and libraries)
 883 if test "x$ac_cv_enable_usr_local" = "xyes" ; then
 884         if test -d "/usr/local"; then
 885                 AC_MSG_RESULT(yes)
 886                 #
 887                 # Arrange that we search for header files in the source directory
 888                 # and in its "wiretap" subdirectory, as well as in "/usr/local/include",
 889                 # as various packages we use ("libpcap", "zlib", "adns")
 890                 # may have been installed under "/usr/local/include".
 891                 #
 892                 CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 893
 894                 #
 895                 # Arrange that we search for libraries in "/usr/local/lib".
 896                 #
 897                 AC_WIRESHARK_ADD_DASH_L(LDFLAGS, /usr/local/lib)
 898         else
 899                 AC_MSG_RESULT(no)
 900         fi
 901 else
 902         AC_MSG_RESULT(no)
 903 fi
 904
 905 #
 906 # If we're running Solaris, and LD_LIBRARY_PATH is defined, add it as a
 907 # link directory.
 908 #
 909 case "$host_os" in
 910   solaris*)
 911     AC_MSG_CHECKING(for LD_LIBRARY_PATH, since you appear to be running Solaris)
 912     if test x$LD_LIBRARY_PATH != x ; then
 913       LIBS="$LIBS -R$LD_LIBRARY_PATH"
 914       AC_MSG_RESULT(yes -- added LD_LIBRARY_PATH to run-time linker path)
 915     else
 916       AC_MSG_RESULT(no -- this may be a problem in a few seconds)
 917     fi
 918   ;;
 919 esac
 920
 921 #
 922 # Check for versions of "sed" inadequate to handle, in libtool, a list
 923 # of object files as large as the list in Wireshark.
 924 #
 925 # On Solaris, we check for "/bin/sed", "/usr/bin/sed", and "/usr/ucb/sed",
 926 # as both "/usr/bin/sed" (which is also "/bin/sed", as "/bin" is just a
 927 # symlink to "/usr/bin", but people may have "/bin" before "/usr/bin" in
 928 # their search path) and "/usr/ucb/sed" are inadequate; "/usr/xpg4/bin/sed"
 929 # is the only "sed" that comes with Solaris that can handle Wireshark.
 930 #
 931 # Add any checks here that are necessary for other OSes.
 932 #
 933 AC_WIRESHARK_GNU_SED_CHECK
 934 if test "$HAVE_GNU_SED" = no ; then
 935         case "$host_os" in
 936         solaris*)
 937                 AC_MSG_CHECKING(whether one of /usr/bin/sed or /bin/sed or /usr/ucb/sed will be used)
 938                 case `which sed` in
 939                         /bin/sed|/usr/bin/sed|/usr/ucb/sed)
 940                         AC_MSG_RESULT(yes)
 941                         AC_MSG_ERROR([change your path to search /usr/xpg4/bin or directory containing GNU sed before /usr/bin (and /bin and /usr/ucb)])
 942                         ;;
 943
 944                         *)
 945                         AC_MSG_RESULT(no)
 946                         ;;
 947                 esac
 948                 ;;
 949
 950         *)
 951                 :
 952                 ;;
 953         esac
 954 fi
 955
 956 # Enable/disable wireshark
 957
 958 AC_ARG_ENABLE(wireshark,
 959   AC_HELP_STRING( [--enable-wireshark],
 960                   [build GTK+-based Wireshark @<:@default=yes, if GTK+ available@:>@]),
 961     enable_wireshark=$enableval,enable_wireshark=yes)
 962
 963 AC_ARG_ENABLE(packet-editor,
 964   AC_HELP_STRING( [--enable-packet-editor],
 965                   [add support for packet editor in Wireshark @<:@default=no@:>@]),
 966     enable_packet_editor=$enableval,enable_packet_editor=no)
 967 if test x$enable_packet_editor = xyes; then
 968         AC_DEFINE(WANT_PACKET_EDITOR, 1, [Support for packet editor])
 969 fi
 970
 971 AC_ARG_ENABLE(profile-build,
 972   AC_HELP_STRING( [--enable-profile-build],
 973                   [build profile-ready binaries @<:@default=no@:>@]),
 974     enable_profile_build=$enableval,enable_profile_build=no)
 975 AM_CONDITIONAL(USE_PROFILE_BUILD, test x$enable_profile_build = xyes)
 976 AC_MSG_CHECKING(if profile builds must be generated)
 977 if test "x$enable_profile_build" = "xyes" ; then
 978         if test "x$GCC" = "xyes" -o "x$CLANG" = "xyes" ; then
 979                 AC_MSG_RESULT(yes)
 980                 CFLAGS=" -pg $CFLAGS"
 981                 CXXFLAGS=" -pg $CXXFLAGS"
 982         else
 983                 AC_MSG_RESULT(no)
 984                 echo "Building profile binaries currently only supported for GCC and clang."
 985         fi
 986 else
 987         AC_MSG_RESULT(no)
 988 fi
 989
 990 # Create DATAFILE_DIR #define for config.h
 991 datafiledir=$datadir/wireshark
 992 datafiledir=`(
 993     test "x$prefix" = xNONE && prefix=$ac_default_prefix
 994     test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
 995     # Ugly hack, but I don't see how this problem can be solved
 996     # properly that DATAFILE_DIR had a value starting with
 997     # "${prefix}/" instead of e.g. "/usr/local/"
 998     eval eval echo "$datafiledir"
 999 )`
1000 AC_DEFINE_UNQUOTED(DATAFILE_DIR,"$datafiledir", [Directory for data])
1001
1002 # Create DOC_DIR #define for config.h
1003 docdir=`(
1004     test "x$prefix" = xNONE && prefix=$ac_default_prefix
1005     test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
1006     # Ugly hack, but I don't see how this problem can be solved
1007     # properly that DOC_DIR had a value starting with
1008     # "${prefix}/" instead of e.g. "/usr/local/"
1009     eval eval echo "$docdir"
1010 )`
1011 AC_DEFINE_UNQUOTED(DOC_DIR, "$docdir", [Directory for docs])
1012
1013 GTK2_MIN_VERSION=2.12.0
1014 AC_SUBST(GTK2_MIN_VERSION)
1015 GTK3_MIN_VERSION=3.0.0
1016 AC_SUBST(GTK3_MIN_VERSION)
1017 QT_MIN_VERSION=4.6.0
1018 AC_SUBST(QT_MIN_VERSION)
1019 # GTK+ and Qt checks; we require GTK+ $GTK2_MIN_VERSION or later or
1020 # GTK3_MIN_VERSION or later or Qt $QT_MIN_VERSION or later.
1021 #
1022 # We only do those if we're going to be building Wireshark;
1023 # otherwise, we don't have any GUI to build, so we don't use
1024 # GTK+ or Qt.
1025 #
1026 # We don't add $GTK_LIBS or $Qt_LIBS to LIBS, because we don't want to
1027 # force all programs to be built with GTK+ or Qt.
1028 #
1029 # Release dates for GTK+ versions:
1030 # 2.12.0: 14 Sep 2007
1031 # 2.14.0: 04 Sep 2008
1032 # 2.16.0: 13 Mar 2009
1033 # 2.18.0: 23 Sep 2009
1034 # 2.20.0: 23 Mar 2010
1035 # 2.22.0: 23 Sep 2010
1036 # 2.24.0: 30 Jan 2011
1037 # 3.0.0:  10 Feb 2011
1038 # 3.2.0:  25 Sep 2011
1039 # 3.4.0:  26 Mar 2012
1040 # 3.6.0:  24 Sep 2012
1041 # 3.8.0:  25 Mar 2013
1042
1043 if test "x$enable_wireshark" = "xyes"; then
1044         if test "x$with_qt" = "xyes"; then
1045
1046                 AC_MSG_CHECKING(whether we have a working C++ compiler)
1047                 AC_LANG_PUSH([C++])
1048                 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1049                         [AC_MSG_RESULT(yes)],
1050                         [
1051                          AC_MSG_RESULT(no)
1052                          AC_MSG_ERROR(Need a working C++ compiler to build Wireshark with Qt)
1053                         ])
1054                 AC_LANG_POP([C++])
1055
1056                 AM_PATH_QT($QT_MIN_VERSION,
1057                 [
1058                         CFLAGS="$CFLAGS $Qt_CFLAGS"
1059                         CXXFLAGS="$CXXFLAGS $Qt_CFLAGS"
1060                         have_qt=yes
1061                 ]
1062                 , [AC_MSG_ERROR([Qt is not available])])
1063
1064                 #
1065                 # XXX - greasy hack to make ui/gtk/recent.c
1066                 # compile.
1067                 #
1068                 CPPFLAGS="-DQT_GUI_LIB"
1069
1070                 #
1071                 # We don't know whether we have GTK+, but we
1072                 # won't be using it, so it's as if we don't
1073                 # have it.
1074                 #
1075                 have_gtk=no
1076         else
1077                 #
1078                 # Not Qt - either GTK+ 3.x or 2.x.
1079                 #
1080                 if test "x$with_gtk3" = "xyes"; then
1081                         AM_PATH_GTK_3_0(3.0.0,
1082                         [
1083                                 CFLAGS="$CFLAGS $GTK_CFLAGS"
1084                                 CXXFLAGS="$CXXFLAGS $GTK_CFLAGS"
1085                                 have_gtk=yes
1086                                 AC_DEFINE(HAVE_GTK, 1,
1087                                     [Define to 1 if compiling with GTK])
1088                         ], have_gtk=no)
1089
1090                 else
1091                         AM_PATH_GTK_2_0($GTK2_MIN_VERSION,
1092                         [
1093                                 CFLAGS="$CFLAGS $GTK_CFLAGS"
1094                                 CXXFLAGS="$CXXFLAGS $GTK_CFLAGS"
1095                                 have_gtk=yes
1096                                 AC_DEFINE(HAVE_GTK, 1,
1097                                     [Define to 1 if compiling with GTK])
1098                         ], have_gtk=no)
1099                 fi
1100         fi
1101 else
1102         have_qt=no
1103         have_gtk=no
1104 fi
1105
1106 GLIB_MIN_VERSION=2.16.0
1107 AC_SUBST(GLIB_MIN_VERSION)
1108 # GLib checks; we require GLib $GLIB_MIN_VERSION or later, and require gmodule
1109 # support, as we need that for dynamically loading plugins.
1110 # If we found GTK+, this doesn't add GLIB_CFLAGS to CFLAGS, because
1111 # AM_PATH_GTK will add GTK_CFLAGS to CFLAGS, and GTK_CFLAGS is a
1112 # superset of GLIB_CFLAGS.  If we didn't find GTK+, it does add
1113 # GLIB_CFLAGS to CFLAGS.
1114 # However, this means that both @GLIB_LIBS@ and @GTK_LIBS@ will be
1115 # set when generating the Makefile, so we can make programs that require
1116 # only GLib link with @GLIB_LIBS@ and make programs that require GTK+
1117 # link with @GTK_LIBS@ (which includes @GLIB_LIBS@).
1118 # We don't add $GLIB_LIBS to LIBS, because we don't want to force all
1119 # programs to be built with GLib.
1120 #
1121 # Release dates for GLib versions:
1122 # 2.14.0: 03 Aug 2007
1123 # 2.16.0: 10 Mar 2008
1124 # 2.18.0: 02 Sep 2008
1125 # 2.20.0: 13 Mar 2009
1126 # 2.22.0: 22 Sep 2009
1127 # 2.24.0: 28 Mar 2010
1128 # 2.26.0: 27 Sep 2010
1129 # 2.28.0: 08 Feb 2011
1130 # 2.30.0: 27 Sep 2011
1131 # 2.32.0: 24 Mar 2012
1132 # 2.34.0: 24 Sep 2012
1133 # 2.36.0: 25 Mar 2013
1134
1135 have_wireshark_cxx="false"
1136 if test "$have_gtk" = "no" ; then
1137         #
1138         # We don't have GTK+.
1139         #
1140         if test "$have_qt" = "yes" ; then
1141                 #
1142                 # However, we do have Qt, and thus will be building
1143                 # Wireshark (if the user had explicitly disabled
1144                 # Wireshark, we wouldn't have looked for Qt, so we
1145                 # wouldn't think we had it, and thus wouldn't be here).
1146                 #
1147                 wireshark_bin="wireshark\$(EXEEXT)"
1148                 # Give automake a hint that it needs to use c++ linking.
1149                 have_wireshark_cxx="yes"
1150                 wireshark_man="wireshark.1"
1151                 wireshark_SUBDIRS="codecs ui/qt"
1152         else
1153                 #
1154                 # We don't have Qt, either, which means we have no UI
1155                 # toolkit.
1156                 #
1157                 # If they didn't explicitly say "--disable-wireshark",
1158                 # fail (so that, unless they explicitly indicated that
1159                 # they don't want Wireshark, we stop so they know they
1160                 # won't be getting Wireshark unless they fix the GTK+/Qt
1161                 # problem).
1162                 #
1163                 if test "x$enable_wireshark" = "xyes"; then
1164                         if test "x$with_gtk3" = "xyes"; then
1165                                 AC_MSG_ERROR([GTK+ $GTK3_MIN_VERSION or later isn't available, so Wireshark can't be compiled])
1166                         else
1167                                 AC_MSG_ERROR([Neither Qt nor GTK+ $GTK2_MIN_VERSION or later are available, so Wireshark can't be compiled])
1168                         fi
1169                 fi
1170                 wireshark_bin=""
1171                 wireshark_man=""
1172         fi
1173         # Use GLIB_CFLAGS
1174         AM_PATH_GLIB_2_0($GLIB_MIN_VERSION,
1175         [
1176                 CFLAGS="$CFLAGS $GLIB_CFLAGS"
1177                 CXXFLAGS="$CXXFLAGS $GLIB_CFLAGS"
1178         ], AC_MSG_ERROR(GLib $GLIB_MIN_VERSION or later distribution not found.), gthread gmodule)
1179 else
1180         #
1181         # We have GTK+, and thus will be building Wireshark (if the user
1182         # had explicitly disabled Wireshark, we wouldn't have looked for
1183         # GTK+, so we wouldn't think we had it, and thus wouldn't be here).
1184         #
1185         wireshark_bin="wireshark\$(EXEEXT)"
1186         wireshark_man="wireshark.1"
1187         wireshark_SUBDIRS="codecs ui/gtk"
1188         # Don't use GLIB_CFLAGS
1189         AM_PATH_GLIB_2_0($GLIB_MIN_VERSION, , AC_MSG_ERROR(GLib $GLIB_MIN_VERSION or later distribution not found.), gthread gmodule)
1190
1191         CPPFLAGS="-DGDK_PIXBUF_DISABLE_DEPRECATED $CPPFLAGS"
1192         CPPFLAGS="-DGDK_DISABLE_DEPRECATED $CPPFLAGS"
1193         CPPFLAGS="-DGTK_DISABLE_DEPRECATED $CPPFLAGS"
1194         CPPFLAGS="-DGTK_DISABLE_SINGLE_INCLUDES $CPPFLAGS"
1195         if test ! \( $gtk_config_major_version -eq 2 -a $gtk_config_minor_version -lt 20 \) ; then
1196                 # Enable GSEAL when building with GTK > 2.20
1197                 # (Versions prior to 2.22 lacked some necessary accessors.)
1198                 CPPFLAGS="-DGSEAL_ENABLE $CPPFLAGS"
1199         fi
1200 fi
1201
1202 #
1203 # "make dist" requires that we have the Qt build tools.
1204 #
1205 # Annoyingly, at least on Fedora 16, uic and moc are named XXX-qt4
1206 # rather than just XXX, perhaps to allow Qt 3 and Qt 4 tools to be
1207 # installed; if they're still doing that in current Fedora releases,
1208 # perhaps there will also be XXX-qt5 when they pick up Qt 5.
1209 #
1210 AC_PATH_PROG(UIC, uic)
1211 if test "x$UIC" = x
1212 then
1213         AC_PATH_PROG(UIC, uic-qt4)
1214         if test "x$UIC" = x
1215         then
1216                 if test "x$with_qt" = "xyes"; then
1217                         #
1218                         # If you want to build with Qt, you'd better
1219                         # have uic.
1220                         #
1221                         AC_MSG_ERROR(I couldn't find uic or uic-qt4; make sure it's installed and in your path)
1222                 else
1223                         #
1224                         # We shouldn't fail here, as the user's not
1225                         # building with Qt, and we shouldn't force them
1226                         # to have Qt installed if they're not doing so.
1227                         # "make dist" will fail if they do that, but
1228                         # we don't know whether they'll be doing that,
1229                         # so this is the best we can do.
1230                         #
1231                         UIC=uic
1232                 fi
1233         fi
1234 fi
1235 AC_SUBST(UIC)
1236 AC_PATH_PROG(MOC, moc)
1237 if test "x$MOC" = x
1238 then
1239         AC_PATH_PROG(MOC, moc-qt4)
1240         if test "x$MOC" = x
1241         then
1242                 if test "x$with_qt" = "xyes"; then
1243                         #
1244                         # If you want to build with Qt, you'd better
1245                         # have moc.
1246                         #
1247                         AC_MSG_ERROR(I couldn't find moc or moc-qt4; make sure it's installed and in your path)
1248                 else
1249                         #
1250                         # We shouldn't fail here, as the user's not
1251                         # building with Qt, and we shouldn't force them
1252                         # to have Qt installed if they're not doing so.
1253                         # "make dist" will fail if they do that, but
1254                         # we don't know whether they'll be doing that,
1255                         # so this is the best we can do.
1256                         #
1257                         MIC=moc
1258                 fi
1259         fi
1260 fi
1261 AC_SUBST(MOC)
1262
1263 # Error out if a glib header other than a "top level" header
1264 #  (glib.h, glib-object.h, gio.h) or certain other headers( e.g.,gmodule.h)
1265 #  is used.
1266 CPPFLAGS="-DG_DISABLE_SINGLE_INCLUDES $CPPFLAGS"
1267
1268 # Error out on the usage of deprecated glib functions
1269 CPPFLAGS="-DG_DISABLE_DEPRECATED $CPPFLAGS"
1270
1271 #
1272 # Check whether GLib modules are supported, to determine whether we
1273 # can support plugins.
1274 #
1275 AC_MSG_CHECKING(whether GLib supports loadable modules)
1276 ac_save_CFLAGS="$CFLAGS"
1277 ac_save_LIBS="$LIBS"
1278 CFLAGS="$CFLAGS $GLIB_CFLAGS"
1279 LIBS="$GLIB_LIBS $LIBS"
1280 AC_TRY_RUN([
1281 #include <glib.h>
1282 #include <gmodule.h>
1283 #include <stdio.h>
1284 #include <stdlib.h>
1285
1286 int
1287 main ()
1288 {
1289   if (g_module_supported())
1290     return 0;   /* success */
1291   else
1292     return 1;   /* failure */
1293 }
1294 ], ac_cv_glib_supports_modules=yes, ac_cv_glib_supports_modules=no,
1295    [echo $ac_n "cross compiling; assumed OK... $ac_c"
1296     ac_cv_glib_supports_modules=yes])
1297 CFLAGS="$ac_save_CFLAGS"
1298 LIBS="$ac_save_LIBS"
1299 if test "$ac_cv_glib_supports_modules" = yes ; then
1300   AC_MSG_RESULT(yes)
1301   have_plugins=yes
1302 else
1303   AC_MSG_RESULT(no)
1304   have_plugins=no
1305 fi
1306
1307 #
1308 # If we have <dlfcn.h>, check whether we can use dladdr to find a
1309 # filename (hopefully, a full pathname, but no guarantees) for
1310 # the executable.
1311 #
1312 if test "$ac_cv_header_dlfcn_h" = "yes"
1313 then
1314         AC_MSG_CHECKING(whether dladdr can be used to find the pathname of an executable)
1315         ac_save_CFLAGS="$CFLAGS"
1316         ac_save_LIBS="$LIBS"
1317         CFLAGS="$CFLAGS $GLIB_CFLAGS"
1318         LIBS="$GLIB_LIBS $LIBS"
1319         AC_TRY_RUN([
1320 #define _GNU_SOURCE     /* required on Linux, sigh */
1321 #include <dlfcn.h>
1322
1323 int
1324 main(void)
1325 {
1326         Dl_info info;
1327
1328         if (!dladdr((void *)main, &info))
1329                 return 1;       /* failure */
1330         return 0;               /* assume success */
1331 }
1332 ], ac_cv_dladdr_finds_executable_path=yes, ac_cv_dladdr_finds_executable_path=no,
1333    [echo $ac_n "cross compiling; assumed OK... $ac_c"
1334     ac_cv_dladdr_finds_executable_path=yes])
1335         CFLAGS="$ac_save_CFLAGS"
1336         LIBS="$ac_save_LIBS"
1337         if test x$ac_cv_dladdr_finds_executable_path = xyes
1338         then
1339                 AC_DEFINE(DLADDR_FINDS_EXECUTABLE_PATH, 1, [Define if dladdr can be used to find the path of the executable])
1340         fi
1341         AC_MSG_RESULT($ac_cv_dladdr_finds_executable_path)
1342 fi
1343
1344 #
1345 # Check whether GLib's printf supports thousands grouping. (This might
1346 # be different from the system's printf since GLib can optionally use
1347 # its own printf implementation.)
1348 #
1349 AC_MSG_CHECKING(whether GLib supports POSIX/XSI thousands grouping)
1350 ac_save_CFLAGS="$CFLAGS"
1351 ac_save_LIBS="$LIBS"
1352 CFLAGS="$CFLAGS $GLIB_CFLAGS"
1353 LIBS="$GLIB_LIBS $LIBS"
1354 AC_TRY_RUN([
1355 #include <glib.h>
1356 #include <locale.h>
1357 #include <stdio.h>
1358 #include <string.h>
1359
1360 int
1361 main ()
1362 {
1363   gchar *str;
1364   setlocale(LC_ALL, "en_US.UTF-8");
1365   str = g_strdup_printf("%'u", 123456);
1366   return (strcmp (str, "123,456") != 0);
1367 }
1368 ], ac_cv_glib_supports_printf_grouping=yes, ac_cv_glib_supports_printf_grouping=no,
1369    [echo $ac_n "cross compiling; playing it safe... $ac_c"
1370     ac_cv_glib_supports_printf_grouping=no])
1371 CFLAGS="$ac_save_CFLAGS"
1372 LIBS="$ac_save_LIBS"
1373 if test "$ac_cv_glib_supports_printf_grouping" = yes ; then
1374   AC_MSG_RESULT(yes)
1375   AC_DEFINE(HAVE_GLIB_PRINTF_GROUPING, 1, [Define if your printf() function supports thousands grouping.])
1376 else
1377   AC_MSG_RESULT(no)
1378 fi
1379
1380 if test "x$have_gtk" = "xyes"
1381 then
1382     #
1383     # We have GTK+; do we want the OS X integration functions and,
1384     # if so, do we have them and, if so, which versions do we have,
1385     # the old Carbon-based ones or the new Cocoa-based ones?
1386     #
1387     AC_MSG_CHECKING(whether to use OS X integration functions)
1388
1389     AC_ARG_WITH(osx-integration,
1390       AC_HELP_STRING( [--with-osx-integration],
1391                       [use OS X integration functions @<:@default=yes, if available@:>@]),
1392     [
1393         if test $withval = no
1394         then
1395             want_osx_integration=no
1396         else
1397             want_osx_integration=yes
1398         fi
1399     ],[
1400         want_osx_integration=yes
1401     ])
1402     if test "x$want_osx_integration" = "xno"; then
1403         AC_MSG_RESULT(no)
1404     else
1405         AC_MSG_RESULT(yes)
1406         AC_WIRESHARK_OSX_INTEGRATION_CHECK
1407     fi
1408 fi
1409
1410 AC_SUBST(wireshark_bin)
1411 AC_SUBST(wireshark_man)
1412 AM_CONDITIONAL(HAVE_Qt, test "$have_qt" = "yes")
1413 AM_CONDITIONAL(HAVE_WIRESHARK_CXX, test "$have_wireshark_cxx" = "yes")
1414
1415
1416 # Enable/disable tshark
1417
1418 AC_ARG_ENABLE(tshark,
1419   AC_HELP_STRING( [--enable-tshark],
1420                   [build TShark @<:@default=yes@:>@]),
1421     tshark=$enableval,enable_tshark=yes)
1422
1423 if test "x$enable_tshark" = "xyes" ; then
1424         tshark_bin="tshark\$(EXEEXT)"
1425         tshark_man="tshark.1"
1426         wiresharkfilter_man="wireshark-filter.4"
1427 else
1428         tshark_bin=""
1429         tshark_man=""
1430 fi
1431 AC_SUBST(tshark_bin)
1432 AC_SUBST(tshark_man)
1433 AC_SUBST(wiresharkfilter_man)
1434
1435
1436
1437 # Enable/disable editcap
1438
1439 AC_ARG_ENABLE(editcap,
1440   AC_HELP_STRING( [--enable-editcap],
1441                   [build editcap @<:@default=yes@:>@]),
1442     enable_editcap=$enableval,enable_editcap=yes)
1443
1444 if test "x$enable_editcap" = "xyes" ; then
1445         editcap_bin="editcap\$(EXEEXT)"
1446         editcap_man="editcap.1"
1447 else
1448         editcap_bin=""
1449         editcap_man=""
1450 fi
1451 AC_SUBST(editcap_bin)
1452 AC_SUBST(editcap_man)
1453
1454
1455
1456 # Enable/disable echld
1457
1458 AC_ARG_WITH(echld,
1459   AC_HELP_STRING( [--with-echld],
1460                   [support echld]),
1461 [
1462   if test "x$withval" = "xno"; then
1463       have_echld="no"
1464   else
1465       have_echld="$withval"
1466   fi
1467 ])
1468 AM_CONDITIONAL(HAVE_ECHLD, test "x$have_echld" = "xyes")
1469 if test "x$have_echld" = xyes
1470 then
1471   AC_DEFINE(HAVE_ECHLD, 1, [Define if echld is enabled])
1472   echld_test_bin="echld_test\$(EXEEXT)"
1473 else
1474   have_echld="no"
1475   echld_test_bin=""
1476 fi
1477 AC_SUBST(echld_test_bin)
1478
1479
1480 # Enabling/disabling of dumpcap is done later (after we know if we have PCAP
1481 # or not)
1482
1483 # Enable/disable capinfos
1484
1485 AC_ARG_ENABLE(capinfos,
1486   AC_HELP_STRING( [--enable-capinfos],
1487                   [build capinfos @<:@default=yes@:>@]),
1488     enable_capinfos=$enableval,enable_capinfos=yes)
1489
1490 if test "x$enable_capinfos" = "xyes" ; then
1491         capinfos_bin="capinfos\$(EXEEXT)"
1492         capinfos_man="capinfos.1"
1493 else
1494         capinfos_bin=""
1495         capinfos_man=""
1496 fi
1497 AC_SUBST(capinfos_bin)
1498 AC_SUBST(capinfos_man)
1499
1500
1501 # Enable/disable mergecap
1502
1503 AC_ARG_ENABLE(mergecap,
1504   AC_HELP_STRING( [--enable-mergecap],
1505                   [build mergecap @<:@default=yes@:>@]),
1506     enable_mergecap=$enableval,enable_mergecap=yes)
1507
1508 if test "x$enable_mergecap" = "xyes" ; then
1509         mergecap_bin="mergecap\$(EXEEXT)"
1510         mergecap_man="mergecap.1"
1511 else
1512         mergecap_bin=""
1513         mergecap_man=""
1514 fi
1515 AC_SUBST(mergecap_bin)
1516 AC_SUBST(mergecap_man)
1517
1518
1519 # Enable/disable reordercap
1520
1521 AC_ARG_ENABLE(reordercap,
1522   AC_HELP_STRING( [--enable-reordercap],
1523                   [build reordercap @<:@default=yes@:>@]),
1524     enable_reordercap=$enableval,enable_reordercap=yes)
1525
1526 if test "x$enable_reordercap" = "xyes" ; then
1527         reordercap_bin="reordercap\$(EXEEXT)"
1528         reordercap_man="reordercap.1"
1529 else
1530         reordercap_bin=""
1531         reordercap_man=""
1532 fi
1533 AC_SUBST(reordercap_bin)
1534 AC_SUBST(reordercap_man)
1535
1536
1537 # Enable/disable text2pcap
1538
1539 AC_ARG_ENABLE(text2pcap,
1540   AC_HELP_STRING( [--enable-text2pcap],
1541                   [build text2pcap @<:@default=yes@:>@]),
1542     text2pcap=$enableval,enable_text2pcap=yes)
1543
1544 if test "x$enable_text2pcap" = "xyes" ; then
1545         text2pcap_bin="text2pcap\$(EXEEXT)"
1546         text2pcap_man="text2pcap.1"
1547 else
1548         text2pcap_bin=""
1549         text2pcap_man=""
1550 fi
1551 AC_SUBST(text2pcap_bin)
1552 AC_SUBST(text2pcap_man)
1553
1554
1555 # Enable/disable dftest
1556
1557 AC_ARG_ENABLE(dftest,
1558   AC_HELP_STRING( [--enable-dftest],
1559                   [build dftest @<:@default=yes@:>@]),
1560     enable_dftest=$enableval,enable_dftest=yes)
1561
1562 if test "x$enable_dftest" = "xyes" ; then
1563         dftest_bin="dftest\$(EXEEXT)"
1564         dftest_man="dftest.1"
1565 else
1566         dftest_bin=""
1567         dftest_man=""
1568 fi
1569 AC_SUBST(dftest_bin)
1570 AC_SUBST(dftest_man)
1571
1572
1573 # Enable/disable randpkt
1574
1575 AC_ARG_ENABLE(randpkt,
1576   AC_HELP_STRING( [--enable-randpkt],
1577                   [build randpkt @<:@default=yes@:>@]),
1578     enable_randpkt=$enableval,enable_randpkt=yes)
1579
1580 if test "x$enable_randpkt" = "xyes" ; then
1581         randpkt_bin="randpkt\$(EXEEXT)"
1582         randpkt_man="randpkt.1"
1583 else
1584         randpkt_bin=""
1585         randpkt_man=""
1586 fi
1587 AC_SUBST(randpkt_bin)
1588 AC_SUBST(randpkt_man)
1589
1590
1591
1592 dnl Checks for "gethostbyname()" - and "-lnsl", if we need it to get
1593 dnl "gethostbyname()".
1594 AC_WIRESHARK_GETHOSTBY_LIB_CHECK
1595
1596 dnl Checks for "connect()", used as a proxy for "socket()" - and
1597 dnl "-lsocket", if we need it to get "connect()".
1598 AC_WIRESHARK_SOCKET_LIB_CHECK
1599
1600 dnl pcap check
1601 AC_MSG_CHECKING(whether to use libpcap for packet capture)
1602
1603 AC_ARG_WITH(pcap,
1604   AC_HELP_STRING( [--with-pcap@<:@=DIR@:>@],
1605                   [use libpcap for packet capturing @<:@default=yes@:>@]),
1606 [
1607         if test $withval = no
1608         then
1609                 want_pcap=no
1610         elif test $withval = yes
1611         then
1612                 want_pcap=yes
1613         else
1614                 want_pcap=yes
1615                 pcap_dir=$withval
1616         fi
1617 ],[
1618         want_pcap=yes
1619         pcap_dir=
1620 ])
1621 if test "x$want_pcap" = "xno" ; then
1622         AC_MSG_RESULT(no)
1623 else
1624         AC_MSG_RESULT(yes)
1625         AC_WIRESHARK_PCAP_CHECK
1626 fi
1627
1628
1629 dnl Check for airpcap
1630 AC_MSG_CHECKING(whether to include airpcap support)
1631 AC_ARG_ENABLE(airpcap,
1632   AC_HELP_STRING( [--enable-airpcap],
1633                   [use AirPcap in Wireshark @<:@default=yes@:>@]),
1634   enable_airpcap=$enableval, enable_airpcap=yes)
1635
1636 if test x$enable_airpcap = xyes; then
1637         if test "x$want_pcap" = "xno" ; then
1638                 enable_airpcap=no
1639                 AC_MSG_RESULT(pcap not available - disabling airpcap)
1640         else
1641                 AC_MSG_RESULT(yes)
1642                 AC_DEFINE(HAVE_AIRPCAP, 1, [Enable AirPcap])
1643         fi
1644 else
1645         AC_MSG_RESULT(no)
1646 fi
1647
1648
1649 dnl dumpcap check
1650 AC_MSG_CHECKING(whether to build dumpcap)
1651
1652 AC_ARG_ENABLE(dumpcap,
1653   AC_HELP_STRING( [--enable-dumpcap],
1654                   [build dumpcap @<:@default=yes@:>@]),
1655     enable_dumpcap=$enableval,enable_dumpcap=yes)
1656
1657 if test "x$enable_dumpcap" = "xyes" ; then
1658         if test "x$want_pcap" = "xno" ; then
1659                 enable_dumpcap=no
1660                 AC_MSG_RESULT(pcap not available - disabling dumpcap)
1661         else
1662                 AC_MSG_RESULT(yes)
1663         fi
1664 else
1665         AC_MSG_RESULT(no)
1666 fi
1667
1668 if test "x$enable_dumpcap" = "xyes" ; then
1669         dumpcap_bin="dumpcap\$(EXEEXT)"
1670         dumpcap_man="dumpcap.1"
1671 else
1672         dumpcap_bin=""
1673         dumpcap_man=""
1674 fi
1675 AC_SUBST(dumpcap_bin)
1676 AC_SUBST(dumpcap_man)
1677
1678 # Enable/disable rawshark
1679
1680 dnl rawshark check
1681 AC_MSG_CHECKING(whether to build rawshark)
1682
1683 AC_ARG_ENABLE(rawshark,
1684   AC_HELP_STRING( [--enable-rawshark],
1685                   [build rawshark @<:@default=yes@:>@]),
1686     rawshark=$enableval,enable_rawshark=yes)
1687
1688 if test "x$enable_rawshark" = "xyes" ; then
1689         if test "x$want_pcap" = "xno" ; then
1690                 enable_rawshark=no
1691                 AC_MSG_RESULT(pcap not available - disabling rawshark)
1692         else
1693                 AC_MSG_RESULT(yes)
1694         fi
1695 else
1696         AC_MSG_RESULT(no)
1697 fi
1698
1699 if test "x$enable_rawshark" = "xyes" ; then
1700         rawshark_bin="rawshark\$(EXEEXT)"
1701         rawshark_man="rawshark.1"
1702 else
1703         rawshark_bin=""
1704         rawshark_man=""
1705 fi
1706 AC_SUBST(rawshark_bin)
1707 AC_SUBST(rawshark_man)
1708
1709 dnl Use pcap-ng by default
1710 AC_ARG_ENABLE(pcap-ng-default,
1711   AC_HELP_STRING( [--enable-pcap-ng-default],
1712                   [use the pcap-ng file format by default instead of pcap @<:@default=yes@:>@]),
1713     enable_pcap_ng_default=$enableval,enable_pcap_ng_default=yes)
1714 if test x$enable_pcap_ng_default = xyes; then
1715         AC_DEFINE(PCAP_NG_DEFAULT, 1, [Support for pcap-ng])
1716 fi
1717
1718 dnl pcap remote check
1719 AC_MSG_CHECKING(whether to use libpcap remote capturing feature)
1720
1721 AC_ARG_WITH(pcap-remote,
1722     AC_HELP_STRING([--with-pcap-remote],
1723                    [use libpcap remote capturing (requires libpcap)]),
1724 [
1725     if test $withval = no
1726     then
1727         want_pcap_remote=no
1728     else
1729         want_pcap_remote=yes
1730     fi
1731 ],[
1732     want_pcap_remote=no
1733 ])
1734 if test "x$want_pcap_remote" = "xno" -o "x$want_pcap" = "xno" ; then
1735     AC_MSG_RESULT(no)
1736 else
1737     AC_MSG_RESULT(yes)
1738     AC_WIRESHARK_PCAP_REMOTE_CHECK
1739 fi
1740
1741 dnl zlib check
1742 AC_MSG_CHECKING(whether to use zlib for gzip compression and decompression)
1743
1744 AC_ARG_WITH(zlib,
1745   AC_HELP_STRING([--with-zlib@<:@=DIR@:>@],
1746                  [use zlib (located in directory DIR, if supplied) for gzip compression and decompression @<:@default=yes, if available@:>@]),
1747 [
1748         if test "x$withval" = "xno"
1749         then
1750                 want_zlib=no
1751         elif test "x$withval" = "xyes"
1752         then
1753                 want_zlib=yes
1754         else
1755                 want_zlib=yes
1756                 zlib_dir="$withval"
1757         fi
1758 ],[
1759         #
1760         # Use zlib if it's present, otherwise don't.
1761         #
1762         want_zlib=ifavailable
1763         zlib_dir=
1764 ])
1765 if test "x$want_zlib" = "xno" ; then
1766         AC_MSG_RESULT(no)
1767 else
1768         AC_MSG_RESULT(yes)
1769         AC_WIRESHARK_ZLIB_CHECK
1770         if test "x$want_zlib" = "xno" ; then
1771                 AC_MSG_RESULT(zlib not found - disabling gzip compression and decompression)
1772         else
1773                 if test "x$ac_cv_func_inflatePrime" = "xno" ; then
1774                         AC_MSG_RESULT(inflatePrime not found in zlib - disabling gzipped capture file support)
1775                 fi
1776         fi
1777 fi
1778
1779 dnl Lua check
1780 AC_MSG_CHECKING(whether to use liblua for the Lua scripting plugin)
1781
1782 AC_ARG_WITH(lua,
1783   AC_HELP_STRING( [--with-lua@<:@=DIR@:>@],
1784                   [use liblua (located in directory DIR, if supplied) for the Lua scripting plugin @<:@default=yes, if available@:>@]),
1785 [
1786         if test $withval = no
1787         then
1788                 want_lua=no
1789         elif test $withval = yes
1790         then
1791                 want_lua=yes
1792         else
1793                 want_lua=yes
1794                 lua_dir=$withval
1795         fi
1796 ],[
1797         #
1798         # Use liblua by default
1799         #
1800         want_lua=ifavailable
1801         lua_dir=
1802 ])
1803 if test "x$want_lua" = "xno" ; then
1804         AC_MSG_RESULT(no)
1805 else
1806         AC_MSG_RESULT(yes)
1807         AC_WIRESHARK_LIBLUA_CHECK
1808         if test "x$want_lua" = "xno" ; then
1809                 AC_MSG_RESULT(liblua not found - disabling support for the lua scripting plugin)
1810         fi
1811 fi
1812 AM_CONDITIONAL(HAVE_LIBLUA, test x$want_lua = xyes)
1813
1814
1815 dnl portaudio check
1816 AC_MSG_CHECKING(whether to use libportaudio for the rtp_player)
1817
1818 AC_ARG_WITH(portaudio,
1819   AC_HELP_STRING( [--with-portaudio@<:@=DIR@:>@],
1820                   [use libportaudio (located in directory DIR, if supplied) for the rtp_player @<:@default=yes, if available@:>@]),
1821 [
1822         if test $withval = no
1823         then
1824                 want_portaudio=no
1825         elif test $withval = yes
1826         then
1827                 want_portaudio=yes
1828         else
1829                 want_portaudio=yes
1830                 portaudio_dir=$withval
1831         fi
1832 ],[
1833         #
1834         # Use libportaudio by default
1835         #
1836         want_portaudio=ifavailable
1837         portaudio_dir=
1838 ])
1839 if test "x$want_portaudio" = "xno" ; then
1840         AC_MSG_RESULT(no)
1841 else
1842         AC_MSG_RESULT(yes)
1843         AC_WIRESHARK_LIBPORTAUDIO_CHECK
1844         if test "x$want_portaudio" = "xno" ; then
1845                 AC_MSG_RESULT(libportaudio not found - disabling support for the rtp_player)
1846         fi
1847 fi
1848 AM_CONDITIONAL(HAVE_LIBPORTAUDIO, test x$want_portaudio = xyes)
1849
1850
1851 dnl ipv6 check
1852 AC_ARG_ENABLE(ipv6,
1853   AC_HELP_STRING( [--enable-ipv6],
1854                   [use IPv6 name resolution, if available @<:@default=yes@:>@]),
1855     enable_ipv6=$enableval,enable_ipv6=yes)
1856
1857 AC_MSG_CHECKING(whether to enable ipv6 name resolution if available)
1858 if test "x$enable_ipv6" = "xno" ; then
1859         AC_MSG_RESULT(no)
1860 else
1861         AC_MSG_RESULT(yes)
1862         AC_WIRESHARK_IPV6_STACK
1863 fi
1864
1865
1866 dnl Check if dumpcap should be installed with filesystem capabilities
1867 AC_PATH_PROG(SETCAP, setcap)
1868 AC_ARG_ENABLE(setcap-install,
1869   AC_HELP_STRING( [--enable-setcap-install],
1870                   [install dumpcap with cap_net_admin and cap_net_raw @<:@default=no@:>@]),
1871     enable_setcap_install=$enableval,enable_setcap_install=no)
1872
1873 AC_MSG_CHECKING(whether to install dumpcap with cap_net_admin and cap_net_raw capabilities)
1874 if test "x$enable_setcap_install" = "xno" ; then
1875         AC_MSG_RESULT(no)
1876 else
1877         if test "x$SETCAP" = "x" ; then
1878                 AC_MSG_RESULT(no. Setcap not found)
1879         elif test "x$enable_dumpcap" = "xno" ; then
1880                 AC_MSG_ERROR(Setcap install works only with dumpcap but dumpcap is disabled)
1881         else
1882                 AC_MSG_RESULT(yes)
1883         fi
1884 fi
1885
1886 AM_CONDITIONAL(SETCAP_INSTALL, test x$enable_setcap_install = xyes)
1887
1888 dnl Check if dumpcap should be installed setuid
1889 AC_ARG_ENABLE(setuid-install,
1890   AC_HELP_STRING( [--enable-setuid-install],
1891                   [install dumpcap as setuid @<:@default=no@:>@]),
1892     enable_setuid_install=$enableval,enable_setuid_install=no)
1893
1894 AC_MSG_CHECKING(whether to install dumpcap setuid)
1895 if test "x$enable_setuid_install" = "xno" ; then
1896         AC_MSG_RESULT(no)
1897 else
1898         if test "x$enable_setcap_install" = "xyes" ; then
1899                 enable_setuid_install=no
1900                 AC_MSG_RESULT(no; using setcap instead)
1901         elif test "x$enable_dumpcap" = "xno" ; then
1902                 AC_MSG_ERROR(Setuid install works only with dumpcap but dumpcap is disabled)
1903         else
1904                 AC_MSG_RESULT(yes)
1905         fi
1906 fi
1907
1908 AM_CONDITIONAL(SETUID_INSTALL, test x$enable_setuid_install = xyes)
1909 AC_CHECK_FUNCS(setresuid setresgid)
1910
1911 dnl ...but our Network Operations group is named "no"!
1912 DUMPCAP_GROUP=''
1913 AC_ARG_WITH(dumpcap-group,
1914   AC_HELP_STRING( [--with-dumpcap-group=GROUP],
1915                   [restrict dumpcap to GROUP]),
1916 [
1917   if test "x$withval" = "xyes"; then
1918       AC_MSG_ERROR([No dumpcap group specified.])
1919   elif test "x$withval" != "xno"; then
1920       if test "x$enable_dumpcap" = "xno" ; then
1921           AC_MSG_ERROR(dumpcap group install works only with dumpcap but dumpcap is disabled)
1922       fi
1923       AC_MSG_RESULT($withval)
1924       DUMPCAP_GROUP="$withval"
1925   fi
1926 ])
1927 AC_SUBST(DUMPCAP_GROUP)
1928 AM_CONDITIONAL(HAVE_DUMPCAP_GROUP, test x$DUMPCAP_GROUP != x)
1929
1930 dnl libcap (not libpcap) check
1931 LIBCAP_LIBS=''
1932 AC_MSG_CHECKING(whether to use the libcap capabilities library)
1933
1934 AC_ARG_WITH(libcap,
1935   AC_HELP_STRING( [--with-libcap@<:@=DIR@:>@],
1936                   [use libcap (located in directory DIR, if supplied) for POSIX.1e capabilities management @<:@default=yes, if present@:>@]),
1937 [
1938 if   test "x$withval" = "xno";  then
1939         want_libcap=no
1940 elif test "x$withval" = "xyes"; then
1941         want_libcap=yes
1942 elif test -d "$withval"; then
1943         want_libcap=yes
1944         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
1945 fi
1946 ])
1947 if test "x$with_libcap" = "xno" ; then
1948         AC_MSG_RESULT(no)
1949 else
1950         AC_MSG_RESULT(yes)
1951         AC_WIRESHARK_LIBCAP_CHECK
1952 fi
1953 AC_SUBST(LIBCAP_LIBS)
1954
1955 dnl Checks for header files.
1956 dnl Some of these may not be needed: http://hacks.owlfolio.org/header-survey/
1957 AC_CHECK_HEADERS(direct.h dirent.h fcntl.h grp.h inttypes.h netdb.h pwd.h stdarg.h stddef.h unistd.h)
1958 AC_CHECK_HEADERS(sys/ioctl.h sys/param.h sys/socket.h sys/sockio.h sys/stat.h sys/time.h sys/types.h sys/utsname.h sys/wait.h)
1959 AC_CHECK_HEADERS(netinet/in.h)
1960 AC_CHECK_HEADERS(arpa/inet.h arpa/nameser.h)
1961
1962 dnl SSL Check
1963 SSL_LIBS=''
1964 AC_MSG_CHECKING(whether to use SSL library)
1965
1966 AC_ARG_WITH(ssl,
1967   AC_HELP_STRING( [--with-ssl@<:@=DIR@:>@],
1968                   [use SSL crypto library (located in directory DIR, if supplied) @<:@default=no@:>@]),
1969 [
1970 if test "x$withval" = "xno";  then
1971         want_ssl=no
1972 elif test "x$withval" = "xyes"; then
1973         want_ssl=yes
1974 elif test -d "$withval"; then
1975         want_ssl=yes
1976         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
1977 fi
1978 ],[
1979         want_ssl=no
1980 ])
1981 if test "x$want_ssl" = "xyes"; then
1982         AC_MSG_RESULT(yes)
1983         AC_CHECK_LIB(crypto,EVP_md5,
1984             [
1985                 SSL_LIBS=-lcrypto
1986             ],
1987             [
1988                 AC_MSG_ERROR([SSL crypto library was requested, but is not available])
1989             ])
1990 else
1991         AC_MSG_RESULT(no)
1992 fi
1993 AC_SUBST(SSL_LIBS)
1994
1995 dnl kerberos check
1996 AC_MSG_CHECKING(whether to use Kerberos library)
1997
1998 AC_ARG_WITH(krb5,
1999   AC_HELP_STRING( [--with-krb5@<:@=DIR@:>@],
2000                   [use Kerberos library (located in directory DIR, if supplied) to use in Kerberos dissection @<:@default=yes@:>@]),
2001 [
2002         if test $withval = no
2003         then
2004                 want_krb5=no
2005         elif test $withval = yes
2006         then
2007                 want_krb5=yes
2008         else
2009                 want_krb5=yes
2010                 krb5_dir=$withval
2011         fi
2012 ],[
2013         #
2014         # Use Kerberos library if available, otherwise don't.
2015         #
2016         want_krb5=ifavailable
2017         krb5_dir=
2018 ])
2019 if test "x$want_krb5" = "xno" ; then
2020         AC_MSG_RESULT(no)
2021 else
2022         AC_MSG_RESULT(yes)
2023         AC_WIRESHARK_KRB5_CHECK
2024 fi
2025
2026
2027 dnl c-ares Check
2028 C_ARES_LIBS=''
2029 AC_MSG_CHECKING(whether to use the c-ares library if available)
2030
2031 AC_ARG_WITH(c-ares,
2032   AC_HELP_STRING( [--with-c-ares@<:@=DIR@:>@],
2033                   [use c-ares (located in directory DIR, if supplied) - supersedes --with-adns @<:@default=yes, if present@:>@]),
2034 [
2035 if   test "x$withval" = "xno";  then
2036         want_c_ares=no
2037 elif test "x$withval" = "xyes"; then
2038         want_c_ares=yes
2039 elif test -d "$withval"; then
2040         want_c_ares=yes
2041         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
2042 fi
2043 ])
2044 if test "x$want_c_ares" = "xno" ; then
2045         AC_MSG_RESULT(no)
2046 else
2047         AC_MSG_RESULT(yes)
2048         AC_WIRESHARK_C_ARES_CHECK
2049 fi
2050 AC_SUBST(C_ARES_LIBS)
2051
2052 dnl ADNS Check
2053 ADNS_LIBS=''
2054 AC_MSG_CHECKING(whether to use the GNU ADNS library if available)
2055
2056 AC_ARG_WITH(adns,
2057   AC_HELP_STRING( [--with-adns@<:@=DIR@:>@],
2058                   [use GNU ADNS (located in directory DIR, if supplied) @<:@default=yes, if present@:>@]),
2059 [
2060 if   test "x$withval" = "xno";  then
2061         want_adns=no
2062 elif test "x$withval" = "xyes"; then
2063         want_adns=yes
2064 elif test -d "$withval"; then
2065         want_adns=yes
2066         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
2067 fi
2068 ])
2069 if test "x$want_adns" = "xno" -o "x$have_good_c_ares" = "xyes" ; then
2070         AC_MSG_RESULT(no)
2071 else
2072         AC_MSG_RESULT(yes)
2073         AC_WIRESHARK_ADNS_CHECK
2074 fi
2075 AC_SUBST(ADNS_LIBS)
2076
2077 dnl GEOIP Check
2078 GEOIP_LIBS=''
2079 AC_MSG_CHECKING(whether to use the GeoIP IP address mapping library if available)
2080
2081 AC_ARG_WITH(geoip,
2082   AC_HELP_STRING( [--with-geoip@<:@=DIR@:>@],
2083                   [use GeoIP (located in directory DIR, if supplied) @<:@default=yes, if present@:>@]),
2084 [
2085 if   test "x$withval" = "xno";  then
2086         want_geoip=no
2087 elif test "x$withval" = "xyes"; then
2088         want_geoip=yes
2089 elif test -d "$withval"; then
2090         want_geoip=yes
2091         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
2092 fi
2093 ])
2094 if test "x$want_geoip" = "xno"; then
2095         AC_MSG_RESULT(no)
2096 else
2097         AC_MSG_RESULT(yes)
2098         AC_WIRESHARK_GEOIP_CHECK
2099 fi
2100 AC_SUBST(GEOIP_LIBS)
2101
2102 # Warning: this Python scripting appears to be broken (does not work at all).
2103 # Running it also causes Valgrind to complain about all sorts of memory errors.
2104 # Suggestion: do not enable it unless you are working on fixing it.
2105 #
2106 # An alternative might be https://code.google.com/p/pyreshark/
2107 #
2108 dnl Python devel Check
2109 AC_MSG_CHECKING(whether to use the Python interpreter for scripting)
2110
2111 AC_ARG_WITH(broken-python,
2112     AC_HELP_STRING( [--with-broken-python@<:@=DIR@:>@],
2113                     [use the (BROKEN) Python interpreter (installed in DIR, if supplied) @<:@default=no@:>@]),
2114 [
2115         pythondir='${libdir}/wireshark/python/${VERSION}'
2116         if test "x$withval" = "xno"
2117         then
2118                 want_python=no
2119         elif test "x$withval" = "xyes"
2120         then
2121                 want_python=yes
2122         else
2123                 want_python=yes
2124                 pythondir="$withval"
2125         fi
2126 ],[
2127         # By default (user didn't explicitly enable Python), don't enable
2128         # Python support.
2129         #
2130         want_python=no
2131         #pythondir='${libdir}/wireshark/python/${VERSION}'
2132 ])
2133 if test "x$want_python" = "xno" ; then
2134         AC_MSG_RESULT(no)
2135 else
2136         AC_MSG_RESULT(yes)
2137         AC_WIRESHARK_PYTHON_CHECK
2138 fi
2139 AM_CONDITIONAL(HAVE_LIBPY, test x$want_python != xno)
2140 AC_SUBST(pythondir)
2141
2142 #
2143 # Define WS_MSVC_NORETURN appropriately for declarations of routines that
2144 # never return (just like Charlie on the MTA).
2145 #
2146 # Note that MSVC++ expects __declspec(noreturn) to precede the function
2147 # name and GCC, as far as I know, expects __attribute__((noreturn)) to
2148 # follow the function name, so we need two different flavors of
2149 # noreturn tag.
2150 #
2151 AC_DEFINE(WS_MSVC_NORETURN,, [Define as the string to precede declarations of routines that never return])
2152
2153 dnl Checks for typedefs, structures, and compiler characteristics.
2154 # AC_C_CONST
2155
2156 # Check how we can get the time zone abbreviation
2157 AC_WIRESHARK_TIMEZONE_ABBREV
2158
2159 # We need to know whether "struct stat" has an "st_flags" member
2160 # for file_user_immutable().
2161
2162 AC_WIRESHARK_STRUCT_ST_FLAGS
2163
2164 # We need to know whether "struct sockaddr" has an "sa_len" member
2165 # for get_interface_list().
2166
2167 AC_WIRESHARK_STRUCT_SA_LEN
2168
2169 # We must know our byte order
2170 AC_C_BIGENDIAN
2171
2172 # Checks whether "-traditional" is needed when using "ioctl".
2173 # XXX - do we need this?
2174 AC_PROG_GCC_TRADITIONAL
2175
2176 GETOPT_LO=""
2177 AC_CHECK_FUNC(getopt,
2178   [GETOPT_LO=""
2179    AC_DEFINE(HAVE_GETOPT, 1, [Define to 1 if you have the getopt function.])
2180   ],
2181   GETOPT_LO="wsgetopt.lo"
2182 )
2183 if test "$ac_cv_func_getopt" = no ; then
2184   GETOPT_LO="wsgetopt.lo"
2185 fi
2186 AM_CONDITIONAL(NEED_GETOPT_LO, test "x$ac_cv_func_getopt" = "xno")
2187 AC_SUBST(GETOPT_LO)
2188
2189 AC_CHECK_FUNC(strncasecmp, STRNCASECMP_LO="",
2190   STRNCASECMP_LO="strncasecmp.lo")
2191 if test "$ac_cv_func_strncasecmp" = no ; then
2192   STRNCASECMP_LO="strncasecmp.lo"
2193 fi
2194 AM_CONDITIONAL(NEED_STRNCASECMP_LO, test "x$ac_cv_func_strncasecmp" = "xno")
2195 AC_SUBST(STRNCASECMP_LO)
2196
2197 AC_CHECK_FUNCS(mkstemp mkdtemp)
2198
2199 AC_SEARCH_LIBS(inet_aton, [socket nsl], have_inet_aton=yes,
2200     have_inet_aton=no)
2201 if test "$have_inet_aton" = no; then
2202   INET_ATON_LO="inet_aton.lo"
2203   AC_DEFINE(NEED_INET_ATON_H, 1, [Define if inet/aton.h needs to be included])
2204 else
2205   INET_ATON_LO=""
2206 fi
2207 AM_CONDITIONAL(NEED_INET_ATON_LO, test "x$have_inet_aton" = "xno")
2208 AC_SUBST(INET_ATON_LO)
2209
2210 AC_SEARCH_LIBS(inet_pton, [socket nsl], [
2211   dnl check for pre-BIND82 inet_pton() bug.
2212   AC_MSG_CHECKING(for broken inet_pton)
2213   AC_TRY_RUN([#include <sys/types.h>
2214 #include <sys/socket.h>
2215 #include <netinet/in.h>
2216 #include <arpa/inet.h>
2217 int main()
2218 {
2219 #ifdef AF_INET6
2220   char buf[16];
2221   /* this should return 0 (error) */
2222   return inet_pton(AF_INET6, "0:1:2:3:4:5:6:7:", buf);
2223 #else
2224   return 1;
2225 #endif
2226 }], [AC_MSG_RESULT(ok);
2227 have_inet_pton=yes], [AC_MSG_RESULT(broken);
2228 have_inet_pton=no], [AC_MSG_RESULT(cross compiling, assume it is broken);
2229 have_inet_pton=no])],
2230 have_inet_pton=no)
2231 if test "$have_inet_pton" = no; then
2232   INET_PTON_LO="inet_pton.lo"
2233 else
2234   INET_PTON_LO=""
2235 fi
2236 AM_CONDITIONAL(NEED_INET_PTON_LO, test "x$have_inet_pton" = "xno")
2237 AC_SUBST(INET_PTON_LO)
2238
2239 AC_SEARCH_LIBS(inet_ntop, [socket nsl], [
2240   AC_MSG_CHECKING([for inet_ntop prototype])
2241   AC_TRY_COMPILE([#include <stdio.h>
2242 #include <sys/types.h>
2243 #include <sys/socket.h>
2244 #include <netinet/in.h>
2245 #include <arpa/inet.h>
2246
2247 extern const char *inet_ntop(int, const void *, char *, size_t);],, [
2248     AC_MSG_RESULT(yes)
2249     AC_DEFINE(HAVE_INET_NTOP_PROTO, 1,
2250     [Define if inet_ntop() prototype exists])], [
2251     AC_TRY_COMPILE([#include <stdio.h>
2252 #include <sys/types.h>
2253 #include <sys/socket.h>
2254 #include <netinet/in.h>
2255 #include <arpa/inet.h>
2256
2257 extern const char *inet_ntop(int, const void *, char *, socklen_t);],, [
2258       AC_MSG_RESULT(yes)
2259       AC_DEFINE(HAVE_INET_NTOP_PROTO, 1,
2260       [Define if inet_ntop() prototype exists])], [
2261       AC_MSG_RESULT(no)])])
2262   INET_NTOP_LO=""], [
2263   INET_NTOP_LO="inet_ntop.lo"
2264   AC_DEFINE(NEED_INET_V6DEFS_H, 1,
2265   [Define if inet/v6defs.h needs to be included])])
2266 AM_CONDITIONAL(NEED_INET_NTOP_LO, test "x$INET_NTOP_LO" != "x")
2267 AC_SUBST(INET_NTOP_LO)
2268
2269 AC_CHECK_FUNC(strptime, STRPTIME_LO="",
2270   [STRPTIME_LO="strptime.lo"
2271    AC_DEFINE(NEED_STRPTIME_H, 1, [Define if strptime.h needs to be included])
2272 ])
2273 if test "$ac_cv_func_strptime" = no ; then
2274   STRPTIME_LO="strptime.lo"
2275 fi
2276 AC_SUBST(STRPTIME_C)
2277 AM_CONDITIONAL(NEED_STRPTIME_LO, test "x$ac_cv_func_strptime" = "no")
2278 AC_SUBST(STRPTIME_LO)
2279
2280 AC_CHECK_FUNCS(getprotobynumber gethostbyname2)
2281 AC_CHECK_FUNCS(issetugid)
2282 AC_CHECK_FUNCS(mmap mprotect sysconf)
2283 AC_CHECK_FUNCS(strtoll)
2284
2285 dnl blank for now, but will be used in future
2286 AC_SUBST(wireshark_SUBDIRS)
2287
2288 dnl
2289 dnl check whether plugins should be enabled and, if they should be,
2290 dnl check for plugins directory - stolen from Amanda's configure.ac
2291 dnl
2292 dnl we don't wish to expand ${libdir} yet
2293 plugindir='${libdir}/wireshark/plugins/${VERSION}'
2294 AC_ARG_WITH(plugins,
2295   AC_HELP_STRING( [--with-plugins@<:@=DIR@:>@],
2296                   [support plugins (installed in DIR, if supplied) @<:@default=yes, if possible@:>@]),
2297 [
2298   if test "x$withval" = "xno"; then
2299     have_plugins=no
2300   elif test "x$have_plugins" = "xno"; then
2301       AC_MSG_ERROR([GLib on this platform doesn't support loadable modules, so you can't enable plugins.])
2302   elif test "x$withval" != "xyes"; then
2303       plugindir="$withval"
2304   fi
2305 ])
2306 AM_CONDITIONAL(HAVE_PLUGINS, test "x$have_plugins" = "xyes")
2307 if test x$have_plugins = xyes
2308 then
2309   AC_DEFINE(HAVE_PLUGINS, 1, [Define if plugins are enabled])
2310 fi
2311 AC_SUBST(plugindir)
2312 CPPFLAGS="$CPPFLAGS '-DPLUGIN_DIR=\"\$(plugindir)\"'"
2313
2314 #
2315 # The plugin dissectors reside in ./plugins/PROTO/
2316 #
2317 PLUGIN_LIBS=""
2318 AC_SUBST(PLUGIN_LIBS)
2319
2320 #
2321 # Check if (emem) memory allocations must be 8-byte aligned.
2322 # I haven't been able to write C code that reliably makes that determination
2323 # (different versions of GCC with or without optimization give different
2324 # results) so just assume everything except (32-bit) x86 needs 8-byte
2325 # alignment (64-bit platforms either require 8-byte alignment for pointers
2326 # and 64-bit integral data types or may get better performance from that;
2327 # 64-bit x86 will get 8-byte alignment from G_MEM_ALIGN anyway.  32-bit
2328 # platforms would only require it, or get better performance from it,
2329 # for 64-bit floating-point values.).
2330 #
2331 AC_MSG_CHECKING(whether we need memory allocations to be 8-byte aligned)
2332 case $host_cpu in
2333         i386|i486|i586|i686)
2334                 AC_MSG_RESULT(no)
2335                 ;;
2336         *)
2337                 AC_MSG_RESULT(yes)
2338                 AC_DEFINE(NEED_8_BYTE_ALIGNMENT, 1, [Define if we need memory allocations to be 8-byte aligned])
2339                 ;;
2340 esac
2341
2342 dnl libtool defs
2343 #
2344 # Yes, AM_PROG_LIBTOOL is redundant with newer version(s) of some tool(s)
2345 # (autoconf?  automake?  libtool?) - with the newer version(s), it's
2346 # just an alias for AC_PROG_LIBTOOL, which is called earlier.
2347 #
2348 # With older version(s) of those tool(s), however, it's not just an
2349 # alias, and the configure scripts don't work without it.
2350 #
2351 AM_PROG_LIBTOOL
2352 AC_SUBST(LIBTOOL_DEPS)
2353
2354 AM_CONDITIONAL(ENABLE_STATIC, test x$enable_static = xyes)
2355 if test x$enable_static = xyes -a x$have_plugins = xyes
2356 then
2357   AC_DEFINE(ENABLE_STATIC, 1, [Link plugins statically into Wireshark])
2358 fi
2359 AC_SUBST(ENABLE_STATIC)
2360
2361 dnl Save the cacheable configure results to config.cache before recursing
2362 AC_CACHE_SAVE
2363
2364 sinclude(plugins/Custom.m4) dnl
2365 ifdef(_CUSTOM_AC_OUTPUT_,, define(_CUSTOM_AC_OUTPUT_, )) dnl
2366
2367 sinclude(asn1/Custom.m4) dnl
2368 ifdef(_CUSTOM_ASN1_AC_OUTPUT_,, define(_CUSTOM_ASN1_AC_OUTPUT_, )) dnl
2369
2370 AC_CONFIG_HEADERS(config.h)
2371 AC_OUTPUT(
2372   Makefile
2373   doxygen.cfg
2374   asn1/Makefile
2375   _CUSTOM_ASN1_AC_OUTPUT_
2376   asn1/acp133/Makefile
2377   asn1/acse/Makefile
2378   asn1/ansi_map/Makefile
2379   asn1/ansi_tcap/Makefile
2380   asn1/c1222/Makefile
2381   asn1/camel/Makefile
2382   asn1/cdt/Makefile
2383   asn1/charging_ase/Makefile
2384   asn1/cmip/Makefile
2385   asn1/cmp/Makefile
2386   asn1/crmf/Makefile
2387   asn1/cms/Makefile
2388   asn1/credssp/Makefile
2389   asn1/dap/Makefile
2390   asn1/disp/Makefile
2391   asn1/dop/Makefile
2392   asn1/dsp/Makefile
2393   asn1/ess/Makefile
2394   asn1/ftam/Makefile
2395   asn1/gnm/Makefile
2396   asn1/goose/Makefile
2397   asn1/gprscdr/Makefile
2398   asn1/gsm_map/Makefile
2399   asn1/h225/Makefile
2400   asn1/h235/Makefile
2401   asn1/h245/Makefile
2402   asn1/h248/Makefile
2403   asn1/h282/Makefile
2404   asn1/h283/Makefile
2405   asn1/h323/Makefile
2406   asn1/h450/Makefile
2407   asn1/h450-ros/Makefile
2408   asn1/h460/Makefile
2409   asn1/h501/Makefile
2410   asn1/HI2Operations/Makefile
2411   asn1/hnbap/Makefile
2412   asn1/idmp/Makefile
2413   asn1/inap/Makefile
2414   asn1/isdn-sup/Makefile
2415   asn1/kerberos/Makefile
2416   asn1/lcsap/Makefile
2417   asn1/ldap/Makefile
2418   asn1/logotypecertextn/Makefile
2419   asn1/lpp/Makefile
2420   asn1/lppa/Makefile
2421   asn1/lppe/Makefile
2422   asn1/lte-rrc/Makefile
2423   asn1/m3ap/Makefile
2424   asn1/mms/Makefile
2425   asn1/mpeg-audio/Makefile
2426   asn1/mpeg-pes/Makefile
2427   asn1/nbap/Makefile
2428   asn1/ns_cert_exts/Makefile
2429   asn1/ocsp/Makefile
2430   asn1/p1/Makefile
2431   asn1/p22/Makefile
2432   asn1/p7/Makefile
2433   asn1/p772/Makefile
2434   asn1/pcap/Makefile
2435   asn1/pkcs1/Makefile
2436   asn1/pkcs12/Makefile
2437   asn1/pkinit/Makefile
2438   asn1/pkixac/Makefile
2439   asn1/pkix1explicit/Makefile
2440   asn1/pkix1implicit/Makefile
2441   asn1/pkixproxy/Makefile
2442   asn1/pkixqualified/Makefile
2443   asn1/pkixtsp/Makefile
2444   asn1/pres/Makefile
2445   asn1/q932/Makefile
2446   asn1/q932-ros/Makefile
2447   asn1/qsig/Makefile
2448   asn1/ranap/Makefile
2449   asn1/rnsap/Makefile
2450   asn1/ros/Makefile
2451   asn1/rrc/Makefile
2452   asn1/rrlp/Makefile
2453   asn1/rtse/Makefile
2454   asn1/rua/Makefile
2455   asn1/s1ap/Makefile
2456   asn1/sabp/Makefile
2457   asn1/sbc-ap/Makefile
2458   asn1/smrse/Makefile
2459   asn1/snmp/Makefile
2460   asn1/spnego/Makefile
2461   asn1/sv/Makefile
2462   asn1/t124/Makefile
2463   asn1/t125/Makefile
2464   asn1/t38/Makefile
2465   asn1/tcap/Makefile
2466   asn1/tetra/Makefile
2467   asn1/ulp/Makefile
2468   asn1/wlancertextn/Makefile
2469   asn1/x2ap/Makefile
2470   asn1/x509af/Makefile
2471   asn1/x509ce/Makefile
2472   asn1/x509if/Makefile
2473   asn1/x509sat/Makefile
2474   asn1/x721/Makefile
2475   doc/Makefile
2476   docbook/Makefile
2477   epan/Makefile
2478   epan/crypt/Makefile
2479   epan/doxygen.cfg
2480   epan/dfilter/Makefile
2481   epan/dissectors/Makefile
2482   epan/dissectors/dcerpc/Makefile
2483   epan/dissectors/pidl/Makefile
2484   epan/ftypes/Makefile
2485   epan/wmem/Makefile
2486   epan/wslua/Makefile
2487   epan/wspython/Makefile
2488   codecs/Makefile
2489   ui/Makefile
2490   ui/doxygen.cfg
2491   ui/gtk/Makefile
2492   ui/gtk/doxygen.cfg
2493   ui/cli/Makefile
2494   ui/qt/Makefile
2495   ui/qt/doxygen.cfg
2496   help/Makefile
2497   packaging/Makefile
2498   packaging/macosx/Info.plist
2499   packaging/macosx/Makefile
2500   packaging/macosx/osx-dmg.sh
2501   packaging/nsis/Makefile
2502   packaging/rpm/Makefile
2503   packaging/rpm/SPECS/Makefile
2504   packaging/rpm/SPECS/wireshark.spec
2505   packaging/svr4/Makefile
2506   packaging/svr4/checkinstall
2507   packaging/svr4/pkginfo
2508   plugins/Makefile
2509   plugins/asn1/Makefile
2510   plugins/docsis/Makefile
2511   plugins/ethercat/Makefile
2512   plugins/gryphon/Makefile
2513   plugins/irda/Makefile
2514   plugins/m2m/Makefile
2515   plugins/mate/Makefile
2516   plugins/opcua/Makefile
2517   plugins/profinet/Makefile
2518   plugins/stats_tree/Makefile
2519   plugins/unistim/Makefile
2520   plugins/wimax/Makefile
2521   plugins/wimaxasncp/Makefile
2522   plugins/wimaxmacphy/Makefile
2523   tools/Makefile
2524   tools/lemon/Makefile
2525   wiretap/Makefile
2526   wsutil/Makefile
2527   echld/Makefile
2528   _CUSTOM_AC_OUTPUT_
2529   ,)
2530 dnl AC_CONFIG_FILES([tools/setuid-root.pl], [chmod +x tools/setuid-root.pl])
2531
2532
2533 # Pretty messages
2534
2535 if test "x$have_qt" = "xyes"; then
2536         gui_lib_message=" (with Qt)"
2537 else
2538         if test "x$have_gtk" = "xyes"; then
2539                 if test "x$with_gtk3" = "xyes"; then
2540                         gui_lib_message=" (with GTK+ 3"
2541                 else
2542                         gui_lib_message=" (with GTK+ 2"
2543                 fi
2544                 if test "x$have_ige_mac" = "xyes"; then
2545                         gui_lib_message="$gui_lib_message and Mac OS X integration)"
2546                 else
2547                         gui_lib_message="$gui_lib_message)"
2548                 fi
2549         fi
2550 fi
2551
2552 if test "x$enable_setcap_install" = "xyes" ; then
2553         setcap_message="yes"
2554 else
2555         setcap_message="no"
2556 fi
2557
2558 if test "x$enable_setuid_install" = "xyes" ; then
2559         setuid_message="yes"
2560 else
2561         setuid_message="no"
2562 fi
2563
2564 if test "x$DUMPCAP_GROUP" = "x" ; then
2565         dumpcap_group_message="(none)"
2566 else
2567         dumpcap_group_message="$DUMPCAP_GROUP"
2568 fi
2569
2570 if test "x$want_zlib" = "xno" ; then
2571         zlib_message="no"
2572 else
2573         zlib_message="yes"
2574 fi
2575
2576 if test "x$want_lua" = "xyes" ; then
2577         lua_message="yes"
2578 else
2579         lua_message="no"
2580 fi
2581
2582 if test "x$want_python" = "xno"; then
2583         python_message="no"
2584 else
2585         python_message="yes"
2586 fi
2587
2588 if test "x$want_portaudio" = "xyes" ; then
2589         portaudio_message="yes"
2590 else
2591         portaudio_message="no"
2592 fi
2593
2594 if test "x$want_ssl" = "xno" ; then
2595         ssl_message="no"
2596 else
2597         ssl_message="yes"
2598 fi
2599
2600 if test "x$want_krb5" = "xno" ; then
2601         krb5_message="no"
2602 else
2603         krb5_message="yes ($ac_krb5_version)"
2604 fi
2605
2606 if test "x$have_good_c_ares" = "xyes" ; then
2607         c_ares_message="yes"
2608 else
2609         c_ares_message="no"
2610 fi
2611
2612 if test "x$have_good_adns" = "xyes" ; then
2613         adns_message="yes"
2614 else
2615         if test "x$have_good_c_ares" = "xyes" ; then
2616                 adns_message="no (using c-ares instead)"
2617         else
2618                 adns_message="no"
2619         fi
2620 fi
2621
2622 if test "x$have_good_libcap" = "xyes" ; then
2623         libcap_message="yes"
2624 else
2625         libcap_message="no"
2626 fi
2627
2628 if test "x$have_good_geoip" = "xyes" ; then
2629         geoip_message="yes"
2630 else
2631         geoip_message="no"
2632 fi
2633
2634 echo ""
2635 echo "The Wireshark package has been configured with the following options."
2636 echo "                    Build wireshark : $enable_wireshark""$gui_lib_message"
2637 echo "                       Build tshark : $enable_tshark"
2638 echo "                     Build capinfos : $enable_capinfos"
2639 echo "                      Build editcap : $enable_editcap"
2640 echo "                      Build dumpcap : $enable_dumpcap"
2641 echo "                     Build mergecap : $enable_mergecap"
2642 echo "                   Build reordercap : $enable_reordercap"
2643 echo "                    Build text2pcap : $enable_text2pcap"
2644 echo "                      Build randpkt : $enable_randpkt"
2645 echo "                       Build dftest : $enable_dftest"
2646 echo "                     Build rawshark : $enable_rawshark"
2647 echo "                     Build echld : $have_echld"
2648 echo ""
2649 echo "   Save files as pcap-ng by default : $enable_pcap_ng_default"
2650 echo "  Install dumpcap with capabilities : $setcap_message"
2651 echo "             Install dumpcap setuid : $setuid_message"
2652 echo "                  Use dumpcap group : $dumpcap_group_message"
2653 echo "                        Use plugins : $have_plugins"
2654 echo "                    Use Lua library : $lua_message"
2655 echo "                 Use Python binding : $python_message"
2656 echo "                   Build rtp_player : $portaudio_message"
2657 echo "             Build profile binaries : $enable_profile_build"
2658 echo "                   Use pcap library : $want_pcap"
2659 echo "                   Use zlib library : $zlib_message"
2660 echo "               Use kerberos library : $krb5_message"
2661 echo "                 Use c-ares library : $c_ares_message"
2662 echo "               Use GNU ADNS library : $adns_message"
2663 echo "                Use SMI MIB library : $libsmi_message"
2664 echo "             Use GNU crypto library : $gcrypt_message"
2665 echo "             Use SSL crypto library : $ssl_message"
2666 echo "           Use IPv6 name resolution : $enable_ipv6"
2667 echo "                 Use gnutls library : $tls_message"
2668 echo "     Use POSIX capabilities library : $libcap_message"
2669 echo "                  Use GeoIP library : $geoip_message"
2670 echo "                     Use nl library : $libnl_message"