CMakeLists.txt

   1 # Required cmake version
   2 cmake_minimum_required(VERSION 3.5.0)
   3 cmake_policy(SET CMP0048 NEW)
   4
   5 # Specify search path for CMake modules to be loaded by include()
   6 # and find_package()
   7 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules")
   8
   9 # Add defaults for cmake
  10 # Those need to be set before the project() call.
  11 include(DefineCMakeDefaults)
  12 include(DefineCompilerFlags)
  13
  14 project(socket_wrapper VERSION 1.4.2 LANGUAGES C)
  15
  16 # global needed variables
  17 set(APPLICATION_NAME ${PROJECT_NAME})
  18
  19 # SOVERSION scheme: MAJOR.MINOR.PATCH
  20 #   If there was an incompatible interface change:
  21 #     Increment MAJOR. Set MINOR and PATCH to 0
  22 #   If there was a compatible interface change:
  23 #     Increment MINOR. Set PATCH to 0
  24 #   If the source code was changed, but there were no interface changes:
  25 #     Increment PATCH.
  26 set(LIBRARY_VERSION_MAJOR 0)
  27 set(LIBRARY_VERSION_MINOR 4)
  28 set(LIBRARY_VERSION_PATCH 1)
  29 set(LIBRARY_VERSION "${LIBRARY_VERSION_MAJOR}.${LIBRARY_VERSION_MINOR}.${LIBRARY_VERSION_PATCH}")
  30 set(LIBRARY_SOVERSION ${LIBRARY_VERSION_MAJOR})
  31
  32 set(NOOP_LIBRARY_VERSION_MAJOR 0)
  33 set(NOOP_LIBRARY_VERSION_MINOR 0)
  34 set(NOOP_LIBRARY_VERSION_PATCH 1)
  35 set(NOOP_LIBRARY_VERSION "${NOOP_LIBRARY_VERSION_MAJOR}.${NOOP_LIBRARY_VERSION_MINOR}.${NOOP_LIBRARY_VERSION_PATCH}")
  36 set(NOOP_LIBRARY_SOVERSION ${NOOP_LIBRARY_VERSION_MAJOR})
  37
  38 # add definitions
  39 include(DefinePlatformDefaults)
  40 include(DefineOptions.cmake)
  41 include(CPackConfig.cmake)
  42 include(CompilerChecks.cmake)
  43 include(GNUInstallDirs)
  44
  45 # disallow in-source build
  46 include(MacroEnsureOutOfSourceBuild)
  47 macro_ensure_out_of_source_build("${PROJECT_NAME} requires an out of source build. Please create a separate build directory and run 'cmake /path/to/${PROJECT_NAME} [options]' there.")
  48
  49 # Find out if we have threading available
  50 set(CMAKE_THREAD_PREFER_PTHREADS ON)
  51 find_package(Threads)
  52
  53 # config.h checks
  54 include(ConfigureChecks.cmake)
  55 configure_file(config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config.h)
  56
  57 # check subdirectories
  58 add_subdirectory(src)
  59
  60 if (UNIT_TESTING)
  61     find_package(cmocka 1.1.0 REQUIRED)
  62
  63     include(AddCMockaTest)
  64     add_subdirectory(tests)
  65 endif (UNIT_TESTING)
  66
  67 # pkg-config file
  68 get_filename_component(SOCKET_WRAPPER_LIB ${SOCKET_WRAPPER_LOCATION} NAME)
  69
  70 configure_file(socket_wrapper.pc.cmake ${CMAKE_CURRENT_BINARY_DIR}/socket_wrapper.pc @ONLY)
  71 install(
  72   FILES
  73     ${CMAKE_CURRENT_BINARY_DIR}/socket_wrapper.pc
  74   DESTINATION
  75       ${CMAKE_INSTALL_LIBDIR}/pkgconfig
  76   COMPONENT
  77     pkgconfig
  78 )
  79
  80 configure_file(socket_wrapper_noop.pc.cmake ${CMAKE_CURRENT_BINARY_DIR}/socket_wrapper_noop.pc @ONLY)
  81 install(
  82   FILES
  83     ${CMAKE_CURRENT_BINARY_DIR}/socket_wrapper_noop.pc
  84   DESTINATION
  85       ${CMAKE_INSTALL_LIBDIR}/pkgconfig
  86   COMPONENT
  87     pkgconfig
  88 )
  89
  90 # cmake config files
  91 configure_file(socket_wrapper-config-version.cmake.in ${CMAKE_CURRENT_BINARY_DIR}/socket_wrapper-config-version.cmake @ONLY)
  92 configure_file(socket_wrapper-config.cmake.in ${CMAKE_CURRENT_BINARY_DIR}/socket_wrapper-config.cmake @ONLY)
  93 install(
  94     FILES
  95         ${CMAKE_CURRENT_BINARY_DIR}/socket_wrapper-config-version.cmake
  96         ${CMAKE_CURRENT_BINARY_DIR}/socket_wrapper-config.cmake
  97     DESTINATION
  98         ${CMAKE_INSTALL_LIBDIR}/cmake/socket_wrapper
  99     COMPONENT
 100         devel
 101 )
 102
 103 add_subdirectory(doc)