tests/CMakeLists.txt

   1 project(tests C)
   2
   3 include_directories(
   4   ${CMAKE_BINARY_DIR}
   5   ${CMAKE_CURRENT_SOURCE_DIR}
   6   ${CMAKE_SOURCE_DIR}/src
   7   ${CMOCKA_INCLUDE_DIR}
   8 )
   9
  10 # Required for cmocka >= 1.1.6
  11 if (TARGET cmocka::cmocka)
  12     set(CMOCKA_LIBRARY cmocka::cmocka)
  13 endif()
  14
  15 set(TORTURE_LIBRARY torture)
  16
  17 # RFC862 echo server
  18 add_executable(echo_srv echo_srv.c)
  19 target_compile_options(echo_srv
  20                        PRIVATE
  21                            ${DEFAULT_C_COMPILE_FLAGS}
  22                            -D_GNU_SOURCE)
  23 target_link_libraries(echo_srv ${SWRAP_REQUIRED_LIBRARIES})
  24 if (DEFINED DEFAULT_LINK_FLAGS)
  25     set_target_properties(echo_srv
  26                           PROPERTIES
  27                               LINK_FLAGS ${DEFAULT_LINK_FLAGS})
  28 endif()
  29
  30 add_library(${TORTURE_LIBRARY} STATIC torture.c)
  31 target_compile_options(${TORTURE_LIBRARY}
  32                        PRIVATE
  33                            ${DEFAULT_C_COMPILE_FLAGS}
  34                            -D_GNU_SOURCE)
  35 target_link_libraries(${TORTURE_LIBRARY}
  36     ${CMOCKA_LIBRARY}
  37     ${SWRAP_REQUIRED_LIBRARIES}
  38     ${CMAKE_THREAD_LIBS_INIT})
  39
  40 add_library(swrap_fake_uid_wrapper SHARED swrap_fake_uid_wrapper.c)
  41 target_compile_options(swrap_fake_uid_wrapper
  42                        PRIVATE
  43                            ${DEFAULT_C_COMPILE_FLAGS}
  44                            -D_GNU_SOURCE)
  45 #target_include_directories(swrap_fake_uid_wrapper
  46 #        PRIVATE ${CMAKE_BINARY_DIR} ${CMOCKA_INCLUDE_DIR})
  47 set(SWRAP_FAKE_UID_WRAPPER_LOCATION "${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_SHARED_LIBRARY_PREFIX}swrap_fake_uid_wrapper${CMAKE_SHARED_LIBRARY_SUFFIX}")
  48
  49 set(SWRAP_THREADED_TESTS
  50     test_thread_sockets
  51     test_thread_echo_tcp_connect
  52     test_thread_echo_tcp_write_read
  53     test_thread_echo_tcp_sendmsg_recvmsg
  54     test_thread_echo_udp_send_recv)
  55
  56 set(SWRAP_TESTS
  57     test_ioctl
  58     test_tcp_listen
  59     test_tcp_dup2
  60     test_fcntl
  61     test_echo_tcp_connect
  62     test_echo_tcp_bind
  63     test_echo_tcp_socket_options
  64     test_echo_tcp_sendmsg_recvmsg
  65     test_echo_tcp_sendmmsg_recvmmsg
  66     test_echo_tcp_write_read
  67     test_echo_tcp_poll
  68     test_echo_tcp_writev_readv
  69     test_echo_tcp_get_peer_sock_name
  70     test_echo_udp_sendto_recvfrom
  71     test_echo_udp_send_recv
  72     test_echo_udp_sendmsg_recvmsg
  73     test_swrap_unit
  74     test_max_sockets
  75     test_public_functions
  76     test_close_failure
  77     test_tcp_socket_overwrite
  78     test_syscall_uwrap
  79     ${SWRAP_THREADED_TESTS})
  80
  81 if (HAVE_STRUCT_MSGHDR_MSG_CONTROL)
  82     set(SWRAP_TESTS ${SWRAP_TESTS} test_sendmsg_recvmsg_fd test_echo_tcp_sendmsg_recvmsg_fd)
  83 endif (HAVE_STRUCT_MSGHDR_MSG_CONTROL)
  84
  85 function(ADD_CMOCKA_TEST_ENVIRONMENT _TEST_NAME)
  86     if (CMAKE_BUILD_TYPE)
  87         string(TOLOWER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_LOWER)
  88         if (CMAKE_BUILD_TYPE_LOWER STREQUAL "addresssanitizer")
  89             find_library(ASAN_LIBRARY
  90                          NAMES asan)
  91             if (NOT ASAN_LIBRARY)
  92                 foreach(version RANGE 10 1)
  93                     if (NOT ASAN_LIBRARY)
  94                         find_library(ASAN_LIBRARY libasan.so.${version})
  95                     endif()
  96                 endforeach()
  97             endif()
  98         endif()
  99     endif()
 100
 101     if (ASAN_LIBRARY)
 102         list(APPEND PRELOAD_LIBRARIES ${ASAN_LIBRARY})
 103     endif()
 104     list(APPEND PRELOAD_LIBRARIES ${SWRAP_FAKE_UID_WRAPPER_LOCATION})
 105     list(APPEND PRELOAD_LIBRARIES ${SOCKET_WRAPPER_LOCATION})
 106
 107     if (OSX)
 108         set(TORTURE_ENVIRONMENT "DYLD_FORCE_FLAT_NAMESPACE=1;DYLD_INSERT_LIBRARIES=${SOCKET_WRAPPER_LOCATION}")
 109     else ()
 110         string(REPLACE ";" ":" _TMP_ENV "${PRELOAD_LIBRARIES}")
 111         set(TORTURE_ENVIRONMENT "LD_PRELOAD=${_TMP_ENV}")
 112     endif()
 113
 114     if (CMAKE_BUILD_TYPE)
 115         string(TOLOWER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_LOWER)
 116         if (CMAKE_BUILD_TYPE_LOWER STREQUAL "addresssanitizer" OR
 117             CMAKE_BUILD_TYPE_LOWER STREQUAL "threadsanitizer" OR
 118             CMAKE_BUILD_TYPE_LOWER STREQUAL "undefinedsanitizer")
 119             list(APPEND TORTURE_ENVIRONMENT "SOCKET_WRAPPER_DISABLE_DEEPBIND=1")
 120         endif()
 121     endif()
 122
 123     set_property(TEST
 124                     ${_TEST_NAME}
 125                 PROPERTY
 126                     ENVIRONMENT "${TORTURE_ENVIRONMENT}")
 127 endfunction()
 128
 129 foreach(_SWRAP_TEST ${SWRAP_TESTS})
 130     add_cmocka_test(${_SWRAP_TEST}
 131                     SOURCES ${_SWRAP_TEST}.c
 132                     COMPILE_OPTIONS ${DEFAULT_C_COMPILE_FLAGS} -D_GNU_SOURCE
 133                     LINK_LIBRARIES ${TORTURE_LIBRARY} socket_wrapper_noop
 134                     LINK_OPTIONS ${DEFAULT_LINK_FLAGS})
 135     add_cmocka_test_environment(${_SWRAP_TEST})
 136 endforeach()
 137
 138 if (HELGRIND_TESTING)
 139     find_program(VALGRIND_EXECUTABLE valgrind)
 140     if (VALGRIND_EXECUTABLE)
 141         set(VALGRIND_HELGRIND_OPTIONS -v --trace-children=yes --tool=helgrind --error-exitcode=1 --read-var-info=yes --suppressions=${CMAKE_CURRENT_SOURCE_DIR}/helgrind.supp)
 142
 143         foreach(_TEST ${SWRAP_THREADED_TESTS})
 144             set(_HELGRIND_TEST "helgrind_${_TEST}")
 145
 146             add_test(NAME ${_HELGRIND_TEST} COMMAND ${VALGRIND_EXECUTABLE} ${VALGRIND_HELGRIND_OPTIONS} ${CMAKE_CURRENT_BINARY_DIR}/${_TEST})
 147             if (OSX)
 148                 set_property(
 149                     TEST
 150                         ${_HELGRIND_TEST}
 151                     PROPERTY
 152                         ENVIRONMENT DYLD_FORCE_FLAT_NAMESPACE=1;DYLD_INSERT_LIBRARIES=${SOCKET_WRAPPER_LOCATION})
 153             else ()
 154                 set_property(
 155                     TEST
 156                         ${_HELGRIND_TEST}
 157                     PROPERTY
 158                         ENVIRONMENT LD_PRELOAD=${SOCKET_WRAPPER_LOCATION} SOCKET_WRAPPER_DISABLE_DEEPBIND=1)
 159             endif()
 160         endforeach()
 161     endif()
 162 endif()
 163
 164 # test_fork_pthread
 165 add_library(thread_deadlock SHARED thread_deadlock.c)
 166 target_link_libraries(thread_deadlock ${CMAKE_THREAD_LIBS_INIT})
 167 target_compile_options(thread_deadlock PRIVATE ${DEFAULT_C_COMPILE_FLAGS})
 168
 169 add_cmocka_test(test_fork_thread_deadlock
 170                 SOURCES test_fork_thread_deadlock.c
 171                 COMPILE_OPTIONS ${DEFAULT_C_COMPILE_FLAGS} -D_GNU_SOURCE
 172                 LINK_LIBRARIES ${TORTURE_LIBRARY} thread_deadlock
 173                 LINK_OPTIONS ${DEFAULT_LINK_FLAGS})
 174 add_cmocka_test_environment(test_fork_thread_deadlock)