lib/replace/libreplace.m4

   1 AC_DEFUN_ONCE(AC_LIBREPLACE_LOCATION_CHECKS,
   2 [
   3 echo "LIBREPLACE_LOCATION_CHECKS: START"
   4
   5 dnl find the libreplace sources. This is meant to work both for
   6 dnl libreplace standalone builds, and builds of packages using libreplace
   7 libreplacedir=""
   8 libreplacepaths="$srcdir $srcdir/lib/replace $srcdir/libreplace $srcdir/../libreplace $srcdir/../replace $srcdir/../lib/replace $srcdir/../../../lib/replace"
   9 for d in $libreplacepaths; do
  10         if test -f "$d/replace.c"; then
  11                 libreplacedir="$d"
  12                 AC_SUBST(libreplacedir)
  13                 break;
  14         fi
  15 done
  16 if test x"$libreplacedir" = "x"; then
  17         AC_MSG_ERROR([cannot find libreplace in $libreplacepaths])
  18 fi
  19 LIBREPLACEOBJ="$libreplacedir/replace.o"
  20 AC_SUBST(LIBREPLACEOBJ)
  21
  22 AC_CANONICAL_BUILD
  23 AC_CANONICAL_HOST
  24 AC_CANONICAL_TARGET
  25
  26 echo "LIBREPLACE_LOCATION_CHECKS: END"
  27 ]) dnl end AC_LIBREPLACE_LOCATION_CHECKS
  28
  29
  30 AC_DEFUN_ONCE(AC_LIBREPLACE_BROKEN_CHECKS,
  31 [
  32 echo "LIBREPLACE_BROKEN_CHECKS: START"
  33
  34 dnl find the libreplace sources. This is meant to work both for
  35 dnl libreplace standalone builds, and builds of packages using libreplace
  36 libreplacedir=""
  37 libreplacepaths="$srcdir $srcdir/lib/replace $srcdir/libreplace $srcdir/../libreplace $srcdir/../replace $srcdir/../lib/replace $srcdir/../../../lib/replace"
  38 for d in $libreplacepaths; do
  39         if test -f "$d/replace.c"; then
  40                 libreplacedir="$d"
  41                 AC_SUBST(libreplacedir)
  42                 break;
  43         fi
  44 done
  45 if test x"$libreplacedir" = "x"; then
  46         AC_MSG_ERROR([cannot find libreplace in $libreplacepaths])
  47 fi
  48
  49 LIBREPLACEOBJ="$libreplacedir/replace.o"
  50 AC_SUBST(LIBREPLACEOBJ)
  51
  52 LIBREPLACEOBJ="${LIBREPLACEOBJ} $libreplacedir/snprintf.o"
  53
  54 AC_TYPE_UID_T
  55 AC_TYPE_MODE_T
  56 AC_TYPE_OFF_T
  57 AC_TYPE_SIZE_T
  58 AC_TYPE_PID_T
  59 AC_STRUCT_ST_RDEV
  60 AC_CHECK_TYPE(ino_t,unsigned)
  61 AC_CHECK_TYPE(loff_t,off_t)
  62 AC_CHECK_TYPE(offset_t,loff_t)
  63
  64 AC_FUNC_MEMCMP
  65
  66 AC_CHECK_FUNCS([pipe strftime srandom random srand rand usleep setbuffer lstat getpgrp utime utimes])
  67
  68 AC_CHECK_HEADERS(stdbool.h stdint.h sys/select.h)
  69 AC_CHECK_HEADERS(setjmp.h utime.h)
  70
  71 LIBREPLACE_PROVIDE_HEADER([stdint.h])
  72 LIBREPLACE_PROVIDE_HEADER([stdbool.h])
  73
  74 AC_DEFINE(HAVE_LIBREPLACE, 1, [We have libreplace])
  75
  76 AC_CHECK_TYPE(bool,
  77 [AC_DEFINE(HAVE_BOOL, 1, [Whether the bool type is available])],,
  78 [
  79 AC_INCLUDES_DEFAULT
  80 #ifdef HAVE_STDBOOL_H
  81 #include <stdbool.h>
  82 #endif]
  83 )
  84
  85 AC_CHECK_TYPE(_Bool,
  86 [AC_DEFINE(HAVE__Bool, 1, [Whether the _Bool type is available])],,
  87 [
  88 AC_INCLUDES_DEFAULT
  89 #ifdef HAVE_STDBOOL_H
  90 #include <stdbool.h>
  91 #endif]
  92 )
  93
  94 AC_CHECK_HEADERS(linux/types.h)
  95
  96 AC_CACHE_CHECK([for working mmap],libreplace_cv_HAVE_MMAP,[
  97 AC_TRY_RUN([#include "$libreplacedir/test/shared_mmap.c"],
  98            libreplace_cv_HAVE_MMAP=yes,libreplace_cv_HAVE_MMAP=no,libreplace_cv_HAVE_MMAP=cross)])
  99 if test x"$libreplace_cv_HAVE_MMAP" = x"yes"; then
 100     AC_DEFINE(HAVE_MMAP,1,[Whether mmap works])
 101 fi
 102
 103 AC_CACHE_CHECK([for working mremap],libreplace_cv_HAVE_MREMAP,[
 104 AC_TRY_RUN([#include "$libreplacedir/test/shared_mremap.c"],
 105            libreplace_cv_HAVE_MREMAP=yes,libreplace_cv_HAVE_MREMAP=no,libreplace_cv_HAVE_MREMAP=cross)])
 106 if test x"$libreplace_cv_HAVE_MREMAP" = x"yes"; then
 107     AC_DEFINE(HAVE_MREMAP,1,[Whether mremap works])
 108 fi
 109
 110 AC_CACHE_CHECK([for incoherent mmap],libreplace_cv_HAVE_INCOHERENT_MMAP,[
 111 AC_TRY_RUN([#include "$libreplacedir/test/incoherent_mmap.c"],
 112            libreplace_cv_HAVE_INCOHERENT_MMAP=yes,libreplace_cv_HAVE_INCOHERENT_MMAP=no,libreplace_cv_HAVE_INCOHERENT_MMAP=cross)])
 113 if test x"$libreplace_cv_HAVE_INCOHERENT_MMAP" = x"yes"; then
 114     AC_DEFINE(HAVE_INCOHERENT_MMAP,1,[Whether mmap is incoherent against write])
 115 fi
 116
 117
 118 AC_CHECK_HEADERS(sys/syslog.h syslog.h)
 119 AC_CHECK_HEADERS(sys/time.h time.h)
 120 AC_CHECK_HEADERS(stdarg.h vararg.h)
 121 AC_CHECK_HEADERS(sys/mount.h mntent.h)
 122 AC_CHECK_HEADERS(stropts.h)
 123 AC_CHECK_HEADERS(unix.h)
 124 AC_CHECK_HEADERS(malloc.h)
 125
 126 AC_CHECK_FUNCS(seteuid setreuid setresuid setegid setregid setresgid)
 127 AC_CHECK_FUNCS(chroot bzero strerror strerror_r memalign posix_memalign getpagesize)
 128 AC_CHECK_FUNCS(vsyslog setlinebuf mktime ftruncate chsize rename)
 129 AC_CHECK_FUNCS(waitpid wait4 strlcpy strlcat initgroups memmove strdup)
 130 AC_CHECK_FUNCS(pread pwrite strndup strcasestr strtok_r mkdtemp dup2 dprintf vdprintf)
 131 AC_CHECK_FUNCS(isatty chown lchown link readlink symlink realpath)
 132 AC_CHECK_FUNCS(fdatasync,,[
 133         # if we didn't find it, look in librt (Solaris hides it there...)
 134         AC_CHECK_LIB(rt, fdatasync,
 135                 [libreplace_cv_HAVE_FDATASYNC_IN_LIBRT=yes
 136                 AC_DEFINE(HAVE_FDATASYNC, 1, Define to 1 if there is support for fdatasync)])
 137 ])
 138 AC_HAVE_DECL(fdatasync, [#include <unistd.h>])
 139 AC_CHECK_FUNCS(clock_gettime,libreplace_cv_have_clock_gettime=yes,[
 140         AC_CHECK_LIB(rt, clock_gettime,
 141                 [libreplace_cv_HAVE_CLOCK_GETTIME_IN_LIBRT=yes
 142                 libreplace_cv_have_clock_gettime=yes
 143                 AC_DEFINE(HAVE_CLOCK_GETTIME, 1, Define to 1 if there is support for clock_gettime)])
 144 ])
 145 AC_CHECK_FUNCS(get_current_dir_name)
 146 AC_HAVE_DECL(setresuid, [#include <unistd.h>])
 147 AC_HAVE_DECL(setresgid, [#include <unistd.h>])
 148 AC_HAVE_DECL(errno, [#include <errno.h>])
 149
 150 AC_CACHE_CHECK([for secure mkstemp],libreplace_cv_HAVE_SECURE_MKSTEMP,[
 151 AC_TRY_RUN([#include <stdlib.h>
 152 #include <sys/types.h>
 153 #include <sys/stat.h>
 154 #include <unistd.h>
 155 main() {
 156   struct stat st;
 157   char tpl[20]="/tmp/test.XXXXXX";
 158   int fd = mkstemp(tpl);
 159   if (fd == -1) exit(1);
 160   unlink(tpl);
 161   if (fstat(fd, &st) != 0) exit(1);
 162   if ((st.st_mode & 0777) != 0600) exit(1);
 163   exit(0);
 164 }],
 165 libreplace_cv_HAVE_SECURE_MKSTEMP=yes,
 166 libreplace_cv_HAVE_SECURE_MKSTEMP=no,
 167 libreplace_cv_HAVE_SECURE_MKSTEMP=cross)])
 168 if test x"$libreplace_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
 169     AC_DEFINE(HAVE_SECURE_MKSTEMP,1,[Whether mkstemp is secure])
 170 fi
 171
 172 dnl Provided by snprintf.c:
 173 AC_CHECK_HEADERS(stdio.h strings.h)
 174 AC_CHECK_DECLS([snprintf, vsnprintf, asprintf, vasprintf])
 175 AC_CHECK_FUNCS(snprintf vsnprintf asprintf vasprintf)
 176
 177 AC_CACHE_CHECK([for C99 vsnprintf],libreplace_cv_HAVE_C99_VSNPRINTF,[
 178 AC_TRY_RUN([
 179 #include <sys/types.h>
 180 #include <stdio.h>
 181 #include <stdarg.h>
 182 #include <stdlib.h>
 183 void foo(const char *format, ...) {
 184        va_list ap;
 185        int len;
 186        char buf[20];
 187        long long l = 1234567890;
 188        l *= 100;
 189
 190        va_start(ap, format);
 191        len = vsnprintf(buf, 0, format, ap);
 192        va_end(ap);
 193        if (len != 5) exit(1);
 194
 195        va_start(ap, format);
 196        len = vsnprintf(0, 0, format, ap);
 197        va_end(ap);
 198        if (len != 5) exit(2);
 199
 200        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(3);
 201
 202        if (snprintf(buf, 20, "%lld", l) != 12 || strcmp(buf, "123456789000") != 0) exit(4);
 203        if (snprintf(buf, 20, "%zu", 123456789) != 9 || strcmp(buf, "123456789") != 0) exit(5);
 204        if (snprintf(buf, 20, "%2\$d %1\$d", 3, 4) != 3 || strcmp(buf, "4 3") != 0) exit(6);
 205        if (snprintf(buf, 20, "%s", 0) < 3) exit(7);
 206
 207        exit(0);
 208 }
 209 main() { foo("hello"); }
 210 ],
 211 libreplace_cv_HAVE_C99_VSNPRINTF=yes,libreplace_cv_HAVE_C99_VSNPRINTF=no,libreplace_cv_HAVE_C99_VSNPRINTF=cross)])
 212 if test x"$libreplace_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 213     AC_DEFINE(HAVE_C99_VSNPRINTF,1,[Whether there is a C99 compliant vsnprintf])
 214 fi
 215
 216
 217 dnl VA_COPY
 218 AC_CACHE_CHECK([for va_copy],libreplace_cv_HAVE_VA_COPY,[
 219 AC_TRY_LINK([#include <stdarg.h>
 220 va_list ap1,ap2;], [va_copy(ap1,ap2);],
 221 libreplace_cv_HAVE_VA_COPY=yes,libreplace_cv_HAVE_VA_COPY=no)])
 222 if test x"$libreplace_cv_HAVE_VA_COPY" = x"yes"; then
 223     AC_DEFINE(HAVE_VA_COPY,1,[Whether va_copy() is available])
 224 fi
 225
 226 if test x"$libreplace_cv_HAVE_VA_COPY" != x"yes"; then
 227 AC_CACHE_CHECK([for __va_copy],libreplace_cv_HAVE___VA_COPY,[
 228 AC_TRY_LINK([#include <stdarg.h>
 229 va_list ap1,ap2;], [__va_copy(ap1,ap2);],
 230 libreplace_cv_HAVE___VA_COPY=yes,libreplace_cv_HAVE___VA_COPY=no)])
 231 if test x"$libreplace_cv_HAVE___VA_COPY" = x"yes"; then
 232     AC_DEFINE(HAVE___VA_COPY,1,[Whether __va_copy() is available])
 233 fi
 234 fi
 235
 236 dnl __FUNCTION__ macro
 237 AC_CACHE_CHECK([for __FUNCTION__ macro],libreplace_cv_HAVE_FUNCTION_MACRO,[
 238 AC_TRY_COMPILE([#include <stdio.h>], [printf("%s\n", __FUNCTION__);],
 239 libreplace_cv_HAVE_FUNCTION_MACRO=yes,libreplace_cv_HAVE_FUNCTION_MACRO=no)])
 240 if test x"$libreplace_cv_HAVE_FUNCTION_MACRO" = x"yes"; then
 241     AC_DEFINE(HAVE_FUNCTION_MACRO,1,[Whether there is a __FUNCTION__ macro])
 242 else
 243     dnl __func__ macro
 244     AC_CACHE_CHECK([for __func__ macro],libreplace_cv_HAVE_func_MACRO,[
 245     AC_TRY_COMPILE([#include <stdio.h>], [printf("%s\n", __func__);],
 246     libreplace_cv_HAVE_func_MACRO=yes,libreplace_cv_HAVE_func_MACRO=no)])
 247     if test x"$libreplace_cv_HAVE_func_MACRO" = x"yes"; then
 248        AC_DEFINE(HAVE_func_MACRO,1,[Whether there is a __func__ macro])
 249     fi
 250 fi
 251
 252 AC_CHECK_HEADERS([sys/param.h limits.h])
 253
 254 AC_CHECK_TYPE(comparison_fn_t,
 255 [AC_DEFINE(HAVE_COMPARISON_FN_T, 1,[Whether or not we have comparison_fn_t])])
 256
 257 AC_HAVE_DECL(setenv, [#include <stdlib.h>])
 258 AC_CHECK_FUNCS(setenv unsetenv)
 259 AC_HAVE_DECL(environ, [#include <unistd.h>])
 260
 261 AC_CHECK_FUNCS(strnlen)
 262 AC_CHECK_FUNCS(strtoull __strtoull strtouq strtoll __strtoll strtoq)
 263
 264 AC_CHECK_FUNCS(memmem)
 265
 266 # this test disabled as we don't actually need __VA_ARGS__ yet
 267 AC_TRY_CPP([
 268 #define eprintf(...) fprintf(stderr, __VA_ARGS__)
 269 eprintf("bla", "bar");
 270 ], AC_DEFINE(HAVE__VA_ARGS__MACRO, 1, [Whether the __VA_ARGS__ macro is available]))
 271
 272
 273 AC_CACHE_CHECK([for sig_atomic_t type],libreplace_cv_sig_atomic_t, [
 274     AC_TRY_COMPILE([
 275 #include <sys/types.h>
 276 #if STDC_HEADERS
 277 #include <stdlib.h>
 278 #include <stddef.h>
 279 #endif
 280 #include <signal.h>],[sig_atomic_t i = 0],
 281         libreplace_cv_sig_atomic_t=yes,libreplace_cv_sig_atomic_t=no)])
 282 if test x"$libreplace_cv_sig_atomic_t" = x"yes"; then
 283    AC_DEFINE(HAVE_SIG_ATOMIC_T_TYPE,1,[Whether we have the atomic_t variable type])
 284 fi
 285
 286
 287 AC_CACHE_CHECK([for O_DIRECT flag to open(2)],libreplace_cv_HAVE_OPEN_O_DIRECT,[
 288 AC_TRY_COMPILE([
 289 #include <unistd.h>
 290 #ifdef HAVE_FCNTL_H
 291 #include <fcntl.h>
 292 #endif],
 293 [int fd = open("/dev/null", O_DIRECT);],
 294 libreplace_cv_HAVE_OPEN_O_DIRECT=yes,libreplace_cv_HAVE_OPEN_O_DIRECT=no)])
 295 if test x"$libreplace_cv_HAVE_OPEN_O_DIRECT" = x"yes"; then
 296     AC_DEFINE(HAVE_OPEN_O_DIRECT,1,[Whether the open(2) accepts O_DIRECT])
 297 fi
 298
 299
 300 dnl Check if the C compiler understands volatile (it should, being ANSI).
 301 AC_CACHE_CHECK([that the C compiler understands volatile],libreplace_cv_volatile, [
 302         AC_TRY_COMPILE([#include <sys/types.h>],[volatile int i = 0],
 303                 libreplace_cv_volatile=yes,libreplace_cv_volatile=no)])
 304 if test x"$libreplace_cv_volatile" = x"yes"; then
 305         AC_DEFINE(HAVE_VOLATILE, 1, [Whether the C compiler understands volatile])
 306 fi
 307
 308 m4_include(system/config.m4)
 309
 310 m4_include(dlfcn.m4)
 311 m4_include(getpass.m4)
 312 m4_include(strptime.m4)
 313 m4_include(win32.m4)
 314 m4_include(timegm.m4)
 315 m4_include(repdir.m4)
 316 m4_include(crypt.m4)
 317
 318 if test x$libreplace_cv_have_clock_gettime = xyes ; then
 319         SMB_CHECK_CLOCK_ID(CLOCK_MONOTONIC)
 320         SMB_CHECK_CLOCK_ID(CLOCK_PROCESS_CPUTIME_ID)
 321         SMB_CHECK_CLOCK_ID(CLOCK_REALTIME)
 322 fi
 323
 324 AC_CACHE_CHECK([for struct timespec type],libreplace_cv_struct_timespec, [
 325     AC_TRY_COMPILE([
 326 #include <sys/types.h>
 327 #if STDC_HEADERS
 328 #include <stdlib.h>
 329 #include <stddef.h>
 330 #endif
 331 #if TIME_WITH_SYS_TIME
 332 # include <sys/time.h>
 333 # include <time.h>
 334 #else
 335 # if HAVE_SYS_TIME_H
 336 #  include <sys/time.h>
 337 # else
 338 #  include <time.h>
 339 # endif
 340 #endif
 341 ],[struct timespec ts;],
 342         libreplace_cv_struct_timespec=yes,libreplace_cv_struct_timespec=no)])
 343 if test x"$libreplace_cv_struct_timespec" = x"yes"; then
 344    AC_DEFINE(HAVE_STRUCT_TIMESPEC,1,[Whether we have struct timespec])
 345 fi
 346
 347 AC_CHECK_FUNCS([printf memset memcpy],,[AC_MSG_ERROR([Required function not found])])
 348
 349 echo "LIBREPLACE_BROKEN_CHECKS: END"
 350 ]) dnl end AC_LIBREPLACE_BROKEN_CHECKS
 351
 352 AC_DEFUN_ONCE(AC__LIBREPLACE_ALL_CHECKS_START,
 353 [
 354 #LIBREPLACE_ALL_CHECKS: START"
 355 ])
 356 AC_DEFUN_ONCE(AC__LIBREPLACE_ALL_CHECKS_END,
 357 [
 358 #LIBREPLACE_ALL_CHECKS: END"
 359 ])
 360 m4_define(AC_LIBREPLACE_ALL_CHECKS,
 361 [
 362 AC__LIBREPLACE_ALL_CHECKS_START
 363 AC_LIBREPLACE_LOCATION_CHECKS
 364 AC_LIBREPLACE_CC_CHECKS
 365 AC_LIBREPLACE_BROKEN_CHECKS
 366 AC__LIBREPLACE_ALL_CHECKS_END
 367 CFLAGS="$CFLAGS -I$libreplacedir"
 368 ])
 369
 370 m4_include(libreplace_cc.m4)
 371 m4_include(libreplace_ld.m4)
 372 m4_include(libreplace_network.m4)
 373 m4_include(libreplace_macros.m4)
 374
 375
 376 dnl SMB_CHECK_CLOCK_ID(clockid)
 377 dnl Test whether the specified clock_gettime clock ID is available. If it
 378 dnl is, we define HAVE_clockid
 379 AC_DEFUN([SMB_CHECK_CLOCK_ID],
 380 [
 381     AC_MSG_CHECKING(for $1)
 382     AC_TRY_LINK([
 383 #if TIME_WITH_SYS_TIME
 384 # include <sys/time.h>
 385 # include <time.h>
 386 #else
 387 # if HAVE_SYS_TIME_H
 388 #  include <sys/time.h>
 389 # else
 390 #  include <time.h>
 391 # endif
 392 #endif
 393     ],
 394     [
 395 clockid_t clk = $1;
 396     ],
 397     [
 398         AC_MSG_RESULT(yes)
 399         AC_DEFINE(HAVE_$1, 1,
 400             [Whether the clock_gettime clock ID $1 is available])
 401     ],
 402     [
 403         AC_MSG_RESULT(no)
 404     ])
 405 ])
 406 m4_ifndef([AC_USE_SYSTEM_EXTENSIONS],[m4_include(autoconf-2.60.m4)])