tests/CMakeLists.txt

   1 project(tests C)
   2
   3 include_directories(
   4   ${CMAKE_BINARY_DIR}
   5   ${CMAKE_CURRENT_SOURCE_DIR}
   6   ${CMAKE_SOURCE_DIR}/src
   7   ${CMOCKA_INCLUDE_DIR}
   8 )
   9
  10 set(TORTURE_LIBRARY torture)
  11
  12 # RFC862 echo server
  13 add_executable(echo_srv echo_srv.c)
  14 target_compile_options(echo_srv
  15                        PRIVATE
  16                            ${DEFAULT_C_COMPILE_FLAGS}
  17                            -D_GNU_SOURCE)
  18 target_link_libraries(echo_srv ${SWRAP_REQUIRED_LIBRARIES})
  19 if (DEFINED DEFAULT_LINK_FLAGS)
  20     set_target_properties(echo_srv
  21                           PROPERTIES
  22                               LINK_FLAGS ${DEFAULT_LINK_FLAGS})
  23 endif()
  24
  25 add_library(${TORTURE_LIBRARY} STATIC torture.c)
  26 target_compile_options(${TORTURE_LIBRARY}
  27                        PRIVATE
  28                            ${DEFAULT_C_COMPILE_FLAGS}
  29                            -D_GNU_SOURCE)
  30 target_link_libraries(${TORTURE_LIBRARY}
  31     ${CMOCKA_LIBRARY}
  32     ${SWRAP_REQUIRED_LIBRARIES}
  33     ${CMAKE_THREAD_LIBS_INIT})
  34
  35 set(SWRAP_THREADED_TESTS
  36     test_thread_sockets
  37     test_thread_echo_tcp_connect
  38     test_thread_echo_tcp_write_read
  39     test_thread_echo_tcp_sendmsg_recvmsg
  40     test_thread_echo_udp_send_recv)
  41
  42 set(SWRAP_TESTS
  43     test_ioctl
  44     test_tcp_listen
  45     test_tcp_dup2
  46     test_fcntl
  47     test_echo_tcp_connect
  48     test_echo_tcp_bind
  49     test_echo_tcp_socket_options
  50     test_echo_tcp_sendmsg_recvmsg
  51     test_echo_tcp_write_read
  52     test_echo_tcp_writev_readv
  53     test_echo_tcp_get_peer_sock_name
  54     test_echo_udp_sendto_recvfrom
  55     test_echo_udp_send_recv
  56     test_echo_udp_sendmsg_recvmsg
  57     test_swrap_unit
  58     test_max_sockets
  59     test_public_functions
  60     test_close_failure
  61     test_tcp_socket_overwrite
  62     ${SWRAP_THREADED_TESTS})
  63
  64 if (HAVE_STRUCT_MSGHDR_MSG_CONTROL)
  65     set(SWRAP_TESTS ${SWRAP_TESTS} test_sendmsg_recvmsg_fd test_echo_tcp_sendmsg_recvmsg_fd)
  66 endif (HAVE_STRUCT_MSGHDR_MSG_CONTROL)
  67
  68 function(ADD_CMOCKA_TEST_ENVIRONMENT _TEST_NAME)
  69     if (CMAKE_BUILD_TYPE)
  70         string(TOLOWER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_LOWER)
  71         if (CMAKE_BUILD_TYPE_LOWER STREQUAL "addresssanitizer")
  72             find_library(ASAN_LIBRARY
  73                          NAMES asan)
  74             if (NOT ASAN_LIBRARY)
  75                 foreach(version RANGE 10 1)
  76                     if (NOT ASAN_LIBRARY)
  77                         find_library(ASAN_LIBRARY libasan.so.${version})
  78                     endif()
  79                 endforeach()
  80             endif()
  81         endif()
  82     endif()
  83
  84     if (ASAN_LIBRARY)
  85         list(APPEND PRELOAD_LIBRARIES ${ASAN_LIBRARY})
  86     endif()
  87     list(APPEND PRELOAD_LIBRARIES ${SOCKET_WRAPPER_LOCATION})
  88
  89     if (OSX)
  90         set(TORTURE_ENVIRONMENT "DYLD_FORCE_FLAT_NAMESPACE=1;DYLD_INSERT_LIBRARIES=${SOCKET_WRAPPER_LOCATION}")
  91     else ()
  92         string(REPLACE ";" ":" _TMP_ENV "${PRELOAD_LIBRARIES}")
  93         set(TORTURE_ENVIRONMENT "LD_PRELOAD=${_TMP_ENV}")
  94     endif()
  95
  96     if (CMAKE_BUILD_TYPE)
  97         string(TOLOWER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_LOWER)
  98         if (CMAKE_BUILD_TYPE_LOWER STREQUAL "addresssanitizer" OR
  99             CMAKE_BUILD_TYPE_LOWER STREQUAL "threadsanitizer" OR
 100             CMAKE_BUILD_TYPE_LOWER STREQUAL "undefinedsanitizer")
 101             list(APPEND TORTURE_ENVIRONMENT "SOCKET_WRAPPER_DISABLE_DEEPBIND=1")
 102         endif()
 103     endif()
 104
 105     set_property(TEST
 106                     ${_TEST_NAME}
 107                 PROPERTY
 108                     ENVIRONMENT "${TORTURE_ENVIRONMENT}")
 109 endfunction()
 110
 111 foreach(_SWRAP_TEST ${SWRAP_TESTS})
 112     add_cmocka_test(${_SWRAP_TEST}
 113                     SOURCES ${_SWRAP_TEST}.c
 114                     COMPILE_OPTIONS ${DEFAULT_C_COMPILE_FLAGS} -D_GNU_SOURCE
 115                     LINK_LIBRARIES ${TORTURE_LIBRARY} socket_wrapper_noop
 116                     LINK_OPTIONS ${DEFAULT_LINK_FLAGS})
 117     add_cmocka_test_environment(${_SWRAP_TEST})
 118 endforeach()
 119
 120 if (HELGRIND_TESTING)
 121     find_program(VALGRIND_EXECUTABLE valgrind)
 122     if (VALGRIND_EXECUTABLE)
 123         set(VALGRIND_HELGRIND_OPTIONS -v --trace-children=yes --tool=helgrind --error-exitcode=1 --read-var-info=yes --suppressions=${CMAKE_CURRENT_SOURCE_DIR}/helgrind.supp)
 124
 125         foreach(_TEST ${SWRAP_THREADED_TESTS})
 126             set(_HELGRIND_TEST "helgrind_${_TEST}")
 127
 128             add_test(NAME ${_HELGRIND_TEST} COMMAND ${VALGRIND_EXECUTABLE} ${VALGRIND_HELGRIND_OPTIONS} ${CMAKE_CURRENT_BINARY_DIR}/${_TEST})
 129             if (OSX)
 130                 set_property(
 131                     TEST
 132                         ${_HELGRIND_TEST}
 133                     PROPERTY
 134                         ENVIRONMENT DYLD_FORCE_FLAT_NAMESPACE=1;DYLD_INSERT_LIBRARIES=${SOCKET_WRAPPER_LOCATION})
 135             else ()
 136                 set_property(
 137                     TEST
 138                         ${_HELGRIND_TEST}
 139                     PROPERTY
 140                         ENVIRONMENT LD_PRELOAD=${SOCKET_WRAPPER_LOCATION} SOCKET_WRAPPER_DISABLE_DEEPBIND=1)
 141             endif()
 142         endforeach()
 143     endif()
 144 endif()
 145
 146 # test_fork_pthread
 147 add_library(thread_deadlock SHARED thread_deadlock.c)
 148 target_link_libraries(thread_deadlock ${CMAKE_THREAD_LIBS_INIT})
 149 target_compile_options(thread_deadlock PRIVATE ${DEFAULT_C_COMPILE_FLAGS})
 150
 151 add_cmocka_test(test_fork_thread_deadlock
 152                 SOURCES test_fork_thread_deadlock.c
 153                 COMPILE_OPTIONS ${DEFAULT_C_COMPILE_FLAGS} -D_GNU_SOURCE
 154                 LINK_LIBRARIES ${TORTURE_LIBRARY} thread_deadlock
 155                 LINK_OPTIONS ${DEFAULT_LINK_FLAGS})
 156 add_cmocka_test_environment(test_fork_thread_deadlock)