cmake/Modules/CheckCCompilerFlagSSP.cmake

   1 # - Check whether the C compiler supports a given flag in the
   2 # context of a stack checking compiler option.
   3
   4 # CHECK_C_COMPILER_FLAG_SSP(FLAG VARIABLE)
   5 #
   6 #  FLAG - the compiler flag
   7 #  VARIABLE - variable to store the result
   8 #
   9 #  This actually calls check_c_source_compiles.
  10 #  See help for CheckCSourceCompiles for a listing of variables
  11 #  that can modify the build.
  12
  13 # Copyright (c) 2006, Alexander Neundorf, <neundorf@kde.org>
  14 #
  15 # Redistribution and use is allowed according to the terms of the BSD license.
  16 # For details see the accompanying COPYING-CMAKE-SCRIPTS file.
  17
  18 # Requires cmake 3.10
  19 #include_guard(GLOBAL)
  20 include(CheckCSourceCompiles)
  21 include(CMakeCheckCompilerFlagCommonPatterns)
  22
  23 macro(CHECK_C_COMPILER_FLAG_SSP _FLAG _RESULT)
  24    set(SAFE_CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
  25    set(CMAKE_REQUIRED_FLAGS "${_FLAG}")
  26
  27    # Normalize locale during test compilation.
  28    set(_CheckCCompilerFlag_LOCALE_VARS LC_ALL LC_MESSAGES LANG)
  29    foreach(v ${_CheckCCompilerFlag_LOCALE_VARS})
  30      set(_CheckCCompilerFlag_SAVED_${v} "$ENV{${v}}")
  31      set(ENV{${v}} C)
  32    endforeach()
  33
  34    CHECK_COMPILER_FLAG_COMMON_PATTERNS(_CheckCCompilerFlag_COMMON_PATTERNS)
  35    check_c_source_compiles("int main(int argc, char **argv) { char buffer[256]; return buffer[argc]=0;}"
  36                            ${_RESULT}
  37                            # Some compilers do not fail with a bad flag
  38                            FAIL_REGEX "command line option .* is valid for .* but not for C" # GNU
  39                            ${_CheckCCompilerFlag_COMMON_PATTERNS})
  40    foreach(v ${_CheckCCompilerFlag_LOCALE_VARS})
  41      set(ENV{${v}} ${_CheckCCompilerFlag_SAVED_${v}})
  42      unset(_CheckCCompilerFlag_SAVED_${v})
  43    endforeach()
  44    unset(_CheckCCompilerFlag_LOCALE_VARS)
  45    unset(_CheckCCompilerFlag_COMMON_PATTERNS)
  46
  47    set(CMAKE_REQUIRED_FLAGS "${SAFE_CMAKE_REQUIRED_FLAGS}")
  48 endmacro(CHECK_C_COMPILER_FLAG_SSP)