selftest/target/Samba3.pm

   1 #!/usr/bin/perl
   2 # Bootstrap Samba and run a number of tests against it.
   3 # Copyright (C) 2005-2007 Jelmer Vernooij <jelmer@samba.org>
   4 # Published under the GNU GPL, v3 or later.
   5
   6 package Samba3;
   7
   8 use strict;
   9 use Cwd qw(abs_path);
  10 use FindBin qw($RealBin);
  11 use POSIX;
  12 use target::Samba;
  13
  14 sub new($$) {
  15         my ($classname, $bindir, $binary_mapping, $srcdir, $exeext, $server_maxtime) = @_;
  16         $exeext = "" unless defined($exeext);
  17         my $self = { vars => {},
  18                      bindir => $bindir,
  19                      binary_mapping => $binary_mapping,
  20                      srcdir => $srcdir,
  21                      exeext => $exeext,
  22                      server_maxtime => $server_maxtime
  23         };
  24         bless $self;
  25         return $self;
  26 }
  27
  28 sub teardown_env($$)
  29 {
  30         my ($self, $envvars) = @_;
  31
  32         my $smbdpid = read_pid($envvars, "smbd");
  33         my $nmbdpid = read_pid($envvars, "nmbd");
  34         my $winbinddpid = read_pid($envvars, "winbindd");
  35
  36         $self->stop_sig_term($smbdpid);
  37         $self->stop_sig_term($nmbdpid);
  38         $self->stop_sig_term($winbinddpid);
  39
  40         sleep(2);
  41
  42         $self->stop_sig_kill($smbdpid);
  43         $self->stop_sig_kill($nmbdpid);
  44         $self->stop_sig_kill($winbinddpid);
  45
  46         return 0;
  47 }
  48
  49 sub getlog_env_app($$$)
  50 {
  51         my ($self, $envvars, $name) = @_;
  52
  53         my $title = "$name LOG of: $envvars->{NETBIOSNAME}\n";
  54         my $out = $title;
  55
  56         open(LOG, "<".$envvars->{$name."_TEST_LOG"});
  57
  58         seek(LOG, $envvars->{$name."_TEST_LOG_POS"}, SEEK_SET);
  59         while (<LOG>) {
  60                 $out .= $_;
  61         }
  62         $envvars->{$name."_TEST_LOG_POS"} = tell(LOG);
  63         close(LOG);
  64
  65         return "" if $out eq $title;
  66
  67         return $out;
  68 }
  69
  70 sub getlog_env($$)
  71 {
  72         my ($self, $envvars) = @_;
  73         my $ret = "";
  74
  75         $ret .= $self->getlog_env_app($envvars, "SMBD");
  76         $ret .= $self->getlog_env_app($envvars, "NMBD");
  77         $ret .= $self->getlog_env_app($envvars, "WINBINDD");
  78
  79         return $ret;
  80 }
  81
  82 sub check_env($$)
  83 {
  84         my ($self, $envvars) = @_;
  85
  86         # TODO ...
  87         return 1;
  88 }
  89
  90 sub setup_env($$$)
  91 {
  92         my ($self, $envname, $path) = @_;
  93
  94         if ($envname eq "s3dc") {
  95                 return $self->setup_s3dc("$path/s3dc");
  96         } elsif ($envname eq "secshare") {
  97                 return $self->setup_secshare("$path/secshare");
  98         } elsif ($envname eq "maptoguest") {
  99                 return $self->setup_maptoguest("$path/maptoguest");
 100         } elsif ($envname eq "ktest") {
 101                 return $self->setup_ktest("$path/ktest");
 102         } elsif ($envname eq "secserver") {
 103                 if (not defined($self->{vars}->{s3dc})) {
 104                         if (not defined($self->setup_s3dc("$path/s3dc"))) {
 105                                 return undef;
 106                         }
 107                 }
 108                 return $self->setup_secserver("$path/secserver", $self->{vars}->{s3dc});
 109         } elsif ($envname eq "member") {
 110                 if (not defined($self->{vars}->{s3dc})) {
 111                         if (not defined($self->setup_s3dc("$path/s3dc"))) {
 112                                 return undef;
 113                         }
 114                 }
 115                 return $self->setup_member("$path/member", $self->{vars}->{s3dc});
 116         } else {
 117                 return undef;
 118         }
 119 }
 120
 121 sub setup_s3dc($$)
 122 {
 123         my ($self, $path) = @_;
 124
 125         print "PROVISIONING S3DC...";
 126
 127         my $s3dc_options = "
 128         domain master = yes
 129         domain logons = yes
 130         lanman auth = yes
 131 ";
 132
 133         my $vars = $self->provision($path,
 134                                     "LOCALS3DC2",
 135                                     2,
 136                                     "locals3dc2pass",
 137                                     $s3dc_options);
 138
 139         $vars or return undef;
 140
 141         $self->check_or_start($vars,
 142                                "yes", "yes", "yes");
 143
 144         if (not $self->wait_for_start($vars)) {
 145                return undef;
 146         }
 147
 148         $vars->{DC_SERVER} = $vars->{SERVER};
 149         $vars->{DC_SERVER_IP} = $vars->{SERVER_IP};
 150         $vars->{DC_NETBIOSNAME} = $vars->{NETBIOSNAME};
 151         $vars->{DC_USERNAME} = $vars->{USERNAME};
 152         $vars->{DC_PASSWORD} = $vars->{PASSWORD};
 153
 154         $self->{vars}->{s3dc} = $vars;
 155
 156         return $vars;
 157 }
 158
 159 sub setup_member($$$)
 160 {
 161         my ($self, $prefix, $s3dcvars) = @_;
 162
 163         print "PROVISIONING MEMBER...";
 164
 165         my $member_options = "
 166         security = domain
 167         server signing = on
 168 ";
 169         my $ret = $self->provision($prefix,
 170                                    "LOCALMEMBER3",
 171                                    3,
 172                                    "localmember3pass",
 173                                    $member_options);
 174
 175         $ret or return undef;
 176
 177         my $net = Samba::bindir_path($self, "net");
 178         my $cmd = "";
 179         $cmd .= "SOCKET_WRAPPER_DEFAULT_IFACE=\"$ret->{SOCKET_WRAPPER_DEFAULT_IFACE}\" ";
 180         $cmd .= "$net join $ret->{CONFIGURATION} $s3dcvars->{DOMAIN} member";
 181         $cmd .= " -U$s3dcvars->{USERNAME}\%$s3dcvars->{PASSWORD}";
 182
 183         if (system($cmd) != 0) {
 184             warn("Join failed\n$cmd");
 185             return undef;
 186         }
 187
 188         $self->check_or_start($ret, "yes", "yes", "yes");
 189
 190         if (not $self->wait_for_start($ret)) {
 191                return undef;
 192         }
 193
 194         $ret->{DC_SERVER} = $s3dcvars->{SERVER};
 195         $ret->{DC_SERVER_IP} = $s3dcvars->{SERVER_IP};
 196         $ret->{DC_NETBIOSNAME} = $s3dcvars->{NETBIOSNAME};
 197         $ret->{DC_USERNAME} = $s3dcvars->{USERNAME};
 198         $ret->{DC_PASSWORD} = $s3dcvars->{PASSWORD};
 199
 200         return $ret;
 201 }
 202
 203 sub setup_admember($$$$)
 204 {
 205         my ($self, $prefix, $dcvars, $iface) = @_;
 206
 207         print "PROVISIONING S3 AD MEMBER$iface...";
 208
 209         my $member_options = "
 210         security = ads
 211         server signing = on
 212         workgroup = $dcvars->{DOMAIN}
 213         realm = $dcvars->{REALM}
 214 ";
 215
 216         my $ret = $self->provision($prefix,
 217                                    "LOCALADMEMBER$iface",
 218                                    $iface,
 219                                    "loCalMember${iface}Pass",
 220                                    $member_options);
 221
 222         $ret or return undef;
 223
 224         close(USERMAP);
 225         $ret->{DOMAIN} = $dcvars->{DOMAIN};
 226         $ret->{REALM} = $dcvars->{REALM};
 227
 228         my $ctx;
 229         my $prefix_abs = abs_path($prefix);
 230         $ctx = {};
 231         $ctx->{krb5_conf} = "$prefix_abs/lib/krb5.conf";
 232         $ctx->{domain} = $dcvars->{DOMAIN};
 233         $ctx->{realm} = $dcvars->{REALM};
 234         $ctx->{dnsname} = lc($dcvars->{REALM});
 235         $ctx->{kdc_ipv4} = $dcvars->{SERVER_IP};
 236         Samba::mk_krb5_conf($ctx, "");
 237
 238         $ret->{KRB5_CONFIG} = $ctx->{krb5_conf};
 239
 240         my $net = Samba::bindir_path($self, "net");
 241         my $cmd = "";
 242         $cmd .= "SOCKET_WRAPPER_DEFAULT_IFACE=\"$ret->{SOCKET_WRAPPER_DEFAULT_IFACE}\" ";
 243         $cmd .= "KRB5_CONFIG=\"$ret->{KRB5_CONFIG}\" ";
 244         $cmd .= "$net join $ret->{CONFIGURATION}";
 245         $cmd .= " -U$dcvars->{USERNAME}\%$dcvars->{PASSWORD}";
 246
 247         if (system($cmd) != 0) {
 248             warn("Join failed\n$cmd");
 249             return undef;
 250         }
 251
 252         # We need world access to this share, as otherwise the domain
 253         # administrator from the AD domain provided by Samba4 can't
 254         # access the share for tests.
 255         chmod 0777, "$prefix/share";
 256
 257         $self->check_or_start($ret,
 258                               "yes", "yes", "yes");
 259
 260         $self->wait_for_start($ret);
 261
 262         $ret->{DC_SERVER} = $dcvars->{SERVER};
 263         $ret->{DC_SERVER_IP} = $dcvars->{SERVER_IP};
 264         $ret->{DC_NETBIOSNAME} = $dcvars->{NETBIOSNAME};
 265         $ret->{DC_USERNAME} = $dcvars->{USERNAME};
 266         $ret->{DC_PASSWORD} = $dcvars->{PASSWORD};
 267
 268         # Special case, this is called from Samba4.pm but needs to use the Samba3 check_env and get_log_env
 269         $ret->{target} = $self;
 270
 271         return $ret;
 272 }
 273
 274 sub setup_plugin_s4_dc($$$$)
 275 {
 276         my ($self, $prefix, $dcvars, $iface) = @_;
 277
 278         print "PROVISIONING S4 PLUGIN AD DC$iface...";
 279
 280         my $plugin_s4_dc_options = "
 281         workgroup = $dcvars->{DOMAIN}
 282         realm = $dcvars->{REALM}
 283
 284         security = ads
 285         domain logons = yes
 286         passdb backend = samba4
 287         auth methods = guest samba4
 288         server signing = on
 289
 290         rpc_server:epmapper = disabled
 291         rpc_server:rpcecho = disabled
 292         rpc_server:dssetup = disabled
 293         rpc_server:svctl = disabled
 294         rpc_server:ntsvcs = disabled
 295         rpc_server:eventlog = disabled
 296         rpc_server:initshutdown = disabled
 297
 298         rpc_server:winreg = embedded
 299         rpc_server:srvsvc = embedded
 300         rpc_server:netdfs = embedded
 301         rpc_server:wkssvc = embedded
 302         rpc_server:spoolss = embedded
 303
 304         rpc_server:lsarpc = external
 305         rpc_server:netlogon = external
 306         rpc_server:samr = external
 307
 308         rpc_daemon:epmd = disabled
 309         rpc_daemon:lsasd = disabled
 310         rpc_daemon:spoolssd = disabled
 311
 312         rpc_server:tcpip = no
 313
 314 [IPC\$]
 315         vfs objects = dfs_samba4
 316 ";
 317
 318         my $ret = $self->provision($prefix,
 319                                    "plugindc",
 320                                    $iface,
 321                                    "pluGin${iface}Pass",
 322                                    $plugin_s4_dc_options, 1);
 323
 324         $ret or return undef;
 325
 326         close(USERMAP);
 327         $ret->{DOMAIN} = $dcvars->{DOMAIN};
 328         $ret->{REALM} = $dcvars->{REALM};
 329         $ret->{KRB5_CONFIG} = $dcvars->{KRB5_CONFIG};
 330
 331         # We need world access to this share, as otherwise the domain
 332         # administrator from the AD domain provided by Samba4 can't
 333         # access the share for tests.
 334         chmod 0777, "$prefix/share";
 335
 336         $self->check_or_start($ret,
 337                               "no", "no", "yes");
 338
 339         $self->wait_for_start($ret);
 340
 341         # Special case, this is called from Samba4.pm but needs to use the Samba3 check_env and get_log_env
 342         $ret->{target} = $self;
 343
 344         return $ret;
 345 }
 346
 347 sub setup_secshare($$)
 348 {
 349         my ($self, $path) = @_;
 350
 351         print "PROVISIONING server with security=share...";
 352
 353         my $secshare_options = "
 354         security = share
 355         lanman auth = yes
 356 ";
 357
 358         my $vars = $self->provision($path,
 359                                     "LOCALSHARE4",
 360                                     4,
 361                                     "local4pass",
 362                                     $secshare_options);
 363
 364         $vars or return undef;
 365
 366         $self->check_or_start($vars, "yes", "no", "yes");
 367
 368         if (not $self->wait_for_start($vars)) {
 369                return undef;
 370         }
 371
 372         $self->{vars}->{secshare} = $vars;
 373
 374         return $vars;
 375 }
 376
 377 sub setup_secserver($$$)
 378 {
 379         my ($self, $prefix, $s3dcvars) = @_;
 380
 381         print "PROVISIONING server with security=server...";
 382
 383         my $secserver_options = "
 384         security = server
 385         password server = $s3dcvars->{SERVER_IP}
 386 ";
 387
 388         my $ret = $self->provision($prefix,
 389                                    "LOCALSERVER5",
 390                                    5,
 391                                    "localserver5pass",
 392                                    $secserver_options);
 393
 394         $ret or return undef;
 395
 396         $self->check_or_start($ret, "yes", "no", "yes");
 397
 398         if (not $self->wait_for_start($ret)) {
 399                return undef;
 400         }
 401
 402         $ret->{DC_SERVER} = $s3dcvars->{SERVER};
 403         $ret->{DC_SERVER_IP} = $s3dcvars->{SERVER_IP};
 404         $ret->{DC_NETBIOSNAME} = $s3dcvars->{NETBIOSNAME};
 405         $ret->{DC_USERNAME} = $s3dcvars->{USERNAME};
 406         $ret->{DC_PASSWORD} = $s3dcvars->{PASSWORD};
 407
 408         return $ret;
 409 }
 410
 411 sub setup_ktest($$$)
 412 {
 413         my ($self, $prefix) = @_;
 414
 415         print "PROVISIONING server with security=ads...";
 416
 417         my $ktest_options = "
 418         workgroup = KTEST
 419         realm = ktest.samba.example.com
 420         security = ads
 421         username map = $prefix/lib/username.map
 422 ";
 423
 424         my $ret = $self->provision($prefix,
 425                                    "LOCALKTEST6",
 426                                    6,
 427                                    "localktest6pass",
 428                                    $ktest_options);
 429
 430         $ret or return undef;
 431
 432         my $ctx;
 433         my $prefix_abs = abs_path($prefix);
 434         $ctx = {};
 435         $ctx->{krb5_conf} = "$prefix_abs/lib/krb5.conf";
 436         $ctx->{domain} = "KTEST";
 437         $ctx->{realm} = "KTEST.SAMBA.EXAMPLE.COM";
 438         $ctx->{dnsname} = lc($ctx->{realm});
 439         $ctx->{kdc_ipv4} = "0.0.0.0";
 440         Samba::mk_krb5_conf($ctx, "");
 441
 442         $ret->{KRB5_CONFIG} = $ctx->{krb5_conf};
 443
 444         open(USERMAP, ">$prefix/lib/username.map") or die("Unable to open $prefix/lib/username.map");
 445         print USERMAP "
 446 $ret->{USERNAME} = KTEST\\Administrator
 447 ";
 448         close(USERMAP);
 449
 450 #This is the secrets.tdb created by 'net ads join' from Samba3 to a
 451 #Samba4 DC with the same parameters as are being used here.  The
 452 #domain SID is S-1-5-21-1071277805-689288055-3486227160
 453
 454         if (defined($ENV{BUILD_TDB2})) {
 455             system("cp $self->{srcdir}/source3/selftest/ktest-secrets.tdb2 $prefix/private/secrets.tdb");
 456         } else {
 457             system("cp $self->{srcdir}/source3/selftest/ktest-secrets.tdb $prefix/private/secrets.tdb");
 458         }
 459         chmod 0600, "$prefix/private/secrets.tdb";
 460
 461 #This uses a pre-calculated krb5 credentials cache, obtained by running Samba4 with:
 462 # "--option=kdc:service ticket lifetime=239232" "--option=kdc:user ticket lifetime=239232" "--option=kdc:renewal lifetime=239232"
 463 #
 464 #and having in krb5.conf:
 465 # ticket_lifetime = 799718400
 466 # renew_lifetime = 799718400
 467 #
 468 # The commands for the -2 keytab where were:
 469 # kinit administrator@KTEST.SAMBA.EXAMPLE.COM
 470 # kvno host/localktest6@KTEST.SAMBA.EXAMPLE.COM
 471 # kvno cifs/localktest6@KTEST.SAMBA.EXAMPLE.COM
 472 # kvno host/LOCALKTEST6@KTEST.SAMBA.EXAMPLE.COM
 473 # kvno cifs/LOCALKTEST6@KTEST.SAMBA.EXAMPLE.COM
 474 #
 475 # and then for the -3 keytab, I did
 476 #
 477 # net changetrustpw; kdestroy and the same again.
 478 #
 479 # This creates a credential cache with a very long lifetime (2036 at
 480 # at 2011-04), and shows that running 'net changetrustpw' does not
 481 # break existing logins (for the secrets.tdb method at least).
 482 #
 483
 484         $ret->{KRB5_CCACHE}="FILE:$prefix/krb5_ccache";
 485
 486         system("cp $self->{srcdir}/source3/selftest/ktest-krb5_ccache-2 $prefix/krb5_ccache-2");
 487         chmod 0600, "$prefix/krb5_ccache-2";
 488
 489         system("cp $self->{srcdir}/source3/selftest/ktest-krb5_ccache-3 $prefix/krb5_ccache-3");
 490         chmod 0600, "$prefix/krb5_ccache-3";
 491
 492         $self->check_or_start($ret, "yes", "no", "yes");
 493
 494         if (not $self->wait_for_start($ret)) {
 495                return undef;
 496         }
 497         return $ret;
 498 }
 499
 500 sub setup_maptoguest($$)
 501 {
 502         my ($self, $path) = @_;
 503
 504         print "PROVISIONING maptoguest...";
 505
 506         my $options = "
 507 map to guest = bad user
 508 ";
 509
 510         my $vars = $self->provision($path,
 511                                     "maptoguest",
 512                                     7,
 513                                     "maptoguestpass",
 514                                     $options);
 515
 516         $vars or return undef;
 517
 518         $self->check_or_start($vars,
 519                                "yes", "no", "yes");
 520
 521         if (not $self->wait_for_start($vars)) {
 522                return undef;
 523         }
 524
 525         $self->{vars}->{s3maptoguest} = $vars;
 526
 527         return $vars;
 528 }
 529
 530 sub stop_sig_term($$) {
 531         my ($self, $pid) = @_;
 532         kill("USR1", $pid) or kill("ALRM", $pid) or warn("Unable to kill $pid: $!");
 533 }
 534
 535 sub stop_sig_kill($$) {
 536         my ($self, $pid) = @_;
 537         kill("ALRM", $pid) or warn("Unable to kill $pid: $!");
 538 }
 539
 540 sub write_pid($$$)
 541 {
 542         my ($env_vars, $app, $pid) = @_;
 543
 544         open(PID, ">$env_vars->{PIDDIR}/timelimit.$app.pid");
 545         print PID $pid;
 546         close(PID);
 547 }
 548
 549 sub read_pid($$)
 550 {
 551         my ($env_vars, $app) = @_;
 552
 553         open(PID, "<$env_vars->{PIDDIR}/timelimit.$app.pid");
 554         my $pid = <PID>;
 555         close(PID);
 556         return $pid;
 557 }
 558
 559 sub check_or_start($$$$$) {
 560         my ($self, $env_vars, $nmbd, $winbindd, $smbd) = @_;
 561
 562         unlink($env_vars->{NMBD_TEST_LOG});
 563         print "STARTING NMBD...";
 564         my $pid = fork();
 565         if ($pid == 0) {
 566                 open STDOUT, ">$env_vars->{NMBD_TEST_LOG}";
 567                 open STDERR, '>&STDOUT';
 568
 569                 SocketWrapper::set_default_iface($env_vars->{SOCKET_WRAPPER_DEFAULT_IFACE});
 570
 571                 $ENV{KRB5_CONFIG} = $env_vars->{KRB5_CONFIG};
 572                 $ENV{WINBINDD_SOCKET_DIR} = $env_vars->{WINBINDD_SOCKET_DIR};
 573                 $ENV{NMBD_SOCKET_DIR} = $env_vars->{NMBD_SOCKET_DIR};
 574
 575                 $ENV{NSS_WRAPPER_PASSWD} = $env_vars->{NSS_WRAPPER_PASSWD};
 576                 $ENV{NSS_WRAPPER_GROUP} = $env_vars->{NSS_WRAPPER_GROUP};
 577                 $ENV{NSS_WRAPPER_WINBIND_SO_PATH} = $env_vars->{NSS_WRAPPER_WINBIND_SO_PATH};
 578
 579                 $ENV{UID_WRAPPER} = "1";
 580
 581                 if ($nmbd ne "yes") {
 582                         $SIG{USR1} = $SIG{ALRM} = $SIG{INT} = $SIG{QUIT} = $SIG{TERM} = sub {
 583                                 my $signame = shift;
 584                                 print("Skip nmbd received signal $signame");
 585                                 exit 0;
 586                         };
 587                         sleep($self->{server_maxtime});
 588                         exit 0;
 589                 }
 590
 591                 my @optargs = ("-d0");
 592                 if (defined($ENV{NMBD_OPTIONS})) {
 593                         @optargs = split(/ /, $ENV{NMBD_OPTIONS});
 594                 }
 595
 596                 $ENV{MAKE_TEST_BINARY} = Samba::bindir_path($self, "nmbd");
 597
 598                 my @preargs = (Samba::bindir_path($self, "timelimit"), $self->{server_maxtime});
 599                 if(defined($ENV{NMBD_VALGRIND})) {
 600                         @preargs = split(/ /, $ENV{NMBD_VALGRIND});
 601                 }
 602
 603                 exec(@preargs, Samba::bindir_path($self, "nmbd"), "-F", "--no-process-group", "--log-stdout", "-s", $env_vars->{SERVERCONFFILE}, @optargs) or die("Unable to start nmbd: $!");
 604         }
 605         write_pid($env_vars, "nmbd", $pid);
 606         print "DONE\n";
 607
 608         unlink($env_vars->{WINBINDD_TEST_LOG});
 609         print "STARTING WINBINDD...";
 610         $pid = fork();
 611         if ($pid == 0) {
 612                 open STDOUT, ">$env_vars->{WINBINDD_TEST_LOG}";
 613                 open STDERR, '>&STDOUT';
 614
 615                 SocketWrapper::set_default_iface($env_vars->{SOCKET_WRAPPER_DEFAULT_IFACE});
 616
 617                 $ENV{KRB5_CONFIG} = $env_vars->{KRB5_CONFIG};
 618                 $ENV{WINBINDD_SOCKET_DIR} = $env_vars->{WINBINDD_SOCKET_DIR};
 619                 $ENV{NMBD_SOCKET_DIR} = $env_vars->{NMBD_SOCKET_DIR};
 620
 621                 $ENV{NSS_WRAPPER_PASSWD} = $env_vars->{NSS_WRAPPER_PASSWD};
 622                 $ENV{NSS_WRAPPER_GROUP} = $env_vars->{NSS_WRAPPER_GROUP};
 623                 $ENV{NSS_WRAPPER_WINBIND_SO_PATH} = $env_vars->{NSS_WRAPPER_WINBIND_SO_PATH};
 624
 625                 $ENV{UID_WRAPPER} = "1";
 626
 627                 if ($winbindd ne "yes") {
 628                         $SIG{USR1} = $SIG{ALRM} = $SIG{INT} = $SIG{QUIT} = $SIG{TERM} = sub {
 629                                 my $signame = shift;
 630                                 print("Skip winbindd received signal $signame");
 631                                 exit 0;
 632                         };
 633                         sleep($self->{server_maxtime});
 634                         exit 0;
 635                 }
 636
 637                 my @optargs = ("-d0");
 638                 if (defined($ENV{WINBINDD_OPTIONS})) {
 639                         @optargs = split(/ /, $ENV{WINBINDD_OPTIONS});
 640                 }
 641
 642                 $ENV{MAKE_TEST_BINARY} = Samba::bindir_path($self, "winbindd");
 643
 644                 my @preargs = (Samba::bindir_path($self, "timelimit"), $self->{server_maxtime});
 645                 if(defined($ENV{WINBINDD_VALGRIND})) {
 646                         @preargs = split(/ /, $ENV{WINBINDD_VALGRIND});
 647                 }
 648
 649                 print "Starting winbindd with config $env_vars->{SERVERCONFFILE}\n";
 650
 651                 exec(@preargs, Samba::bindir_path($self, "winbindd"), "-F", "--no-process-group", "--stdout", "-s", $env_vars->{SERVERCONFFILE}, @optargs) or die("Unable to start winbindd: $!");
 652         }
 653         write_pid($env_vars, "winbindd", $pid);
 654         print "DONE\n";
 655
 656         unlink($env_vars->{SMBD_TEST_LOG});
 657         print "STARTING SMBD...";
 658         $pid = fork();
 659         if ($pid == 0) {
 660                 open STDOUT, ">$env_vars->{SMBD_TEST_LOG}";
 661                 open STDERR, '>&STDOUT';
 662
 663                 SocketWrapper::set_default_iface($env_vars->{SOCKET_WRAPPER_DEFAULT_IFACE});
 664
 665                 $ENV{KRB5_CONFIG} = $env_vars->{KRB5_CONFIG};
 666                 $ENV{WINBINDD_SOCKET_DIR} = $env_vars->{WINBINDD_SOCKET_DIR};
 667                 $ENV{NMBD_SOCKET_DIR} = $env_vars->{NMBD_SOCKET_DIR};
 668
 669                 $ENV{NSS_WRAPPER_PASSWD} = $env_vars->{NSS_WRAPPER_PASSWD};
 670                 $ENV{NSS_WRAPPER_GROUP} = $env_vars->{NSS_WRAPPER_GROUP};
 671                 $ENV{NSS_WRAPPER_WINBIND_SO_PATH} = $env_vars->{NSS_WRAPPER_WINBIND_SO_PATH};
 672
 673                 $ENV{UID_WRAPPER} = "1";
 674
 675                 if ($smbd ne "yes") {
 676                         $SIG{USR1} = $SIG{ALRM} = $SIG{INT} = $SIG{QUIT} = $SIG{TERM} = sub {
 677                                 my $signame = shift;
 678                                 print("Skip smbd received signal $signame");
 679                                 exit 0;
 680                         };
 681                         sleep($self->{server_maxtime});
 682                         exit 0;
 683                 }
 684
 685                 $ENV{MAKE_TEST_BINARY} = Samba::bindir_path($self, "smbd");
 686                 my @optargs = ("-d0");
 687                 if (defined($ENV{SMBD_OPTIONS})) {
 688                         @optargs = split(/ /, $ENV{SMBD_OPTIONS});
 689                 }
 690                 my @preargs = (Samba::bindir_path($self, "timelimit"), $self->{server_maxtime});
 691                 if(defined($ENV{SMBD_VALGRIND})) {
 692                         @preargs = split(/ /,$ENV{SMBD_VALGRIND});
 693                 }
 694                 exec(@preargs, Samba::bindir_path($self, "smbd"), "-F", "--no-process-group", "--log-stdout", "-s", $env_vars->{SERVERCONFFILE}, @optargs) or die("Unable to start smbd: $!");
 695         }
 696         write_pid($env_vars, "smbd", $pid);
 697         print "DONE\n";
 698
 699         return 0;
 700 }
 701
 702 sub provision($$$$$$$)
 703 {
 704         my ($self, $prefix, $server, $swiface, $password, $extra_options, $no_delete_prefix) = @_;
 705
 706         ##
 707         ## setup the various environment variables we need
 708         ##
 709
 710         my %ret = ();
 711         my $server_ip = "127.0.0.$swiface";
 712         my $domain = "SAMBA-TEST";
 713
 714         my $unix_name = ($ENV{USER} or $ENV{LOGNAME} or `PATH=/usr/ucb:$ENV{PATH} whoami`);
 715         chomp $unix_name;
 716         my $unix_uid = $>;
 717         my $unix_gids_str = $);
 718         my @unix_gids = split(" ", $unix_gids_str);
 719
 720         my $prefix_abs = abs_path($prefix);
 721         my $bindir_abs = abs_path($self->{bindir});
 722         my $vfs_modulesdir_abs = ($ENV{VFSLIBDIR} or $bindir_abs);
 723
 724         my $dns_host_file = "$ENV{SELFTEST_PREFIX}/dns_host_file";
 725
 726         my @dirs = ();
 727
 728         my $shrdir="$prefix_abs/share";
 729         push(@dirs,$shrdir);
 730
 731         my $libdir="$prefix_abs/lib";
 732         push(@dirs,$libdir);
 733
 734         my $piddir="$prefix_abs/pid";
 735         push(@dirs,$piddir);
 736
 737         my $privatedir="$prefix_abs/private";
 738         push(@dirs,$privatedir);
 739
 740         my $lockdir="$prefix_abs/lockdir";
 741         push(@dirs,$lockdir);
 742
 743         my $eventlogdir="$prefix_abs/lockdir/eventlog";
 744         push(@dirs,$eventlogdir);
 745
 746         my $logdir="$prefix_abs/logs";
 747         push(@dirs,$logdir);
 748
 749         my $driver32dir="$shrdir/W32X86";
 750         push(@dirs,$driver32dir);
 751
 752         my $driver64dir="$shrdir/x64";
 753         push(@dirs,$driver64dir);
 754
 755         my $driver40dir="$shrdir/WIN40";
 756         push(@dirs,$driver40dir);
 757
 758         my $ro_shrdir="$shrdir/root-tmp";
 759         push(@dirs,$ro_shrdir);
 760
 761         my $msdfs_shrdir="$shrdir/msdfsshare";
 762         push(@dirs,$msdfs_shrdir);
 763
 764         my $msdfs_deeppath="$msdfs_shrdir/deeppath";
 765         push(@dirs,$msdfs_deeppath);
 766
 767         # this gets autocreated by winbindd
 768         my $wbsockdir="$prefix_abs/winbindd";
 769         my $wbsockprivdir="$lockdir/winbindd_privileged";
 770
 771         my $nmbdsockdir="$prefix_abs/nmbd";
 772         unlink($nmbdsockdir);
 773
 774         ##
 775         ## create the test directory layout
 776         ##
 777         die ("prefix_abs = ''") if $prefix_abs eq "";
 778         die ("prefix_abs = '/'") if $prefix_abs eq "/";
 779
 780         mkdir($prefix_abs, 0777);
 781         print "CREATE TEST ENVIRONMENT IN '$prefix'...";
 782         if (not defined($no_delete_prefix) or not $no_delete_prefix) {
 783             system("rm -rf $prefix_abs/*");
 784         }
 785         mkdir($_, 0777) foreach(@dirs);
 786
 787         ##
 788         ## create ro and msdfs share layout
 789         ##
 790
 791         chmod 0755, $ro_shrdir;
 792         my $unreadable_file = "$ro_shrdir/unreadable_file";
 793         unless (open(UNREADABLE_FILE, ">$unreadable_file")) {
 794                 warn("Unable to open $unreadable_file");
 795                 return undef;
 796         }
 797         close(UNREADABLE_FILE);
 798         chmod 0600, $unreadable_file;
 799
 800         my $msdfs_target = "$ro_shrdir/msdfs-target";
 801         unless (open(MSDFS_TARGET, ">$msdfs_target")) {
 802                 warn("Unable to open $msdfs_target");
 803                 return undef;
 804         }
 805         close(MSDFS_TARGET);
 806         chmod 0666, $msdfs_target;
 807         symlink "msdfs:$server_ip\\ro-tmp", "$msdfs_shrdir/msdfs-src1";
 808         symlink "msdfs:$server_ip\\ro-tmp", "$msdfs_shrdir/deeppath/msdfs-src2";
 809
 810         my $conffile="$libdir/server.conf";
 811
 812         my $nss_wrapper_pl = "$ENV{PERL} $self->{srcdir}/lib/nss_wrapper/nss_wrapper.pl";
 813         my $nss_wrapper_passwd = "$privatedir/passwd";
 814         my $nss_wrapper_group = "$privatedir/group";
 815
 816         my $mod_printer_pl = "$ENV{PERL} $self->{srcdir}/source3/script/tests/printing/modprinter.pl";
 817
 818         my @eventlog_list = ("dns server", "application");
 819
 820         ##
 821         ## calculate uids and gids
 822         ##
 823
 824         my ($max_uid, $max_gid);
 825         my ($uid_nobody, $uid_root);
 826         my ($gid_nobody, $gid_nogroup, $gid_root, $gid_domusers);
 827
 828         if ($unix_uid < 0xffff - 2) {
 829                 $max_uid = 0xffff;
 830         } else {
 831                 $max_uid = $unix_uid;
 832         }
 833
 834         $uid_root = $max_uid - 1;
 835         $uid_nobody = $max_uid - 2;
 836
 837         if ($unix_gids[0] < 0xffff - 3) {
 838                 $max_gid = 0xffff;
 839         } else {
 840                 $max_gid = $unix_gids[0];
 841         }
 842
 843         $gid_nobody = $max_gid - 1;
 844         $gid_nogroup = $max_gid - 2;
 845         $gid_root = $max_gid - 3;
 846         $gid_domusers = $max_gid - 4;
 847
 848         ##
 849         ## create conffile
 850         ##
 851
 852         unless (open(CONF, ">$conffile")) {
 853                 warn("Unable to open $conffile");
 854                 return undef;
 855         }
 856         print CONF "
 857 [global]
 858         netbios name = $server
 859         interfaces = $server_ip/8
 860         bind interfaces only = yes
 861         panic action = $self->{srcdir}/selftest/gdb_backtrace %d %\$(MAKE_TEST_BINARY)
 862
 863         workgroup = $domain
 864
 865         private dir = $privatedir
 866         pid directory = $piddir
 867         lock directory = $lockdir
 868         log file = $logdir/log.\%m
 869         log level = 0
 870         debug pid = yes
 871         max log size = 0
 872
 873         state directory = $lockdir
 874         cache directory = $lockdir
 875
 876         passdb backend = tdbsam
 877
 878         time server = yes
 879
 880         add user script =               $nss_wrapper_pl --passwd_path $nss_wrapper_passwd --type passwd --action add --name %u --gid $gid_nogroup
 881         add group script =              $nss_wrapper_pl --group_path  $nss_wrapper_group  --type group  --action add --name %g
 882         add machine script =            $nss_wrapper_pl --passwd_path $nss_wrapper_passwd --type passwd --action add --name %u --gid $gid_nogroup
 883         add user to group script =      $nss_wrapper_pl --passwd_path $nss_wrapper_passwd --type member --action add --member %u --name %g --group_path $nss_wrapper_group
 884         delete user script =            $nss_wrapper_pl --passwd_path $nss_wrapper_passwd --type passwd --action delete --name %u
 885         delete group script =           $nss_wrapper_pl --group_path  $nss_wrapper_group  --type group  --action delete --name %g
 886         delete user from group script = $nss_wrapper_pl --passwd_path $nss_wrapper_passwd --type member --action delete --member %u --name %g --group_path $nss_wrapper_group
 887
 888         addprinter command =            $mod_printer_pl -a -s $conffile --
 889         deleteprinter command =         $mod_printer_pl -d -s $conffile --
 890
 891         eventlog list = application \"dns server\"
 892
 893         kernel oplocks = no
 894         kernel change notify = no
 895
 896         syslog = no
 897         printing = bsd
 898         printcap name = /dev/null
 899
 900         winbindd:socket dir = $wbsockdir
 901         nmbd:socket dir = $nmbdsockdir
 902         idmap config * : range = 100000-200000
 903         winbind enum users = yes
 904         winbind enum groups = yes
 905
 906 #       min receivefile size = 4000
 907
 908         max protocol = SMB2
 909         read only = no
 910         server signing = auto
 911
 912         smbd:sharedelay = 100000
 913 #       smbd:writetimeupdatedelay = 500000
 914         map hidden = no
 915         map system = no
 916         map readonly = no
 917         store dos attributes = yes
 918         create mask = 755
 919         dos filemode = yes
 920         vfs objects = $vfs_modulesdir_abs/xattr_tdb.so $vfs_modulesdir_abs/streams_depot.so
 921
 922         printing = vlp
 923         print command = $bindir_abs/vlp tdbfile=$lockdir/vlp.tdb print %p %s
 924         lpq command = $bindir_abs/vlp tdbfile=$lockdir/vlp.tdb lpq %p
 925         lp rm command = $bindir_abs/vlp tdbfile=$lockdir/vlp.tdb lprm %p %j
 926         lp pause command = $bindir_abs/vlp tdbfile=$lockdir/vlp.tdb lppause %p %j
 927         lp resume command = $bindir_abs/vlp tdbfile=$lockdir/vlp.tdb lpresume %p %j
 928         queue pause command = $bindir_abs/vlp tdbfile=$lockdir/vlp.tdb queuepause %p
 929         queue resume command = $bindir_abs/vlp tdbfile=$lockdir/vlp.tdb queueresume %p
 930         lpq cache time = 0
 931
 932         ncalrpc dir = $prefix_abs/ncalrpc
 933         rpc_server:epmapper = external
 934         rpc_server:spoolss = external
 935         rpc_server:lsarpc = external
 936         rpc_server:samr = external
 937         rpc_server:netlogon = external
 938         rpc_server:tcpip = yes
 939
 940         rpc_daemon:epmd = fork
 941         rpc_daemon:spoolssd = fork
 942         rpc_daemon:lsasd = fork
 943
 944         resolv:host file = $dns_host_file
 945
 946         # The samba3.blackbox.smbclient_s3 test uses this to test that
 947         # sending messages works, and that the %m sub works.
 948         message command = mv %s $shrdir/message.%m
 949
 950         # Begin extra options
 951         $extra_options
 952         # End extra options
 953
 954         #Include user defined custom parameters if set
 955 ";
 956
 957         if (defined($ENV{INCLUDE_CUSTOM_CONF})) {
 958                 print CONF "\t$ENV{INCLUDE_CUSTOM_CONF}\n";
 959         }
 960
 961         print CONF "
 962 [tmp]
 963         path = $shrdir
 964         comment = smb username is [%U]
 965 [tmpguest]
 966         path = $shrdir
 967         guest ok = yes
 968 [guestonly]
 969         path = $shrdir
 970         guest only = yes
 971         guest ok = yes
 972 [forceuser]
 973         path = $shrdir
 974         force user = $unix_name
 975         guest ok = yes
 976 [forcegroup]
 977         path = $shrdir
 978         force group = nogroup
 979         guest ok = yes
 980 [ro-tmp]
 981         path = $ro_shrdir
 982         guest ok = yes
 983 [msdfs-share]
 984         path = $msdfs_shrdir
 985         msdfs root = yes
 986         guest ok = yes
 987 [hideunread]
 988         copy = tmp
 989         hide unreadable = yes
 990 [tmpcase]
 991         copy = tmp
 992         case sensitive = yes
 993 [hideunwrite]
 994         copy = tmp
 995         hide unwriteable files = yes
 996 [print1]
 997         copy = tmp
 998         printable = yes
 999
1000 [print2]
1001         copy = print1
1002 [print3]
1003         copy = print1
1004 [lp]
1005         copy = print1
1006 [xcopy_share]
1007         path = $shrdir
1008         comment = smb username is [%U]
1009         create mask = 777
1010         force create mode = 777
1011 [print\$]
1012         copy = tmp
1013         ";
1014         close(CONF);
1015
1016         ##
1017         ## create a test account
1018         ##
1019
1020         unless (open(PASSWD, ">$nss_wrapper_passwd")) {
1021            warn("Unable to open $nss_wrapper_passwd");
1022            return undef;
1023         }
1024         print PASSWD "nobody:x:$uid_nobody:$gid_nobody:nobody gecos:$prefix_abs:/bin/false
1025 $unix_name:x:$unix_uid:$unix_gids[0]:$unix_name gecos:$prefix_abs:/bin/false
1026 ";
1027         if ($unix_uid != 0) {
1028                 print PASSWD "root:x:$uid_root:$gid_root:root gecos:$prefix_abs:/bin/false";
1029         }
1030         close(PASSWD);
1031
1032         unless (open(GROUP, ">$nss_wrapper_group")) {
1033              warn("Unable to open $nss_wrapper_group");
1034              return undef;
1035         }
1036         print GROUP "nobody:x:$gid_nobody:
1037 nogroup:x:$gid_nogroup:nobody
1038 $unix_name-group:x:$unix_gids[0]:
1039 domusers:X:$gid_domusers:
1040 ";
1041         if ($unix_gids[0] != 0) {
1042                 print GROUP "root:x:$gid_root:";
1043         }
1044
1045         close(GROUP);
1046
1047         foreach my $evlog (@eventlog_list) {
1048                 my $evlogtdb = "$eventlogdir/$evlog.tdb";
1049                 open(EVENTLOG, ">$evlogtdb") or die("Unable to open $evlogtdb");
1050                 close(EVENTLOG);
1051         }
1052
1053         $ENV{NSS_WRAPPER_PASSWD} = $nss_wrapper_passwd;
1054         $ENV{NSS_WRAPPER_GROUP} = $nss_wrapper_group;
1055
1056         my $cmd = Samba::bindir_path($self, "smbpasswd")." -c $conffile -L -s -a $unix_name > /dev/null";
1057         unless (open(PWD, "|$cmd")) {
1058              warn("Unable to set password for test account\n$cmd");
1059              return undef;
1060         }
1061         print PWD "$password\n$password\n";
1062         unless (close(PWD)) {
1063              warn("Unable to set password for test account\n$cmd");
1064              return undef;
1065         }
1066         print "DONE\n";
1067
1068         open(HOSTS, ">>$ENV{SELFTEST_PREFIX}/dns_host_file") or die("Unable to open $ENV{SELFTEST_PREFIX}/dns_host_file");
1069         print HOSTS "A $server. $server_ip
1070 ";
1071         close(HOSTS);
1072
1073         $ret{SERVER_IP} = $server_ip;
1074         $ret{NMBD_TEST_LOG} = "$prefix/nmbd_test.log";
1075         $ret{NMBD_TEST_LOG_POS} = 0;
1076         $ret{WINBINDD_TEST_LOG} = "$prefix/winbindd_test.log";
1077         $ret{WINBINDD_TEST_LOG_POS} = 0;
1078         $ret{SMBD_TEST_LOG} = "$prefix/smbd_test.log";
1079         $ret{SMBD_TEST_LOG_POS} = 0;
1080         $ret{SERVERCONFFILE} = $conffile;
1081         $ret{CONFIGURATION} ="-s $conffile";
1082         $ret{SERVER} = $server;
1083         $ret{USERNAME} = $unix_name;
1084         $ret{USERID} = $unix_uid;
1085         $ret{DOMAIN} = $domain;
1086         $ret{NETBIOSNAME} = $server;
1087         $ret{PASSWORD} = $password;
1088         $ret{PIDDIR} = $piddir;
1089         $ret{WINBINDD_SOCKET_DIR} = $wbsockdir;
1090         $ret{WINBINDD_PRIV_PIPE_DIR} = $wbsockprivdir;
1091         $ret{NMBD_SOCKET_DIR} = $nmbdsockdir;
1092         $ret{SOCKET_WRAPPER_DEFAULT_IFACE} = $swiface;
1093         $ret{NSS_WRAPPER_PASSWD} = $nss_wrapper_passwd;
1094         $ret{NSS_WRAPPER_GROUP} = $nss_wrapper_group;
1095         $ret{NSS_WRAPPER_WINBIND_SO_PATH} = $ENV{NSS_WRAPPER_WINBIND_SO_PATH};
1096         if (not defined($ret{NSS_WRAPPER_WINBIND_SO_PATH})) {
1097                 $ret{NSS_WRAPPER_WINBIND_SO_PATH} = Samba::bindir_path($self, "default/nsswitch/libnss-winbind.so");
1098         }
1099         $ret{LOCAL_PATH} = "$shrdir";
1100
1101         return \%ret;
1102 }
1103
1104 sub wait_for_start($$)
1105 {
1106         my ($self, $envvars) = @_;
1107
1108         # give time for nbt server to register its names
1109         print "delaying for nbt name registration\n";
1110         sleep(10);
1111         # This will return quickly when things are up, but be slow if we need to wait for (eg) SSL init
1112         system(Samba::bindir_path($self, "nmblookup3") ." $envvars->{CONFIGURATION} -U $envvars->{SERVER_IP} __SAMBA__");
1113         system(Samba::bindir_path($self, "nmblookup3") ." $envvars->{CONFIGURATION} __SAMBA__");
1114         system(Samba::bindir_path($self, "nmblookup3") ." $envvars->{CONFIGURATION} -U 127.255.255.255 __SAMBA__");
1115         system(Samba::bindir_path($self, "nmblookup3") ." $envvars->{CONFIGURATION} -U $envvars->{SERVER_IP} $envvars->{SERVER}");
1116         system(Samba::bindir_path($self, "nmblookup3") ." $envvars->{CONFIGURATION} $envvars->{SERVER}");
1117
1118         # make sure smbd is also up set
1119         print "wait for smbd\n";
1120
1121         my $count = 0;
1122         my $ret;
1123         do {
1124             $ret = system(Samba::bindir_path($self, "smbclient3") ." $envvars->{CONFIGURATION} -L $envvars->{SERVER} -U% -p 139");
1125             if ($ret != 0) {
1126                 sleep(2);
1127             }
1128             $count++
1129         } while ($ret != 0 && $count < 10);
1130         if ($count == 10) {
1131             print "SMBD failed to start up in a reasonable time (20sec)\n";
1132             teardown_env($self, $envvars);
1133             return 0;
1134         }
1135         # Ensure we have domain users mapped.
1136         $ret = system(Samba::bindir_path($self, "net") ." $envvars->{CONFIGURATION} groupmap add rid=513 unixgroup=domusers type=domain");
1137         if ($ret != 0) {
1138             return 1;
1139         }
1140
1141         print $self->getlog_env($envvars);
1142
1143         return 1;
1144 }
1145
1146 1;