CMakeLists.txt

   1 # Required cmake version
   2 cmake_minimum_required(VERSION 3.5.0)
   3 cmake_policy(SET CMP0048 NEW)
   4
   5 # Specify search path for CMake modules to be loaded by include()
   6 # and find_package()
   7 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules")
   8
   9 # Add defaults for cmake
  10 # Those need to be set before the project() call.
  11 include(DefineCMakeDefaults)
  12 include(DefineCompilerFlags)
  13
  14 project(socket_wrapper VERSION 1.3.2 LANGUAGES C)
  15
  16 # global needed variables
  17 set(APPLICATION_NAME ${PROJECT_NAME})
  18
  19 # SOVERSION scheme: MAJOR.MINOR.PATCH
  20 #   If there was an incompatible interface change:
  21 #     Increment MAJOR. Set MINOR and PATCH to 0
  22 #   If there was a compatible interface change:
  23 #     Increment MINOR. Set PATCH to 0
  24 #   If the source code was changed, but there were no interface changes:
  25 #     Increment PATCH.
  26 set(LIBRARY_VERSION_MAJOR 0)
  27 set(LIBRARY_VERSION_MINOR 2)
  28 set(LIBRARY_VERSION_PATCH 2)
  29 set(LIBRARY_VERSION "${LIBRARY_VERSION_MAJOR}.${LIBRARY_VERSION_MINOR}.${LIBRARY_VERSION_PATCH}")
  30 set(LIBRARY_SOVERSION ${LIBRARY_VERSION_MAJOR})
  31
  32 # add definitions
  33 include(DefinePlatformDefaults)
  34 include(DefineOptions.cmake)
  35 include(CPackConfig.cmake)
  36 include(CompilerChecks.cmake)
  37 include(GNUInstallDirs)
  38
  39 # disallow in-source build
  40 include(MacroEnsureOutOfSourceBuild)
  41 macro_ensure_out_of_source_build("${PROJECT_NAME} requires an out of source build. Please create a separate build directory and run 'cmake /path/to/${PROJECT_NAME} [options]' there.")
  42
  43 # Find out if we have threading available
  44 set(CMAKE_THREAD_PREFER_PTHREADS ON)
  45 find_package(Threads)
  46
  47 # config.h checks
  48 include(ConfigureChecks.cmake)
  49 configure_file(config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config.h)
  50
  51 # check subdirectories
  52 add_subdirectory(src)
  53
  54 if (UNIT_TESTING)
  55     find_package(cmocka 1.1.0 REQUIRED)
  56
  57     include(AddCMockaTest)
  58     add_subdirectory(tests)
  59 endif (UNIT_TESTING)
  60
  61 # pkg-config file
  62 get_filename_component(SOCKET_WRAPPER_LIB ${SOCKET_WRAPPER_LOCATION} NAME)
  63
  64 configure_file(socket_wrapper.pc.cmake ${CMAKE_CURRENT_BINARY_DIR}/socket_wrapper.pc @ONLY)
  65 install(
  66   FILES
  67     ${CMAKE_CURRENT_BINARY_DIR}/socket_wrapper.pc
  68   DESTINATION
  69       ${CMAKE_INSTALL_LIBDIR}/pkgconfig
  70   COMPONENT
  71     pkgconfig
  72 )
  73
  74 # cmake config files
  75 configure_file(socket_wrapper-config-version.cmake.in ${CMAKE_CURRENT_BINARY_DIR}/socket_wrapper-config-version.cmake @ONLY)
  76 configure_file(socket_wrapper-config.cmake.in ${CMAKE_CURRENT_BINARY_DIR}/socket_wrapper-config.cmake @ONLY)
  77 install(
  78     FILES
  79         ${CMAKE_CURRENT_BINARY_DIR}/socket_wrapper-config-version.cmake
  80         ${CMAKE_CURRENT_BINARY_DIR}/socket_wrapper-config.cmake
  81     DESTINATION
  82         ${CMAKE_INSTALL_LIBDIR}/cmake/socket_wrapper
  83     COMPONENT
  84         devel
  85 )
  86
  87 add_subdirectory(doc)