configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([rsync],[ ],[https://rsync.samba.org/bug-tracking.html])
   4
   5 AC_C_BIGENDIAN
   6 AC_HEADER_DIRENT
   7 AC_HEADER_SYS_WAIT
   8 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
   9     unistd.h utime.h compat.h sys/param.h ctype.h sys/wait.h sys/stat.h \
  10     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h grp.h \
  11     sys/un.h sys/attr.h arpa/inet.h arpa/nameser.h locale.h sys/types.h \
  12     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h mcheck.h \
  13     sys/acl.h acl/libacl.h attr/xattr.h sys/xattr.h sys/extattr.h dl.h \
  14     popt.h popt/popt.h linux/falloc.h netinet/in_systm.h netgroup.h \
  15     zlib.h xxhash.h openssl/md4.h openssl/md5.h zstd.h lz4.h sys/file.h \
  16     bsd/string.h)
  17 AC_CHECK_HEADERS([netinet/ip.h], [], [], [[#include <netinet/in.h>]])
  18 AC_HEADER_MAJOR_FIXED
  19
  20 AC_CONFIG_MACRO_DIR([m4])
  21 AC_CONFIG_SRCDIR([byteorder.h])
  22 AC_CONFIG_HEADERS([config.h])
  23 AC_PREREQ([2.69])
  24
  25 PACKAGE_VERSION=`sed -n 's/.*RSYNC_VERSION.*"\(.*\)".*/\1/p' <$srcdir/version.h`
  26
  27 AC_MSG_NOTICE([Configuring rsync $PACKAGE_VERSION])
  28
  29 LDFLAGS=${LDFLAGS-""}
  30
  31 AC_CANONICAL_HOST
  32
  33 dnl define the directory for replacement function since AC_LIBOBJ does not
  34 dnl officially support subdirs and fails with automake
  35 AC_CONFIG_LIBOBJ_DIR([lib])
  36
  37 # We must decide this before testing the compiler.
  38
  39 # Please allow this to default to yes, so that your users have more
  40 # chance of getting a useful stack trace if problems occur.
  41
  42 AC_MSG_CHECKING([whether to include debugging symbols])
  43 AC_ARG_ENABLE(debug,
  44         AS_HELP_STRING([--disable-debug],[disable to omit debugging symbols and features]))
  45
  46 if test x"$enable_debug" = x"no"; then
  47     AC_MSG_RESULT(no)
  48     ac_cv_prog_cc_g=no
  49 else
  50     AC_MSG_RESULT([yes])
  51     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  52     # leave ac_cv_prog_cc_g alone; AC_PROG_CC will try to include -g if it can
  53 fi
  54
  55 dnl Checks for programs.
  56 AC_PROG_CC
  57 AC_PROG_CPP
  58 AC_PROG_CXX
  59 AC_PROG_AWK
  60 AC_PROG_EGREP
  61 AC_PROG_INSTALL
  62 AC_PROG_MKDIR_P
  63 AC_SUBST(SHELL)
  64 AC_PATH_PROG([PERL], [perl])
  65 AC_PATH_PROG([PYTHON3], [python3])
  66
  67 AC_DEFINE([_GNU_SOURCE], 1,
  68           [Define _GNU_SOURCE so that we get all necessary prototypes])
  69
  70 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  71         AC_MSG_WARN([rsync requires an ANSI C compiler and you do not seem to have one])
  72 fi
  73
  74 no_lib=''
  75 err_msg=''
  76 nl='
  77 '
  78
  79 AC_ARG_ENABLE(profile,
  80         AS_HELP_STRING([--enable-profile],[enable to turn on CPU profiling]))
  81 if test x"$enable_profile" = x"yes"; then
  82         CFLAGS="$CFLAGS -pg"
  83 fi
  84
  85 AC_MSG_CHECKING([if md2man can create manpages])
  86 if test x"$ac_cv_path_PYTHON3" = x; then
  87     AC_MSG_RESULT(no - python3 not found)
  88     md2man_works=no
  89 else
  90     md2man_out=`"$srcdir/md2man" --test "$srcdir/rsync-ssl.1.md" 2>&1`
  91     if test $? = 0; then
  92         AC_MSG_RESULT(yes)
  93         md2man_works=yes
  94     else
  95         AC_MSG_RESULT(no)
  96         md2man_works=no
  97         echo "$md2man_out"
  98     fi
  99 fi
 100
 101 AC_MSG_CHECKING([if we require man-page building])
 102 AC_ARG_ENABLE([md2man],
 103         AS_HELP_STRING([--disable-md2man],[disable to omit manpage creation]))
 104 if test x"$enable_md2man" != x"no"; then
 105     if test -f "$srcdir/rsync.1"; then
 106         AC_MSG_RESULT(optional)
 107     else
 108         AC_MSG_RESULT(required)
 109         if test x"$md2man_works" = x"no"; then
 110             err_msg="$err_msg$nl- You need python3 and either the cmarkgfm OR commonmark python3 lib in order"
 111             err_msg="$err_msg$nl  to build manpages based on the git source (manpages are included in the"
 112             err_msg="$err_msg$nl  official release tar files)."
 113             no_lib="$no_lib md2man"
 114         fi
 115     fi
 116     MAKE_MAN=man
 117 else
 118     AC_MSG_RESULT(no)
 119 fi
 120
 121 # Specifically, this turns on panic_action handling.
 122 AC_ARG_ENABLE(maintainer-mode,
 123         AS_HELP_STRING([--enable-maintainer-mode],[enable to turn on extra debug features]))
 124 if test x"$enable_maintainer_mode" = x"yes"; then
 125         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
 126 fi
 127
 128 # This is needed for our included version of popt.  Kind of silly, but
 129 # I don't want our version too far out of sync.
 130 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
 131
 132 # If GCC, turn on warnings.
 133 if test x"$GCC" = x"yes"; then
 134         CFLAGS="$CFLAGS -Wall -W"
 135 fi
 136
 137 AC_ARG_WITH(openssl-conf,
 138         AS_HELP_STRING([--with-openssl-conf=PATH],[set default OPENSSL_CONF path for rsync]))
 139 case "$with_openssl_conf" in
 140     *[^-/a-zA-Z0-9.,=@+_]*) AC_MSG_ERROR([Invalid path given to --with-openssl-conf]) ;;
 141     /*) CFLAGS="$CFLAGS -DSET_OPENSSL_CONF=$with_openssl_conf" ;;
 142     no|'') ;;
 143     yes) AC_MSG_ERROR([No path given to --with-openssl-conf]) ;;
 144     *) AC_MSG_ERROR([Non absolute path given to --with-openssl-conf]) ;;
 145 esac
 146
 147 AC_ARG_WITH(rrsync,
 148         AS_HELP_STRING([--with-rrsync],[also install the rrsync script and its manpage]))
 149 if test x"$with_rrsync" != x"yes"; then
 150     with_rrsync=no
 151 else
 152     MAKE_RRSYNC='rrsync'
 153     MAKE_RRSYNC_1='rrsync.1'
 154     GEN_RRSYNC='rrsync.1 rrsync.1.html'
 155 fi
 156 AC_SUBST(with_rrsync)
 157
 158 AC_ARG_WITH(included-popt,
 159         AS_HELP_STRING([--with-included-popt],[use bundled popt library, not from system]))
 160
 161 AC_ARG_WITH(included-zlib,
 162         AS_HELP_STRING([--with-included-zlib],[use bundled zlib library, not from system]))
 163
 164 AC_ARG_WITH(secluded-args,
 165         AS_HELP_STRING([--with-secluded-args],[make --secluded-args option the default]))
 166 if test x"$with_secluded_args" = x"yes"; then
 167         AC_DEFINE_UNQUOTED(RSYNC_USE_SECLUDED_ARGS, 1, [Define to 1 if --secluded-args should be the default])
 168 fi
 169
 170 AC_ARG_WITH(rsync-path,
 171         AS_HELP_STRING([--with-rsync-path=PATH],[set default --rsync-path to PATH (default: rsync)]),
 172         [ RSYNC_PATH="$with_rsync_path" ],
 173         [ RSYNC_PATH="rsync" ])
 174
 175 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
 176
 177 AC_ARG_WITH(rsyncd-conf,
 178         AS_HELP_STRING([--with-rsyncd-conf=PATH],[set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
 179         [ if test ! -z "$with_rsyncd_conf" ; then
 180                 case $with_rsyncd_conf in
 181                         yes|no)
 182                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 183                                 ;;
 184                         /*)
 185                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
 186                                 ;;
 187                         *)
 188                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 189                                 ;;
 190                 esac
 191         else
 192                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 193         fi ],
 194         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 195
 196 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 197
 198 AC_ARG_WITH(rsh,
 199         AS_HELP_STRING([--with-rsh=CMD],[set remote shell command to CMD (default: ssh)]))
 200
 201 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 202 if test x$HAVE_REMSH = x1; then
 203         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 204 fi
 205
 206 if test x"$with_rsh" != x; then
 207         RSYNC_RSH="$with_rsh"
 208 else
 209         RSYNC_RSH="ssh"
 210 fi
 211 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 212
 213 # Some programs on solaris are only found in /usr/xpg4/bin (or work better than others versions).
 214 AC_PATH_PROG(SHELL_PATH, sh, /bin/sh, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 215 AC_PATH_PROG(FAKEROOT_PATH, fakeroot, /usr/bin/fakeroot, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 216
 217 AC_ARG_WITH(nobody-user,
 218     AS_HELP_STRING([--with-nobody-user=USER],[set the default unprivileged user (default nobody)]),
 219     [ NOBODY_USER="$with_nobody_user" ],
 220     [ NOBODY_USER="nobody" ])
 221
 222 AC_ARG_WITH(nobody-group,
 223     AS_HELP_STRING([--with-nobody-group=GROUP],[set the default unprivileged group (default nobody or nogroup)]),
 224     [ NOBODY_GROUP="$with_nobody_group" ])
 225
 226 if test x"$with_nobody_group" = x; then
 227     AC_MSG_CHECKING([the group for user "nobody"])
 228     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 229         NOBODY_GROUP=nobody
 230     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 231         NOBODY_GROUP=nogroup
 232     else
 233         NOBODY_GROUP=nobody # test for others?
 234     fi
 235     AC_MSG_RESULT($NOBODY_GROUP)
 236 fi
 237
 238 AC_DEFINE_UNQUOTED(NOBODY_USER, "$NOBODY_USER", [unprivileged user--e.g. nobody])
 239 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 240
 241 # rolling-checksum SIMD optimizations
 242 ROLL_SIMD=
 243
 244 AC_MSG_CHECKING([whether to enable rolling-checksum SIMD optimizations])
 245 AC_ARG_ENABLE(roll-simd,
 246     AS_HELP_STRING([--enable-roll-simd],[enable/disable to control rolling-checksum SIMD optimizations (requires c++)]))
 247
 248 # Clag is crashing with -g -O2, so we'll get rid of -g for now.
 249 CXXFLAGS=`echo "$CXXFLAGS" | sed 's/-g //'`
 250 m4_define(SIMD_X86_64_TEST, [[#include <stdio.h>
 251 #if HAVE_STDLIB_H
 252 #include <stdlib.h>
 253 #endif
 254 #include <immintrin.h>
 255 __attribute__ ((target("default"))) int test_ssse3(int x) { return x; }
 256 __attribute__ ((target("default"))) int test_sse2(int x) { return x; }
 257 __attribute__ ((target("default"))) int test_avx2(int x) { return x; }
 258 __attribute__ ((target("ssse3"))) int test_ssse3(int x) { return x; }
 259 __attribute__ ((target("sse2"))) int test_sse2(int x) { return x; }
 260 __attribute__ ((target("avx2"))) int test_avx2(int x) { return x; }
 261 typedef long long __m128i_u __attribute__((__vector_size__(16), __may_alias__, __aligned__(1)));
 262 typedef long long __m256i_u __attribute__((__vector_size__(32), __may_alias__, __aligned__(1)));
 263 __attribute__ ((target("default"))) void more_testing(char* buf, int len) { }
 264 __attribute__ ((target("ssse3"))) void more_testing(char* buf, int len)
 265 {
 266     int i;
 267     for (i = 0; i < (len-32); i+=32) {
 268         __m128i in8_1, in8_2;
 269         in8_1 = _mm_lddqu_si128((__m128i_u*)&buf[i]);
 270         in8_2 = _mm_lddqu_si128((__m128i_u*)&buf[i + 16]);
 271     }
 272 }
 273 ]])
 274
 275 if test x"$enable_roll_simd" = x""; then
 276     case "$host_os" in
 277         *linux*) ;;
 278         *) enable_roll_simd=no ;;
 279     esac
 280 fi
 281
 282 if test x"$enable_roll_simd" != x"no"; then
 283     # For x86-64 SIMD, g++ >=5 or clang++ >=7 is required
 284     if test x"$host_cpu" = x"x86_64" || test x"$host_cpu" = x"amd64"; then
 285         AC_LANG(C++)
 286         if test x"$host" = x"$build"; then
 287             AC_RUN_IFELSE([AC_LANG_PROGRAM([SIMD_X86_64_TEST],[[if (test_ssse3(42) != 42 || test_sse2(42) != 42 || test_avx2(42) != 42) exit(1);]])],
 288                 [CXX_OK=yes],[CXX_OK=no])
 289         else
 290             AC_COMPILE_IFELSE([AC_LANG_PROGRAM([SIMD_X86_64_TEST])],[CXX_OK=yes],[CXX_OK=no])
 291         fi
 292         AC_LANG(C)
 293         if test x"$CXX_OK" = x"yes"; then
 294             # AC_MSG_RESULT() is called below.
 295             ROLL_SIMD="$host_cpu"
 296         elif test x"$enable_roll_simd" = x"yes"; then
 297             AC_MSG_RESULT(error)
 298             AC_MSG_ERROR(The rolling-checksum SIMD compilation test failed.
 299 Omit --enable-roll-simd to continue without it.)
 300         fi
 301     elif test x"$enable_roll_simd" = x"yes"; then
 302         AC_MSG_RESULT(unavailable)
 303         AC_MSG_ERROR(The rolling-checksum SIMD optimizations are currently x86_64|amd64 only.
 304 Omit --enable-roll-simd to continue without it.)
 305     fi
 306 fi
 307
 308 if test x"$ROLL_SIMD" != x""; then
 309     AC_MSG_RESULT([yes ($ROLL_SIMD)])
 310     AC_DEFINE(USE_ROLL_SIMD, 1, [Define to 1 to enable rolling-checksum SIMD optimizations])
 311     ROLL_SIMD='$(ROLL_SIMD_'"$ROLL_SIMD)"
 312     # We only use c++ for its target attribute dispatching, disable unneeded bulky features
 313     CXXFLAGS="$CXXFLAGS -fno-exceptions -fno-rtti"
 314     # Apple often has "g++" as a symlink for clang. Try to find out the truth.
 315     CXX_VERSION=`$CXX --version 2>/dev/null | head -n 2`
 316     case "$CXX_VERSION" in
 317     *clang*) CXXFLAGS="$CXXFLAGS -fno-slp-vectorize" ;; # avoid a performance hit
 318     esac
 319 else
 320     AC_MSG_RESULT(no)
 321 fi
 322
 323 AC_SUBST(ROLL_SIMD)
 324
 325 AC_MSG_CHECKING([if assembler accepts noexecstack])
 326 OLD_CFLAGS="$CFLAGS"
 327 CFLAGS="$CFLAGS -Wa,--noexecstack"
 328 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ ]], [[return 0;]])],
 329 [ NOEXECSTACK='-Wa,--noexecstack' ; AC_MSG_RESULT(yes) ],
 330 [ NOEXECSTACK='' ; AC_MSG_RESULT(no) ])
 331 CFLAGS="$OLD_CFLAGS"
 332 AC_SUBST(NOEXECSTACK)
 333
 334 # arrgh. libc in some old debian version screwed up the largefile
 335 # stuff, getting byte range locking wrong
 336 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 337 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 338 #define _FILE_OFFSET_BITS 64
 339 $ac_includes_default
 340 #ifdef HAVE_FCNTL_H
 341 # include <fcntl.h>
 342 #elif defined HAVE_SYS_FCNTL_H
 343 # include <sys/fcntl.h>
 344 #endif
 345 #ifdef HAVE_SYS_WAIT_H
 346 #include <sys/wait.h>
 347 #endif
 348
 349 int main(void)
 350 {
 351         struct flock lock;
 352         int status;
 353         char tpl[32] = "/tmp/locktest.XXXXXX";
 354         int fd = mkstemp(tpl);
 355         if (fd < 0) {
 356                 strcpy(tpl, "conftest.dat");
 357                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 358         }
 359
 360         lock.l_type = F_WRLCK;
 361         lock.l_whence = SEEK_SET;
 362         lock.l_start = 0;
 363         lock.l_len = 1;
 364         lock.l_pid = 0;
 365         fcntl(fd,F_SETLK,&lock);
 366         if (fork() == 0) {
 367                 lock.l_start = 1;
 368                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 369         }
 370         wait(&status);
 371         unlink(tpl);
 372         return WEXITSTATUS(status);
 373 }
 374 ]])],[rsync_cv_HAVE_BROKEN_LARGEFILE=yes],[rsync_cv_HAVE_BROKEN_LARGEFILE=no],[rsync_cv_HAVE_BROKEN_LARGEFILE=cross])])
 375 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 376    AC_SYS_LARGEFILE
 377 fi
 378
 379 AC_MSG_CHECKING([whether to enable ipv6])
 380 AC_ARG_ENABLE(ipv6,
 381 AS_HELP_STRING([--disable-ipv6],[disable to omit ipv6 support]),
 382 [ case "$enableval" in
 383   no)
 384         AC_MSG_RESULT(no)
 385         ;;
 386   *)    AC_MSG_RESULT(yes)
 387         AC_DEFINE(INET6, 1, [true if you have IPv6])
 388         ;;
 389   esac ],
 390
 391   AC_RUN_IFELSE([AC_LANG_SOURCE([[ /* AF_INET6 availability check */
 392 #include <stdlib.h>
 393 #include <sys/types.h>
 394 #include <sys/socket.h>
 395 main()
 396 {
 397    if (socket(AF_INET6, SOCK_STREAM, 0) < 0)
 398      exit(1);
 399    else
 400      exit(0);
 401 }
 402 ]])],
 403   [AC_MSG_RESULT(yes)
 404   AC_DEFINE(INET6, 1, true if you have IPv6)],
 405   [AC_MSG_RESULT(no)],
 406   [AC_MSG_RESULT(no)]
 407 ))
 408
 409 dnl Do you want to disable use of locale functions
 410 AC_ARG_ENABLE([locale],
 411         AS_HELP_STRING([--disable-locale],[disable to omit locale features]))
 412 AH_TEMPLATE([CONFIG_LOCALE],
 413 [Undefine if you do not want locale features.  By default this is defined.])
 414 if test x"$enable_locale" != x"no"; then
 415         AC_DEFINE(CONFIG_LOCALE)
 416 fi
 417
 418 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 419 case $host_os in
 420         *cygwin* ) AC_MSG_RESULT(yes)
 421                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 422                             [Define to 1 if sockets need to be shutdown])
 423                    ;;
 424                * ) AC_MSG_RESULT(no);;
 425 esac
 426
 427 AC_MSG_CHECKING([whether to enable use of openssl crypto library])
 428 AC_ARG_ENABLE([openssl],
 429         AS_HELP_STRING([--disable-openssl],[disable to omit openssl crypto library]))
 430 AH_TEMPLATE([USE_OPENSSL],
 431 [Undefine if you do not want to use openssl crypto library.  By default this is defined.])
 432 if test x"$enable_openssl" != x"no"; then
 433     if test x"$ac_cv_header_openssl_md4_h" = x"yes" && test x"$ac_cv_header_openssl_md5_h" = x"yes"; then
 434       AC_MSG_RESULT(yes)
 435       AC_SEARCH_LIBS(EVP_MD_CTX_copy, crypto,
 436           [AC_DEFINE(USE_OPENSSL)
 437            enable_openssl=yes],
 438           [err_msg="$err_msg$nl- Failed to find EVP_MD_CTX_copy function in openssl crypto lib.";
 439            no_lib="$no_lib openssl"])
 440     else
 441         AC_MSG_RESULT(no)
 442         err_msg="$err_msg$nl- Failed to find openssl/md4.h and openssl/md5.h for openssl crypto lib support."
 443         no_lib="$no_lib openssl"
 444     fi
 445     if test x"$enable_md5_asm" != x"yes"; then
 446         enable_md5_asm=no
 447     fi
 448 else
 449     AC_MSG_RESULT(no)
 450 fi
 451
 452 MD5_ASM=
 453
 454 AC_MSG_CHECKING([whether to enable MD5 ASM optimizations])
 455 AC_ARG_ENABLE(md5-asm,
 456     AS_HELP_STRING([--enable-md5-asm],[enable/disable to control MD5 ASM optimizations]))
 457
 458 if test x"$enable_md5_asm" = x""; then
 459     case "$host_os" in
 460         *linux*) ;;
 461         *) enable_md5_asm=no ;;
 462     esac
 463 fi
 464
 465 if test x"$enable_md5_asm" != x"no"; then
 466     if test x"$host_cpu" = x"x86_64" || test x"$host_cpu" = x"amd64"; then
 467         MD5_ASM="$host_cpu"
 468     elif test x"$enable_md5_asm" = x"yes"; then
 469         AC_MSG_RESULT(unavailable)
 470         AC_MSG_ERROR(The ASM optimizations are currently x86_64|amd64 only.
 471 Omit --enable-md5-asm to continue without it.)
 472     fi
 473 fi
 474
 475 if test x"$MD5_ASM" != x""; then
 476     AC_MSG_RESULT([yes ($MD5_ASM)])
 477     AC_DEFINE(USE_MD5_ASM, 1, [Define to 1 to enable MD5 ASM optimizations])
 478     MD5_ASM='$(MD5_ASM_'"$MD5_ASM)"
 479 else
 480     AC_MSG_RESULT(no)
 481 fi
 482
 483 AC_SUBST(MD5_ASM)
 484
 485 ROLL_ASM=
 486
 487 AC_MSG_CHECKING([whether to enable rolling-checksum ASM optimizations])
 488 AC_ARG_ENABLE(roll-asm,
 489     AS_HELP_STRING([--enable-roll-asm],[enable/disable to control rolling-checksum ASM optimizations (requires --enable-roll-simd)]))
 490
 491 if test x"$ROLL_SIMD" = x""; then
 492     enable_roll_asm=no
 493 fi
 494
 495 if test x"$enable_roll_asm" = x"yes"; then
 496     ROLL_ASM="$host_cpu"
 497     AC_MSG_RESULT([yes ($ROLL_ASM)])
 498     AC_DEFINE(USE_ROLL_ASM, 1, [Define to 1 to enable rolling-checksum ASM optimizations (requires --enable-roll-simd)])
 499     ROLL_ASM='$(ROLL_ASM_'"$ROLL_ASM)"
 500 else
 501     AC_MSG_RESULT(no)
 502 fi
 503
 504 AC_SUBST(ROLL_ASM)
 505
 506 AC_MSG_CHECKING([whether to enable xxhash checksum support])
 507 AC_ARG_ENABLE([xxhash],
 508         AS_HELP_STRING([--disable-xxhash],[disable to omit xxhash checksums]))
 509 AH_TEMPLATE([SUPPORT_XXHASH],
 510 [Undefine if you do not want xxhash checksums.  By default this is defined.])
 511 if test x"$enable_xxhash" != x"no"; then
 512     if test x"$ac_cv_header_xxhash_h" = x"yes"; then
 513         AC_MSG_RESULT(yes)
 514         AC_SEARCH_LIBS(XXH64_createState, xxhash,
 515             [AC_DEFINE(SUPPORT_XXHASH)],
 516             [err_msg="$err_msg$nl- Failed to find XXH64_createState function in xxhash lib.";
 517              no_lib="$no_lib xxhash"])
 518     else
 519         AC_MSG_RESULT(no)
 520         err_msg="$err_msg$nl- Failed to find xxhash.h for xxhash checksum support.";
 521         no_lib="$no_lib xxhash"
 522     fi
 523 else
 524     AC_MSG_RESULT(no)
 525 fi
 526
 527 AC_MSG_CHECKING([whether to enable zstd compression])
 528 AC_ARG_ENABLE([zstd],
 529         AS_HELP_STRING([--disable-zstd], [disable to omit zstd compression]))
 530 AH_TEMPLATE([SUPPORT_ZSTD],
 531 [Undefine if you do not want zstd compression.  By default this is defined.])
 532 if test x"$enable_zstd" != x"no"; then
 533     if test x"$ac_cv_header_zstd_h" = x"yes"; then
 534         AC_MSG_RESULT(yes)
 535         AC_SEARCH_LIBS(ZSTD_minCLevel, zstd,
 536             [AC_DEFINE(SUPPORT_ZSTD)],
 537             [err_msg="$err_msg$nl- Failed to find ZSTD_minCLevel function in zstd lib.";
 538              no_lib="$no_lib zstd"])
 539     else
 540         AC_MSG_RESULT(no)
 541         err_msg="$err_msg$nl- Failed to find zstd.h for zstd compression support.";
 542         no_lib="$no_lib zstd"
 543     fi
 544 else
 545     AC_MSG_RESULT(no)
 546 fi
 547
 548 AC_MSG_CHECKING([whether to enable LZ4 compression])
 549 AC_ARG_ENABLE([lz4],
 550         AS_HELP_STRING([--disable-lz4], [disable to omit LZ4 compression]))
 551 AH_TEMPLATE([SUPPORT_LZ4],
 552 [Undefine if you do not want LZ4 compression.  By default this is defined.])
 553 if test x"$enable_lz4" != x"no"; then
 554     if test x"$ac_cv_header_lz4_h" = x"yes"; then
 555         AC_MSG_RESULT(yes)
 556         AC_SEARCH_LIBS(LZ4_compress_default, lz4,
 557             [AC_DEFINE(SUPPORT_LZ4)],
 558             [err_msg="$err_msg$nl- Failed to find LZ4_compress_default function in lz4 lib.";
 559              no_lib="$no_lib lz4"])
 560     else
 561         AC_MSG_RESULT(no)
 562         err_msg="$err_msg$nl- Failed to find lz4.h for lz4 compression support."
 563         no_lib="$no_lib lz4"
 564     fi
 565 else
 566     AC_MSG_RESULT(no)
 567 fi
 568
 569 if test x"$no_lib" != x; then
 570     echo ""
 571     echo "Configure found the following issues:"
 572     echo "$err_msg"
 573     echo ""
 574     echo "See the INSTALL file for hints on how to install the missing libraries and/or"
 575     echo "how to generate (or fetch) manpages:"
 576     echo "    https://github.com/WayneD/rsync/blob/master/INSTALL.md"
 577     echo ""
 578     echo "To disable one or more features, the relevant configure options are:"
 579     for lib in $no_lib; do
 580         echo "    --disable-$lib"
 581     done
 582     echo ""
 583     AC_MSG_ERROR(Aborting configure run)
 584 fi
 585
 586 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
 587 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 588 #ifdef HAVE_SYS_TYPES_H
 589 #include <sys/types.h>
 590 #endif
 591 #ifdef MAJOR_IN_MKDEV
 592 #include <sys/mkdev.h>
 593 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
 594 #  define makedev mkdev
 595 # endif
 596 #elif defined MAJOR_IN_SYSMACROS
 597 #include <sys/sysmacros.h>
 598 #endif
 599
 600 int main(void)
 601 {
 602         dev_t dev = makedev(0, 5, 7);
 603         if (major(dev) != 5 || minor(dev) != 7)
 604                 return 1;
 605         return 0;
 606 }
 607 ]])],[rsync_cv_MAKEDEV_TAKES_3_ARGS=yes],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no])])
 608 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
 609    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
 610 fi
 611
 612 AC_CHECK_SIZEOF(int)
 613 AC_CHECK_SIZEOF(long)
 614 AC_CHECK_SIZEOF(long long)
 615 AC_CHECK_SIZEOF(short)
 616 AC_CHECK_SIZEOF(int16_t)
 617 AC_CHECK_SIZEOF(uint16_t)
 618 AC_CHECK_SIZEOF(int32_t)
 619 AC_CHECK_SIZEOF(uint32_t)
 620 AC_CHECK_SIZEOF(int64_t)
 621 AC_CHECK_SIZEOF(off_t)
 622 AC_CHECK_SIZEOF(off64_t)
 623 AC_CHECK_SIZEOF(time_t)
 624 AC_CHECK_SIZEOF(char*)
 625
 626 AC_C_INLINE
 627
 628 AC_TYPE_LONG_DOUBLE_WIDER
 629 ac_cv_c_long_double=$ac_cv_type_long_double_wider
 630 if test $ac_cv_c_long_double = yes; then
 631   AC_DEFINE([HAVE_LONG_DOUBLE],[1],[Define to 1 if the type `long double' works and has more range or precision than `double'.])
 632 fi
 633
 634 AC_TYPE_UID_T
 635 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
 636 if test "$cross_compiling" = no; then
 637     AC_TYPE_GETGROUPS
 638 else
 639     AC_DEFINE([GETGROUPS_T],[gid_t],[Define to the type of elements in the array set by `getgroups'. Usually this is either `int' or `gid_t'.])
 640 fi
 641 AC_CHECK_MEMBERS([struct stat.st_rdev,
 642                   struct stat.st_mtimensec,
 643                   struct stat.st_mtimespec.tv_nsec,
 644                   struct stat.st_mtim.tv_nsec],,,[
 645 #ifdef HAVE_SYS_TYPES_H
 646 #include <sys/types.h>
 647 #endif
 648 #ifdef HAVE_SYS_STAT_H
 649 #include <sys/stat.h>
 650 #endif
 651 #ifdef HAVE_UNISTD_H
 652 #include <unistd.h>
 653 #endif])
 654
 655 TYPE_SOCKLEN_T
 656
 657 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 658     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]], [[int i = errno]])],[rsync_cv_errno=yes],[rsync_cv_have_errno_decl=no])])
 659 if test x"$rsync_cv_errno" = x"yes"; then
 660    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 661 fi
 662
 663 # The following test taken from the cvs sources
 664 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 665 # These need checks to be before checks for any other functions that
 666 #    might be in the same libraries.
 667 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 668 # libsocket.so which has a bad implementation of gethostbyname (it
 669 # only looks in /etc/hosts), so we only look for -lsocket if we need
 670 # it.
 671 AC_CHECK_FUNCS(connect)
 672 if test x"$ac_cv_func_connect" = x"no"; then
 673     case "$LIBS" in
 674     *-lnsl*) ;;
 675     *) AC_CHECK_LIB(nsl_s, printf) ;;
 676     esac
 677     case "$LIBS" in
 678     *-lnsl*) ;;
 679     *) AC_CHECK_LIB(nsl, printf) ;;
 680     esac
 681     case "$LIBS" in
 682     *-lsocket*) ;;
 683     *) AC_CHECK_LIB(socket, connect) ;;
 684     esac
 685     case "$LIBS" in
 686     *-linet*) ;;
 687     *) AC_CHECK_LIB(inet, connect) ;;
 688     esac
 689     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 690     dnl has been cached.
 691     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 692        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 693         # ac_cv_func_connect=yes
 694         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 695         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 696     fi
 697 fi
 698
 699 AC_SEARCH_LIBS(inet_ntop, resolv)
 700
 701 # For OS X, Solaris, HP-UX, etc.: figure out if -liconv is needed.  We'll
 702 # accept either iconv_open or libiconv_open, since some include files map
 703 # the former to the latter.
 704 AC_SEARCH_LIBS(iconv_open, iconv)
 705 AC_SEARCH_LIBS(libiconv_open, iconv)
 706
 707 AC_MSG_CHECKING([for iconv declaration])
 708 AC_CACHE_VAL(am_cv_proto_iconv, [
 709     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 710 #if HAVE_STDLIB_H
 711 #include <stdlib.h>
 712 #endif
 713 #include <iconv.h>
 714 extern
 715 #ifdef __cplusplus
 716 "C"
 717 #endif
 718 #if defined(__STDC__) || defined(__cplusplus)
 719 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 720 #else
 721 size_t iconv();
 722 #endif
 723 ]], [[]])],[am_cv_proto_iconv_arg1=""],[am_cv_proto_iconv_arg1="const"])
 724       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 725     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed 's/( /(/'`
 726 AC_MSG_RESULT([$]{ac_t:-
 727          }[$]am_cv_proto_iconv)
 728 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 729                    [Define as const if the declaration of iconv() needs const.])
 730
 731 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 732
 733 AC_REPLACE_FUNCS([inet_ntop inet_pton])
 734
 735 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
 736 AC_HAVE_TYPE([struct sockaddr_storage], [
 737 #ifdef HAVE_SYS_TYPES_H
 738 #include <sys/types.h>
 739 #endif
 740 #ifdef HAVE_SYS_SOCKET_H
 741 #include <sys/socket.h>
 742 #endif])
 743
 744 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 745 #   builtin getaddrinfo if one of the defines don't exist
 746 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 747                rsync_cv_HAVE_GETADDR_DEFINES,[
 748                         AC_EGREP_CPP(yes, [
 749 #ifdef HAVE_SYS_TYPES_H
 750 #include <sys/types.h>
 751 #endif
 752 #ifdef HAVE_SYS_SOCKET_H
 753 #include <sys/socket.h>
 754 #endif
 755 #ifdef HAVE_NETDB_H
 756 #include <netdb.h>
 757 #endif
 758 #ifdef AI_PASSIVE
 759 yes
 760 #endif],
 761                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 762                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 763 AS_IF([test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" && test x"$ac_cv_type_struct_addrinfo" = x"yes"],[
 764         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 765         # something else so we must include <netdb.h> to get the
 766         # redefinition.
 767         AC_CHECK_FUNCS(getaddrinfo, ,
 768                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 769                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 770 #ifdef HAVE_SYS_TYPES_H
 771 #include <sys/types.h>
 772 #endif
 773 #ifdef HAVE_SYS_SOCKET_H
 774 #include <sys/socket.h>
 775 #endif
 776 #include <netdb.h>]], [[getaddrinfo(NULL, NULL, NULL, NULL);]])],[AC_MSG_RESULT([yes])
 777                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 778                                 [Define to 1 if you have the "getaddrinfo" function and required types.])],[AC_MSG_RESULT([no])
 779                         AC_LIBOBJ([getaddrinfo])])])
 780     ],[AC_LIBOBJ([getaddrinfo])])
 781
 782 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 783                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 784                 [],
 785                 [
 786 #ifdef HAVE_SYS_TYPES_H
 787 #include <sys/types.h>
 788 #endif
 789 #ifdef HAVE_SYS_SOCKET_H
 790 #include <sys/socket.h>
 791 #endif
 792 ])
 793
 794 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 795                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 796                 [],
 797                 [
 798 #ifdef HAVE_SYS_TYPES_H
 799 #include <sys/types.h>
 800 #endif
 801 #ifdef HAVE_SYS_SOCKET_H
 802 #include <sys/socket.h>
 803 #endif
 804 #include <netinet/in.h>
 805 ])
 806
 807 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 808                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 809                 [],
 810                 [
 811 #ifdef HAVE_SYS_TYPES_H
 812 #include <sys/types.h>
 813 #endif
 814 #ifdef HAVE_SYS_SOCKET_H
 815 #include <sys/socket.h>
 816 #endif
 817 #include <netinet/in.h>
 818 ])
 819
 820 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 821                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 822                 [],
 823                 [
 824 #ifdef HAVE_SYS_TYPES_H
 825 #include <sys/types.h>
 826 #endif
 827 #ifdef HAVE_SYS_SOCKET_H
 828 #include <sys/socket.h>
 829 #endif
 830 #include <netinet/in.h>
 831 ])
 832
 833 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
 834 #if HAVE_SYS_TYPES_H
 835 # include <sys/types.h>
 836 #endif
 837 #if HAVE_SYS_STAT_H
 838 # include <sys/stat.h>
 839 #endif
 840 #if STDC_HEADERS
 841 # include <stdlib.h>
 842 # include <stddef.h>
 843 #else
 844 # if HAVE_STDLIB_H
 845 #  include <stdlib.h>
 846 # endif
 847 #endif
 848 ])
 849
 850 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 851 #
 852 AC_CHECK_FUNCS(strcasecmp)
 853 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 854     AC_CHECK_LIB(resolv, strcasecmp)
 855 fi
 856
 857 AC_CHECK_FUNCS(aclsort)
 858 if test x"$ac_cv_func_aclsort" = x"no"; then
 859     AC_CHECK_LIB(sec, aclsort)
 860 fi
 861
 862 dnl At the moment we don't test for a broken memcmp(), because all we
 863 dnl need to do is test for equality, not comparison, and it seems that
 864 dnl every platform has a memcmp that can do at least that.
 865 dnl AC_FUNC_MEMCMP
 866
 867 AC_FUNC_UTIME_NULL
 868 AC_FUNC_ALLOCA
 869 AC_CHECK_FUNCS(waitpid wait4 getcwd chown chmod lchmod mknod mkfifo \
 870     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 871     chflags getattrlist mktime innetgr linkat \
 872     memmove lchown vsnprintf snprintf vasprintf asprintf setsid strpbrk \
 873     strlcat strlcpy strtol mallinfo mallinfo2 getgroups setgroups geteuid getegid \
 874     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 875     seteuid strerror putenv iconv_open locale_charset nl_langinfo getxattr \
 876     extattr_get_link sigaction sigprocmask setattrlist getgrouplist \
 877     initgroups utimensat posix_fallocate attropen setvbuf nanosleep usleep \
 878     setenv unsetenv)
 879
 880 dnl cygwin iconv.h defines iconv_open as libiconv_open
 881 if test x"$ac_cv_func_iconv_open" != x"yes"; then
 882     AC_CHECK_FUNC(libiconv_open, [ac_cv_func_iconv_open=yes; AC_DEFINE(HAVE_ICONV_OPEN, 1)])
 883 fi
 884
 885 dnl Preallocation stuff (also fallocate, posix_fallocate function tests above):
 886
 887 AC_CACHE_CHECK([for useable fallocate],rsync_cv_have_fallocate,[
 888 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <fcntl.h>
 889 #ifdef HAVE_SYS_TYPES_H
 890 #include <sys/types.h>
 891 #endif]], [[fallocate(0, 0, 0, 0);]])],[rsync_cv_have_fallocate=yes],[rsync_cv_have_fallocate=no])])
 892 if test x"$rsync_cv_have_fallocate" = x"yes"; then
 893     AC_DEFINE(HAVE_FALLOCATE, 1, [Define to 1 if you have the fallocate function and it compiles and links without error])
 894 fi
 895
 896 AC_MSG_CHECKING([for FALLOC_FL_PUNCH_HOLE])
 897 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 898         #define _GNU_SOURCE 1
 899         #include <linux/falloc.h>
 900         #ifndef FALLOC_FL_PUNCH_HOLE
 901         #error FALLOC_FL_PUNCH_HOLE is missing
 902         #endif
 903     ]])], [
 904         AC_MSG_RESULT([yes])
 905         AC_DEFINE([HAVE_FALLOC_FL_PUNCH_HOLE], [1], [Define if FALLOC_FL_PUNCH_HOLE is available.])
 906     ], [
 907         AC_MSG_RESULT([no])
 908     ]
 909 )
 910
 911 AC_MSG_CHECKING([for FALLOC_FL_ZERO_RANGE])
 912 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 913         #define _GNU_SOURCE 1
 914         #include <linux/falloc.h>
 915         #ifndef FALLOC_FL_ZERO_RANGE
 916         #error FALLOC_FL_ZERO_RANGE is missing
 917         #endif
 918     ]])], [
 919         AC_MSG_RESULT([yes])
 920         AC_DEFINE([HAVE_FALLOC_FL_ZERO_RANGE], [1], [Define if FALLOC_FL_ZERO_RANGE is available.])
 921     ], [
 922         AC_MSG_RESULT([no])
 923     ]
 924 )
 925
 926 AC_CACHE_CHECK([for SYS_fallocate],rsync_cv_have_sys_fallocate,[
 927 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/syscall.h>
 928 #ifdef HAVE_UNISTD_H
 929 #include <unistd.h>
 930 #endif
 931 #ifdef HAVE_SYS_TYPES_H
 932 #include <sys/types.h>
 933 #endif]], [[syscall(SYS_fallocate, 0, 0, (loff_t)0, (loff_t)0);]])],[rsync_cv_have_sys_fallocate=yes],[rsync_cv_have_sys_fallocate=no])])
 934 if test x"$rsync_cv_have_sys_fallocate" = x"yes"; then
 935     AC_DEFINE(HAVE_SYS_FALLOCATE, 1, [Define to 1 if you have the SYS_fallocate syscall number])
 936 fi
 937
 938 if test x"$ac_cv_func_posix_fallocate" = x"yes"; then
 939     AC_MSG_CHECKING([whether posix_fallocate is efficient])
 940     case $host_os in
 941     *cygwin*)
 942         AC_MSG_RESULT(yes)
 943         AC_DEFINE(HAVE_EFFICIENT_POSIX_FALLOCATE, 1,
 944                   [Define if posix_fallocate is efficient (Cygwin)])
 945         ;;
 946     *)
 947         AC_MSG_RESULT(no)
 948         ;;
 949     esac
 950 fi
 951
 952 dnl End of preallocation stuff
 953
 954 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 955 if test $ac_cv_func_getpgrp = yes; then
 956     AC_FUNC_GETPGRP
 957 fi
 958
 959 AC_ARG_ENABLE(iconv-open,
 960     AS_HELP_STRING([--disable-iconv-open],[disable to avoid all use of iconv_open()]),
 961     [], [enable_iconv_open=$ac_cv_func_iconv_open])
 962
 963 if test x"$enable_iconv_open" != x"no"; then
 964     AC_DEFINE(USE_ICONV_OPEN, 1, [Define to 1 if you want rsync to make use of iconv_open()])
 965 fi
 966
 967 AC_ARG_ENABLE(iconv,
 968     AS_HELP_STRING([--disable-iconv],[disable to omit the --iconv option]),
 969     [], [enable_iconv=$enable_iconv_open])
 970 AH_TEMPLATE([ICONV_OPTION],
 971 [Define if you want the --iconv option.  Specifying a value will set the
 972 default iconv setting (a NULL means no --iconv processing by default).])
 973 if test x"$enable_iconv" != x"no"; then
 974         if test x"$enable_iconv" = x"yes"; then
 975                 AC_DEFINE(ICONV_OPTION, NULL)
 976         else
 977                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
 978         fi
 979         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
 980 fi
 981
 982 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
 983   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 984 #if HAVE_UNISTD_H
 985 # include <unistd.h>
 986 #endif
 987 #include <stdlib.h>
 988 #include <errno.h>
 989 int main(void) {
 990         char const *dangling_symlink = "conftest.dangle";
 991         unlink(dangling_symlink);
 992         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 993         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) return 1;
 994         return 0;
 995     }]])],[rsync_cv_chown_modifies_symlink=yes],[rsync_cv_chown_modifies_symlink=no],[rsync_cv_chown_modifies_symlink=no])])
 996 if test $rsync_cv_chown_modifies_symlink = yes; then
 997   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 998 fi
 999
1000 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
1001   AC_RUN_IFELSE([AC_LANG_SOURCE([[
1002 #ifdef HAVE_FCNTL_H
1003 # include <fcntl.h>
1004 #elif defined HAVE_SYS_FCNTL_H
1005 # include <sys/fcntl.h>
1006 #endif
1007 #if HAVE_UNISTD_H
1008 # include <unistd.h>
1009 #endif
1010 #include <stdlib.h>
1011 #include <errno.h>
1012 #define FILENAME "conftest.dangle"
1013 int main(void) {
1014         unlink(FILENAME);
1015         if (symlink("conftest.no-such", FILENAME) < 0) abort();
1016         unlink(FILENAME "2");
1017 #ifdef HAVE_LINKAT
1018         if (linkat(AT_FDCWD, FILENAME, AT_FDCWD, FILENAME "2", 0) < 0) return 1;
1019 #else
1020         if (link(FILENAME, FILENAME "2") < 0) return 1;
1021 #endif
1022         return 0;
1023     }]])],[rsync_cv_can_hardlink_symlink=yes],[rsync_cv_can_hardlink_symlink=no],[rsync_cv_can_hardlink_symlink=no])])
1024 if test $rsync_cv_can_hardlink_symlink = yes; then
1025   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
1026 fi
1027
1028 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
1029   AC_RUN_IFELSE([AC_LANG_SOURCE([[
1030 #if HAVE_UNISTD_H
1031 # include <unistd.h>
1032 #endif
1033 #ifdef HAVE_SYS_STAT_H
1034 #include <sys/stat.h>
1035 #endif
1036 #include <stdlib.h>
1037 #include <errno.h>
1038 #define FILENAME "conftest.fifi"
1039 int main(void) {
1040         unlink(FILENAME);
1041         if (mkfifo(FILENAME, 0777) < 0) abort();
1042         unlink(FILENAME "2");
1043         if (link(FILENAME, FILENAME "2") < 0) return 1;
1044         return 0;
1045     }]])],[rsync_cv_can_hardlink_special=yes],[rsync_cv_can_hardlink_special=no],[rsync_cv_can_hardlink_special=no])])
1046 if test $rsync_cv_can_hardlink_special = yes; then
1047     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
1048 fi
1049
1050 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
1051 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1052 #ifdef HAVE_SYS_TYPES_H
1053 #include <sys/types.h>
1054 #endif
1055 #ifdef HAVE_SYS_SOCKET_H
1056 #include <sys/socket.h>
1057 #endif
1058
1059 int main(void) {
1060        int fd[2];
1061        return (socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1;
1062 }]])],[rsync_cv_HAVE_SOCKETPAIR=yes],[rsync_cv_HAVE_SOCKETPAIR=no],[rsync_cv_HAVE_SOCKETPAIR=cross])])
1063 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
1064     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
1065 fi
1066
1067 AC_REPLACE_FUNCS([getpass])
1068
1069 if test x"$with_included_popt" != x"yes"; then
1070     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
1071 fi
1072 if test x"$ac_cv_header_popt_popt_h" = x"yes"; then
1073     # If the system has /usr/include/popt/popt.h, we enable the
1074     # included popt because an attempt to "#include <popt/popt.h>"
1075     # would use our included header file anyway (due to -I.), and
1076     # might conflict with the system popt.
1077     with_included_popt=yes
1078 elif test x"$ac_cv_header_popt_h" != x"yes"; then
1079     with_included_popt=yes
1080 fi
1081
1082 AC_MSG_CHECKING([whether to use included libpopt])
1083 if test x"$with_included_popt" = x"yes"; then
1084     AC_MSG_RESULT($srcdir/popt)
1085     BUILD_POPT='$(popt_OBJS)'
1086     CFLAGS="-I$srcdir/popt $CFLAGS"
1087     if test x"$ALLOCA" != x
1088     then
1089         # this can be removed when/if we add an included alloca.c;
1090         #  see autoconf documentation on AC_FUNC_ALLOCA
1091         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
1092     fi
1093 else
1094     AC_MSG_RESULT(no)
1095 fi
1096
1097 # We default to using our zlib unless --with-included-zlib=no is given.
1098 if test x"$with_included_zlib" != x"no"; then
1099     with_included_zlib=yes
1100 elif test x"$ac_cv_header_zlib_h" != x"yes"; then
1101     with_included_zlib=yes
1102 fi
1103 if test x"$with_included_zlib" != x"yes"; then
1104     AC_CHECK_LIB(z, deflateParams, , [with_included_zlib=yes])
1105 fi
1106
1107 AC_MSG_CHECKING([whether to use included zlib])
1108 if test x"$with_included_zlib" = x"yes"; then
1109     AC_MSG_RESULT($srcdir/zlib)
1110     BUILD_ZLIB='$(zlib_OBJS)'
1111     CFLAGS="-I$srcdir/zlib $CFLAGS"
1112 else
1113     AC_DEFINE(EXTERNAL_ZLIB, 1, [Define to 1 if using external zlib])
1114     AC_MSG_RESULT(no)
1115 fi
1116
1117 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
1118 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[signed char *s = (signed char *)""]])],[rsync_cv_SIGNED_CHAR_OK=yes],[rsync_cv_SIGNED_CHAR_OK=no])])
1119 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
1120     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
1121 fi
1122
1123 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
1124 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1125 #ifdef HAVE_SYS_TYPES_H
1126 #include <sys/types.h>
1127 #endif
1128 #include <dirent.h>
1129 int main(void) { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
1130 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
1131 di->d_name[0] == 0) return 0; return 1;} ]])],[rsync_cv_HAVE_BROKEN_READDIR=yes],[rsync_cv_HAVE_BROKEN_READDIR=no],[rsync_cv_HAVE_BROKEN_READDIR=cross])])
1132 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
1133     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
1134 fi
1135
1136 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
1137 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1138 #ifdef HAVE_SYS_TYPES_H
1139 #include <sys/types.h>
1140 #endif
1141 #include <utime.h>]], [[struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; return utime("foo.c",&tbuf);]])],[rsync_cv_HAVE_STRUCT_UTIMBUF=yes],[rsync_cv_HAVE_STRUCT_UTIMBUF=no])])
1142 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
1143     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
1144 fi
1145
1146 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
1147 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/time.h>
1148 #ifdef HAVE_UNISTD_H
1149 #include <unistd.h>
1150 #endif]], [[struct timeval tv; return gettimeofday(&tv, NULL);]])],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=no])])
1151 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
1152     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
1153 fi
1154
1155 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
1156 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1157 #ifdef HAVE_SYS_TYPES_H
1158 #include <sys/types.h>
1159 #endif
1160 #include <stdarg.h>
1161 #include <stdio.h>
1162 #if HAVE_STDLIB_H
1163 #include <stdlib.h>
1164 #endif
1165 #include <string.h>
1166 void foo(const char *format, ...) {
1167        va_list ap;
1168        int len;
1169        static char buf[] = "12345678901234567890";
1170
1171        va_start(ap, format);
1172        len = vsnprintf(0, 0, format, ap);
1173        va_end(ap);
1174        if (len != 5) exit(1);
1175
1176        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
1177 }
1178 int main(void) { foo("hello"); return 0; }
1179 ]])],[rsync_cv_HAVE_C99_VSNPRINTF=yes],[rsync_cv_HAVE_C99_VSNPRINTF=no],[rsync_cv_HAVE_C99_VSNPRINTF=cross])])
1180 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
1181     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
1182 fi
1183
1184
1185 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
1186 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1187 #ifdef HAVE_SYS_TYPES_H
1188 #include <sys/types.h>
1189 #endif
1190 #include <sys/stat.h>
1191 #ifdef HAVE_UNISTD_H
1192 #include <unistd.h>
1193 #endif
1194 int main(void) {
1195   struct stat st;
1196   char tpl[20]="/tmp/test.XXXXXX";
1197   int fd = mkstemp(tpl);
1198   if (fd == -1) return 1;
1199   unlink(tpl);
1200   if (fstat(fd, &st) != 0) return 1;
1201   if ((st.st_mode & 0777) != 0600) return 1;
1202   return 0;
1203 }]])],[rsync_cv_HAVE_SECURE_MKSTEMP=yes],[rsync_cv_HAVE_SECURE_MKSTEMP=no],[rsync_cv_HAVE_SECURE_MKSTEMP=cross])])
1204 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
1205     case $host_os in
1206     hpux*)
1207         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
1208         dnl so we noisily skip using it.  See HP change request JAGaf34426
1209         dnl for details. (sbonds)
1210         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
1211         ;;
1212     *)
1213         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
1214         ;;
1215     esac
1216 fi
1217
1218
1219 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
1220 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1221 #include <stdio.h>
1222 #include <sys/stat.h>
1223 #include <errno.h>
1224 #if HAVE_UNISTD_H
1225 # include <unistd.h>
1226 #endif
1227 int main(void) { int rc, ec; char *fn = "fifo-test";
1228 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
1229 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1230 return 0;}]])],[rsync_cv_MKNOD_CREATES_FIFOS=yes],[rsync_cv_MKNOD_CREATES_FIFOS=no],[rsync_cv_MKNOD_CREATES_FIFOS=cross])])
1231 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
1232     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
1233 fi
1234
1235 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
1236 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1237 #include <stdio.h>
1238 #include <sys/stat.h>
1239 #include <errno.h>
1240 #if HAVE_UNISTD_H
1241 # include <unistd.h>
1242 #endif
1243 int main(void) { int rc, ec; char *fn = "sock-test";
1244 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
1245 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1246 return 0;}]])],[rsync_cv_MKNOD_CREATES_SOCKETS=yes],[rsync_cv_MKNOD_CREATES_SOCKETS=no],[rsync_cv_MKNOD_CREATES_SOCKETS=cross])])
1247 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
1248     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
1249 fi
1250
1251 #
1252 # The following test was mostly taken from the tcl/tk plus patches
1253 #
1254 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
1255 rm -rf conftest*
1256 cat > conftest.$ac_ext <<EOF
1257 int main(void) { return 0; }
1258 EOF
1259 ${CC-cc} -c -o conftest..o conftest.$ac_ext
1260 if test -f conftest..o; then
1261     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
1262 else
1263     rsync_cv_DASHC_WORKS_WITH_DASHO=no
1264 fi
1265 rm -rf conftest*
1266 ])
1267 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
1268     OBJ_SAVE="#"
1269     OBJ_RESTORE="#"
1270     CC_SHOBJ_FLAG='-o $@'
1271 else
1272     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
1273     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
1274     CC_SHOBJ_FLAG=""
1275 fi
1276
1277 AC_SUBST(OBJ_SAVE)
1278 AC_SUBST(OBJ_RESTORE)
1279 AC_SUBST(CC_SHOBJ_FLAG)
1280 AC_SUBST(BUILD_POPT)
1281 AC_SUBST(BUILD_ZLIB)
1282 AC_SUBST(MAKE_RRSYNC)
1283 AC_SUBST(MAKE_RRSYNC_1)
1284 AC_SUBST(GEN_RRSYNC)
1285 AC_SUBST(MAKE_MAN)
1286
1287 AC_CHECK_FUNCS(_acl __acl _facl __facl)
1288 #################################################
1289 # check for ACL support
1290
1291 AC_MSG_CHECKING([whether to support ACLs])
1292 AC_ARG_ENABLE(acl-support,
1293         AS_HELP_STRING([--disable-acl-support],[disable to omit ACL support]))
1294
1295 if test x"$enable_acl_support" = x"no"; then
1296     AC_MSG_RESULT(no)
1297 else
1298     case "$host_os" in
1299     *sysv5*)
1300         AC_MSG_RESULT(Using UnixWare ACLs)
1301         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
1302         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
1303         ;;
1304     solaris*)
1305         AC_MSG_RESULT(Using solaris ACLs)
1306         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
1307         AC_DEFINE(SUPPORT_ACLS, 1)
1308         ;;
1309     *irix*)
1310         AC_MSG_RESULT(Using IRIX ACLs)
1311         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
1312         AC_DEFINE(SUPPORT_ACLS, 1)
1313         ;;
1314     *aix*)
1315         AC_MSG_RESULT(Using AIX ACLs)
1316         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
1317         AC_DEFINE(SUPPORT_ACLS, 1)
1318         ;;
1319     *osf*)
1320         AC_MSG_RESULT(Using Tru64 ACLs)
1321         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
1322         AC_DEFINE(SUPPORT_ACLS, 1)
1323         LIBS="$LIBS -lpacl"
1324         ;;
1325     darwin*)
1326         AC_MSG_RESULT(Using OS X ACLs)
1327         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
1328         AC_DEFINE(SUPPORT_ACLS, 1)
1329         ;;
1330     *hpux*|*nsk*)
1331         AC_MSG_RESULT(Using HPUX ACLs)
1332         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
1333         AC_DEFINE(SUPPORT_ACLS, 1)
1334         ;;
1335     *)
1336         AC_MSG_RESULT(running tests:)
1337         AC_CHECK_LIB(acl,acl_get_file)
1338         AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
1339             AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1340 #ifdef HAVE_SYS_TYPES_H
1341 #include <sys/types.h>
1342 #endif
1343 #ifdef HAVE_SYS_ACL_H
1344 #include <sys/acl.h>
1345 #endif]], [[ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);]])],[samba_cv_HAVE_POSIX_ACLS=yes],[samba_cv_HAVE_POSIX_ACLS=no])])
1346         AC_MSG_CHECKING(ACL test results)
1347         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
1348             AC_MSG_RESULT(Using posix ACLs)
1349             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
1350             AC_DEFINE(SUPPORT_ACLS, 1)
1351             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
1352                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1353 #ifdef HAVE_SYS_TYPES_H
1354 #include <sys/types.h>
1355 #endif
1356 #ifdef HAVE_SYS_ACL_H
1357 #include <sys/acl.h>
1358 #endif]], [[ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);]])],[samba_cv_HAVE_ACL_GET_PERM_NP=yes],[samba_cv_HAVE_ACL_GET_PERM_NP=no])])
1359             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
1360                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
1361             fi
1362         else
1363             if test x"$enable_acl_support" = x"yes"; then
1364                 AC_MSG_ERROR(Failed to find ACL support)
1365             else
1366                 AC_MSG_RESULT(No ACL support found)
1367             fi
1368         fi
1369         ;;
1370     esac
1371 fi
1372
1373 #################################################
1374 # check for extended attribute support
1375 AC_MSG_CHECKING(whether to support extended attributes)
1376 AC_ARG_ENABLE(xattr-support,
1377     AS_HELP_STRING([--disable-xattr-support],[disable to omit extended attributes]),
1378     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link$ac_cv_func_attropen" in
1379         *yes*) enable_xattr_support=maybe ;;
1380         *) enable_xattr_support=no ;;
1381         esac])
1382 AH_TEMPLATE([SUPPORT_XATTRS],
1383 [Define to 1 to add support for extended attributes])
1384 if test x"$enable_xattr_support" = x"no"; then
1385     AC_MSG_RESULT(no)
1386 else
1387     case "$host_os" in
1388     *linux*|*netbsd*|*cygwin*)
1389         AC_MSG_RESULT(Using Linux xattrs)
1390         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs (or equivalent)])
1391         AC_DEFINE(SUPPORT_XATTRS, 1)
1392         AC_DEFINE(NO_SYMLINK_USER_XATTRS, 1, [True if symlinks do not support user xattrs])
1393         AC_CHECK_LIB(attr,getxattr)
1394         ;;
1395     darwin*)
1396         AC_MSG_RESULT(Using OS X xattrs)
1397         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
1398         AC_DEFINE(SUPPORT_XATTRS, 1)
1399         AC_DEFINE(NO_DEVICE_XATTRS, 1, [True if device files do not support xattrs])
1400         AC_DEFINE(NO_SPECIAL_XATTRS, 1, [True if special files do not support xattrs])
1401         ;;
1402     freebsd*)
1403         AC_MSG_RESULT(Using FreeBSD extattrs)
1404         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
1405         AC_DEFINE(SUPPORT_XATTRS, 1)
1406         ;;
1407     solaris*)
1408         AC_MSG_RESULT(Using Solaris xattrs)
1409         AC_DEFINE(HAVE_SOLARIS_XATTRS, 1, [True if you have Solaris xattrs])
1410         AC_DEFINE(SUPPORT_XATTRS, 1)
1411         AC_DEFINE(NO_SYMLINK_XATTRS, 1, [True if symlinks do not support xattrs])
1412         ;;
1413     *)
1414         if test x"$enable_xattr_support" = x"yes"; then
1415             AC_MSG_ERROR(Failed to find extended attribute support)
1416         else
1417             AC_MSG_RESULT(No extended attribute support found)
1418         fi
1419         ;;
1420     esac
1421 fi
1422
1423 if test x"$enable_acl_support" = x"no" || test x"$enable_xattr_support" = x"no" || test x"$enable_iconv" = x"no"; then
1424     AC_MSG_CHECKING([whether $CC supports -Wno-unused-parameter])
1425     OLD_CFLAGS="$CFLAGS"
1426     CFLAGS="$CFLAGS -Wno-unused-parameter"
1427     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]], [[printf("hello\n");]])],[rsync_warn_flag=yes],[rsync_warn_flag=no])
1428     AC_MSG_RESULT([$rsync_warn_flag])
1429     if test x"$rsync_warn_flag" = x"no"; then
1430         CFLAGS="$OLD_CFLAGS"
1431     fi
1432 fi
1433
1434 case "$CC" in
1435 ' checker'*|checker*)
1436     AC_DEFINE(FORCE_FD_ZERO_MEMSET, 1, [Used to make "checker" understand that FD_ZERO() clears memory.])
1437     ;;
1438 esac
1439
1440 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
1441 AC_OUTPUT
1442
1443 AC_MSG_RESULT()
1444 AC_MSG_RESULT([    rsync $PACKAGE_VERSION configuration successful])
1445 AC_MSG_RESULT()