tests/CMakeLists.txt

   1 project(tests C)
   2
   3 include_directories(
   4   ${CMAKE_BINARY_DIR}
   5   ${CMAKE_CURRENT_SOURCE_DIR}
   6   ${CMAKE_SOURCE_DIR}/src
   7   ${CMOCKA_INCLUDE_DIR}
   8 )
   9
  10 set(TORTURE_LIBRARY torture)
  11
  12 # RFC862 echo server
  13 add_executable(echo_srv echo_srv.c)
  14 target_compile_options(echo_srv
  15                        PRIVATE
  16                            ${DEFAULT_C_COMPILE_FLAGS}
  17                            -D_GNU_SOURCE)
  18 target_link_libraries(echo_srv ${SWRAP_REQUIRED_LIBRARIES})
  19 if (DEFINED DEFAULT_LINK_FLAGS)
  20     set_target_properties(echo_srv
  21                           PROPERTIES
  22                               LINK_FLAGS ${DEFAULT_LINK_FLAGS})
  23 endif()
  24
  25 add_library(${TORTURE_LIBRARY} STATIC torture.c)
  26 target_compile_options(${TORTURE_LIBRARY}
  27                        PRIVATE
  28                            ${DEFAULT_C_COMPILE_FLAGS}
  29                            -D_GNU_SOURCE)
  30 target_link_libraries(${TORTURE_LIBRARY}
  31     ${CMOCKA_LIBRARY}
  32     ${SWRAP_REQUIRED_LIBRARIES}
  33     ${CMAKE_THREAD_LIBS_INIT})
  34
  35 set(SWRAP_THREADED_TESTS
  36     test_thread_sockets
  37     test_thread_echo_tcp_connect
  38     test_thread_echo_tcp_write_read
  39     test_thread_echo_tcp_sendmsg_recvmsg
  40     test_thread_echo_udp_send_recv)
  41
  42 set(SWRAP_TESTS
  43     test_ioctl
  44     test_tcp_listen
  45     test_tcp_dup2
  46     test_fcntl
  47     test_echo_tcp_connect
  48     test_echo_tcp_bind
  49     test_echo_tcp_socket_options
  50     test_echo_tcp_sendmsg_recvmsg
  51     test_echo_tcp_write_read
  52     test_echo_tcp_writev_readv
  53     test_echo_tcp_get_peer_sock_name
  54     test_echo_udp_sendto_recvfrom
  55     test_echo_udp_send_recv
  56     test_echo_udp_sendmsg_recvmsg
  57     test_swrap_unit
  58     test_max_sockets
  59     test_close_failure
  60     test_tcp_socket_overwrite
  61     ${SWRAP_THREADED_TESTS})
  62
  63 if (HAVE_STRUCT_MSGHDR_MSG_CONTROL)
  64     set(SWRAP_TESTS ${SWRAP_TESTS} test_sendmsg_recvmsg_fd test_echo_tcp_sendmsg_recvmsg_fd)
  65 endif (HAVE_STRUCT_MSGHDR_MSG_CONTROL)
  66
  67 function(ADD_CMOCKA_TEST_ENVIRONMENT _TEST_NAME)
  68     if (CMAKE_BUILD_TYPE)
  69         string(TOLOWER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_LOWER)
  70         if (CMAKE_BUILD_TYPE_LOWER STREQUAL "addresssanitizer")
  71             find_library(ASAN_LIBRARY
  72                          NAMES asan)
  73             if (NOT ASAN_LIBRARY)
  74                 foreach(version RANGE 10 1)
  75                     if (NOT ASAN_LIBRARY)
  76                         find_library(ASAN_LIBRARY libasan.so.${version})
  77                     endif()
  78                 endforeach()
  79             endif()
  80         endif()
  81     endif()
  82
  83     if (ASAN_LIBRARY)
  84         list(APPEND PRELOAD_LIBRARIES ${ASAN_LIBRARY})
  85     endif()
  86     list(APPEND PRELOAD_LIBRARIES ${SOCKET_WRAPPER_LOCATION})
  87
  88     if (OSX)
  89         set(TORTURE_ENVIRONMENT "DYLD_FORCE_FLAT_NAMESPACE=1;DYLD_INSERT_LIBRARIES=${SOCKET_WRAPPER_LOCATION}")
  90     else ()
  91         string(REPLACE ";" ":" _TMP_ENV "${PRELOAD_LIBRARIES}")
  92         set(TORTURE_ENVIRONMENT "LD_PRELOAD=${_TMP_ENV}")
  93     endif()
  94
  95     if (CMAKE_BUILD_TYPE)
  96         string(TOLOWER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_LOWER)
  97         if (CMAKE_BUILD_TYPE_LOWER STREQUAL "addresssanitizer" OR
  98             CMAKE_BUILD_TYPE_LOWER STREQUAL "threadsanitizer" OR
  99             CMAKE_BUILD_TYPE_LOWER STREQUAL "undefinedsanitizer")
 100             list(APPEND TORTURE_ENVIRONMENT "SOCKET_WRAPPER_DISABLE_DEEPBIND=1")
 101         endif()
 102     endif()
 103
 104     set_property(TEST
 105                     ${_TEST_NAME}
 106                 PROPERTY
 107                     ENVIRONMENT "${TORTURE_ENVIRONMENT}")
 108 endfunction()
 109
 110 foreach(_SWRAP_TEST ${SWRAP_TESTS})
 111     add_cmocka_test(${_SWRAP_TEST}
 112                     SOURCES ${_SWRAP_TEST}.c
 113                     COMPILE_OPTIONS ${DEFAULT_C_COMPILE_FLAGS} -D_GNU_SOURCE
 114                     LINK_LIBRARIES ${TORTURE_LIBRARY}
 115                     LINK_OPTIONS ${DEFAULT_LINK_FLAGS})
 116     add_cmocka_test_environment(${_SWRAP_TEST})
 117 endforeach()
 118
 119 if (HELGRIND_TESTING)
 120     find_program(VALGRIND_EXECUTABLE valgrind)
 121     if (VALGRIND_EXECUTABLE)
 122         set(VALGRIND_HELGRIND_OPTIONS -v --trace-children=yes --tool=helgrind --error-exitcode=1 --read-var-info=yes --suppressions=${CMAKE_CURRENT_SOURCE_DIR}/helgrind.supp)
 123
 124         foreach(_TEST ${SWRAP_THREADED_TESTS})
 125             set(_HELGRIND_TEST "helgrind_${_TEST}")
 126
 127             add_test(NAME ${_HELGRIND_TEST} COMMAND ${VALGRIND_EXECUTABLE} ${VALGRIND_HELGRIND_OPTIONS} ${CMAKE_CURRENT_BINARY_DIR}/${_TEST})
 128             if (OSX)
 129                 set_property(
 130                     TEST
 131                         ${_HELGRIND_TEST}
 132                     PROPERTY
 133                         ENVIRONMENT DYLD_FORCE_FLAT_NAMESPACE=1;DYLD_INSERT_LIBRARIES=${SOCKET_WRAPPER_LOCATION})
 134             else ()
 135                 set_property(
 136                     TEST
 137                         ${_HELGRIND_TEST}
 138                     PROPERTY
 139                         ENVIRONMENT LD_PRELOAD=${SOCKET_WRAPPER_LOCATION} SOCKET_WRAPPER_DISABLE_DEEPBIND=1)
 140             endif()
 141         endforeach()
 142     endif()
 143 endif()
 144
 145 # test_fork_pthread
 146 add_library(thread_deadlock SHARED thread_deadlock.c)
 147 target_link_libraries(thread_deadlock ${CMAKE_THREAD_LIBS_INIT})
 148 target_compile_options(thread_deadlock PRIVATE ${DEFAULT_C_COMPILE_FLAGS})
 149
 150 add_cmocka_test(test_fork_thread_deadlock
 151                 SOURCES test_fork_thread_deadlock.c
 152                 COMPILE_OPTIONS ${DEFAULT_C_COMPILE_FLAGS} -D_GNU_SOURCE
 153                 LINK_LIBRARIES ${TORTURE_LIBRARY} thread_deadlock
 154                 LINK_OPTIONS ${DEFAULT_LINK_FLAGS})
 155 add_cmocka_test_environment(test_fork_thread_deadlock)