source4/configure.ac

   1 dnl -*- mode: m4-mode -*-
   2 dnl Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.54)
   5
   6 AC_INIT([samba],[4],[samba-technical@samba.org])
   7
   8 AC_CONFIG_SRCDIR([include/includes.h])
   9 AC_CONFIG_HEADER(include/config_tmp.h)
  10 AC_DEFINE(CONFIG_H_IS_FROM_SAMBA,1,[Marker for samba's config.h])
  11
  12 # Configuration rules.
  13 m4_include(build/m4/env.m4)
  14 m4_include(../lib/replace/samba.m4)
  15 m4_include(lib/smbreadline/readline.m4)
  16 m4_include(heimdal_build/config.m4)
  17 m4_include(../lib/util/fault.m4)
  18 m4_include(../lib/util/signal.m4)
  19 m4_include(../lib/util/util.m4)
  20 m4_include(../lib/util/fsusage.m4)
  21 m4_include(../lib/util/xattr.m4)
  22 m4_include(../lib/util/capability.m4)
  23 m4_include(../lib/util/time.m4)
  24 m4_include(../lib/util/tevent.m4)
  25 m4_include(../lib/popt/samba.m4)
  26 m4_include(../lib/util/charset/config.m4)
  27 m4_include(lib/socket/config.m4)
  28 m4_include(../lib/zlib/zlib.m4)
  29 AC_ZLIB([
  30 SMB_EXT_LIB(ZLIB, [${ZLIB_LIBS}])
  31 ],[
  32 SMB_INCLUDE_MK(lib/zlib.mk)
  33 ])
  34 m4_include(../nsswitch/nsstest.m4)
  35 m4_include(../pidl/config.m4)
  36
  37 AC_CONFIG_FILES(lib/registry/registry.pc)
  38 AC_CONFIG_FILES(librpc/dcerpc.pc)
  39 AC_CONFIG_FILES(../librpc/ndr.pc)
  40 AC_CONFIG_FILES(../lib/torture/torture.pc)
  41 AC_CONFIG_FILES(auth/gensec/gensec.pc)
  42 AC_CONFIG_FILES(param/samba-hostconfig.pc)
  43 AC_CONFIG_FILES(librpc/dcerpc_samr.pc)
  44 AC_CONFIG_FILES(librpc/dcerpc_atsvc.pc)
  45
  46 m4_include(min_versions.m4)
  47
  48 SMB_INCLUDED_LIB_PKGCONFIG(LIBTALLOC, talloc >= TALLOC_MIN_VERSION, [],
  49         [
  50                 m4_include(../lib/talloc/libtalloc.m4)
  51                 SMB_INCLUDE_MK(../lib/talloc/config.mk)
  52         ]
  53 )
  54
  55 SMB_INCLUDED_LIB_PKGCONFIG(LIBTDB, tdb >= TDB_MIN_VERSION,
  56         [],
  57         [
  58                 m4_include(../lib/tdb/libtdb.m4)
  59                 SMB_INCLUDE_MK(../lib/tdb/config.mk)
  60         ]
  61 )
  62
  63 SMB_INCLUDE_MK(../lib/tdb/python.mk)
  64
  65 SMB_INCLUDED_LIB_PKGCONFIG(LIBTEVENT, tevent = TEVENT_REQUIRED_VERSION,
  66         [],[m4_include(../lib/tevent/samba.m4)]
  67 )
  68
  69 SMB_INCLUDE_MK(../lib/tevent/python.mk)
  70
  71 SMB_INCLUDED_LIB_PKGCONFIG(LIBLDB, ldb = LDB_REQUIRED_VERSION,
  72         [
  73                 SMB_INCLUDE_MK(lib/ldb/ldb_ildap/config.mk)
  74                 SMB_INCLUDE_MK(lib/ldb/tools/config.mk)
  75                 define_ldb_modulesdir=no
  76         ],
  77         [
  78                 # Here we need to do some tricks
  79                 # with AC_CONFIG_COMMANDS_PRE
  80                 # as that's the deferrs the commands
  81                 # to location after $prefix and $exec_prefix
  82                 # have usefull values and directly before
  83                 # creating config.status.
  84                 #
  85                 # The 'eval eval echo' trick is used to
  86                 # actually get the raw absolute directory
  87                 # path as this is needed in config.h
  88                 define_ldb_modulesdir=yes
  89                 AC_CONFIG_COMMANDS_PRE([
  90                 if test x"$define_ldb_modulesdir" = x"yes";then
  91                         LDB_MODULESDIR=`eval eval echo ${modulesdir}/ldb`
  92                         AC_DEFINE_UNQUOTED(LDB_MODULESDIR, "${LDB_MODULESDIR}" , [ldb Modules directory])
  93                 fi
  94                 ])
  95                 ldbdir=lib/ldb
  96                 AC_SUBST(ldbdir)
  97                 m4_include(lib/ldb/sqlite3.m4)
  98                 m4_include(lib/ldb/libldb.m4)
  99                 SMB_INCLUDE_MK(lib/ldb/config.mk)
 100                 AC_CONFIG_FILES(lib/ldb/ldb.pc)
 101         ], [no])
 102 SMB_INCLUDE_MK(lib/ldb/python.mk)
 103
 104 m4_include(lib/tls/config.m4)
 105
 106 dnl m4_include(auth/kerberos/config.m4)
 107 m4_include(auth/gensec/config.m4)
 108 m4_include(smbd/process_model.m4)
 109 m4_include(ntvfs/posix/config.m4)
 110 m4_include(ntvfs/unixuid/config.m4)
 111 m4_include(../lib/socket_wrapper/config.m4)
 112 m4_include(../lib/nss_wrapper/config.m4)
 113 m4_include(auth/config.m4)
 114 m4_include(kdc/config.m4)
 115 m4_include(ntvfs/sysdep/config.m4)
 116 m4_include(../nsswitch/config.m4)
 117
 118 #################################################
 119 # add *_CFLAGS only for the real build
 120 CFLAGS="${CFLAGS} ${DEVELOPER_CFLAGS}"
 121
 122 #################################################
 123 # final configure stuff
 124
 125 AC_MSG_CHECKING([configure summary])
 126 AC_TRY_RUN([#include "${srcdir-.}/../tests/summary.c"],
 127            AC_MSG_RESULT(yes),
 128            AC_MSG_ERROR([summary failure. Aborting config]); exit 1;,
 129            AC_MSG_WARN([cannot run when cross-compiling]))
 130
 131 LIBS=`echo $LIBS | sed -e 's/ *//g'`
 132 if test x"$LIBS" != x""; then
 133         echo "LIBS: $LIBS"
 134         AC_MSG_WARN([the global \$LIBS variable contains some libraries!])
 135         AC_MSG_WARN([this should not happen, please report to samba-technical@lists.samba.org!])
 136         AC_MSG_ERROR([only _EXT macros from aclocal.m4 should be used!])
 137 fi
 138
 139 dnl Remove -L/usr/lib/? from LDFLAGS and LIBS
 140 LIB_REMOVE_USR_LIB(LDFLAGS)
 141 LIB_REMOVE_USR_LIB(LIBS)
 142
 143 dnl Remove -I/usr/include/? from CFLAGS and CPPFLAGS
 144 CFLAGS_REMOVE_USR_INCLUDE(CFLAGS)
 145 CFLAGS_REMOVE_USR_INCLUDE(CPPFLAGS)
 146
 147 AC_SUBST(ac_default_prefix)
 148
 149 for d in build/smb_build bin include ; do
 150     test -d ${builddir}/$d || AS_MKDIR_P(${builddir}/$d)
 151 done
 152
 153 AC_SUBST(INTERN_LDFLAGS)
 154 AC_SUBST(INSTALL_LINK_FLAGS)
 155 if test $USESHARED = "true";
 156 then
 157         INTERN_LDFLAGS="-L\$(shliboutputdir) -L\${builddir}/bin/static"
 158         INSTALL_LINK_FLAGS="-Wl,-rpath-link,\$(shliboutputdir)";
 159 else
 160         INTERN_LDFLAGS="-L\${builddir}/bin/static -L\$(shliboutputdir)"
 161 fi
 162
 163 builddir_headers=""
 164
 165 if test "x$ac_abs_srcdir" != "x$ac_abs_builddir"
 166 then
 167         builddir_headers="-I\$(builddir)/include -I\$(builddir) -I\$(builddir)/lib ";
 168 fi
 169
 170 CPPFLAGS="$builddir_headers-I\$(srcdir)/include -I\$(srcdir) -I\$(srcdir)/lib -I\$(srcdir)/../lib/replace -I\$(srcdir)/../lib/talloc -I\$(srcdir)/.. -D_SAMBA_BUILD_=4 -DHAVE_CONFIG_H $CPPFLAGS"
 171
 172 SMB_WRITE_PERLVARS(build/smb_build/config.pm)
 173
 174 echo "configure: creating config.mk"
 175 cat >config.mk<<CEOF
 176 # config.mk - Autogenerated by configure, DO NOT EDIT!
 177 $SMB_INFO_EXT_LIBS
 178 $SMB_INFO_SUBSYSTEMS
 179 $SMB_INFO_LIBRARIES
 180 CEOF
 181
 182 SMB_BUILD_RUN(data.mk)
 183 AC_OUTPUT
 184
 185 cmp include/config_tmp.h include/config.h >/dev/null 2>&1
 186 CMP_RET=$?
 187 if test $CMP_RET != 0; then
 188         cp include/config_tmp.h include/config.h
 189 fi
 190
 191 SMB_WRITE_MAKEVARS(mkconfig.mk)
 192
 193 if test $USESHARED = true
 194 then
 195         echo "To run binaries without installing, set the following environment variable:"
 196         echo "$LIB_PATH_VAR=$builddir/bin/shared"
 197 fi
 198
 199 echo
 200 echo "To build Samba, run $MAKE"