pidl/lib/Parse/Pidl/Wireshark/NDR.pm

   1 ##################################################
   2 # Wireshark NDR parser generator for IDL structures
   3 # Copyright tridge@samba.org 2000-2003
   4 # Copyright tpot@samba.org 2001,2005
   5 # Copyright jelmer@samba.org 2004-2007
   6 # Portions based on idl2eth.c by Ronnie Sahlberg
   7 # released under the GNU GPL
   8
   9 =pod
  10
  11 =head1 NAME
  12
  13 Parse::Pidl::Wireshark::NDR - Parser generator for Wireshark
  14
  15 =cut
  16
  17 package Parse::Pidl::Wireshark::NDR;
  18
  19 use Exporter;
  20 @ISA = qw(Exporter);
  21 @EXPORT_OK = qw(field2name %res PrintIdl StripPrefixes RegisterInterfaceHandoff register_hf_field CheckUsed ProcessImport ProcessInclude find_type DumpEttList DumpEttDeclaration DumpHfList DumpHfDeclaration DumpFunctionTable register_type register_ett);
  22
  23 use strict;
  24 use Parse::Pidl qw(error warning);
  25 use Parse::Pidl::Typelist qw(getType);
  26 use Parse::Pidl::Util qw(has_property property_matches make_str);
  27 use Parse::Pidl::NDR qw(ContainsString GetNextLevel);
  28 use Parse::Pidl::Dump qw(DumpType DumpFunction);
  29 use Parse::Pidl::Wireshark::Conformance qw(ReadConformance);
  30 use File::Basename;
  31
  32 use vars qw($VERSION);
  33 $VERSION = '0.01';
  34
  35 my %return_types = ();
  36 my %dissector_used = ();
  37
  38 my %ptrtype_mappings = (
  39         "unique" => "NDR_POINTER_UNIQUE",
  40         "ref" => "NDR_POINTER_REF",
  41         "ptr" => "NDR_POINTER_PTR"
  42 );
  43
  44 sub StripPrefixes($$)
  45 {
  46         my ($s, $prefixes) = @_;
  47
  48         foreach (@$prefixes) {
  49                 $s =~ s/^$_\_//g;
  50         }
  51
  52         return $s;
  53 }
  54
  55 # Convert a IDL structure field name (e.g access_mask) to a prettier
  56 # string like 'Access Mask'.
  57
  58 sub field2name($)
  59 {
  60     my($field) = shift;
  61
  62     $field =~ s/_/ /g;          # Replace underscores with spaces
  63     $field =~ s/(\w+)/\u\L$1/g; # Capitalise each word
  64
  65     return $field;
  66 }
  67
  68 sub new($)
  69 {
  70         my ($class) = @_;
  71         my $self = {res => {hdr => "", def => "", code => ""}, tabs => "", cur_fn => undef,
  72                 hf_used => {}, ett => [], conformance => undef
  73
  74         };
  75         bless($self, $class);
  76 }
  77
  78 sub pidl_fn_start($$)
  79 {
  80         my ($self, $fn) = @_;
  81         $self->{cur_fn} = $fn;
  82 }
  83 sub pidl_fn_end($$)
  84 {
  85         my ($self, $fn) = @_;
  86         die("Inconsistent state: $fn != $self->{cur_fn}") if ($fn ne $self->{cur_fn});
  87         $self->{cur_fn} = undef;
  88 }
  89
  90 sub pidl_code($$)
  91 {
  92         my ($self, $d) = @_;
  93         return if (defined($self->{cur_fn}) and defined($self->{conformance}->{manual}->{$self->{cur_fn}}));
  94
  95         if ($d) {
  96                 $self->{res}->{code} .= $self->{tabs};
  97                 $self->{res}->{code} .= $d;
  98         }
  99         $self->{res}->{code} .="\n";
 100 }
 101
 102 sub pidl_hdr($$) { my ($self,$x) = @_; $self->{res}->{hdr} .= "$x\n"; }
 103 sub pidl_def($$) { my ($self,$x) = @_; $self->{res}->{def} .= "$x\n"; }
 104
 105 sub indent($)
 106 {
 107         my ($self) = @_;
 108         $self->{tabs} .= "\t";
 109 }
 110
 111 sub deindent($)
 112 {
 113         my ($self) = @_;
 114         $self->{tabs} = substr($self->{tabs}, 0, -1);
 115 }
 116
 117 sub PrintIdl($$)
 118 {
 119         my ($self, $idl) = @_;
 120
 121         foreach (split /\n/, $idl) {
 122                 $self->pidl_code("/* IDL: $_ */");
 123         }
 124
 125         $self->pidl_code("");
 126 }
 127
 128 #####################################################################
 129 # parse the interface definitions
 130 sub Interface($$)
 131 {
 132         my($self, $interface) = @_;
 133         $self->Const($_,$interface->{NAME}) foreach (@{$interface->{CONSTS}});
 134         $self->Type($_, $_->{NAME}, $interface->{NAME}) foreach (@{$interface->{TYPES}});
 135         $self->Function($_,$interface->{NAME}) foreach (@{$interface->{FUNCTIONS}});
 136 }
 137
 138 sub Enum($$$$)
 139 {
 140         my ($self, $e,$name,$ifname) = @_;
 141         my $valsstring = "$ifname\_$name\_vals";
 142         my $dissectorname = "$ifname\_dissect\_enum\_".StripPrefixes($name, $self->{conformance}->{strip_prefixes});
 143
 144         return if (defined($self->{conformance}->{noemit}->{StripPrefixes($name, $self->{conformance}->{strip_prefixes})}));
 145
 146         foreach (@{$e->{ELEMENTS}}) {
 147                 if (/([^=]*)=(.*)/) {
 148                         $self->pidl_hdr("#define $1 ($2)");
 149                 }
 150         }
 151
 152         $self->pidl_hdr("extern const value_string $valsstring\[];");
 153         $self->pidl_hdr("int $dissectorname(tvbuff_t *tvb _U_, int offset _U_, packet_info *pinfo _U_, proto_tree *tree _U_, guint8 *drep _U_, int hf_index _U_, guint32 *param _U_);");
 154
 155         $self->pidl_def("const value_string ".$valsstring."[] = {");
 156         foreach (@{$e->{ELEMENTS}}) {
 157                 next unless (/([^=]*)=(.*)/);
 158                 $self->pidl_def("\t{ $1, \"$1\" },");
 159         }
 160
 161         $self->pidl_def("{ 0, NULL }");
 162         $self->pidl_def("};");
 163
 164         $self->pidl_fn_start($dissectorname);
 165         $self->pidl_code("int");
 166         $self->pidl_code("$dissectorname(tvbuff_t *tvb _U_, int offset _U_, packet_info *pinfo _U_, proto_tree *tree _U_, guint8 *drep _U_, int hf_index _U_, guint32 *param _U_)");
 167         $self->pidl_code("{");
 168         $self->indent;
 169         $self->pidl_code("g$e->{BASE_TYPE} parameter=0;");
 170         $self->pidl_code("if(param){");
 171         $self->indent;
 172         $self->pidl_code("parameter=(g$e->{BASE_TYPE})*param;");
 173         $self->deindent;
 174         $self->pidl_code("}");
 175         $self->pidl_code("offset = dissect_ndr_$e->{BASE_TYPE}(tvb, offset, pinfo, tree, drep, hf_index, &parameter);");
 176         $self->pidl_code("if(param){");
 177         $self->indent;
 178         $self->pidl_code("*param=(guint32)parameter;");
 179         $self->deindent;
 180         $self->pidl_code("}");
 181         $self->pidl_code("return offset;");
 182         $self->deindent;
 183         $self->pidl_code("}\n");
 184         $self->pidl_fn_end($dissectorname);
 185
 186         my $enum_size = $e->{BASE_TYPE};
 187         $enum_size =~ s/uint//g;
 188         $self->register_type($name, "offset = $dissectorname(tvb, offset, pinfo, tree, drep, \@HF\@, \@PARAM\@);", "FT_UINT$enum_size", "BASE_DEC", "0", "VALS($valsstring)", $enum_size / 8);
 189 }
 190
 191 sub Bitmap($$$$)
 192 {
 193         my ($self,$e,$name,$ifname) = @_;
 194         my $dissectorname = "$ifname\_dissect\_bitmap\_".StripPrefixes($name, $self->{conformance}->{strip_prefixes});
 195
 196         $self->register_ett("ett_$ifname\_$name");
 197
 198         $self->pidl_hdr("int $dissectorname(tvbuff_t *tvb _U_, int offset _U_, packet_info *pinfo _U_, proto_tree *tree _U_, guint8 *drep _U_, int hf_index _U_, guint32 param _U_);");
 199
 200         $self->pidl_fn_start($dissectorname);
 201         $self->pidl_code("int");
 202         $self->pidl_code("$dissectorname(tvbuff_t *tvb _U_, int offset _U_, packet_info *pinfo _U_, proto_tree *parent_tree _U_, guint8 *drep _U_, int hf_index _U_, guint32 param _U_)");
 203         $self->pidl_code("{");
 204         $self->indent;
 205         $self->pidl_code("proto_item *item = NULL;");
 206         $self->pidl_code("proto_tree *tree = NULL;");
 207         $self->pidl_code("");
 208
 209         $self->pidl_code("g$e->{BASE_TYPE} flags;");
 210         if ($e->{ALIGN} > 1) {
 211                 $self->pidl_code("ALIGN_TO_$e->{ALIGN}_BYTES;");
 212         }
 213
 214         $self->pidl_code("");
 215
 216         $self->pidl_code("if (parent_tree) {");
 217         $self->indent;
 218         $self->pidl_code("item = proto_tree_add_item(parent_tree, hf_index, tvb, offset, $e->{ALIGN}, TRUE);");
 219         $self->pidl_code("tree = proto_item_add_subtree(item,ett_$ifname\_$name);");
 220         $self->deindent;
 221         $self->pidl_code("}\n");
 222
 223         $self->pidl_code("offset = dissect_ndr_$e->{BASE_TYPE}(tvb, offset, pinfo, NULL, drep, -1, &flags);");
 224
 225         $self->pidl_code("proto_item_append_text(item, \": \");\n");
 226         $self->pidl_code("if (!flags)");
 227         $self->pidl_code("\tproto_item_append_text(item, \"(No values set)\");\n");
 228
 229         foreach (@{$e->{ELEMENTS}}) {
 230                 next unless (/([^ ]*) (.*)/);
 231                 my ($en,$ev) = ($1,$2);
 232                 my $hf_bitname = "hf_$ifname\_$name\_$en";
 233                 my $filtername = "$ifname\.$name\.$en";
 234
 235                 $self->{hf_used}->{$hf_bitname} = 1;
 236
 237                 $self->register_hf_field($hf_bitname, field2name($en), $filtername, "FT_BOOLEAN", $e->{ALIGN} * 8, "TFS(&$name\_$en\_tfs)", $ev, "");
 238
 239                 $self->pidl_def("static const true_false_string $name\_$en\_tfs = {");
 240                 if (defined($self->{conformance}->{tfs}->{$hf_bitname})) {
 241                         $self->pidl_def("   $self->{conformance}->{tfs}->{$hf_bitname}->{TRUE_STRING},");
 242                         $self->pidl_def("   $self->{conformance}->{tfs}->{$hf_bitname}->{FALSE_STRING},");
 243                         $self->{conformance}->{tfs}->{$hf_bitname}->{USED} = 1;
 244                 } else {
 245                         $self->pidl_def("   \"$en is SET\",");
 246                         $self->pidl_def("   \"$en is NOT SET\",");
 247                 }
 248                 $self->pidl_def("};");
 249
 250                 $self->pidl_code("proto_tree_add_boolean(tree, $hf_bitname, tvb, offset-$e->{ALIGN}, $e->{ALIGN}, flags);");
 251                 $self->pidl_code("if (flags&$ev){");
 252                 $self->pidl_code("\tproto_item_append_text(item, \"$en\");");
 253                 $self->pidl_code("\tif (flags & (~$ev))");
 254                 $self->pidl_code("\t\tproto_item_append_text(item, \", \");");
 255                 $self->pidl_code("}");
 256                 $self->pidl_code("flags&=(~$ev);");
 257                 $self->pidl_code("");
 258         }
 259
 260         $self->pidl_code("if (flags) {");
 261         $self->pidl_code("\tproto_item_append_text(item, \"Unknown bitmap value 0x%x\", flags);");
 262         $self->pidl_code("}\n");
 263         $self->pidl_code("return offset;");
 264         $self->deindent;
 265         $self->pidl_code("}\n");
 266         $self->pidl_fn_end($dissectorname);
 267
 268         my $size = $e->{BASE_TYPE};
 269         $size =~ s/uint//g;
 270         $self->register_type($name, "offset = $dissectorname(tvb, offset, pinfo, tree, drep, \@HF\@, \@PARAM\@);", "FT_UINT$size", "BASE_HEX", "0", "NULL", $size/8);
 271 }
 272
 273 sub ElementLevel($$$$$$$)
 274 {
 275         my ($self,$e,$l,$hf,$myname,$pn,$ifname) = @_;
 276
 277         my $param = 0;
 278
 279         if (defined($self->{conformance}->{dissectorparams}->{$myname})) {
 280                 $param = $self->{conformance}->{dissectorparams}->{$myname}->{PARAM};
 281         }
 282
 283         if ($l->{TYPE} eq "POINTER") {
 284                 my $type;
 285                 if ($l->{LEVEL} eq "TOP") {
 286                         $type = "toplevel";
 287                 } elsif ($l->{LEVEL} eq "EMBEDDED") {
 288                         $type = "embedded";
 289                 }
 290                 $self->pidl_code("offset = dissect_ndr_$type\_pointer(tvb, offset, pinfo, tree, drep, $myname\_, $ptrtype_mappings{$l->{POINTER_TYPE}}, \"Pointer to ".field2name(StripPrefixes($e->{NAME}, $self->{conformance}->{strip_prefixes})) . " ($e->{TYPE})\",$hf);");
 291         } elsif ($l->{TYPE} eq "ARRAY") {
 292                 if ($l->{IS_INLINE}) {
 293                         error($e->{ORIGINAL}, "Inline arrays not supported");
 294                 } elsif ($l->{IS_FIXED}) {
 295                         $self->pidl_code("int i;");
 296                         $self->pidl_code("for (i = 0; i < $l->{SIZE_IS}; i++)");
 297                         $self->pidl_code("\toffset = $myname\_(tvb, offset, pinfo, tree, drep);");
 298                 } else {
 299                         my $type = "";
 300                         $type .= "c" if ($l->{IS_CONFORMANT});
 301                         $type .= "v" if ($l->{IS_VARYING});
 302
 303                         unless ($l->{IS_ZERO_TERMINATED}) {
 304                                 $self->pidl_code("offset = dissect_ndr_u" . $type . "array(tvb, offset, pinfo, tree, drep, $myname\_);");
 305                         } else {
 306                                 my $nl = GetNextLevel($e,$l);
 307                                 $self->pidl_code("char *data;");
 308                                 $self->pidl_code("");
 309                                 $self->pidl_code("offset = dissect_ndr_$type" . "string(tvb, offset, pinfo, tree, drep, sizeof(g$nl->{DATA_TYPE}), $hf, FALSE, &data);");
 310                                 $self->pidl_code("proto_item_append_text(tree, \": %s\", data);");
 311                         }
 312                 }
 313         } elsif ($l->{TYPE} eq "DATA") {
 314                 if ($l->{DATA_TYPE} eq "string") {
 315                         my $bs = 2; # Byte size defaults to that of UCS2
 316
 317
 318                         ($bs = 1) if (property_matches($e, "flag", ".*LIBNDR_FLAG_STR_ASCII.*"));
 319
 320                         if (property_matches($e, "flag", ".*LIBNDR_FLAG_STR_SIZE4.*") and property_matches($e, "flag", ".*LIBNDR_FLAG_STR_LEN4.*")) {
 321                                 $self->pidl_code("char *data;\n");
 322                                 $self->pidl_code("offset = dissect_ndr_cvstring(tvb, offset, pinfo, tree, drep, $bs, $hf, FALSE, &data);");
 323                                 $self->pidl_code("proto_item_append_text(tree, \": %s\", data);");
 324                         } elsif (property_matches($e, "flag", ".*LIBNDR_FLAG_STR_SIZE4.*")) {
 325                                 $self->pidl_code("offset = dissect_ndr_vstring(tvb, offset, pinfo, tree, drep, $bs, $hf, FALSE, NULL);");
 326                         } elsif (property_matches($e, "flag", ".*STR_NULLTERM.*")) {
 327                                 if ($bs == 2) {
 328                                         $self->pidl_code("offset = dissect_null_term_wstring(tvb, offset, pinfo, tree, drep, $hf , 0);")
 329                                 } else {
 330                                         $self->pidl_code("offset = dissect_null_term_string(tvb, offset, pinfo, tree, drep, $hf , 0);")
 331                                 }
 332                         } else {
 333                                 warn("Unable to handle string with flags $e->{PROPERTIES}->{flag}");
 334                         }
 335                 } elsif ($l->{DATA_TYPE} eq "DATA_BLOB") {
 336                         my $remain = 0;
 337                         $remain = 1 if (property_matches($e->{ORIGINAL}, "flag", ".*LIBNDR_FLAG_REMAINING.*"));
 338                         $self->pidl_code("offset = dissect_ndr_datablob(tvb, offset, pinfo, tree, drep, $hf, $remain);");
 339                 } else {
 340                         my $call;
 341
 342                         if ($self->{conformance}->{imports}->{$l->{DATA_TYPE}}) {
 343                                 $call = $self->{conformance}->{imports}->{$l->{DATA_TYPE}}->{DATA};
 344                                 $self->{conformance}->{imports}->{$l->{DATA_TYPE}}->{USED} = 1;
 345                         } elsif (defined($self->{conformance}->{imports}->{"$pn.$e->{NAME}"})) {
 346                                 $call = $self->{conformance}->{imports}->{"$pn.$e->{NAME}"}->{DATA};
 347                                 $self->{conformance}->{imports}->{"$pn.$e->{NAME}"}->{USED} = 1;
 348
 349                         } elsif (defined($self->{conformance}->{types}->{$l->{DATA_TYPE}})) {
 350                                 $call= $self->{conformance}->{types}->{$l->{DATA_TYPE}}->{DISSECTOR_NAME};
 351                                 $self->{conformance}->{types}->{$l->{DATA_TYPE}}->{USED} = 1;
 352                         } else {
 353                                 $self->pidl_code("offset = $ifname\_dissect_struct_" . $l->{DATA_TYPE} . "(tvb,offset,pinfo,tree,drep,$hf,$param);");
 354
 355                                 return;
 356                         }
 357
 358                         $call =~ s/\@HF\@/$hf/g;
 359                         $call =~ s/\@PARAM\@/$param/g;
 360                         $self->pidl_code($call);
 361                 }
 362         } elsif ($_->{TYPE} eq "SUBCONTEXT") {
 363                 my $num_bits = ($l->{HEADER_SIZE}*8);
 364                 my $hf2 = $self->register_hf_field($hf."_", "Subcontext length", "$ifname.$pn.$_->{NAME}subcontext", "FT_UINT$num_bits", "BASE_HEX", "NULL", 0, "");
 365                 $self->{hf_used}->{$hf2} = 1;
 366                 $self->pidl_code("dcerpc_info *di = pinfo->private_data;");
 367                 $self->pidl_code("guint$num_bits size;");
 368                 $self->pidl_code("int conformant = di->conformant_run;");
 369                 $self->pidl_code("tvbuff_t *subtvb;");
 370                 $self->pidl_code("");
 371                 # We need to be able to dissect the length of the context in every case
 372                 # and conformant run skips the dissections of scalars ...
 373                 $self->pidl_code("if (!conformant) {");
 374                 $self->indent;
 375                 $self->pidl_code("offset = dissect_ndr_uint$num_bits(tvb, offset, pinfo, tree, drep, $hf2, &size);");
 376
 377                 $self->pidl_code("subtvb = tvb_new_subset(tvb, offset, size, -1);");
 378                 $self->pidl_code("$myname\_(subtvb, 0, pinfo, tree, drep);");
 379         } else {
 380                 die("Unknown type `$_->{TYPE}'");
 381         }
 382 }
 383
 384 sub Element($$$)
 385 {
 386         my ($self,$e,$pn,$ifname) = @_;
 387
 388         my $dissectorname = "$ifname\_dissect\_element\_".StripPrefixes($pn, $self->{conformance}->{strip_prefixes})."\_".StripPrefixes($e->{NAME}, $self->{conformance}->{strip_prefixes});
 389
 390         my $call_code = "offset = $dissectorname(tvb, offset, pinfo, tree, drep);";
 391
 392         my $type = $self->find_type($e->{TYPE});
 393
 394         if (not defined($type)) {
 395                 # default settings
 396                 $type = {
 397                         MASK => 0,
 398                         VALSSTRING => "NULL",
 399                         FT_TYPE => "FT_NONE",
 400                         BASE_TYPE => "BASE_NONE"
 401                 };
 402         }
 403
 404         if (ContainsString($e)) {
 405                 $type = {
 406                         MASK => 0,
 407                         VALSSTRING => "NULL",
 408                         FT_TYPE => "FT_STRING",
 409                         BASE_TYPE => "BASE_NONE"
 410                 };
 411         }
 412
 413         my $hf = $self->register_hf_field("hf_$ifname\_$pn\_$e->{NAME}", field2name($e->{NAME}), "$ifname.$pn.$e->{NAME}", $type->{FT_TYPE}, $type->{BASE_TYPE}, $type->{VALSSTRING}, $type->{MASK}, "");
 414         $self->{hf_used}->{$hf} = 1;
 415
 416         my $eltname = StripPrefixes($pn, $self->{conformance}->{strip_prefixes}) . ".$e->{NAME}";
 417         if (defined($self->{conformance}->{noemit}->{$eltname})) {
 418                 return $call_code;
 419         }
 420
 421         my $add = "";
 422
 423         foreach (@{$e->{LEVELS}}) {
 424                 next if ($_->{TYPE} eq "SWITCH");
 425                 $self->pidl_def("static int $dissectorname$add(tvbuff_t *tvb _U_, int offset _U_, packet_info *pinfo _U_, proto_tree *tree _U_, guint8 *drep _U_);");
 426                 $self->pidl_fn_start("$dissectorname$add");
 427                 $self->pidl_code("static int");
 428                 $self->pidl_code("$dissectorname$add(tvbuff_t *tvb _U_, int offset _U_, packet_info *pinfo _U_, proto_tree *tree _U_, guint8 *drep _U_)");
 429                 $self->pidl_code("{");
 430                 $self->indent;
 431
 432                 $self->ElementLevel($e,$_,$hf,$dissectorname.$add,$pn,$ifname);
 433
 434                 $self->pidl_code("");
 435                 $self->pidl_code("return offset;");
 436                 $self->deindent;
 437                 $self->pidl_code("}\n");
 438                 $self->pidl_fn_end("$dissectorname$add");
 439                 $add.="_";
 440                 last if ($_->{TYPE} eq "ARRAY" and $_->{IS_ZERO_TERMINATED});
 441         }
 442
 443         return $call_code;
 444 }
 445
 446 sub Function($$$)
 447 {
 448         my ($self, $fn,$ifname) = @_;
 449
 450         my %dissectornames;
 451
 452         foreach (@{$fn->{ELEMENTS}}) {
 453             $dissectornames{$_->{NAME}} = $self->Element($_, $fn->{NAME}, $ifname) if not defined($dissectornames{$_->{NAME}});
 454         }
 455
 456         my $fn_name = $_->{NAME};
 457         $fn_name =~ s/^${ifname}_//;
 458
 459         $self->PrintIdl(DumpFunction($fn->{ORIGINAL}));
 460         $self->pidl_fn_start("$ifname\_dissect\_$fn_name\_response");
 461         $self->pidl_code("static int");
 462         $self->pidl_code("$ifname\_dissect\_${fn_name}_response(tvbuff_t *tvb _U_, int offset _U_, packet_info *pinfo _U_, proto_tree *tree _U_, guint8 *drep _U_)");
 463         $self->pidl_code("{");
 464         $self->indent;
 465         if ( not defined($fn->{RETURN_TYPE})) {
 466         } elsif ($fn->{RETURN_TYPE} eq "NTSTATUS" or $fn->{RETURN_TYPE} eq "WERROR")
 467         {
 468                 $self->pidl_code("guint32 status;\n");
 469         } elsif (my $type = getType($fn->{RETURN_TYPE})) {
 470                 if ($type->{DATA}->{TYPE} eq "ENUM") {
 471                         $self->pidl_code("g".Parse::Pidl::Typelist::enum_type_fn($type->{DATA}) . " status;\n");
 472                 } elsif ($type->{DATA}->{TYPE} eq "SCALAR") {
 473                         $self->pidl_code("g$fn->{RETURN_TYPE} status;\n");
 474                 } else {
 475                 error($fn, "return type `$fn->{RETURN_TYPE}' not yet supported");
 476                 }
 477         } else {
 478                 error($fn, "unknown return type `$fn->{RETURN_TYPE}'");
 479         }
 480
 481         $self->pidl_code("pinfo->dcerpc_procedure_name=\"${fn_name}\";");
 482         foreach (@{$fn->{ELEMENTS}}) {
 483                 if (grep(/out/,@{$_->{DIRECTION}})) {
 484                         $self->pidl_code("$dissectornames{$_->{NAME}}");
 485                         $self->pidl_code("offset = dissect_deferred_pointers(pinfo, tvb, offset, drep);");
 486                         $self->pidl_code("");
 487                 }
 488         }
 489
 490         if (not defined($fn->{RETURN_TYPE})) {
 491         } elsif ($fn->{RETURN_TYPE} eq "NTSTATUS") {
 492                 $self->pidl_code("offset = dissect_ntstatus(tvb, offset, pinfo, tree, drep, hf\_$ifname\_status, &status);\n");
 493                 $self->pidl_code("if (status != 0 && check_col(pinfo->cinfo, COL_INFO))");
 494                 $self->pidl_code("\tcol_append_fstr(pinfo->cinfo, COL_INFO, \", Error: %s\", val_to_str(status, NT_errors, \"Unknown NT status 0x%08x\"));\n");
 495                 $return_types{$ifname}->{"status"} = ["NTSTATUS", "NT Error"];
 496         } elsif ($fn->{RETURN_TYPE} eq "WERROR") {
 497                 $self->pidl_code("offset = dissect_ndr_uint32(tvb, offset, pinfo, tree, drep, hf\_$ifname\_werror, &status);\n");
 498                 $self->pidl_code("if (status != 0 && check_col(pinfo->cinfo, COL_INFO))");
 499                 $self->pidl_code("\tcol_append_fstr(pinfo->cinfo, COL_INFO, \", Error: %s\", val_to_str(status, WERR_errors, \"Unknown DOS error 0x%08x\"));\n");
 500
 501                 $return_types{$ifname}->{"werror"} = ["WERROR", "Windows Error"];
 502         } elsif (my $type = getType($fn->{RETURN_TYPE})) {
 503                 if ($type->{DATA}->{TYPE} eq "ENUM") {
 504                         my $return_type = "g".Parse::Pidl::Typelist::enum_type_fn($type->{DATA});
 505                         my $return_dissect = "dissect_ndr_" .Parse::Pidl::Typelist::enum_type_fn($type->{DATA});
 506
 507                         $self->pidl_code("offset = $return_dissect(tvb, offset, pinfo, tree, drep, hf\_$ifname\_$fn->{RETURN_TYPE}_status, &status);");
 508                         $self->pidl_code("if (status != 0 && check_col(pinfo->cinfo, COL_INFO))");
 509                         $self->pidl_code("\tcol_append_fstr(pinfo->cinfo, COL_INFO, \", Status: %s\", val_to_str(status, $ifname\_$fn->{RETURN_TYPE}\_vals, \"Unknown " . $fn->{RETURN_TYPE} . " error 0x%08x\"));\n");
 510                         $return_types{$ifname}->{$fn->{RETURN_TYPE}."_status"} = [$fn->{RETURN_TYPE}, $fn->{RETURN_TYPE}];
 511                 } elsif ($type->{DATA}->{TYPE} eq "SCALAR") {
 512                         $self->pidl_code("offset = dissect_ndr_$fn->{RETURN_TYPE}(tvb, offset, pinfo, tree, drep, hf\_$ifname\_$fn->{RETURN_TYPE}_status, &status);");
 513                         $self->pidl_code("if (status != 0 && check_col(pinfo->cinfo, COL_INFO))");
 514                         $self->pidl_code("\tcol_append_fstr(pinfo->cinfo, COL_INFO, \", Status: %d\", status);\n");
 515                         $return_types{$ifname}->{$fn->{RETURN_TYPE}."_status"} = [$fn->{RETURN_TYPE}, $fn->{RETURN_TYPE}];
 516                 }
 517         }
 518
 519         $self->pidl_code("return offset;");
 520         $self->deindent;
 521         $self->pidl_code("}\n");
 522         $self->pidl_fn_end("$ifname\_dissect\_$fn_name\_response");
 523
 524         $self->pidl_fn_start("$ifname\_dissect\_$fn_name\_request");
 525         $self->pidl_code("static int");
 526         $self->pidl_code("$ifname\_dissect\_${fn_name}_request(tvbuff_t *tvb _U_, int offset _U_, packet_info *pinfo _U_, proto_tree *tree _U_, guint8 *drep _U_)");
 527         $self->pidl_code("{");
 528         $self->indent;
 529         $self->pidl_code("pinfo->dcerpc_procedure_name=\"${fn_name}\";");
 530         foreach (@{$fn->{ELEMENTS}}) {
 531                 if (grep(/in/,@{$_->{DIRECTION}})) {
 532                         $self->pidl_code("$dissectornames{$_->{NAME}}");
 533                         $self->pidl_code("offset = dissect_deferred_pointers(pinfo, tvb, offset, drep);");
 534                 }
 535
 536         }
 537
 538         $self->pidl_code("return offset;");
 539         $self->deindent;
 540         $self->pidl_code("}\n");
 541         $self->pidl_fn_end("$ifname\_dissect\_$fn_name\_request");
 542 }
 543
 544 sub Struct($$$$)
 545 {
 546         my ($self,$e,$name,$ifname) = @_;
 547         my $dissectorname = "$ifname\_dissect\_struct\_".StripPrefixes($name, $self->{conformance}->{strip_prefixes});
 548
 549         return if (defined($self->{conformance}->{noemit}->{StripPrefixes($name, $self->{conformance}->{strip_prefixes})}));
 550
 551         $self->register_ett("ett_$ifname\_$name");
 552
 553         my $res = "";
 554         ($res.="\t".$self->Element($_, $name, $ifname)."\n\n") foreach (@{$e->{ELEMENTS}});
 555
 556         $self->pidl_hdr("int $dissectorname(tvbuff_t *tvb _U_, int offset _U_, packet_info *pinfo _U_, proto_tree *parent_tree _U_, guint8 *drep _U_, int hf_index _U_, guint32 param _U_);");
 557
 558         $self->pidl_fn_start($dissectorname);
 559         $self->pidl_code("int");
 560         $self->pidl_code("$dissectorname(tvbuff_t *tvb _U_, int offset _U_, packet_info *pinfo _U_, proto_tree *parent_tree _U_, guint8 *drep _U_, int hf_index _U_, guint32 param _U_)");
 561         $self->pidl_code("{");
 562         $self->indent;
 563         $self->pidl_code("proto_item *item = NULL;");
 564         $self->pidl_code("proto_tree *tree = NULL;");
 565         if ($e->{ALIGN} > 1) {
 566                 $self->pidl_code("dcerpc_info *di = pinfo->private_data;");
 567         }
 568         $self->pidl_code("int old_offset;");
 569         $self->pidl_code("");
 570
 571         if ($e->{ALIGN} > 1) {
 572                 $self->pidl_code("ALIGN_TO_$e->{ALIGN}_BYTES;");
 573         }
 574         $self->pidl_code("");
 575
 576         $self->pidl_code("old_offset = offset;");
 577         $self->pidl_code("");
 578         $self->pidl_code("if (parent_tree) {");
 579         $self->indent;
 580         $self->pidl_code("item = proto_tree_add_item(parent_tree, hf_index, tvb, offset, -1, TRUE);");
 581         $self->pidl_code("tree = proto_item_add_subtree(item, ett_$ifname\_$name);");
 582         $self->deindent;
 583         $self->pidl_code("}");
 584
 585         $self->pidl_code("\n$res");
 586
 587         $self->pidl_code("proto_item_set_len(item, offset-old_offset);\n");
 588         if ($e->{ALIGN} > 1) {
 589                 $self->pidl_code("");
 590                 $self->pidl_code("if (di->call_data->flags & DCERPC_IS_NDR64) {");
 591                 $self->indent;
 592                 $self->pidl_code("ALIGN_TO_$e->{ALIGN}_BYTES;");
 593                 $self->deindent;
 594                 $self->pidl_code("}");
 595         }
 596         $self->pidl_code("");
 597         $self->pidl_code("return offset;");
 598         $self->deindent;
 599         $self->pidl_code("}\n");
 600         $self->pidl_fn_end($dissectorname);
 601
 602         $self->register_type($name, "offset = $dissectorname(tvb,offset,pinfo,tree,drep,\@HF\@,\@PARAM\@);", "FT_NONE", "BASE_NONE", 0, "NULL", 0);
 603 }
 604
 605 sub Union($$$$)
 606 {
 607         my ($self,$e,$name,$ifname) = @_;
 608
 609         my $dissectorname = "$ifname\_dissect_".StripPrefixes($name, $self->{conformance}->{strip_prefixes});
 610
 611         return if (defined($self->{conformance}->{noemit}->{StripPrefixes($name, $self->{conformance}->{strip_prefixes})}));
 612
 613         $self->register_ett("ett_$ifname\_$name");
 614
 615         my $res = "";
 616         foreach (@{$e->{ELEMENTS}}) {
 617                 $res.="\n\t\t$_->{CASE}:\n";
 618                 if ($_->{TYPE} ne "EMPTY") {
 619                         $res.="\t\t\t".$self->Element($_, $name, $ifname)."\n";
 620                 }
 621                 $res.="\t\tbreak;\n";
 622         }
 623
 624         my $switch_type;
 625         my $switch_dissect;
 626         my $switch_dt = getType($e->{SWITCH_TYPE});
 627         if ($switch_dt->{DATA}->{TYPE} eq "ENUM") {
 628                 $switch_type = "g".Parse::Pidl::Typelist::enum_type_fn($switch_dt->{DATA});
 629                 $switch_dissect = "dissect_ndr_" .Parse::Pidl::Typelist::enum_type_fn($switch_dt->{DATA});
 630         } elsif ($switch_dt->{DATA}->{TYPE} eq "SCALAR") {
 631                 $switch_type = "g$e->{SWITCH_TYPE}";
 632                 $switch_dissect = "dissect_ndr_$e->{SWITCH_TYPE}";
 633         }
 634
 635         $self->pidl_fn_start($dissectorname);
 636         $self->pidl_code("static int");
 637         $self->pidl_code("$dissectorname(tvbuff_t *tvb _U_, int offset _U_, packet_info *pinfo _U_, proto_tree *parent_tree _U_, guint8 *drep _U_, int hf_index _U_, guint32 param _U_)");
 638         $self->pidl_code("{");
 639         $self->indent;
 640         $self->pidl_code("proto_item *item = NULL;");
 641         $self->pidl_code("proto_tree *tree = NULL;");
 642         $self->pidl_code("int old_offset;");
 643         $self->pidl_code("$switch_type level;");
 644         $self->pidl_code("");
 645
 646         $self->pidl_code("old_offset = offset;");
 647         $self->pidl_code("if (parent_tree) {");
 648         $self->indent;
 649         $self->pidl_code("item = proto_tree_add_text(parent_tree, tvb, offset, -1, \"$name\");");
 650         $self->pidl_code("tree = proto_item_add_subtree(item, ett_$ifname\_$name);");
 651         $self->deindent;
 652         $self->pidl_code("}");
 653
 654         $self->pidl_code("");
 655
 656         $self->pidl_code("offset = $switch_dissect(tvb, offset, pinfo, tree, drep, hf_index, &level);");
 657
 658         if ($e->{ALIGN} > 1) {
 659                 $self->pidl_code("ALIGN_TO_$e->{ALIGN}_BYTES;");
 660                 $self->pidl_code("");
 661         }
 662
 663
 664         $self->pidl_code("switch(level) {$res\t}");
 665         $self->pidl_code("proto_item_set_len(item, offset-old_offset);\n");
 666         $self->pidl_code("");
 667
 668         $self->pidl_code("return offset;");
 669         $self->deindent;
 670         $self->pidl_code("}");
 671         $self->pidl_fn_end($dissectorname);
 672
 673         $self->register_type($name, "offset = $dissectorname(tvb, offset, pinfo, tree, drep, \@HF\@, \@PARAM\@);", "FT_NONE", "BASE_NONE", 0, "NULL", 0);
 674 }
 675
 676 sub Const($$$)
 677 {
 678         my ($self,$const,$ifname) = @_;
 679
 680         if (!defined($const->{ARRAY_LEN}[0])) {
 681                 $self->pidl_hdr("#define $const->{NAME}\t( $const->{VALUE} )\n");
 682         } else {
 683                 $self->pidl_hdr("#define $const->{NAME}\t $const->{VALUE}\n");
 684         }
 685 }
 686
 687 sub Typedef($$$$)
 688 {
 689         my ($self,$e,$name,$ifname) = @_;
 690
 691         $self->Type($e->{DATA}, $name, $ifname);
 692 }
 693
 694 sub Type($$$$)
 695 {
 696         my ($self, $e, $name, $ifname) = @_;
 697
 698         $self->PrintIdl(DumpType($e->{ORIGINAL}));
 699
 700         {
 701                 ENUM => \&Enum,
 702                 STRUCT => \&Struct,
 703                 UNION => \&Union,
 704                 BITMAP => \&Bitmap,
 705                 TYPEDEF => \&Typedef
 706         }->{$e->{TYPE}}->($self, $e, $name, $ifname);
 707 }
 708
 709 sub RegisterInterface($$)
 710 {
 711         my ($self, $x) = @_;
 712
 713         $self->pidl_fn_start("proto_register_dcerpc_$x->{NAME}");
 714         $self->pidl_code("void proto_register_dcerpc_$x->{NAME}(void)");
 715         $self->pidl_code("{");
 716         $self->indent;
 717
 718         $self->{res}->{code}.=$self->DumpHfList()."\n";
 719         $self->{res}->{code}.="\n".DumpEttList($self->{ett})."\n";
 720
 721         if (defined($x->{UUID})) {
 722             # These can be changed to non-pidl_code names if the old dissectors
 723             # in epan/dissctors are deleted.
 724
 725             my $name = uc($x->{NAME}) . " (pidl)";
 726             my $short_name = uc($x->{NAME});
 727             my $filter_name = $x->{NAME};
 728
 729             if (has_property($x, "helpstring")) {
 730                 $name = $x->{PROPERTIES}->{helpstring};
 731             }
 732
 733             if (defined($self->{conformance}->{protocols}->{$x->{NAME}})) {
 734                 $short_name = $self->{conformance}->{protocols}->{$x->{NAME}}->{SHORTNAME};
 735                 $name = $self->{conformance}->{protocols}->{$x->{NAME}}->{LONGNAME};
 736                 $filter_name = $self->{conformance}->{protocols}->{$x->{NAME}}->{FILTERNAME};
 737             }
 738
 739             $self->pidl_code("proto_dcerpc_$x->{NAME} = proto_register_protocol(".make_str($name).", ".make_str($short_name).", ".make_str($filter_name).");");
 740
 741             $self->pidl_code("proto_register_field_array(proto_dcerpc_$x->{NAME}, hf, array_length (hf));");
 742             $self->pidl_code("proto_register_subtree_array(ett, array_length(ett));");
 743         } else {
 744             $self->pidl_code("proto_dcerpc = proto_get_id_by_filter_name(\"dcerpc\");");
 745             $self->pidl_code("proto_register_field_array(proto_dcerpc, hf, array_length(hf));");
 746             $self->pidl_code("proto_register_subtree_array(ett, array_length(ett));");
 747         }
 748
 749         $self->deindent;
 750         $self->pidl_code("}\n");
 751         $self->pidl_fn_end("proto_register_dcerpc_$x->{NAME}");
 752 }
 753
 754 sub RegisterInterfaceHandoff($$)
 755 {
 756         my ($self,$x) = @_;
 757
 758         if (defined($x->{UUID})) {
 759                 $self->pidl_fn_start("proto_reg_handoff_dcerpc_$x->{NAME}");
 760             $self->pidl_code("void proto_reg_handoff_dcerpc_$x->{NAME}(void)");
 761             $self->pidl_code("{");
 762             $self->indent;
 763             $self->pidl_code("dcerpc_init_uuid(proto_dcerpc_$x->{NAME}, ett_dcerpc_$x->{NAME},");
 764             $self->pidl_code("\t&uuid_dcerpc_$x->{NAME}, ver_dcerpc_$x->{NAME},");
 765             $self->pidl_code("\t$x->{NAME}_dissectors, hf_$x->{NAME}_opnum);");
 766             $self->deindent;
 767             $self->pidl_code("}");
 768                 $self->pidl_fn_end("proto_reg_handoff_dcerpc_$x->{NAME}");
 769
 770                 $self->{hf_used}->{"hf_$x->{NAME}_opnum"} = 1;
 771         }
 772 }
 773
 774 sub ProcessInclude
 775 {
 776         my $self = shift;
 777         my @includes = @_;
 778         foreach (@includes) {
 779                 $self->pidl_hdr("#include \"$_\"");
 780         }
 781         $self->pidl_hdr("");
 782 }
 783
 784 sub ProcessImport
 785 {
 786         my $self = shift;
 787         my @imports = @_;
 788         foreach (@imports) {
 789                 next if($_ eq "security");
 790                 s/^\"//;
 791                 s/\.idl"?$//;
 792                 $self->pidl_hdr("#include \"packet-dcerpc-$_\.h\"");
 793         }
 794         $self->pidl_hdr("");
 795 }
 796
 797 sub ProcessInterface($$)
 798 {
 799         my ($self, $x) = @_;
 800
 801         push(@{$self->{conformance}->{strip_prefixes}}, $x->{NAME});
 802
 803         my $define = "__PACKET_DCERPC_" . uc($_->{NAME}) . "_H";
 804         $self->pidl_hdr("#ifndef $define");
 805         $self->pidl_hdr("#define $define");
 806         $self->pidl_hdr("");
 807
 808         $self->pidl_def("static gint proto_dcerpc_$x->{NAME} = -1;");
 809         $self->register_ett("ett_dcerpc_$x->{NAME}");
 810         $self->register_hf_field("hf_$x->{NAME}_opnum", "Operation", "$x->{NAME}.opnum", "FT_UINT16", "BASE_DEC", "NULL", 0, "");
 811
 812         if (defined($x->{UUID})) {
 813                 my $if_uuid = $x->{UUID};
 814
 815             $self->pidl_def("/* Version information */\n\n");
 816
 817             $self->pidl_def("static e_uuid_t uuid_dcerpc_$x->{NAME} = {");
 818             $self->pidl_def("\t0x" . substr($if_uuid, 1, 8)
 819                 . ", 0x" . substr($if_uuid, 10, 4)
 820             . ", 0x" . substr($if_uuid, 15, 4) . ",");
 821             $self->pidl_def("\t{ 0x" . substr($if_uuid, 20, 2)
 822                 . ", 0x" . substr($if_uuid, 22, 2)
 823             . ", 0x" . substr($if_uuid, 25, 2)
 824             . ", 0x" . substr($if_uuid, 27, 2)
 825             . ", 0x" . substr($if_uuid, 29, 2)
 826             . ", 0x" . substr($if_uuid, 31, 2)
 827             . ", 0x" . substr($if_uuid, 33, 2)
 828             . ", 0x" . substr($if_uuid, 35, 2) . " }");
 829             $self->pidl_def("};");
 830
 831             my $maj = $x->{VERSION};
 832             $maj =~ s/\.(.*)$//g;
 833             $self->pidl_def("static guint32 ver_dcerpc_$x->{NAME} = $maj;");
 834             $self->pidl_def("");
 835         }
 836
 837         $return_types{$x->{NAME}} = {};
 838
 839         $self->Interface($x);
 840
 841         $self->pidl_code("\n".DumpFunctionTable($x));
 842
 843         foreach (keys %{$return_types{$x->{NAME}}}) {
 844                 my ($type, $desc) = @{$return_types{$x->{NAME}}->{$_}};
 845                 my $dt = $self->find_type($type);
 846                 $dt or die("Unable to find information about return type `$type'");
 847                 $self->register_hf_field("hf_$x->{NAME}_$_", $desc, "$x->{NAME}.$_", $dt->{FT_TYPE}, "BASE_HEX", $dt->{VALSSTRING}, 0, "");
 848                 $self->{hf_used}->{"hf_$x->{NAME}_$_"} = 1;
 849         }
 850
 851         $self->RegisterInterface($x);
 852         $self->RegisterInterfaceHandoff($x);
 853
 854         $self->pidl_hdr("#endif /* $define */");
 855 }
 856
 857 sub find_type($$)
 858 {
 859         my ($self, $n) = @_;
 860
 861         return $self->{conformance}->{types}->{$n};
 862 }
 863
 864 sub register_type($$$$$$$$)
 865 {
 866         my ($self, $type,$call,$ft,$base,$mask,$vals,$length) = @_;
 867
 868         return if (defined($self->{conformance}->{types}->{$type}));
 869
 870         $self->{conformance}->{types}->{$type} = {
 871                 NAME => $type,
 872                 DISSECTOR_NAME => $call,
 873                 FT_TYPE => $ft,
 874                 BASE_TYPE => $base,
 875                 MASK => $mask,
 876                 VALSSTRING => $vals,
 877                 ALIGNMENT => $length
 878         };
 879 }
 880
 881 # Loads the default types
 882 sub Initialize($$)
 883 {
 884         my ($self, $cnf_file) = @_;
 885
 886         $self->{conformance} = {
 887                 imports => {},
 888                 header_fields=> {}
 889         };
 890
 891         ReadConformance($cnf_file, $self->{conformance}) or print STDERR "warning: No conformance file `$cnf_file'\n";
 892
 893         foreach my $bytes (qw(1 2 4 8)) {
 894                 my $bits = $bytes * 8;
 895                 $self->register_type("uint$bits", "offset = PIDL_dissect_uint$bits(tvb, offset, pinfo, tree, drep, \@HF\@, \@PARAM\@);", "FT_UINT$bits", "BASE_DEC", 0, "NULL", $bytes);
 896                 $self->register_type("int$bits", "offset = PIDL_dissect_uint$bits(tvb, offset, pinfo, tree, drep, \@HF\@, \@PARAM\@);", "FT_INT$bits", "BASE_DEC", 0, "NULL", $bytes);
 897         }
 898
 899         $self->register_type("hyper", "offset = dissect_ndr_uint64(tvb, offset, pinfo, tree, drep, \@HF\@, NULL);", "FT_UINT64", "BASE_DEC", 0, "NULL", 8);
 900         $self->register_type("udlong", "offset = dissect_ndr_duint32(tvb, offset, pinfo, tree, drep, \@HF\@, NULL);", "FT_UINT64", "BASE_DEC", 0, "NULL", 4);
 901         $self->register_type("bool8", "offset = PIDL_dissect_uint8(tvb, offset, pinfo, tree, drep, \@HF\@, \@PARAM\@);","FT_INT8", "BASE_DEC", 0, "NULL", 1);
 902         $self->register_type("char", "offset = PIDL_dissect_uint8(tvb, offset, pinfo, tree, drep, \@HF\@, \@PARAM\@);","FT_INT8", "BASE_DEC", 0, "NULL", 1);
 903         $self->register_type("long", "offset = PIDL_dissect_uint32(tvb, offset, pinfo, tree, drep, \@HF\@, \@PARAM\@);","FT_INT32", "BASE_DEC", 0, "NULL", 4);
 904         $self->register_type("dlong", "offset = dissect_ndr_duint32(tvb, offset, pinfo, tree, drep, \@HF\@, NULL);","FT_INT64", "BASE_DEC", 0, "NULL", 8);
 905         $self->register_type("GUID", "offset = dissect_ndr_uuid_t(tvb, offset, pinfo, tree, drep, \@HF\@, NULL);","FT_GUID", "BASE_NONE", 0, "NULL", 4);
 906         $self->register_type("policy_handle", "offset = PIDL_dissect_policy_hnd(tvb, offset, pinfo, tree, drep, \@HF\@, \@PARAM\@);","FT_BYTES", "BASE_NONE", 0, "NULL", 4);
 907         $self->register_type("NTTIME", "offset = dissect_ndr_nt_NTTIME(tvb, offset, pinfo, tree, drep, \@HF\@);","FT_ABSOLUTE_TIME", "ABSOLUTE_TIME_LOCAL", 0, "NULL", 4);
 908         $self->register_type("NTTIME_hyper", "offset = dissect_ndr_nt_NTTIME(tvb, offset, pinfo, tree, drep, \@HF\@);","FT_ABSOLUTE_TIME", "ABSOLUTE_TIME_LOCAL", 0, "NULL", 4);
 909         $self->register_type("time_t", "offset = dissect_ndr_time_t(tvb, offset, pinfo,tree, drep, \@HF\@, NULL);","FT_ABSOLUTE_TIME", "ABSOLUTE_TIME_LOCAL", 0, "NULL", 4);
 910         $self->register_type("NTTIME_1sec", "offset = dissect_ndr_nt_NTTIME(tvb, offset, pinfo, tree, drep, \@HF\@);", "FT_ABSOLUTE_TIME", "ABSOLUTE_TIME_LOCAL", 0, "NULL", 4);
 911         $self->register_type("SID", "
 912                 dcerpc_info *di = (dcerpc_info *)pinfo->private_data;
 913
 914                 di->hf_index = \@HF\@;
 915
 916                 offset = dissect_ndr_nt_SID_with_options(tvb, offset, pinfo, tree, drep, param);
 917         ","FT_STRING", "BASE_NONE", 0, "NULL", 4);
 918         $self->register_type("WERROR",
 919                 "offset = PIDL_dissect_uint32(tvb, offset, pinfo, tree, drep, \@HF\@, \@PARAM\@);","FT_UINT32", "BASE_DEC", 0, "VALS(WERR_errors)", 4);
 920         $self->register_type("NTSTATUS",
 921                 "offset = PIDL_dissect_uint32(tvb, offset, pinfo, tree, drep, \@HF\@, \@PARAM\@);","FT_UINT32", "BASE_DEC", 0, "VALS(NT_errors)", 4);
 922
 923 }
 924
 925 #####################################################################
 926 # Generate Wireshark parser and header code
 927 sub Parse($$$$$)
 928 {
 929         my($self,$ndr,$idl_file,$h_filename,$cnf_file) = @_;
 930
 931         $self->Initialize($cnf_file);
 932
 933         return (undef, undef) if defined($self->{conformance}->{noemit_dissector});
 934
 935         my $notice =
 936 "/* DO NOT EDIT
 937         This filter was automatically generated
 938         from $idl_file and $cnf_file.
 939
 940         Pidl is a perl based IDL compiler for DCE/RPC idl files.
 941         It is maintained by the Samba team, not the Wireshark team.
 942         Instructions on how to download and install Pidl can be
 943         found at http://wiki.wireshark.org/Pidl
 944 */
 945
 946 ";
 947
 948         $self->pidl_hdr($notice);
 949
 950         $self->{res}->{headers} = "\n";
 951         $self->{res}->{headers} .= "#ifdef HAVE_CONFIG_H\n";
 952         $self->{res}->{headers} .= "#include \"config.h\"\n";
 953         $self->{res}->{headers} .= "#endif\n\n";
 954
 955         $self->{res}->{headers} .= "#ifdef _MSC_VER\n";
 956         $self->{res}->{headers} .= "#pragma warning(disable:4005)\n";
 957         $self->{res}->{headers} .= "#pragma warning(disable:4013)\n";
 958         $self->{res}->{headers} .= "#pragma warning(disable:4018)\n";
 959         $self->{res}->{headers} .= "#pragma warning(disable:4101)\n";
 960         $self->{res}->{headers} .= "#endif\n\n";
 961
 962         $self->{res}->{headers} .= "#include <glib.h>\n";
 963         $self->{res}->{headers} .= "#include <string.h>\n";
 964         $self->{res}->{headers} .= "#include <epan/packet.h>\n\n";
 965
 966         $self->{res}->{headers} .= "#include \"packet-dcerpc.h\"\n";
 967         $self->{res}->{headers} .= "#include \"packet-dcerpc-nt.h\"\n";
 968         $self->{res}->{headers} .= "#include \"packet-windows-common.h\"\n";
 969
 970         my $h_basename = basename($h_filename);
 971
 972         $self->{res}->{headers} .= "#include \"$h_basename\"\n";
 973         $self->pidl_code("");
 974
 975         if (defined($self->{conformance}->{ett})) {
 976                 register_ett($self,$_) foreach(@{$self->{conformance}->{ett}})
 977         }
 978
 979         # Wireshark protocol registration
 980
 981         foreach (@$ndr) {
 982                 $self->ProcessInterface($_) if ($_->{TYPE} eq "INTERFACE");
 983                 $self->ProcessImport(@{$_->{PATHS}}) if ($_->{TYPE} eq "IMPORT");
 984                 $self->ProcessInclude(@{$_->{PATHS}}) if ($_->{TYPE} eq "INCLUDE");
 985         }
 986
 987         $self->{res}->{ett} = DumpEttDeclaration($self->{ett});
 988         $self->{res}->{hf} = $self->DumpHfDeclaration();
 989
 990         my $parser = $notice;
 991         $parser.= $self->{res}->{headers};
 992         $parser.=$self->{res}->{ett};
 993         $parser.=$self->{res}->{hf};
 994         $parser.=$self->{res}->{def};
 995         if (exists ($self->{conformance}->{override})) {
 996                 $parser.=$self->{conformance}->{override};
 997         }
 998         $parser.=$self->{res}->{code};
 999
1000         my $header = "/* autogenerated by pidl */\n\n";
1001         $header.=$self->{res}->{hdr};
1002
1003         $self->CheckUsed($self->{conformance});
1004
1005         return ($parser,$header);
1006 }
1007
1008 ###############################################################################
1009 # ETT
1010 ###############################################################################
1011
1012 sub register_ett($$)
1013 {
1014         my ($self, $name) = @_;
1015
1016         push (@{$self->{ett}}, $name);
1017 }
1018
1019 sub DumpEttList
1020 {
1021         my ($ett) = @_;
1022         my $res = "\tstatic gint *ett[] = {\n";
1023         foreach (@$ett) {
1024                 $res .= "\t\t&$_,\n";
1025         }
1026
1027         return "$res\t};\n";
1028 }
1029
1030 sub DumpEttDeclaration
1031 {
1032         my ($ett) = @_;
1033         my $res = "\n/* Ett declarations */\n";
1034         foreach (@$ett) {
1035                 $res .= "static gint $_ = -1;\n";
1036         }
1037
1038         return "$res\n";
1039 }
1040
1041 ###############################################################################
1042 # HF
1043 ###############################################################################
1044
1045 sub register_hf_field($$$$$$$$$)
1046 {
1047         my ($self,$index,$name,$filter_name,$ft_type,$base_type,$valsstring,$mask,$blurb) = @_;
1048
1049         if (defined ($self->{conformance}->{hf_renames}->{$index})) {
1050                 $self->{conformance}->{hf_renames}->{$index}->{USED} = 1;
1051                 return $self->{conformance}->{hf_renames}->{$index}->{NEWNAME};
1052         }
1053
1054         $self->{conformance}->{header_fields}->{$index} = {
1055                 INDEX => $index,
1056                 NAME => $name,
1057                 FILTER => $filter_name,
1058                 FT_TYPE => $ft_type,
1059                 BASE_TYPE => $base_type,
1060                 VALSSTRING => $valsstring,
1061                 MASK => $mask,
1062                 BLURB => $blurb
1063         };
1064
1065         if ((not defined($blurb) or $blurb eq "") and
1066                         defined($self->{conformance}->{fielddescription}->{$index})) {
1067                 $self->{conformance}->{header_fields}->{$index}->{BLURB} =
1068                         $self->{conformance}->{fielddescription}->{$index}->{DESCRIPTION};
1069                 $self->{conformance}->{fielddescription}->{$index}->{USED} = 1;
1070         }
1071
1072         return $index;
1073 }
1074
1075 sub DumpHfDeclaration($)
1076 {
1077         my ($self) = @_;
1078         my $res = "";
1079
1080         $res = "\n/* Header field declarations */\n";
1081
1082         foreach (keys %{$self->{conformance}->{header_fields}})
1083         {
1084                 $res .= "static gint $_ = -1;\n";
1085         }
1086
1087         return "$res\n";
1088 }
1089
1090 sub make_str_or_null($)
1091 {
1092       my $str = shift;
1093       if (substr($str, 0, 1) eq "\"") {
1094               $str = substr($str, 1, length($str)-2);
1095       }
1096       $str =~ s/^\s*//;
1097       $str =~ s/\s*$//;
1098       if ($str eq "") {
1099               return "NULL";
1100       }
1101       return make_str($str);
1102 }
1103
1104 sub DumpHfList($)
1105 {
1106         my ($self) = @_;
1107         my $res = "\tstatic hf_register_info hf[] = {\n";
1108
1109         foreach (values %{$self->{conformance}->{header_fields}})
1110         {
1111                 $res .= "\t{ &$_->{INDEX},
1112           { ".make_str($_->{NAME}).", ".make_str($_->{FILTER}).", $_->{FT_TYPE}, $_->{BASE_TYPE}, $_->{VALSSTRING}, $_->{MASK}, ".make_str_or_null($_->{BLURB}).", HFILL }},
1113 ";
1114         }
1115
1116         return $res."\t};\n";
1117 }
1118
1119
1120 ###############################################################################
1121 # Function table
1122 ###############################################################################
1123
1124 sub DumpFunctionTable($)
1125 {
1126         my $if = shift;
1127
1128         my $res = "static dcerpc_sub_dissector $if->{NAME}\_dissectors[] = {\n";
1129         foreach (@{$if->{FUNCTIONS}}) {
1130                 my $fn_name = $_->{NAME};
1131                 $fn_name =~ s/^$if->{NAME}_//;
1132                 $res.= "\t{ $_->{OPNUM}, \"$fn_name\",\n";
1133                 $res.= "\t   $if->{NAME}_dissect_${fn_name}_request, $if->{NAME}_dissect_${fn_name}_response},\n";
1134         }
1135
1136         $res .= "\t{ 0, NULL, NULL, NULL }\n";
1137
1138         return "$res};\n";
1139 }
1140
1141 sub CheckUsed($$)
1142 {
1143         my ($self, $conformance) = @_;
1144         foreach (values %{$conformance->{header_fields}}) {
1145                 if (not defined($self->{hf_used}->{$_->{INDEX}})) {
1146                         warning($_->{POS}, "hf field `$_->{INDEX}' not used");
1147                 }
1148         }
1149
1150         foreach (values %{$conformance->{hf_renames}}) {
1151                 if (not $_->{USED}) {
1152                         warning($_->{POS}, "hf field `$_->{OLDNAME}' not used");
1153                 }
1154         }
1155
1156         foreach (values %{$conformance->{dissectorparams}}) {
1157                 if (not $_->{USED}) {
1158                         warning($_->{POS}, "dissector param never used");
1159                 }
1160         }
1161
1162         foreach (values %{$conformance->{imports}}) {
1163                 if (not $_->{USED}) {
1164                         warning($_->{POS}, "import never used");
1165                 }
1166         }
1167
1168         foreach (values %{$conformance->{types}}) {
1169                 if (not $_->{USED} and defined($_->{POS})) {
1170                         warning($_->{POS}, "type never used");
1171                 }
1172         }
1173
1174         foreach (values %{$conformance->{fielddescription}}) {
1175                 if (not $_->{USED}) {
1176                         warning($_->{POS}, "description never used");
1177                 }
1178         }
1179
1180         foreach (values %{$conformance->{tfs}}) {
1181                 if (not $_->{USED}) {
1182                         warning($_->{POS}, "True/False description never used");
1183                 }
1184         }
1185 }
1186
1187 1;