selftest/selftest.pl

   1 #!/usr/bin/perl
   2 # Bootstrap Samba and run a number of tests against it.
   3 # Copyright (C) 2005-2010 Jelmer Vernooij <jelmer@samba.org>
   4 # Copyright (C) 2007-2009 Stefan Metzmacher <metze@samba.org>
   5
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 use strict;
  20
  21 use FindBin qw($RealBin $Script);
  22 use File::Spec;
  23 use File::Temp qw(tempfile);
  24 use Getopt::Long;
  25 use POSIX;
  26 use Cwd qw(abs_path);
  27 use lib "$RealBin";
  28 use Subunit;
  29 use SocketWrapper;
  30
  31 eval {
  32 require Time::HiRes;
  33 Time::HiRes->import("time");
  34 };
  35 if ($@) {
  36         print "You don't have Time::Hires installed !\n";
  37 }
  38
  39 my $opt_help = 0;
  40 my $opt_target = "samba";
  41 my $opt_quick = 0;
  42 my $opt_socket_wrapper = 0;
  43 my $opt_socket_wrapper_pcap = undef;
  44 my $opt_socket_wrapper_keep_pcap = undef;
  45 my $opt_random_order = 0;
  46 my $opt_one = 0;
  47 my @opt_exclude = ();
  48 my @opt_include = ();
  49 my $opt_testenv = 0;
  50 my $opt_list = 0;
  51 my $ldap = undef;
  52 my $opt_resetup_env = undef;
  53 my $opt_binary_mapping = "";
  54 my $opt_load_list = undef;
  55 my $opt_libnss_wrapper_so_path = "";
  56 my $opt_libresolv_wrapper_so_path = "";
  57 my $opt_libsocket_wrapper_so_path = "";
  58 my $opt_libuid_wrapper_so_path = "";
  59 my @testlists = ();
  60
  61 my $srcdir = ".";
  62 my $bindir = "./bin";
  63 my $prefix = "./st";
  64
  65 my @includes = ();
  66 my @excludes = ();
  67
  68 sub find_in_list($$)
  69 {
  70         my ($list, $fullname) = @_;
  71
  72         foreach (@$list) {
  73                 if ($fullname =~ /$$_[0]/) {
  74                          return ($$_[1]) if ($$_[1]);
  75                          return "";
  76                 }
  77         }
  78
  79         return undef;
  80 }
  81
  82 sub skip($)
  83 {
  84         my ($name) = @_;
  85
  86         return find_in_list(\@excludes, $name);
  87 }
  88
  89 sub getlog_env($);
  90
  91 sub setup_pcap($)
  92 {
  93         my ($name) = @_;
  94
  95         return unless ($opt_socket_wrapper_pcap);
  96         return unless defined($ENV{SOCKET_WRAPPER_PCAP_DIR});
  97
  98         my $fname = $name;
  99         $fname =~ s%[^abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789\-]%_%g;
 100
 101         my $pcap_file = "$ENV{SOCKET_WRAPPER_PCAP_DIR}/$fname.pcap";
 102
 103         SocketWrapper::setup_pcap($pcap_file);
 104
 105         return $pcap_file;
 106 }
 107
 108 sub cleanup_pcap($$)
 109 {
 110         my ($pcap_file, $exitcode) = @_;
 111
 112         return unless ($opt_socket_wrapper_pcap);
 113         return if ($opt_socket_wrapper_keep_pcap);
 114         return unless ($exitcode == 0);
 115         return unless defined($pcap_file);
 116
 117         unlink($pcap_file);
 118 }
 119
 120 # expand strings from %ENV
 121 sub expand_environment_strings($)
 122 {
 123         my $s = shift;
 124         # we use a reverse sort so we do the longer ones first
 125         foreach my $k (sort { $b cmp $a } keys %ENV) {
 126                 $s =~ s/\$$k/$ENV{$k}/g;
 127         }
 128         return $s;
 129 }
 130
 131 sub run_testsuite($$$$$)
 132 {
 133         my ($envname, $name, $cmd, $i, $totalsuites) = @_;
 134         my $pcap_file = setup_pcap($name);
 135
 136         Subunit::start_testsuite($name);
 137         Subunit::progress_push();
 138         Subunit::report_time(time());
 139         system($cmd);
 140         Subunit::report_time(time());
 141         Subunit::progress_pop();
 142
 143         if ($? == -1) {
 144                 Subunit::progress_pop();
 145                 Subunit::end_testsuite($name, "error", "Unable to run $cmd: $!");
 146                 exit(1);
 147         } elsif ($? & 127) {
 148                 Subunit::end_testsuite($name, "error",
 149                         sprintf("%s died with signal %d, %s coredump\n", $cmd, ($? & 127),  ($? & 128) ? 'with' : 'without'));
 150                 exit(1);
 151         }
 152
 153         my $exitcode = $? >> 8;
 154
 155         my $envlog = getlog_env($envname);
 156         if ($envlog ne "") {
 157                 print "envlog: $envlog\n";
 158         }
 159
 160         print "command: $cmd\n";
 161         printf "expanded command: %s\n", expand_environment_strings($cmd);
 162
 163         if ($exitcode == 0) {
 164                 Subunit::end_testsuite($name, "success");
 165         } else {
 166                 Subunit::end_testsuite($name, "failure", "Exit code was $exitcode");
 167         }
 168
 169         cleanup_pcap($pcap_file, $exitcode);
 170
 171         if (not $opt_socket_wrapper_keep_pcap and defined($pcap_file)) {
 172                 print "PCAP FILE: $pcap_file\n";
 173         }
 174
 175         if ($exitcode != 0) {
 176                 exit(1) if ($opt_one);
 177         }
 178
 179         return $exitcode;
 180 }
 181
 182 sub ShowHelp()
 183 {
 184         print "Samba test runner
 185 Copyright (C) Jelmer Vernooij <jelmer\@samba.org>
 186 Copyright (C) Stefan Metzmacher <metze\@samba.org>
 187
 188 Usage: $Script [OPTIONS] TESTNAME-REGEX
 189
 190 Generic options:
 191  --help                     this help page
 192  --target=samba[3]|win      Samba version to target
 193  --testlist=FILE            file to read available tests from
 194  --exclude=FILE             Exclude tests listed in the file
 195  --include=FILE             Include tests listed in the file
 196
 197 Paths:
 198  --prefix=DIR               prefix to run tests in [st]
 199  --srcdir=DIR               source directory [.]
 200  --bindir=DIR               binaries directory [./bin]
 201
 202 Preload cwrap:
 203  --nss_wrapper_so_path=FILE the nss_wrapper library to preload
 204  --resolv_wrapper_so_path=FILE the resolv_wrapper library to preload
 205  --socket_wrapper_so_path=FILE the socket_wrapper library to preload
 206  --uid_wrapper_so_path=FILE the uid_wrapper library to preload
 207
 208 Target Specific:
 209  --socket-wrapper-pcap      save traffic to pcap directories
 210  --socket-wrapper-keep-pcap keep all pcap files, not just those for tests that
 211                             failed
 212  --socket-wrapper           enable socket wrapper
 213
 214 Samba4 Specific:
 215  --ldap=openldap|fedora-ds  back samba onto specified ldap server
 216
 217 Behaviour:
 218  --quick                    run quick overall test
 219  --one                      abort when the first test fails
 220  --testenv                  run a shell in the requested test environment
 221  --list                     list available tests
 222 ";
 223         exit(0);
 224 }
 225
 226 my $result = GetOptions (
 227                 'help|h|?' => \$opt_help,
 228                 'target=s' => \$opt_target,
 229                 'prefix=s' => \$prefix,
 230                 'socket-wrapper' => \$opt_socket_wrapper,
 231                 'socket-wrapper-pcap' => \$opt_socket_wrapper_pcap,
 232                 'socket-wrapper-keep-pcap' => \$opt_socket_wrapper_keep_pcap,
 233                 'quick' => \$opt_quick,
 234                 'one' => \$opt_one,
 235                 'exclude=s' => \@opt_exclude,
 236                 'include=s' => \@opt_include,
 237                 'srcdir=s' => \$srcdir,
 238                 'bindir=s' => \$bindir,
 239                 'testenv' => \$opt_testenv,
 240                 'list' => \$opt_list,
 241                 'ldap:s' => \$ldap,
 242                 'resetup-environment' => \$opt_resetup_env,
 243                 'testlist=s' => \@testlists,
 244                 'random-order' => \$opt_random_order,
 245                 'load-list=s' => \$opt_load_list,
 246                 'binary-mapping=s' => \$opt_binary_mapping,
 247                 'nss_wrapper_so_path=s' => \$opt_libnss_wrapper_so_path,
 248                 'resolv_wrapper_so_path=s' => \$opt_libresolv_wrapper_so_path,
 249                 'socket_wrapper_so_path=s' => \$opt_libsocket_wrapper_so_path,
 250                 'uid_wrapper_so_path=s' => \$opt_libuid_wrapper_so_path
 251             );
 252
 253 exit(1) if (not $result);
 254
 255 ShowHelp() if ($opt_help);
 256
 257 die("--list and --testenv are mutually exclusive") if ($opt_list and $opt_testenv);
 258
 259 # we want unbuffered output
 260 $| = 1;
 261
 262 my @tests = @ARGV;
 263
 264 # quick hack to disable rpc validation when using valgrind - its way too slow
 265 unless (defined($ENV{VALGRIND})) {
 266         $ENV{VALIDATE} = "validate";
 267         $ENV{MALLOC_CHECK_} = 3;
 268 }
 269
 270 # make all our python scripts unbuffered
 271 $ENV{PYTHONUNBUFFERED} = 1;
 272
 273 my $bindir_abs = abs_path($bindir);
 274
 275 # Backwards compatibility:
 276 if (defined($ENV{TEST_LDAP}) and $ENV{TEST_LDAP} eq "yes") {
 277         if (defined($ENV{FEDORA_DS_ROOT})) {
 278                 $ldap = "fedora-ds";
 279         } else {
 280                 $ldap = "openldap";
 281         }
 282 }
 283
 284 my $torture_maxtime = ($ENV{TORTURE_MAXTIME} or 1200);
 285 if ($ldap) {
 286         # LDAP is slow
 287         $torture_maxtime *= 2;
 288 }
 289
 290 $prefix =~ s+//+/+;
 291 $prefix =~ s+/./+/+;
 292 $prefix =~ s+/$++;
 293
 294 die("using an empty prefix isn't allowed") unless $prefix ne "";
 295
 296 # Ensure we have the test prefix around.
 297 #
 298 # We need restrictive
 299 # permissions on this as some subdirectories in this tree will have
 300 # wider permissions (ie 0777) and this would allow other users on the
 301 # host to subvert the test process.
 302 mkdir($prefix, 0700) unless -d $prefix;
 303 chmod 0700, $prefix;
 304
 305 my $prefix_abs = abs_path($prefix);
 306 my $tmpdir_abs = abs_path("$prefix/tmp");
 307 mkdir($tmpdir_abs, 0777) unless -d $tmpdir_abs;
 308
 309 my $srcdir_abs = abs_path($srcdir);
 310
 311 die("using an empty absolute prefix isn't allowed") unless $prefix_abs ne "";
 312 die("using '/' as absolute prefix isn't allowed") unless $prefix_abs ne "/";
 313
 314 $ENV{PREFIX} = $prefix;
 315 $ENV{KRB5CCNAME} = "$prefix/krb5ticket";
 316 $ENV{PREFIX_ABS} = $prefix_abs;
 317 $ENV{SRCDIR} = $srcdir;
 318 $ENV{SRCDIR_ABS} = $srcdir_abs;
 319 $ENV{BINDIR} = $bindir_abs;
 320
 321 my $tls_enabled = not $opt_quick;
 322 $ENV{TLS_ENABLED} = ($tls_enabled?"yes":"no");
 323
 324 sub prefix_pathvar($$)
 325 {
 326         my ($name, $newpath) = @_;
 327         if (defined($ENV{$name})) {
 328                 $ENV{$name} = "$newpath:$ENV{$name}";
 329         } else {
 330                 $ENV{$name} = $newpath;
 331         }
 332 }
 333 prefix_pathvar("PKG_CONFIG_PATH", "$bindir_abs/pkgconfig");
 334 prefix_pathvar("PYTHONPATH", "$bindir_abs/python");
 335
 336 if ($opt_socket_wrapper_keep_pcap) {
 337         # Socket wrapper keep pcap implies socket wrapper pcap
 338         $opt_socket_wrapper_pcap = 1;
 339 }
 340
 341 if ($opt_socket_wrapper_pcap) {
 342         # Socket wrapper pcap implies socket wrapper
 343         $opt_socket_wrapper = 1;
 344 }
 345
 346 my $ld_preload = $ENV{LD_PRELOAD};
 347
 348 if ($opt_libnss_wrapper_so_path) {
 349         if ($ld_preload) {
 350                 $ld_preload = "$ld_preload:$opt_libnss_wrapper_so_path";
 351         } else {
 352                 $ld_preload = "$opt_libnss_wrapper_so_path";
 353         }
 354 }
 355
 356 if ($opt_libresolv_wrapper_so_path) {
 357         if ($ld_preload) {
 358                 $ld_preload = "$ld_preload:$opt_libresolv_wrapper_so_path";
 359         } else {
 360                 $ld_preload = "$opt_libresolv_wrapper_so_path";
 361         }
 362 }
 363
 364 if ($opt_libsocket_wrapper_so_path) {
 365         if ($ld_preload) {
 366                 $ld_preload = "$ld_preload:$opt_libsocket_wrapper_so_path";
 367         } else {
 368                 $ld_preload = "$opt_libsocket_wrapper_so_path";
 369         }
 370 }
 371
 372 if ($opt_libuid_wrapper_so_path) {
 373         if ($ld_preload) {
 374                 $ld_preload = "$ld_preload:$opt_libuid_wrapper_so_path";
 375         } else {
 376                 $ld_preload = "$opt_libuid_wrapper_so_path";
 377         }
 378 }
 379
 380 $ENV{LD_PRELOAD} = $ld_preload;
 381 print "LD_PRELOAD=$ENV{LD_PRELOAD}\n";
 382
 383 # Enable uid_wrapper globally
 384 $ENV{UID_WRAPPER} = 1;
 385
 386 # Disable RTLD_DEEPBIND hack for Samba bind dlz module
 387 #
 388 # This is needed in order to allow the ldb_*ldap module
 389 # to work with a preloaded socket wrapper.
 390 $ENV{LDB_MODULES_DISABLE_DEEPBIND} = 1;
 391
 392 my $socket_wrapper_dir;
 393 if ($opt_socket_wrapper) {
 394         $socket_wrapper_dir = SocketWrapper::setup_dir("$prefix_abs/w", $opt_socket_wrapper_pcap);
 395         print "SOCKET_WRAPPER_DIR=$socket_wrapper_dir\n";
 396 } elsif (not $opt_list) {
 397          unless ($< == 0) {
 398                  warn("not using socket wrapper, but also not running as root. Will not be able to listen on proper ports");
 399          }
 400 }
 401
 402 my $target;
 403 my $testenv_default = "none";
 404
 405 my %binary_mapping = ();
 406 if ($opt_binary_mapping) {
 407     my @binmapping_list = split(/,/, $opt_binary_mapping);
 408     foreach my $mapping (@binmapping_list) {
 409         my ($bin, $map) = split(/\:/, $mapping);
 410         $binary_mapping{$bin} = $map;
 411     }
 412 }
 413
 414 $ENV{BINARY_MAPPING} = $opt_binary_mapping;
 415
 416 # After this many seconds, the server will self-terminate.  All tests
 417 # must terminate in this time, and testenv will only stay alive this
 418 # long
 419
 420 my $server_maxtime = 7500;
 421 if (defined($ENV{SMBD_MAXTIME}) and $ENV{SMBD_MAXTIME} ne "") {
 422     $server_maxtime = $ENV{SMBD_MAXTIME};
 423 }
 424
 425 unless ($opt_list) {
 426         if ($opt_target eq "samba") {
 427                 $testenv_default = "dc";
 428                 require target::Samba;
 429                 $target = new Samba($bindir, \%binary_mapping, $ldap, $srcdir, $server_maxtime);
 430         } elsif ($opt_target eq "samba3") {
 431                 $testenv_default = "member";
 432                 require target::Samba3;
 433                 $target = new Samba3($bindir, \%binary_mapping, $srcdir_abs, $server_maxtime);
 434         }
 435 }
 436
 437 sub read_test_regexes($)
 438 {
 439         my ($name) = @_;
 440         my @ret = ();
 441         open(LF, "<$name") or die("unable to read $name: $!");
 442         while (<LF>) {
 443                 chomp;
 444                 next if (/^#/);
 445                 if (/^(.*?)([ \t]+)\#([\t ]*)(.*?)$/) {
 446                         push (@ret, [$1, $4]);
 447                 } else {
 448                         s/^(.*?)([ \t]+)\#([\t ]*)(.*?)$//;
 449                         push (@ret, [$_, undef]);
 450                 }
 451         }
 452         close(LF);
 453         return @ret;
 454 }
 455
 456 foreach (@opt_exclude) {
 457         push (@excludes, read_test_regexes($_));
 458 }
 459
 460 foreach (@opt_include) {
 461         push (@includes, read_test_regexes($_));
 462 }
 463
 464 my $interfaces = join(',', ("127.0.0.11/8",
 465                             "127.0.0.12/8",
 466                             "127.0.0.13/8",
 467                             "127.0.0.14/8",
 468                             "127.0.0.15/8",
 469                             "127.0.0.16/8"));
 470
 471 my $clientdir = "$prefix_abs/client";
 472
 473 my $conffile = "$clientdir/client.conf";
 474 $ENV{SMB_CONF_PATH} = $conffile;
 475
 476 sub write_clientconf($$$)
 477 {
 478         my ($conffile, $clientdir, $vars) = @_;
 479
 480         mkdir("$clientdir", 0777) unless -d "$clientdir";
 481
 482         if ( -d "$clientdir/private" ) {
 483                 unlink <$clientdir/private/*>;
 484         } else {
 485                 mkdir("$clientdir/private", 0777);
 486         }
 487
 488         if ( -d "$clientdir/lockdir" ) {
 489                 unlink <$clientdir/lockdir/*>;
 490         } else {
 491                 mkdir("$clientdir/lockdir", 0777);
 492         }
 493
 494         if ( -d "$clientdir/statedir" ) {
 495                 unlink <$clientdir/statedir/*>;
 496         } else {
 497                 mkdir("$clientdir/statedir", 0777);
 498         }
 499
 500         if ( -d "$clientdir/cachedir" ) {
 501                 unlink <$clientdir/cachedir/*>;
 502         } else {
 503                 mkdir("$clientdir/cachedir", 0777);
 504         }
 505
 506         # this is ugly, but the ncalrpcdir needs exactly 0755
 507         # otherwise tests fail.
 508         my $mask = umask;
 509         umask 0022;
 510         if ( -d "$clientdir/ncalrpcdir/np" ) {
 511                 unlink <$clientdir/ncalrpcdir/np/*>;
 512                 rmdir "$clientdir/ncalrpcdir/np";
 513         }
 514         if ( -d "$clientdir/ncalrpcdir" ) {
 515                 unlink <$clientdir/ncalrpcdir/*>;
 516                 rmdir "$clientdir/ncalrpcdir";
 517         }
 518         mkdir("$clientdir/ncalrpcdir", 0755);
 519         umask $mask;
 520
 521         open(CF, ">$conffile");
 522         print CF "[global]\n";
 523         print CF "\tnetbios name = client\n";
 524         if (defined($vars->{DOMAIN})) {
 525                 print CF "\tworkgroup = $vars->{DOMAIN}\n";
 526         }
 527         if (defined($vars->{REALM})) {
 528                 print CF "\trealm = $vars->{REALM}\n";
 529         }
 530         if ($opt_socket_wrapper) {
 531                 print CF "\tinterfaces = $interfaces\n";
 532         }
 533         print CF "
 534         private dir = $clientdir/private
 535         lock dir = $clientdir/lockdir
 536         state directory = $clientdir/statedir
 537         cache directory = $clientdir/cachedir
 538         ncalrpc dir = $clientdir/ncalrpcdir
 539         name resolve order = file bcast
 540         panic action = $RealBin/gdb_backtrace \%d
 541         max xmit = 32K
 542         notify:inotify = false
 543         ldb:nosync = true
 544         system:anonymous = true
 545         client lanman auth = Yes
 546         log level = 1
 547         torture:basedir = $clientdir
 548 #We don't want to pass our self-tests if the PAC code is wrong
 549         gensec:require_pac = true
 550         resolv:host file = $prefix_abs/dns_host_file
 551 #We don't want to run 'speed' tests for very long
 552         torture:timelimit = 1
 553         winbind separator = /
 554 ";
 555         close(CF);
 556 }
 557
 558 my @todo = ();
 559
 560 sub should_run_test($)
 561 {
 562         my $name = shift;
 563         if ($#tests == -1) {
 564                 return 1;
 565         }
 566         for (my $i=0; $i <= $#tests; $i++) {
 567                 if ($name =~ /$tests[$i]/i) {
 568                         return 1;
 569                 }
 570         }
 571         return 0;
 572 }
 573
 574 sub read_testlist($)
 575 {
 576         my ($filename) = @_;
 577
 578         my @ret = ();
 579         open(IN, $filename) or die("Unable to open $filename: $!");
 580
 581         while (<IN>) {
 582                 if (/-- TEST(-LOADLIST|) --\n/) {
 583                         my $supports_loadlist = (defined($1) and $1 eq "-LOADLIST");
 584                         my $name = <IN>;
 585                         $name =~ s/\n//g;
 586                         my $env = <IN>;
 587                         $env =~ s/\n//g;
 588                         my $loadlist;
 589                         if ($supports_loadlist) {
 590                                 $loadlist = <IN>;
 591                                 $loadlist =~ s/\n//g;
 592                         }
 593                         my $cmdline = <IN>;
 594                         $cmdline =~ s/\n//g;
 595                         if (should_run_test($name) == 1) {
 596                                 push (@ret, [$name, $env, $cmdline, $loadlist]);
 597                         }
 598                 } else {
 599                         print;
 600                 }
 601         }
 602         close(IN) or die("Error creating recipe from $filename");
 603         return @ret;
 604 }
 605
 606 if ($#testlists == -1) {
 607         die("No testlists specified");
 608 }
 609
 610 $ENV{SELFTEST_PREFIX} = "$prefix_abs";
 611 $ENV{SELFTEST_TMPDIR} = "$tmpdir_abs";
 612 $ENV{TEST_DATA_PREFIX} = "$tmpdir_abs";
 613 if ($opt_socket_wrapper) {
 614         $ENV{SELFTEST_INTERFACES} = $interfaces;
 615 } else {
 616         $ENV{SELFTEST_INTERFACES} = "";
 617 }
 618 if ($opt_quick) {
 619         $ENV{SELFTEST_QUICK} = "1";
 620 } else {
 621         $ENV{SELFTEST_QUICK} = "";
 622 }
 623 $ENV{SELFTEST_MAXTIME} = $torture_maxtime;
 624
 625 my @available = ();
 626 foreach my $fn (@testlists) {
 627         foreach (read_testlist($fn)) {
 628                 my $name = $$_[0];
 629                 next if (@includes and not defined(find_in_list(\@includes, $name)));
 630                 push (@available, $_);
 631         }
 632 }
 633
 634 my $restricted = undef;
 635 my $restricted_used = {};
 636
 637 if ($opt_load_list) {
 638         $restricted = [];
 639         open(LOAD_LIST, "<$opt_load_list") or die("Unable to open $opt_load_list");
 640         while (<LOAD_LIST>) {
 641                 chomp;
 642                 push (@$restricted, $_);
 643         }
 644         close(LOAD_LIST);
 645 }
 646
 647 my $individual_tests = undef;
 648 $individual_tests = {};
 649
 650 foreach my $testsuite (@available) {
 651         my $name = $$testsuite[0];
 652         my $skipreason = skip($name);
 653         if (defined($restricted)) {
 654                 # Find the testsuite for this test
 655                 my $match = undef;
 656                 foreach my $r (@$restricted) {
 657                         if ($r eq $name) {
 658                                 $individual_tests->{$name} = [];
 659                                 $match = $r;
 660                                 $restricted_used->{$r} = 1;
 661                         } elsif (substr($r, 0, length($name)+1) eq "$name.") {
 662                                 push(@{$individual_tests->{$name}}, $r);
 663                                 $match = $r;
 664                                 $restricted_used->{$r} = 1;
 665                         }
 666                 }
 667                 if ($match) {
 668                         if (defined($skipreason)) {
 669                                 if (not $opt_list) {
 670                                         Subunit::skip_testsuite($name, $skipreason);
 671                                 }
 672                         } else {
 673                                 push(@todo, $testsuite);
 674                         }
 675                 }
 676         } elsif (defined($skipreason)) {
 677                 if (not $opt_list) {
 678                         Subunit::skip_testsuite($name, $skipreason);
 679                 }
 680         } else {
 681                 push(@todo, $testsuite);
 682         }
 683 }
 684
 685 if (defined($restricted)) {
 686         foreach (@$restricted) {
 687                 unless (defined($restricted_used->{$_})) {
 688                         print "No test or testsuite found matching $_\n";
 689                 }
 690         }
 691 } elsif ($#todo == -1) {
 692         print STDERR "No tests to run\n";
 693         exit(1);
 694 }
 695
 696 my $suitestotal = $#todo + 1;
 697
 698 unless ($opt_list) {
 699         Subunit::progress($suitestotal);
 700         Subunit::report_time(time());
 701 }
 702
 703 my $i = 0;
 704 $| = 1;
 705
 706 my %running_envs = ();
 707
 708 sub get_running_env($)
 709 {
 710         my ($name) = @_;
 711
 712         my $envname = $name;
 713
 714         $envname =~ s/:.*//;
 715
 716         return $running_envs{$envname};
 717 }
 718
 719 my @exported_envvars = (
 720         # domain stuff
 721         "DOMAIN",
 722         "REALM",
 723
 724         # domain controller stuff
 725         "DC_SERVER",
 726         "DC_SERVER_IP",
 727         "DC_SERVER_IPV6",
 728         "DC_NETBIOSNAME",
 729         "DC_NETBIOSALIAS",
 730
 731         # domain member
 732         "MEMBER_SERVER",
 733         "MEMBER_SERVER_IP",
 734         "MEMBER_SERVER_IPV6",
 735         "MEMBER_NETBIOSNAME",
 736         "MEMBER_NETBIOSALIAS",
 737
 738         # rpc proxy controller stuff
 739         "RPC_PROXY_SERVER",
 740         "RPC_PROXY_SERVER_IP",
 741         "RPC_PROXY_SERVER_IPV6",
 742         "RPC_PROXY_NETBIOSNAME",
 743         "RPC_PROXY_NETBIOSALIAS",
 744
 745         # domain controller stuff for Vampired DC
 746         "VAMPIRE_DC_SERVER",
 747         "VAMPIRE_DC_SERVER_IP",
 748         "VAMPIRE_DC_SERVER_IPV6",
 749         "VAMPIRE_DC_NETBIOSNAME",
 750         "VAMPIRE_DC_NETBIOSALIAS",
 751
 752         "PROMOTED_DC_SERVER",
 753         "PROMOTED_DC_SERVER_IP",
 754         "PROMOTED_DC_SERVER_IPV6",
 755         "PROMOTED_DC_NETBIOSNAME",
 756         "PROMOTED_DC_NETBIOSALIAS",
 757
 758         # server stuff
 759         "SERVER",
 760         "SERVER_IP",
 761         "SERVER_IPV6",
 762         "NETBIOSNAME",
 763         "NETBIOSALIAS",
 764
 765         # user stuff
 766         "USERNAME",
 767         "USERID",
 768         "PASSWORD",
 769         "DC_USERNAME",
 770         "DC_PASSWORD",
 771
 772         # misc stuff
 773         "KRB5_CONFIG",
 774         "SELFTEST_WINBINDD_SOCKET_DIR",
 775         "WINBINDD_PRIV_PIPE_DIR",
 776         "NMBD_SOCKET_DIR",
 777         "LOCAL_PATH",
 778
 779         # nss_wrapper
 780         "NSS_WRAPPER_PASSWD",
 781         "NSS_WRAPPER_GROUP",
 782
 783         # UID/GID for rfc2307 mapping tests
 784         "UID_RFC2307TEST",
 785         "GID_RFC2307TEST"
 786 );
 787
 788 sub sighandler($)
 789 {
 790         my $signame = shift;
 791
 792         $SIG{INT} = $SIG{QUIT} = $SIG{TERM} = 'DEFAULT';
 793         $SIG{PIPE} = 'IGNORE';
 794
 795         open(STDOUT, ">&STDERR") or die "can't dup STDOUT to STDERR: $!";
 796
 797         print "$0: PID[$$]: Got SIG${signame} teardown environments.\n";
 798         teardown_env($_) foreach(keys %running_envs);
 799         system("pstree -p $$");
 800         print "$0: PID[$$]: Exiting...\n";
 801         exit(1);
 802 };
 803
 804 $SIG{INT} = $SIG{QUIT} = $SIG{TERM} = $SIG{PIPE} = \&sighandler;
 805
 806 sub setup_env($$)
 807 {
 808         my ($name, $prefix) = @_;
 809
 810         my $testenv_vars = undef;
 811
 812         my $envname = $name;
 813         my $option = $name;
 814
 815         $envname =~ s/:.*//;
 816         $option =~ s/^[^:]*//;
 817         $option =~ s/^://;
 818
 819         $option = "client" if $option eq "";
 820
 821         if ($envname eq "none") {
 822                 $testenv_vars = {};
 823         } elsif (defined(get_running_env($envname))) {
 824                 $testenv_vars = get_running_env($envname);
 825                 if (not $testenv_vars->{target}->check_env($testenv_vars)) {
 826                         print $testenv_vars->{target}->getlog_env($testenv_vars);
 827                         $testenv_vars = undef;
 828                 }
 829         } else {
 830                 $testenv_vars = $target->setup_env($envname, $prefix);
 831                 if (defined($testenv_vars) and $testenv_vars eq "UNKNOWN") {
 832                     return $testenv_vars;
 833                 } elsif (defined($testenv_vars) && not defined($testenv_vars->{target})) {
 834                         $testenv_vars->{target} = $target;
 835                 }
 836                 if (not defined($testenv_vars)) {
 837                         warn("$opt_target can't start up known environment '$envname'");
 838                 }
 839         }
 840
 841         return undef unless defined($testenv_vars);
 842
 843         $running_envs{$envname} = $testenv_vars;
 844
 845         if ($option eq "local") {
 846                 SocketWrapper::set_default_iface($testenv_vars->{SOCKET_WRAPPER_DEFAULT_IFACE});
 847                 $ENV{SMB_CONF_PATH} = $testenv_vars->{SERVERCONFFILE};
 848         } elsif ($option eq "client") {
 849                 SocketWrapper::set_default_iface(11);
 850                 write_clientconf($conffile, $clientdir, $testenv_vars);
 851                 $ENV{SMB_CONF_PATH} = $conffile;
 852         } else {
 853                 die("Unknown option[$option] for envname[$envname]");
 854         }
 855
 856         foreach (@exported_envvars) {
 857                 if (defined($testenv_vars->{$_})) {
 858                         $ENV{$_} = $testenv_vars->{$_};
 859                 } else {
 860                         delete $ENV{$_};
 861                 }
 862         }
 863
 864         return $testenv_vars;
 865 }
 866
 867 sub exported_envvars_str($)
 868 {
 869         my ($testenv_vars) = @_;
 870         my $out = "";
 871
 872         foreach (@exported_envvars) {
 873                 next unless defined($testenv_vars->{$_});
 874                 $out .= $_."=".$testenv_vars->{$_}."\n";
 875         }
 876
 877         return $out;
 878 }
 879
 880 sub getlog_env($)
 881 {
 882         my ($envname) = @_;
 883         return "" if ($envname eq "none");
 884         my $env = get_running_env($envname);
 885         return $env->{target}->getlog_env($env);
 886 }
 887
 888 sub check_env($)
 889 {
 890         my ($envname) = @_;
 891         return 1 if ($envname eq "none");
 892         my $env = get_running_env($envname);
 893         return $env->{target}->check_env($env);
 894 }
 895
 896 sub teardown_env($)
 897 {
 898         my ($envname) = @_;
 899         return if ($envname eq "none");
 900         print STDERR "teardown_env($envname)\n";
 901         my $env = get_running_env($envname);
 902         $env->{target}->teardown_env($env);
 903         delete $running_envs{$envname};
 904 }
 905
 906 # This 'global' file needs to be empty when we start
 907 unlink("$prefix_abs/dns_host_file");
 908 unlink("$prefix_abs/hosts");
 909
 910 if ($opt_random_order) {
 911         require List::Util;
 912         my @newtodo = List::Util::shuffle(@todo);
 913         @todo = @newtodo;
 914 }
 915
 916 if ($opt_testenv) {
 917         my $testenv_name = $ENV{SELFTEST_TESTENV};
 918         $testenv_name = $testenv_default unless defined($testenv_name);
 919
 920         my $testenv_vars = setup_env($testenv_name, $prefix);
 921
 922         if (not $testenv_vars or $testenv_vars eq "UNKNOWN") {
 923                 die("Unable to setup environment $testenv_name");
 924         }
 925
 926         $ENV{PIDDIR} = $testenv_vars->{PIDDIR};
 927         $ENV{ENVNAME} = $testenv_name;
 928
 929         my $envvarstr = exported_envvars_str($testenv_vars);
 930
 931         my @term_args = ("echo -e \"
 932 Welcome to the Samba4 Test environment '$testenv_name'
 933
 934 This matches the client environment used in make test
 935 server is pid `cat \$PIDDIR/samba.pid`
 936
 937 Some useful environment variables:
 938 TORTURE_OPTIONS=\$TORTURE_OPTIONS
 939 SMB_CONF_PATH=\$SMB_CONF_PATH
 940
 941 $envvarstr
 942 \" && LD_LIBRARY_PATH=$ENV{LD_LIBRARY_PATH} bash");
 943         my @term = ();
 944         if ($ENV{TERMINAL}) {
 945             @term = ($ENV{TERMINAL});
 946         } else {
 947             @term = ("xterm", "-e");
 948             unshift(@term_args, ("bash", "-c"));
 949         }
 950
 951         system(@term, @term_args);
 952
 953         teardown_env($testenv_name);
 954 } elsif ($opt_list) {
 955         foreach (@todo) {
 956                 my $name = $$_[0];
 957                 my $envname = $$_[1];
 958                 my $cmd = $$_[2];
 959                 my $listcmd = $$_[3];
 960
 961                 unless (defined($listcmd)) {
 962                         warn("Unable to list tests in $name");
 963                         # Rather than ignoring this testsuite altogether, just pretend the entire testsuite is
 964                         # a single "test".
 965                         print "$name\n";
 966                         next;
 967                 }
 968
 969                 system($listcmd);
 970
 971                 if ($? == -1) {
 972                         die("Unable to run $listcmd: $!");
 973                 } elsif ($? & 127) {
 974                         die(sprintf("%s died with signal %d, %s coredump\n", $listcmd, ($? & 127),  ($? & 128) ? 'with' : 'without'));
 975                 }
 976
 977                 my $exitcode = $? >> 8;
 978                 if ($exitcode != 0) {
 979                         die("$cmd exited with exit code $exitcode");
 980                 }
 981         }
 982 } else {
 983         foreach (@todo) {
 984                 $i++;
 985                 my $cmd = $$_[2];
 986                 my $name = $$_[0];
 987                 my $envname = $$_[1];
 988
 989                 my $envvars = setup_env($envname, $prefix);
 990                 if (not defined($envvars)) {
 991                         Subunit::start_testsuite($name);
 992                         Subunit::end_testsuite($name, "error",
 993                                 "unable to set up environment $envname - exiting");
 994                         next;
 995                 } elsif ($envvars eq "UNKNOWN") {
 996                         Subunit::start_testsuite($name);
 997                         Subunit::end_testsuite($name, "skip",
 998                                 "environment $envname is unknown in this test backend - skipping");
 999                         next;
1000                 }
1001
1002                 # Generate a file with the individual tests to run, if the
1003                 # test runner for this test suite supports it.
1004                 if ($individual_tests and $individual_tests->{$name}) {
1005                         if ($$_[3]) {
1006                                 my ($fh, $listid_file) = tempfile(UNLINK => 0);
1007                                 foreach my $test (@{$individual_tests->{$name}}) {
1008                                         print $fh substr($test, length($name)+1) . "\n";
1009                                 }
1010                                 $cmd =~ s/\$LOADLIST/--load-list=$listid_file/g;
1011                         } else {
1012                                 warn("Unable to run individual tests in $name, it does not support --loadlist.");
1013                         }
1014                 }
1015
1016                 run_testsuite($envname, $name, $cmd, $i, $suitestotal);
1017
1018                 teardown_env($envname) if ($opt_resetup_env);
1019         }
1020 }
1021
1022 print "\n";
1023
1024 teardown_env($_) foreach (keys %running_envs);
1025
1026 my $failed = 0;
1027
1028 # if there were any valgrind failures, show them
1029 foreach (<$prefix/valgrind.log*>) {
1030         next unless (-s $_);
1031         print "VALGRIND FAILURE\n";
1032         $failed++;
1033         system("cat $_");
1034 }
1035 exit 0;