pidl/lib/Parse/Pidl/NDR.pm

   1 ###################################################
   2 # Samba4 NDR info tree generator
   3 # Copyright tridge@samba.org 2000-2003
   4 # Copyright tpot@samba.org 2001
   5 # Copyright jelmer@samba.org 2004-2006
   6 # released under the GNU GPL
   7
   8 =pod
   9
  10 =head1 NAME
  11
  12 Parse::Pidl::NDR - NDR parsing information generator
  13
  14 =head1 DESCRIPTION
  15
  16 Return a table describing the order in which the parts of an element
  17 should be parsed
  18 Possible level types:
  19  - POINTER
  20  - ARRAY
  21  - SUBCONTEXT
  22  - SWITCH
  23  - DATA
  24
  25 =head1 AUTHOR
  26
  27 Jelmer Vernooij <jelmer@samba.org>
  28
  29 =cut
  30
  31 package Parse::Pidl::NDR;
  32
  33 require Exporter;
  34 use vars qw($VERSION);
  35 $VERSION = '0.01';
  36 @ISA = qw(Exporter);
  37 @EXPORT = qw(GetPrevLevel GetNextLevel ContainsDeferred ContainsString);
  38 @EXPORT_OK = qw(GetElementLevelTable ParseElement ValidElement align_type mapToScalar ParseType can_contain_deferred is_charset_array);
  39
  40 use strict;
  41 use Parse::Pidl qw(warning fatal);
  42 use Parse::Pidl::Typelist qw(hasType getType expandAlias mapScalarType);
  43 use Parse::Pidl::Util qw(has_property property_matches);
  44
  45 # Alignment of the built-in scalar types
  46 my $scalar_alignment = {
  47         'void' => 0,
  48         'char' => 1,
  49         'int8' => 1,
  50         'uint8' => 1,
  51         'int16' => 2,
  52         'uint16' => 2,
  53         'int1632' => 3,
  54         'uint1632' => 3,
  55         'int32' => 4,
  56         'uint32' => 4,
  57         'int3264' => 5,
  58         'uint3264' => 5,
  59         'hyper' => 8,
  60         'double' => 8,
  61         'pointer' => 8,
  62         'dlong' => 4,
  63         'udlong' => 4,
  64         'udlongr' => 4,
  65         'DATA_BLOB' => 4,
  66         'string' => 4,
  67         'string_array' => 4, #???
  68         'time_t' => 4,
  69         'NTTIME' => 4,
  70         'NTTIME_1sec' => 4,
  71         'NTTIME_hyper' => 8,
  72         'WERROR' => 4,
  73         'NTSTATUS' => 4,
  74         'COMRESULT' => 4,
  75         'nbt_string' => 4,
  76         'wrepl_nbt_name' => 4,
  77         'ipv4address' => 4,
  78         'dnsp_name' => 1
  79 };
  80
  81 sub GetElementLevelTable($$)
  82 {
  83         my ($e, $pointer_default) = @_;
  84
  85         my $order = [];
  86         my $is_deferred = 0;
  87         my @bracket_array = ();
  88         my @length_is = ();
  89         my @size_is = ();
  90         my $pointer_idx = 0;
  91
  92         if (has_property($e, "size_is")) {
  93                 @size_is = split /,/, has_property($e, "size_is");
  94         }
  95
  96         if (has_property($e, "length_is")) {
  97                 @length_is = split /,/, has_property($e, "length_is");
  98         }
  99
 100         if (defined($e->{ARRAY_LEN})) {
 101                 @bracket_array = @{$e->{ARRAY_LEN}};
 102         }
 103
 104         if (has_property($e, "out")) {
 105                 my $needptrs = 1;
 106
 107                 if (has_property($e, "string")) { $needptrs++; }
 108                 if ($#bracket_array >= 0) { $needptrs = 0; }
 109
 110                 warning($e, "[out] argument `$e->{NAME}' not a pointer") if ($needptrs > $e->{POINTERS});
 111         }
 112
 113         # Parse the [][][][] style array stuff
 114         for my $i (0 .. $#bracket_array) {
 115                 my $d = $bracket_array[$#bracket_array - $i];
 116                 my $size = $d;
 117                 my $length = $d;
 118                 my $is_surrounding = 0;
 119                 my $is_varying = 0;
 120                 my $is_conformant = 0;
 121                 my $is_string = 0;
 122                 my $is_fixed = 0;
 123                 my $is_inline = 0;
 124
 125                 if ($d eq "*") {
 126                         $is_conformant = 1;
 127                         if ($size = shift @size_is) {
 128                                 if ($e->{POINTERS} < 1 and has_property($e, "string")) {
 129                                         $is_string = 1;
 130                                         delete($e->{PROPERTIES}->{string});
 131                                 }
 132                         } elsif ((scalar(@size_is) == 0) and has_property($e, "string")) {
 133                                 $is_string = 1;
 134                                 delete($e->{PROPERTIES}->{string});
 135                         } else {
 136                                 fatal($e, "Must specify size_is() for conformant array!")
 137                         }
 138
 139                         if (($length = shift @length_is) or $is_string) {
 140                                 $is_varying = 1;
 141                         } else {
 142                                 $length = $size;
 143                         }
 144
 145                         if ($e == $e->{PARENT}->{ELEMENTS}[-1]
 146                                 and $e->{PARENT}->{TYPE} ne "FUNCTION") {
 147                                 $is_surrounding = 1;
 148                         }
 149                 }
 150
 151                 $is_fixed = 1 if (not $is_conformant and Parse::Pidl::Util::is_constant($size));
 152                 $is_inline = 1 if (not $is_conformant and not Parse::Pidl::Util::is_constant($size));
 153
 154                 if ($i == 0 and $is_fixed and has_property($e, "string")) {
 155                         $is_fixed = 0;
 156                         $is_varying = 1;
 157                         $is_string = 1;
 158                         delete($e->{PROPERTIES}->{string});
 159                 }
 160
 161                 push (@$order, {
 162                         TYPE => "ARRAY",
 163                         SIZE_IS => $size,
 164                         LENGTH_IS => $length,
 165                         IS_DEFERRED => $is_deferred,
 166                         IS_SURROUNDING => $is_surrounding,
 167                         IS_ZERO_TERMINATED => $is_string,
 168                         IS_VARYING => $is_varying,
 169                         IS_CONFORMANT => $is_conformant,
 170                         IS_FIXED => $is_fixed,
 171                         IS_INLINE => $is_inline
 172                 });
 173         }
 174
 175         # Next, all the pointers
 176         foreach my $i (1..$e->{POINTERS}) {
 177                 my $level = "EMBEDDED";
 178                 # Top level "ref" pointers do not have a referrent identifier
 179                 $level = "TOP" if ($i == 1 and $e->{PARENT}->{TYPE} eq "FUNCTION");
 180
 181                 my $pt;
 182                 #
 183                 # Only the first level gets the pointer type from the
 184                 # pointer property, the others get them from
 185                 # the pointer_default() interface property
 186                 #
 187                 # see http://msdn2.microsoft.com/en-us/library/aa378984(VS.85).aspx
 188                 # (Here they talk about the rightmost pointer, but testing shows
 189                 #  they mean the leftmost pointer.)
 190                 #
 191                 # --metze
 192                 #
 193                 $pt = pointer_type($e);
 194                 if ($i > 1) {
 195                         $is_deferred = 1 if ($pt ne "ref" and $e->{PARENT}->{TYPE} eq "FUNCTION");
 196                         $pt = $pointer_default;
 197                 }
 198
 199                 push (@$order, {
 200                         TYPE => "POINTER",
 201                         POINTER_TYPE => $pt,
 202                         POINTER_INDEX => $pointer_idx,
 203                         IS_DEFERRED => "$is_deferred",
 204                         LEVEL => $level
 205                 });
 206
 207                 warning($e, "top-level \[out\] pointer `$e->{NAME}' is not a \[ref\] pointer")
 208                         if ($i == 1 and $pt ne "ref" and
 209                                 $e->{PARENT}->{TYPE} eq "FUNCTION" and
 210                                 not has_property($e, "in"));
 211
 212                 $pointer_idx++;
 213
 214                 # everything that follows will be deferred
 215                 $is_deferred = 1 if ($level ne "TOP");
 216
 217                 my $array_size = shift @size_is;
 218                 my $array_length;
 219                 my $is_varying;
 220                 my $is_conformant;
 221                 my $is_string = 0;
 222                 if ($array_size) {
 223                         $is_conformant = 1;
 224                         if ($array_length = shift @length_is) {
 225                                 $is_varying = 1;
 226                         } else {
 227                                 $array_length = $array_size;
 228                                 $is_varying =0;
 229                         }
 230                 }
 231
 232                 if (scalar(@size_is) == 0 and has_property($e, "string") and
 233                     $i == $e->{POINTERS}) {
 234                         $is_string = 1;
 235                         $is_varying = $is_conformant = has_property($e, "noheader")?0:1;
 236                         delete($e->{PROPERTIES}->{string});
 237                 }
 238
 239                 if ($array_size or $is_string) {
 240                         push (@$order, {
 241                                 TYPE => "ARRAY",
 242                                 SIZE_IS => $array_size,
 243                                 LENGTH_IS => $array_length,
 244                                 IS_DEFERRED => $is_deferred,
 245                                 IS_SURROUNDING => 0,
 246                                 IS_ZERO_TERMINATED => $is_string,
 247                                 IS_VARYING => $is_varying,
 248                                 IS_CONFORMANT => $is_conformant,
 249                                 IS_FIXED => 0,
 250                                 IS_INLINE => 0
 251                         });
 252
 253                         $is_deferred = 0;
 254                 }
 255         }
 256
 257         if (defined(has_property($e, "subcontext"))) {
 258                 my $hdr_size = has_property($e, "subcontext");
 259                 my $subsize = has_property($e, "subcontext_size");
 260                 if (not defined($subsize)) {
 261                         $subsize = -1;
 262                 }
 263
 264                 push (@$order, {
 265                         TYPE => "SUBCONTEXT",
 266                         HEADER_SIZE => $hdr_size,
 267                         SUBCONTEXT_SIZE => $subsize,
 268                         IS_DEFERRED => $is_deferred,
 269                         COMPRESSION => has_property($e, "compression"),
 270                 });
 271         }
 272
 273         if (my $switch = has_property($e, "switch_is")) {
 274                 push (@$order, {
 275                         TYPE => "SWITCH",
 276                         SWITCH_IS => $switch,
 277                         IS_DEFERRED => $is_deferred
 278                 });
 279         }
 280
 281         if (scalar(@size_is) > 0) {
 282                 fatal($e, "size_is() on non-array element");
 283         }
 284
 285         if (scalar(@length_is) > 0) {
 286                 fatal($e, "length_is() on non-array element");
 287         }
 288
 289         if (has_property($e, "string")) {
 290                 fatal($e, "string() attribute on non-array element");
 291         }
 292
 293         push (@$order, {
 294                 TYPE => "DATA",
 295                 DATA_TYPE => $e->{TYPE},
 296                 IS_DEFERRED => $is_deferred,
 297                 CONTAINS_DEFERRED => can_contain_deferred($e->{TYPE}),
 298                 IS_SURROUNDING => 0 #FIXME
 299         });
 300
 301         my $i = 0;
 302         foreach (@$order) { $_->{LEVEL_INDEX} = $i; $i+=1; }
 303
 304         return $order;
 305 }
 306
 307 sub GetTypedefLevelTable($$$)
 308 {
 309         my ($e, $data, $pointer_default) = @_;
 310
 311         my $order = [];
 312
 313         push (@$order, {
 314                 TYPE => "TYPEDEF"
 315         });
 316
 317         my $i = 0;
 318         foreach (@$order) { $_->{LEVEL_INDEX} = $i; $i+=1; }
 319
 320         return $order;
 321 }
 322
 323 #####################################################################
 324 # see if a type contains any deferred data
 325 sub can_contain_deferred($)
 326 {
 327         sub can_contain_deferred($);
 328         my ($type) = @_;
 329
 330         return 1 unless (hasType($type)); # assume the worst
 331
 332         $type = getType($type);
 333
 334         return 0 if (Parse::Pidl::Typelist::is_scalar($type));
 335
 336         return can_contain_deferred($type->{DATA}) if ($type->{TYPE} eq "TYPEDEF");
 337
 338         return 0 unless defined($type->{ELEMENTS});
 339
 340         foreach (@{$type->{ELEMENTS}}) {
 341                 return 1 if ($_->{POINTERS});
 342                 return 1 if (can_contain_deferred ($_->{TYPE}));
 343         }
 344
 345         return 0;
 346 }
 347
 348 sub pointer_type($)
 349 {
 350         my $e = shift;
 351
 352         return undef unless $e->{POINTERS};
 353
 354         return "ref" if (has_property($e, "ref"));
 355         return "full" if (has_property($e, "ptr"));
 356         return "sptr" if (has_property($e, "sptr"));
 357         return "unique" if (has_property($e, "unique"));
 358         return "relative" if (has_property($e, "relative"));
 359         return "relative_short" if (has_property($e, "relative_short"));
 360         return "ignore" if (has_property($e, "ignore"));
 361
 362         return undef;
 363 }
 364
 365 #####################################################################
 366 # work out the correct alignment for a structure or union
 367 sub find_largest_alignment($)
 368 {
 369         my $s = shift;
 370
 371         my $align = 1;
 372         for my $e (@{$s->{ELEMENTS}}) {
 373                 my $a = 1;
 374
 375                 if ($e->{POINTERS}) {
 376                         # this is a hack for NDR64
 377                         # the NDR layer translates this into
 378                         # an alignment of 4 for NDR and 8 for NDR64
 379                         $a = 5;
 380                 } elsif (has_property($e, "subcontext")) {
 381                         $a = 1;
 382                 } elsif (has_property($e, "transmit_as")) {
 383                         $a = align_type($e->{PROPERTIES}->{transmit_as});
 384                 } else {
 385                         $a = align_type($e->{TYPE});
 386                 }
 387
 388                 $align = $a if ($align < $a);
 389         }
 390
 391         return $align;
 392 }
 393
 394 #####################################################################
 395 # align a type
 396 sub align_type($)
 397 {
 398         sub align_type($);
 399         my ($e) = @_;
 400
 401         if (ref($e) eq "HASH" and $e->{TYPE} eq "SCALAR") {
 402                 return $scalar_alignment->{$e->{NAME}};
 403         }
 404
 405         return 0 if ($e eq "EMPTY");
 406
 407         unless (hasType($e)) {
 408             # it must be an external type - all we can do is guess
 409                 # warning($e, "assuming alignment of unknown type '$e' is 4");
 410             return 4;
 411         }
 412
 413         my $dt = getType($e);
 414
 415         if ($dt->{TYPE} eq "TYPEDEF") {
 416                 return align_type($dt->{DATA});
 417         } elsif ($dt->{TYPE} eq "CONFORMANCE") {
 418                 return $dt->{DATA}->{ALIGN};
 419         } elsif ($dt->{TYPE} eq "ENUM") {
 420                 return align_type(Parse::Pidl::Typelist::enum_type_fn($dt));
 421         } elsif ($dt->{TYPE} eq "BITMAP") {
 422                 return align_type(Parse::Pidl::Typelist::bitmap_type_fn($dt));
 423         } elsif (($dt->{TYPE} eq "STRUCT") or ($dt->{TYPE} eq "UNION")) {
 424                 # Struct/union without body: assume 4
 425                 return 4 unless (defined($dt->{ELEMENTS}));
 426                 return find_largest_alignment($dt);
 427         }
 428
 429         die("Unknown data type type $dt->{TYPE}");
 430 }
 431
 432 sub ParseElement($$)
 433 {
 434         my ($e, $pointer_default) = @_;
 435
 436         $e->{TYPE} = expandAlias($e->{TYPE});
 437
 438         if (ref($e->{TYPE}) eq "HASH") {
 439                 $e->{TYPE} = ParseType($e->{TYPE}, $pointer_default);
 440         }
 441
 442         return {
 443                 NAME => $e->{NAME},
 444                 TYPE => $e->{TYPE},
 445                 PROPERTIES => $e->{PROPERTIES},
 446                 LEVELS => GetElementLevelTable($e, $pointer_default),
 447                 REPRESENTATION_TYPE => ($e->{PROPERTIES}->{represent_as} or $e->{TYPE}),
 448                 ALIGN => align_type($e->{TYPE}),
 449                 ORIGINAL => $e
 450         };
 451 }
 452
 453 sub ParseStruct($$)
 454 {
 455         my ($struct, $pointer_default) = @_;
 456         my @elements = ();
 457         my $surrounding = undef;
 458
 459         return {
 460                 TYPE => "STRUCT",
 461                 NAME => $struct->{NAME},
 462                 SURROUNDING_ELEMENT => undef,
 463                 ELEMENTS => undef,
 464                 PROPERTIES => $struct->{PROPERTIES},
 465                 ORIGINAL => $struct,
 466                 ALIGN => undef
 467         } unless defined($struct->{ELEMENTS});
 468
 469         CheckPointerTypes($struct, $pointer_default);
 470
 471         foreach my $x (@{$struct->{ELEMENTS}})
 472         {
 473                 my $e = ParseElement($x, $pointer_default);
 474                 if ($x != $struct->{ELEMENTS}[-1] and
 475                         $e->{LEVELS}[0]->{IS_SURROUNDING}) {
 476                         fatal($x, "conformant member not at end of struct");
 477                 }
 478                 push @elements, $e;
 479         }
 480
 481         my $e = $elements[-1];
 482         if (defined($e) and defined($e->{LEVELS}[0]->{IS_SURROUNDING}) and
 483                 $e->{LEVELS}[0]->{IS_SURROUNDING}) {
 484                 $surrounding = $e;
 485         }
 486
 487         if (defined $e->{TYPE} && $e->{TYPE} eq "string"
 488             &&  property_matches($e, "flag", ".*LIBNDR_FLAG_STR_CONFORMANT.*")) {
 489                 $surrounding = $struct->{ELEMENTS}[-1];
 490         }
 491
 492         my $align = undef;
 493         if ($struct->{NAME}) {
 494                 $align = align_type($struct->{NAME});
 495         }
 496
 497         return {
 498                 TYPE => "STRUCT",
 499                 NAME => $struct->{NAME},
 500                 SURROUNDING_ELEMENT => $surrounding,
 501                 ELEMENTS => \@elements,
 502                 PROPERTIES => $struct->{PROPERTIES},
 503                 ORIGINAL => $struct,
 504                 ALIGN => $align
 505         };
 506 }
 507
 508 sub ParseUnion($$)
 509 {
 510         my ($e, $pointer_default) = @_;
 511         my @elements = ();
 512         my $hasdefault = 0;
 513         my $switch_type = has_property($e, "switch_type");
 514         unless (defined($switch_type)) { $switch_type = "uint32"; }
 515         if (has_property($e, "nodiscriminant")) { $switch_type = undef; }
 516
 517         return {
 518                 TYPE => "UNION",
 519                 NAME => $e->{NAME},
 520                 SWITCH_TYPE => $switch_type,
 521                 ELEMENTS => undef,
 522                 PROPERTIES => $e->{PROPERTIES},
 523                 HAS_DEFAULT => $hasdefault,
 524                 ORIGINAL => $e,
 525                 ALIGN => undef
 526         } unless defined($e->{ELEMENTS});
 527
 528         CheckPointerTypes($e, $pointer_default);
 529
 530         foreach my $x (@{$e->{ELEMENTS}})
 531         {
 532                 my $t;
 533                 if ($x->{TYPE} eq "EMPTY") {
 534                         $t = { TYPE => "EMPTY" };
 535                 } else {
 536                         $t = ParseElement($x, $pointer_default);
 537                 }
 538                 if (has_property($x, "default")) {
 539                         $t->{CASE} = "default";
 540                         $hasdefault = 1;
 541                 } elsif (defined($x->{PROPERTIES}->{case})) {
 542                         $t->{CASE} = "case $x->{PROPERTIES}->{case}";
 543                 } else {
 544                         die("Union element $x->{NAME} has neither default nor case property");
 545                 }
 546                 push @elements, $t;
 547         }
 548
 549         my $align = undef;
 550         if ($e->{NAME}) {
 551                 $align = align_type($e->{NAME});
 552         }
 553
 554         return {
 555                 TYPE => "UNION",
 556                 NAME => $e->{NAME},
 557                 SWITCH_TYPE => $switch_type,
 558                 ELEMENTS => \@elements,
 559                 PROPERTIES => $e->{PROPERTIES},
 560                 HAS_DEFAULT => $hasdefault,
 561                 ORIGINAL => $e,
 562                 ALIGN => $align
 563         };
 564 }
 565
 566 sub ParseEnum($$)
 567 {
 568         my ($e, $pointer_default) = @_;
 569
 570         return {
 571                 TYPE => "ENUM",
 572                 NAME => $e->{NAME},
 573                 BASE_TYPE => Parse::Pidl::Typelist::enum_type_fn($e),
 574                 ELEMENTS => $e->{ELEMENTS},
 575                 PROPERTIES => $e->{PROPERTIES},
 576                 ORIGINAL => $e
 577         };
 578 }
 579
 580 sub ParseBitmap($$)
 581 {
 582         my ($e, $pointer_default) = @_;
 583
 584         return {
 585                 TYPE => "BITMAP",
 586                 NAME => $e->{NAME},
 587                 BASE_TYPE => Parse::Pidl::Typelist::bitmap_type_fn($e),
 588                 ELEMENTS => $e->{ELEMENTS},
 589                 PROPERTIES => $e->{PROPERTIES},
 590                 ORIGINAL => $e
 591         };
 592 }
 593
 594 sub ParseType($$)
 595 {
 596         my ($d, $pointer_default) = @_;
 597
 598         my $data = {
 599                 STRUCT => \&ParseStruct,
 600                 UNION => \&ParseUnion,
 601                 ENUM => \&ParseEnum,
 602                 BITMAP => \&ParseBitmap,
 603                 TYPEDEF => \&ParseTypedef,
 604         }->{$d->{TYPE}}->($d, $pointer_default);
 605
 606         return $data;
 607 }
 608
 609 sub ParseTypedef($$)
 610 {
 611         my ($d, $pointer_default) = @_;
 612
 613         if (defined($d->{DATA}->{PROPERTIES}) && !defined($d->{PROPERTIES})) {
 614                 $d->{PROPERTIES} = $d->{DATA}->{PROPERTIES};
 615         }
 616
 617         my $data = ParseType($d->{DATA}, $pointer_default);
 618         $data->{ALIGN} = align_type($d->{NAME});
 619
 620         return {
 621                 NAME => $d->{NAME},
 622                 TYPE => $d->{TYPE},
 623                 PROPERTIES => $d->{PROPERTIES},
 624                 LEVELS => GetTypedefLevelTable($d, $data, $pointer_default),
 625                 DATA => $data,
 626                 ORIGINAL => $d
 627         };
 628 }
 629
 630 sub ParseConst($$)
 631 {
 632         my ($ndr,$d) = @_;
 633
 634         return $d;
 635 }
 636
 637 sub ParseFunction($$$)
 638 {
 639         my ($ndr,$d,$opnum) = @_;
 640         my @elements = ();
 641         my $rettype = undef;
 642         my $thisopnum = undef;
 643
 644         CheckPointerTypes($d, "ref");
 645
 646         if (not defined($d->{PROPERTIES}{noopnum})) {
 647                 $thisopnum = ${$opnum};
 648                 ${$opnum}++;
 649         }
 650
 651         foreach my $x (@{$d->{ELEMENTS}}) {
 652                 my $e = ParseElement($x, $ndr->{PROPERTIES}->{pointer_default});
 653                 push (@{$e->{DIRECTION}}, "in") if (has_property($x, "in"));
 654                 push (@{$e->{DIRECTION}}, "out") if (has_property($x, "out"));
 655
 656                 push (@elements, $e);
 657         }
 658
 659         if ($d->{RETURN_TYPE} ne "void") {
 660                 $rettype = expandAlias($d->{RETURN_TYPE});
 661         }
 662
 663         my $async = 0;
 664         if (has_property($d, "async")) { $async = 1; }
 665
 666         return {
 667                         NAME => $d->{NAME},
 668                         TYPE => "FUNCTION",
 669                         OPNUM => $thisopnum,
 670                         ASYNC => $async,
 671                         RETURN_TYPE => $rettype,
 672                         PROPERTIES => $d->{PROPERTIES},
 673                         ELEMENTS => \@elements,
 674                         ORIGINAL => $d
 675                 };
 676 }
 677
 678 sub CheckPointerTypes($$)
 679 {
 680         my ($s,$default) = @_;
 681
 682         return unless defined($s->{ELEMENTS});
 683
 684         foreach my $e (@{$s->{ELEMENTS}}) {
 685                 if ($e->{POINTERS} and not defined(pointer_type($e))) {
 686                         $e->{PROPERTIES}->{$default} = '1';
 687                 }
 688         }
 689 }
 690
 691 sub FindNestedTypes($$)
 692 {
 693         sub FindNestedTypes($$);
 694         my ($l, $t) = @_;
 695
 696         return unless defined($t->{ELEMENTS});
 697         return if ($t->{TYPE} eq "ENUM");
 698         return if ($t->{TYPE} eq "BITMAP");
 699
 700         foreach (@{$t->{ELEMENTS}}) {
 701                 if (ref($_->{TYPE}) eq "HASH") {
 702                         push (@$l, $_->{TYPE}) if (defined($_->{TYPE}->{NAME}));
 703                         FindNestedTypes($l, $_->{TYPE});
 704                 }
 705         }
 706 }
 707
 708 sub ParseInterface($)
 709 {
 710         my $idl = shift;
 711         my @types = ();
 712         my @consts = ();
 713         my @functions = ();
 714         my @endpoints;
 715         my $opnum = 0;
 716         my $version;
 717
 718         if (not has_property($idl, "pointer_default")) {
 719                 # MIDL defaults to "ptr" in DCE compatible mode (/osf)
 720                 # and "unique" in Microsoft Extensions mode (default)
 721                 $idl->{PROPERTIES}->{pointer_default} = "unique";
 722         }
 723
 724         foreach my $d (@{$idl->{DATA}}) {
 725                 if ($d->{TYPE} eq "FUNCTION") {
 726                         push (@functions, ParseFunction($idl, $d, \$opnum));
 727                 } elsif ($d->{TYPE} eq "CONST") {
 728                         push (@consts, ParseConst($idl, $d));
 729                 } else {
 730                         push (@types, ParseType($d, $idl->{PROPERTIES}->{pointer_default}));
 731                         FindNestedTypes(\@types, $d);
 732                 }
 733         }
 734
 735         $version = "0.0";
 736
 737         if(defined $idl->{PROPERTIES}->{version}) {
 738                 my @if_version = split(/\./, $idl->{PROPERTIES}->{version});
 739                 if ($if_version[0] == $idl->{PROPERTIES}->{version}) {
 740                                 $version = $idl->{PROPERTIES}->{version};
 741                 } else {
 742                                 $version = $if_version[1] << 16 | $if_version[0];
 743                 }
 744         }
 745
 746         # If no endpoint is set, default to the interface name as a named pipe
 747         if (!defined $idl->{PROPERTIES}->{endpoint}) {
 748                 push @endpoints, "\"ncacn_np:[\\\\pipe\\\\" . $idl->{NAME} . "]\"";
 749         } else {
 750                 @endpoints = split /,/, $idl->{PROPERTIES}->{endpoint};
 751         }
 752
 753         return {
 754                 NAME => $idl->{NAME},
 755                 UUID => lc(has_property($idl, "uuid")),
 756                 VERSION => $version,
 757                 TYPE => "INTERFACE",
 758                 PROPERTIES => $idl->{PROPERTIES},
 759                 FUNCTIONS => \@functions,
 760                 CONSTS => \@consts,
 761                 TYPES => \@types,
 762                 ENDPOINTS => \@endpoints
 763         };
 764 }
 765
 766 # Convert a IDL tree to a NDR tree
 767 # Gives a result tree describing all that's necessary for easily generating
 768 # NDR parsers / generators
 769 sub Parse($)
 770 {
 771         my $idl = shift;
 772
 773         return undef unless (defined($idl));
 774
 775         Parse::Pidl::NDR::Validate($idl);
 776
 777         my @ndr = ();
 778
 779         foreach (@{$idl}) {
 780                 ($_->{TYPE} eq "CPP_QUOTE") && push(@ndr, $_);
 781                 ($_->{TYPE} eq "INTERFACE") && push(@ndr, ParseInterface($_));
 782                 ($_->{TYPE} eq "IMPORT") && push(@ndr, $_);
 783         }
 784
 785         return \@ndr;
 786 }
 787
 788 sub GetNextLevel($$)
 789 {
 790         my $e = shift;
 791         my $fl = shift;
 792
 793         my $seen = 0;
 794
 795         foreach my $l (@{$e->{LEVELS}}) {
 796                 return $l if ($seen);
 797                 ($seen = 1) if ($l == $fl);
 798         }
 799
 800         return undef;
 801 }
 802
 803 sub GetPrevLevel($$)
 804 {
 805         my ($e,$fl) = @_;
 806         my $prev = undef;
 807
 808         foreach my $l (@{$e->{LEVELS}}) {
 809                 (return $prev) if ($l == $fl);
 810                 $prev = $l;
 811         }
 812
 813         return undef;
 814 }
 815
 816 sub ContainsString($)
 817 {
 818         my ($e) = @_;
 819
 820         foreach my $l (@{$e->{LEVELS}}) {
 821                 return 1 if ($l->{TYPE} eq "ARRAY" and $l->{IS_ZERO_TERMINATED});
 822         }
 823
 824         return 0;
 825 }
 826
 827 sub ContainsDeferred($$)
 828 {
 829         my ($e,$l) = @_;
 830
 831         return 1 if ($l->{CONTAINS_DEFERRED});
 832
 833         while ($l = GetNextLevel($e,$l))
 834         {
 835                 return 1 if ($l->{IS_DEFERRED});
 836                 return 1 if ($l->{CONTAINS_DEFERRED});
 837         }
 838
 839         return 0;
 840 }
 841
 842 sub el_name($)
 843 {
 844         my $e = shift;
 845         my $name = "<ANONYMOUS>";
 846
 847         $name = $e->{NAME} if defined($e->{NAME});
 848
 849         if (defined($e->{PARENT}) and defined($e->{PARENT}->{NAME})) {
 850                 return "$e->{PARENT}->{NAME}.$name";
 851         }
 852
 853         if (defined($e->{PARENT}) and
 854             defined($e->{PARENT}->{PARENT}) and
 855             defined($e->{PARENT}->{PARENT}->{NAME})) {
 856                 return "$e->{PARENT}->{PARENT}->{NAME}.$name";
 857         }
 858
 859         return $name;
 860 }
 861
 862 ###################################
 863 # find a sibling var in a structure
 864 sub find_sibling($$)
 865 {
 866         my($e,$name) = @_;
 867         my($fn) = $e->{PARENT};
 868
 869         if ($name =~ /\*(.*)/) {
 870                 $name = $1;
 871         }
 872
 873         for my $e2 (@{$fn->{ELEMENTS}}) {
 874                 return $e2 if ($e2->{NAME} eq $name);
 875         }
 876
 877         return undef;
 878 }
 879
 880 my %property_list = (
 881         # interface
 882         "helpstring"            => ["INTERFACE", "FUNCTION"],
 883         "version"               => ["INTERFACE"],
 884         "uuid"                  => ["INTERFACE"],
 885         "endpoint"              => ["INTERFACE"],
 886         "pointer_default"       => ["INTERFACE"],
 887         "helper"                => ["INTERFACE"],
 888         "pyhelper"              => ["INTERFACE"],
 889         "authservice"           => ["INTERFACE"],
 890         "restricted"            => ["INTERFACE"],
 891         "no_srv_register"       => ["INTERFACE"],
 892
 893         # dcom
 894         "object"                => ["INTERFACE"],
 895         "local"                 => ["INTERFACE", "FUNCTION"],
 896         "iid_is"                => ["ELEMENT"],
 897         "call_as"               => ["FUNCTION"],
 898         "idempotent"            => ["FUNCTION"],
 899
 900         # function
 901         "noopnum"               => ["FUNCTION"],
 902         "in"                    => ["ELEMENT"],
 903         "out"                   => ["ELEMENT"],
 904         "async"                 => ["FUNCTION"],
 905
 906         # pointer
 907         "ref"                   => ["ELEMENT"],
 908         "ptr"                   => ["ELEMENT"],
 909         "unique"                => ["ELEMENT"],
 910         "ignore"                => ["ELEMENT"],
 911         "relative"              => ["ELEMENT"],
 912         "relative_short"        => ["ELEMENT"],
 913         "null_is_ffffffff" => ["ELEMENT"],
 914         "relative_base"         => ["TYPEDEF", "STRUCT", "UNION"],
 915
 916         "gensize"               => ["TYPEDEF", "STRUCT", "UNION"],
 917         "value"                 => ["ELEMENT"],
 918         "flag"                  => ["ELEMENT", "TYPEDEF", "STRUCT", "UNION", "ENUM", "BITMAP"],
 919
 920         # generic
 921         "public"                => ["FUNCTION", "TYPEDEF", "STRUCT", "UNION", "ENUM", "BITMAP"],
 922         "nopush"                => ["FUNCTION", "TYPEDEF", "STRUCT", "UNION", "ENUM", "BITMAP"],
 923         "nopull"                => ["FUNCTION", "TYPEDEF", "STRUCT", "UNION", "ENUM", "BITMAP"],
 924         "nosize"                => ["FUNCTION", "TYPEDEF", "STRUCT", "UNION", "ENUM", "BITMAP"],
 925         "noprint"               => ["FUNCTION", "TYPEDEF", "STRUCT", "UNION", "ENUM", "BITMAP", "ELEMENT"],
 926         "nopython"              => ["FUNCTION", "TYPEDEF", "STRUCT", "UNION", "ENUM", "BITMAP"],
 927         "todo"                  => ["FUNCTION"],
 928
 929         # union
 930         "switch_is"             => ["ELEMENT"],
 931         "switch_type"           => ["ELEMENT", "UNION"],
 932         "nodiscriminant"        => ["UNION"],
 933         "case"                  => ["ELEMENT"],
 934         "default"               => ["ELEMENT"],
 935
 936         "represent_as"          => ["ELEMENT"],
 937         "transmit_as"           => ["ELEMENT"],
 938
 939         # subcontext
 940         "subcontext"            => ["ELEMENT"],
 941         "subcontext_size"       => ["ELEMENT"],
 942         "compression"           => ["ELEMENT"],
 943
 944         # enum
 945         "enum8bit"              => ["ENUM"],
 946         "enum16bit"             => ["ENUM"],
 947         "v1_enum"               => ["ENUM"],
 948
 949         # bitmap
 950         "bitmap8bit"            => ["BITMAP"],
 951         "bitmap16bit"           => ["BITMAP"],
 952         "bitmap32bit"           => ["BITMAP"],
 953         "bitmap64bit"           => ["BITMAP"],
 954
 955         # array
 956         "range"                 => ["ELEMENT", "PIPE"],
 957         "size_is"               => ["ELEMENT"],
 958         "string"                => ["ELEMENT"],
 959         "noheader"              => ["ELEMENT"],
 960         "charset"               => ["ELEMENT"],
 961         "length_is"             => ["ELEMENT"],
 962 );
 963
 964 #####################################################################
 965 # check for unknown properties
 966 sub ValidProperties($$)
 967 {
 968         my ($e,$t) = @_;
 969
 970         return unless defined $e->{PROPERTIES};
 971
 972         foreach my $key (keys %{$e->{PROPERTIES}}) {
 973                 warning($e, el_name($e) . ": unknown property '$key'")
 974                         unless defined($property_list{$key});
 975
 976                 fatal($e, el_name($e) . ": property '$key' not allowed on '$t'")
 977                         unless grep(/^$t$/, @{$property_list{$key}});
 978         }
 979 }
 980
 981 sub mapToScalar($)
 982 {
 983         sub mapToScalar($);
 984         my $t = shift;
 985         return $t->{NAME} if (ref($t) eq "HASH" and $t->{TYPE} eq "SCALAR");
 986         my $ti = getType($t);
 987
 988         if (not defined ($ti)) {
 989                 return undef;
 990         } elsif ($ti->{TYPE} eq "TYPEDEF") {
 991                 return mapToScalar($ti->{DATA});
 992         } elsif ($ti->{TYPE} eq "ENUM") {
 993                 return Parse::Pidl::Typelist::enum_type_fn($ti);
 994         } elsif ($ti->{TYPE} eq "BITMAP") {
 995                 return Parse::Pidl::Typelist::bitmap_type_fn($ti);
 996         }
 997
 998         return undef;
 999 }
1000
1001 #####################################################################
1002 # validate an element
1003 sub ValidElement($)
1004 {
1005         my $e = shift;
1006
1007         ValidProperties($e,"ELEMENT");
1008
1009         # Check whether switches are used correctly.
1010         if (my $switch = has_property($e, "switch_is")) {
1011                 my $e2 = find_sibling($e, $switch);
1012                 my $type = getType($e->{TYPE});
1013
1014                 if (defined($type) and $type->{DATA}->{TYPE} ne "UNION") {
1015                         fatal($e, el_name($e) . ": switch_is() used on non-union type $e->{TYPE} which is a $type->{DATA}->{TYPE}");
1016                 }
1017
1018                 if (not has_property($type->{DATA}, "nodiscriminant") and defined($e2)) {
1019                         my $discriminator_type = has_property($type->{DATA}, "switch_type");
1020                         $discriminator_type = "uint32" unless defined ($discriminator_type);
1021
1022                         my $t1 = mapScalarType(mapToScalar($discriminator_type));
1023
1024                         if (not defined($t1)) {
1025                                 fatal($e, el_name($e) . ": unable to map discriminator type '$discriminator_type' to scalar");
1026                         }
1027
1028                         my $t2 = mapScalarType(mapToScalar($e2->{TYPE}));
1029                         if (not defined($t2)) {
1030                                 fatal($e, el_name($e) . ": unable to map variable used for switch_is() to scalar");
1031                         }
1032
1033                         if ($t1 ne $t2) {
1034                                 warning($e, el_name($e) . ": switch_is() is of type $e2->{TYPE} ($t2), while discriminator type for union $type->{NAME} is $discriminator_type ($t1)");
1035                         }
1036                 }
1037         }
1038
1039         if (has_property($e, "subcontext") and has_property($e, "represent_as")) {
1040                 fatal($e, el_name($e) . " : subcontext() and represent_as() can not be used on the same element");
1041         }
1042
1043         if (has_property($e, "subcontext") and has_property($e, "transmit_as")) {
1044                 fatal($e, el_name($e) . " : subcontext() and transmit_as() can not be used on the same element");
1045         }
1046
1047         if (has_property($e, "represent_as") and has_property($e, "transmit_as")) {
1048                 fatal($e, el_name($e) . " : represent_as() and transmit_as() can not be used on the same element");
1049         }
1050
1051         if (has_property($e, "represent_as") and has_property($e, "value")) {
1052                 fatal($e, el_name($e) . " : represent_as() and value() can not be used on the same element");
1053         }
1054
1055         if (has_property($e, "subcontext")) {
1056                 warning($e, "subcontext() is deprecated. Use represent_as() or transmit_as() instead");
1057         }
1058
1059         if (defined (has_property($e, "subcontext_size")) and not defined(has_property($e, "subcontext"))) {
1060                 fatal($e, el_name($e) . " : subcontext_size() on non-subcontext element");
1061         }
1062
1063         if (defined (has_property($e, "compression")) and not defined(has_property($e, "subcontext"))) {
1064                 fatal($e, el_name($e) . " : compression() on non-subcontext element");
1065         }
1066
1067         if (!$e->{POINTERS} && (
1068                 has_property($e, "ptr") or
1069                 has_property($e, "unique") or
1070                 has_property($e, "relative") or
1071                 has_property($e, "relative_short") or
1072                 has_property($e, "ref"))) {
1073                 fatal($e, el_name($e) . " : pointer properties on non-pointer element\n");
1074         }
1075 }
1076
1077 #####################################################################
1078 # validate an enum
1079 sub ValidEnum($)
1080 {
1081         my ($enum) = @_;
1082
1083         ValidProperties($enum, "ENUM");
1084 }
1085
1086 #####################################################################
1087 # validate a bitmap
1088 sub ValidBitmap($)
1089 {
1090         my ($bitmap) = @_;
1091
1092         ValidProperties($bitmap, "BITMAP");
1093 }
1094
1095 #####################################################################
1096 # validate a struct
1097 sub ValidStruct($)
1098 {
1099         my($struct) = shift;
1100
1101         ValidProperties($struct, "STRUCT");
1102
1103         return unless defined($struct->{ELEMENTS});
1104
1105         foreach my $e (@{$struct->{ELEMENTS}}) {
1106                 $e->{PARENT} = $struct;
1107                 ValidElement($e);
1108         }
1109 }
1110
1111 #####################################################################
1112 # parse a union
1113 sub ValidUnion($)
1114 {
1115         my($union) = shift;
1116
1117         ValidProperties($union,"UNION");
1118
1119         if (has_property($union->{PARENT}, "nodiscriminant") and
1120                 has_property($union->{PARENT}, "switch_type")) {
1121                 fatal($union->{PARENT}, $union->{PARENT}->{NAME} . ": switch_type(" . $union->{PARENT}->{PROPERTIES}->{switch_type} . ") on union without discriminant");
1122         }
1123
1124         return unless defined($union->{ELEMENTS});
1125
1126         foreach my $e (@{$union->{ELEMENTS}}) {
1127                 $e->{PARENT} = $union;
1128
1129                 if (defined($e->{PROPERTIES}->{default}) and
1130                         defined($e->{PROPERTIES}->{case})) {
1131                         fatal($e, "Union member $e->{NAME} can not have both default and case properties!");
1132                 }
1133
1134                 unless (defined ($e->{PROPERTIES}->{default}) or
1135                                 defined ($e->{PROPERTIES}->{case})) {
1136                         fatal($e, "Union member $e->{NAME} must have default or case property");
1137                 }
1138
1139                 if (has_property($e, "ref")) {
1140                         fatal($e, el_name($e) . ": embedded ref pointers are not supported yet\n");
1141                 }
1142
1143
1144                 ValidElement($e);
1145         }
1146 }
1147
1148 #####################################################################
1149 # validate a pipe
1150 sub ValidPipe($)
1151 {
1152         my ($pipe) = @_;
1153         my $data = $pipe->{DATA};
1154
1155         ValidProperties($pipe, "PIPE");
1156
1157         fatal($pipe, $pipe->{NAME} . ": 'pipe' is not yet supported by pidl");
1158 }
1159
1160 #####################################################################
1161 # parse a typedef
1162 sub ValidTypedef($)
1163 {
1164         my($typedef) = shift;
1165         my $data = $typedef->{DATA};
1166
1167         ValidProperties($typedef, "TYPEDEF");
1168
1169         $data->{PARENT} = $typedef;
1170
1171         $data->{FILE} = $typedef->{FILE} unless defined($data->{FILE});
1172         $data->{LINE} = $typedef->{LINE} unless defined($data->{LINE});
1173
1174         ValidType($data) if (ref($data) eq "HASH");
1175 }
1176
1177 #####################################################################
1178 # validate a function
1179 sub ValidFunction($)
1180 {
1181         my($fn) = shift;
1182
1183         ValidProperties($fn,"FUNCTION");
1184
1185         foreach my $e (@{$fn->{ELEMENTS}}) {
1186                 $e->{PARENT} = $fn;
1187                 if (has_property($e, "ref") && !$e->{POINTERS}) {
1188                         fatal($e, "[ref] variables must be pointers ($fn->{NAME}/$e->{NAME})");
1189                 }
1190                 ValidElement($e);
1191         }
1192 }
1193
1194 #####################################################################
1195 # validate a type
1196 sub ValidType($)
1197 {
1198         my ($t) = @_;
1199
1200         {
1201                 TYPEDEF => \&ValidTypedef,
1202                 STRUCT => \&ValidStruct,
1203                 UNION => \&ValidUnion,
1204                 ENUM => \&ValidEnum,
1205                 BITMAP => \&ValidBitmap,
1206                 PIPE => \&ValidPipe
1207         }->{$t->{TYPE}}->($t);
1208 }
1209
1210 #####################################################################
1211 # parse the interface definitions
1212 sub ValidInterface($)
1213 {
1214         my($interface) = shift;
1215         my($data) = $interface->{DATA};
1216
1217         if (has_property($interface, "helper")) {
1218                 warning($interface, "helper() is pidl-specific and deprecated. Use `include' instead");
1219         }
1220
1221         ValidProperties($interface,"INTERFACE");
1222
1223         if (has_property($interface, "pointer_default")) {
1224                 if (not grep (/$interface->{PROPERTIES}->{pointer_default}/,
1225                                         ("ref", "unique", "ptr"))) {
1226                         fatal($interface, "Unknown default pointer type `$interface->{PROPERTIES}->{pointer_default}'");
1227                 }
1228         }
1229
1230         if (has_property($interface, "object")) {
1231                 if (has_property($interface, "version") &&
1232                         $interface->{PROPERTIES}->{version} != 0) {
1233                         fatal($interface, "Object interfaces must have version 0.0 ($interface->{NAME})");
1234                 }
1235
1236                 if (!defined($interface->{BASE}) &&
1237                         not ($interface->{NAME} eq "IUnknown")) {
1238                         fatal($interface, "Object interfaces must all derive from IUnknown ($interface->{NAME})");
1239                 }
1240         }
1241
1242         foreach my $d (@{$data}) {
1243                 ($d->{TYPE} eq "FUNCTION") && ValidFunction($d);
1244                 ($d->{TYPE} eq "TYPEDEF" or
1245                  $d->{TYPE} eq "STRUCT" or
1246                  $d->{TYPE} eq "UNION" or
1247                  $d->{TYPE} eq "ENUM" or
1248                  $d->{TYPE} eq "BITMAP" or
1249                  $d->{TYPE} eq "PIPE") && ValidType($d);
1250         }
1251
1252 }
1253
1254 #####################################################################
1255 # Validate an IDL structure
1256 sub Validate($)
1257 {
1258         my($idl) = shift;
1259
1260         foreach my $x (@{$idl}) {
1261                 ($x->{TYPE} eq "INTERFACE") &&
1262                     ValidInterface($x);
1263                 ($x->{TYPE} eq "IMPORTLIB") &&
1264                         fatal($x, "importlib() not supported");
1265         }
1266 }
1267
1268 sub is_charset_array($$)
1269 {
1270         my ($e,$l) = @_;
1271
1272         return 0 if ($l->{TYPE} ne "ARRAY");
1273
1274         my $nl = GetNextLevel($e,$l);
1275
1276         return 0 unless ($nl->{TYPE} eq "DATA");
1277
1278         return has_property($e, "charset");
1279 }
1280
1281
1282
1283 1;